Merge remote branch 'refs/remotes/origin/fruitiex/racefixes'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / nexball.qc
1 //EF_BRIGHTFIELD|EF_BRIGHTLIGHT|EF_DIMLIGHT|EF_BLUE|EF_RED|EF_FLAME
2 #define BALL_EFFECTMASK 1229
3 #define BALL_MINS '-16 -16 -16'  // The model is 24*24*24
4 #define BALL_MAXS '16 16 16'
5 #define BALL_ATTACHORG '3 0 16'
6 #define BALL_SPRITECOLOR '.91 .85 .62'
7 #define BALL_FOOT   1
8 #define BALL_BASKET 2
9 //spawnflags
10 #define GOAL_TOUCHPLAYER 1
11 //goal types
12 #define GOAL_FAULT -1
13 #define GOAL_OUT -2
14
15 #define CVTOV(s) s = cvar( #s )
16
17 float g_nexball_football_boost_forward;
18 float g_nexball_football_boost_up;
19 float g_nexball_football_physics;
20 float g_nexball_delay_idle;
21 float g_nexball_basketball_delay_hold;
22 float g_nexball_basketball_delay_hold_forteam;
23 float g_nexball_basketball_effects_default;
24 float g_nexball_basketball_teamsteal;
25 float balls;
26 float ball_scale;
27 float nb_teams;
28
29 .float teamtime;
30
31 void nb_delayedinit();
32 void nb_init() // Called early (worldspawn stage)
33 {
34         CVTOV(g_nexball_meter_period); //sent with the client init entity
35         if (g_nexball_meter_period <= 0)
36                 g_nexball_meter_period = 2; // avoid division by zero etc. due to silly users
37         g_nexball_meter_period = rint(g_nexball_meter_period * 32) / 32; //Round to 1/32ths to send as a byte multiplied by 32
38         addstat(STAT_NB_METERSTART, AS_FLOAT, metertime);
39
40         // General settings
41         CVTOV(g_nexball_football_boost_forward);   //100
42         CVTOV(g_nexball_football_boost_up);        //200
43         CVTOV(g_nexball_delay_idle);               //10
44         CVTOV(g_nexball_football_physics);         //0
45
46         radar_showennemies = cvar("g_nexball_radar_showallplayers");
47
48         InitializeEntity(world, nb_delayedinit, INITPRIO_GAMETYPE);
49 }
50
51 float OtherTeam(float t)  //works only if there are two teams on the map!
52 {
53         entity e;
54         e = find(world, classname, "nexball_team");
55         if (e.team == t)
56                 e = find(e, classname, "nexball_team");
57         return e.team;
58 }
59
60 void ResetBall();
61
62 void LogNB(string mode, entity actor)
63 {
64         string s;
65         if(!cvar("sv_eventlog"))
66                 return;
67         s = strcat(":nexball:", mode);
68         if(actor != world)
69                 s = strcat(s, ":", ftos(actor.playerid));
70         GameLogEcho(s);
71 }
72
73 void ball_restart (void)
74 {
75         if(self.owner)
76                 DropBall(self, self.owner.origin, '0 0 0');
77         ResetBall();
78 }
79
80 void nexball_setstatus (void)
81 {
82         local entity oldself;
83         if (!g_nexball)
84                 return;
85         if (self.ballcarried)
86         {
87                 if (self.ballcarried.teamtime && (self.ballcarried.teamtime < time))
88                 {
89                         bprint("The ", ColoredTeamName(self.team), " held the ball for too long.\n");
90                         oldself = self;
91                         self = self.ballcarried;
92                         DropBall(self, self.owner.origin, '0 0 0');
93                         ResetBall();
94                         self = oldself;
95                 } else
96                         self.items |= IT_KEY1;
97         }
98 }
99
100 void relocate_nexball (void)
101 {
102         tracebox(self.origin, BALL_MINS, BALL_MAXS, self.origin, TRUE, self);
103         if (trace_startsolid)
104         {
105                 vector o;
106                 o = self.origin;
107                 if(!move_out_of_solid(self))
108                         objerror("could not get out of solid at all!");
109                 print("^1NOTE: this map needs FIXING. ", self.classname, " at ", vtos(o - '0 0 1'));
110                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
111                 print(" ", ftos(self.origin_y - o_y));
112                 print(" ", ftos(self.origin_z - o_z), "'\n");
113                 self.origin = o;
114         }
115 }
116
117 void basketball_touch();
118 void football_touch();
119
120 void DropOwner (void)
121 {
122         local entity ownr;
123         ownr = self.owner;
124         DropBall(self, ownr.origin, ownr.velocity);
125         makevectors(ownr.v_angle_y * '0 1 0');
126         ownr.velocity += ('0 0 0.75' - v_forward) * 1000;
127         ownr.flags &~= FL_ONGROUND;
128 }
129
130 void GiveBall (entity plyr, entity ball)
131 {
132         local entity ownr;
133
134         if ((ownr = ball.owner))
135         {
136                 ownr.effects &~= g_nexball_basketball_effects_default;
137                 ownr.ballcarried = world;
138                 if (ownr.metertime)
139                 {
140                         ownr.metertime = 0;
141                         ownr.weaponentity.state = WS_READY;
142                 }
143                 WaypointSprite_Kill(ownr.waypointsprite_attachedforcarrier);
144         }
145         else
146         {
147                 WaypointSprite_Kill(ball.waypointsprite_attachedforcarrier);
148         }
149
150         setattachment(ball, plyr, "");
151         setorigin(ball, BALL_ATTACHORG);
152
153         if (ball.team != plyr.team)
154                 ball.teamtime = time + g_nexball_basketball_delay_hold_forteam;
155
156         ball.owner = ball.pusher = plyr; //"owner" is set to the player carrying, "pusher" to the last player who touched it
157         ball.team = plyr.team;
158         plyr.ballcarried = ball;
159         ball.dropperid = plyr.playerid;
160
161         plyr.effects |= g_nexball_basketball_effects_default;
162         ball.effects &~= g_nexball_basketball_effects_default;
163
164         ball.velocity = '0 0 0';
165         ball.movetype = MOVETYPE_NONE;
166         ball.touch = SUB_Null;
167         ball.effects |= EF_NOSHADOW;
168         ball.scale = 1; // scale down.
169
170         WaypointSprite_AttachCarrier("nb-ball", plyr);
171         WaypointSprite_UpdateRule(plyr.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
172         WaypointSprite_UpdateTeamRadar(plyr.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
173
174         if (g_nexball_basketball_delay_hold)
175         {
176                 ball.think = DropOwner;
177                 ball.nextthink = time + g_nexball_basketball_delay_hold;
178         }
179 }
180
181 void DropBall (entity ball, vector org, vector vel)
182 {
183         ball.effects |= g_nexball_basketball_effects_default;
184         ball.effects &~= EF_NOSHADOW;
185         ball.owner.effects &~= g_nexball_basketball_effects_default;
186
187         setattachment(ball, world, "");
188         setorigin (ball, org);
189         ball.movetype = MOVETYPE_BOUNCE;
190         ball.flags &~= FL_ONGROUND;
191         ball.scale = ball_scale;
192         ball.velocity = vel;
193         ball.ctf_droptime = time;
194         ball.touch = basketball_touch;
195         ball.think = ResetBall;
196         ball.nextthink = min(time + g_nexball_delay_idle, ball.teamtime);
197
198         if (ball.owner.metertime)
199         {
200                 ball.owner.metertime = 0;
201                 ball.owner.weaponentity.state = WS_READY;
202         }
203
204         WaypointSprite_Kill(ball.owner.waypointsprite_attachedforcarrier);
205         WaypointSprite_AttachCarrier("nb-ball", ball);
206         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
207         WaypointSprite_UpdateTeamRadar(ball.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
208
209         ball.owner.ballcarried = world;
210         ball.owner = world;
211 }
212
213 void InitBall (void)
214 {
215         if (gameover) return;
216         self.flags &~= FL_ONGROUND;
217         self.movetype = MOVETYPE_BOUNCE;
218         if (self.classname == "nexball_basketball")
219                 self.touch = basketball_touch;
220         else if (self.classname == "nexball_football")
221                 self.touch = football_touch;
222         self.cnt = 0;
223         self.think = ResetBall;
224         self.nextthink = time + g_nexball_delay_idle + 3;
225         self.teamtime = 0;
226         self.pusher = world;
227         self.team = FALSE;
228         sound (self, CHAN_PROJECTILE, self.noise1, VOL_BASE, ATTN_NORM);
229         WaypointSprite_Ping(self.waypointsprite_attachedforcarrier);
230         LogNB("init", world);
231 }
232
233 void ResetBall (void)
234 {
235         if (self.cnt < 2) { // step 1
236                 if (time == self.teamtime)
237                         bprint("The ", ColoredTeamName(self.team), " held the ball for too long.\n");
238                 self.touch = SUB_Null;
239                 self.movetype = MOVETYPE_NOCLIP;
240                 self.velocity = '0 0 0'; // just in case?
241                 if(!self.cnt)
242                         LogNB("resetidle", world);
243                 self.cnt = 2;
244                 self.nextthink = time;
245         } else if (self.cnt < 4) { // step 2 and 3
246 //              dprint("Step ", ftos(self.cnt), ": Calculated velocity: ", vtos(self.spawnorigin - self.origin), ", time: ", ftos(time), "\n");
247                 self.velocity = (self.spawnorigin - self.origin) * (self.cnt - 1); // 1 or 0.5 second movement
248                 self.nextthink = time + 0.5;
249                 self.cnt += 1;
250         } else { // step 4
251 //              dprint("Step 4: time: ", ftos(time), "\n");
252                 if (vlen(self.origin - self.spawnorigin) > 10) // should not happen anymore
253                         dprint("The ball moved too far away from its spawn origin.\nOffset: ",
254                                vtos(self.origin - self.spawnorigin), " Velocity: ", vtos(self.velocity), "\n");
255                 self.velocity = '0 0 0';
256                 setorigin(self, self.spawnorigin); // make sure it's positioned correctly anyway
257                 self.movetype = MOVETYPE_NONE;
258                 self.think = InitBall;
259                 self.nextthink = max(time, game_starttime) + cvar("g_nexball_delay_start");
260         }
261 }
262
263 void football_touch (void)
264 {
265         if (other.solid == SOLID_BSP) {
266                 if (time > self.lastground + 0.1)
267                 {
268                         sound (self, CHAN_PROJECTILE, self.noise, VOL_BASE, ATTN_NORM);
269                         self.lastground = time;
270                 }
271                 if (vlen(self.velocity) && !self.cnt)
272                         self.nextthink = time + g_nexball_delay_idle;
273                 return;
274         }
275         if (other.classname != "player")
276                 return;
277         if (other.health < 1)
278                 return;
279         if (!self.cnt)
280                 self.nextthink = time + g_nexball_delay_idle;
281
282         self.pusher = other;
283         self.team = other.team;
284
285         if (g_nexball_football_physics == -1) { // MrBougo try 1, before decompiling Rev's original
286                 if (vlen(other.velocity))
287                         self.velocity = other.velocity * 1.5 + '0 0 1' * g_nexball_football_boost_up;
288         } else if (g_nexball_football_physics == 1) { // MrBougo's modded Rev style: partially independant of the height of the aiming point
289                 makevectors(other.v_angle);
290                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + '0 0 1' * g_nexball_football_boost_up;
291         } else if (g_nexball_football_physics == 2) { // 2nd mod try: totally independant. Really playable!
292                 makevectors(other.v_angle_y * '0 1 0');
293                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + v_up * g_nexball_football_boost_up;
294         } else { // Revenant's original style (from the original mod's disassembly, acknowledged by Revenant)
295                 makevectors(other.v_angle);
296                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + v_up * g_nexball_football_boost_up;
297         }
298         self.avelocity = -250 * v_forward;  // maybe there is a way to make it look better?
299 }
300
301 void basketball_touch (void)
302 {
303         if (other.ballcarried)
304         {
305                 football_touch();
306                 return;
307         }
308         if (!self.cnt && other.classname == "player" && (other.playerid != self.dropperid || time > self.ctf_droptime + cvar("g_nexball_delay_collect"))) {
309                 if (other.health <= 0)
310                         return;
311                 LogNB("caught", other);
312                 GiveBall(other, self);
313         } else if (other.solid == SOLID_BSP) {
314                 sound (self, CHAN_PROJECTILE, self.noise, VOL_BASE, ATTN_NORM);
315                 if (vlen(self.velocity) && !self.cnt)
316                         self.nextthink = min(time + g_nexball_delay_idle, self.teamtime);
317         }
318 }
319
320 void GoalTouch (void)
321 {
322         entity ball;
323         float isclient, pscore, otherteam;
324         string pname;
325
326         if (gameover) return;
327         if ((self.spawnflags & GOAL_TOUCHPLAYER) && other.ballcarried)
328                 ball = other.ballcarried;
329         else
330                 ball = other;
331         if (ball.classname != "nexball_basketball")
332         if (ball.classname != "nexball_football")
333                 return;
334         if ((!ball.pusher && self.team != GOAL_OUT) || ball.cnt)
335                 return;
336         EXACTTRIGGER_TOUCH;
337
338
339         if(nb_teams == 2)
340                 otherteam = OtherTeam(ball.team);
341
342         if((isclient = ball.pusher.flags & FL_CLIENT))
343                 pname = ball.pusher.netname;
344         else
345                 pname = "Someone (?)";
346
347         if        (ball.team == self.team) //owngoal (regular goals)
348         {
349                 LogNB("owngoal", ball.pusher);
350                 bprint("Boo! ", pname, "^7 scored a goal against their own team!\n");
351                 pscore = -1;
352         } else if (self.team == GOAL_FAULT) {
353                 LogNB("fault", ball.pusher);
354                 if (nb_teams == 2)
355                         bprint(ColoredTeamName(otherteam), " gets a point due to ", pname, "^7's silliness.\n");
356                 else
357                         bprint(ColoredTeamName(ball.team), " loses a point due to ", pname, "^7's silliness.\n");
358                 pscore = -1;
359         } else if (self.team == GOAL_OUT) {
360                 LogNB("out", ball.pusher);
361                 if ((self.spawnflags & GOAL_TOUCHPLAYER) && ball.owner)
362                         bprint(pname, "^7 went out of bounds.\n");
363                 else
364                         bprint("The ball was returned.\n");
365                 pscore = 0;
366         } else {                           //score
367                 LogNB(strcat("goal:", ftos(self.team)), ball.pusher);
368                 bprint("Goaaaaal! ", pname, "^7 scored a point for the ", ColoredTeamName(ball.team), ".\n");
369                 pscore = 1;
370         }
371
372         sound (ball, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
373
374         if(ball.team && pscore)
375         {
376                 if (nb_teams == 2 && pscore < 0)
377                         TeamScore_AddToTeam(otherteam, ST_NEXBALL_GOALS, -pscore);
378                 else
379                         TeamScore_AddToTeam(ball.team, ST_NEXBALL_GOALS, pscore);
380         }
381         if (isclient)
382         {
383                 if (pscore > 0)
384                         PlayerScore_Add(ball.pusher, SP_NEXBALL_GOALS, pscore);
385                 else if (pscore < 0)
386                         PlayerScore_Add(ball.pusher, SP_NEXBALL_FAULTS, -pscore);
387         }
388
389         if (ball.owner) // Happens on spawnflag GOAL_TOUCHPLAYER
390                 DropBall(ball, ball.owner.origin, ball.owner.velocity);
391
392         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
393
394         ball.cnt = 1;
395         ball.think = ResetBall;
396         if (ball.classname == "nexball_basketball")
397                 ball.touch = football_touch; // better than SUB_Null: football control until the ball gets reset
398         ball.nextthink = time + cvar("g_nexball_delay_goal") * (self.team != GOAL_OUT);
399 }
400
401 //=======================//
402 //       team ents       //
403 //=======================//
404 void spawnfunc_nexball_team (void)
405 {
406         if(!g_nexball) { remove(self); return; }
407         self.team = self.cnt + 1;
408 }
409
410 void nb_spawnteam (string teamname, float teamcolor)
411 {
412         dprint("^2spawned team ", teamname, "\n");
413         local entity e;
414         e = spawn();
415         e.classname = "nexball_team";
416         e.netname = teamname;
417         e.cnt = teamcolor;
418         e.team = e.cnt + 1;
419         nb_teams += 1;
420 };
421
422 void nb_spawnteams (void)
423 {
424         float t_r, t_b, t_y, t_p;
425         entity e;
426         for(e = world; (e = find(e, classname, "nexball_goal")); )
427         {
428                 switch(e.team)
429                 {
430                         case COLOR_TEAM1: if(!t_r) { nb_spawnteam ("Red", e.team-1)   ; t_r = 1; } break;
431                         case COLOR_TEAM2: if(!t_b) { nb_spawnteam ("Blue", e.team-1)  ; t_b = 1; } break;
432                         case COLOR_TEAM3: if(!t_y) { nb_spawnteam ("Yellow", e.team-1); t_y = 1; } break;
433                         case COLOR_TEAM4: if(!t_p) { nb_spawnteam ("Pink", e.team-1)  ; t_p = 1; } break;
434                 }
435         }
436 }
437
438 void nb_delayedinit (void)
439 {
440         if (find(world, classname, "nexball_team") == world)
441                 nb_spawnteams();
442         ScoreRules_nexball(nb_teams);
443 }
444
445
446 //=======================//
447 //      spawnfuncs       //
448 //=======================//
449
450 void SpawnBall (void)
451 {
452         if(!g_nexball) { remove(self); return; }
453
454 //      balls += 4; // using the remaining bits to count balls will leave more than the max edict count, so it's fine
455
456         if (!self.model) {
457                 self.model = "models/nexball/ball.md3";
458                 self.scale = 1.3;
459         }
460
461         precache_model (self.model);
462         setmodel (self, self.model);
463         setsize (self, BALL_MINS, BALL_MAXS);
464         ball_scale = self.scale;
465
466         relocate_nexball();
467         self.spawnorigin = self.origin;
468
469         self.effects = self.effects | EF_LOWPRECISION;
470
471         if (cvar(strcat("g_", self.classname, "_trail"))) //nexball_basketball :p
472         {
473                 self.glow_color = cvar("g_nexball_trail_color");
474                 self.glow_trail = TRUE;
475         }
476
477         self.movetype = MOVETYPE_FLY;
478
479         if (!cvar("g_nexball_sound_bounce"))
480                 self.noise = "";
481         else if (!self.noise)
482                 self.noise = "sound/nexball/bounce.wav";
483                 //bounce sound placeholder (FIXME)
484         if (!self.noise1)
485                 self.noise1 = "sound/nexball/drop.wav";
486                 //ball drop sound placeholder (FIXME)
487         if (!self.noise2)
488                 self.noise2 = "sound/nexball/steal.wav";
489                 //stealing sound placeholder (FIXME)
490         if (self.noise) precache_sound (self.noise);
491         precache_sound (self.noise1);
492         precache_sound (self.noise2);
493
494         WaypointSprite_AttachCarrier("nb-ball", self); // the ball's team is not set yet, no rule update needed
495         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
496
497         self.reset = ball_restart;
498         self.think = InitBall;
499         self.nextthink = game_starttime + cvar("g_nexball_delay_start");
500 }
501
502 void spawnfunc_nexball_basketball (void)
503 {
504         self.classname = "nexball_basketball";
505         if not(balls & BALL_BASKET)
506         {
507                 CVTOV(g_nexball_basketball_effects_default);
508                 CVTOV(g_nexball_basketball_delay_hold);
509                 CVTOV(g_nexball_basketball_delay_hold_forteam);
510                 CVTOV(g_nexball_basketball_teamsteal);
511                 g_nexball_basketball_effects_default = g_nexball_basketball_effects_default & BALL_EFFECTMASK;
512         }
513         if (!self.effects)
514                 self.effects = g_nexball_basketball_effects_default;
515         self.solid = SOLID_TRIGGER;
516         balls |= BALL_BASKET;
517         self.bouncefactor = cvar("g_nexball_basketball_bouncefactor");
518         self.bouncestop = cvar("g_nexball_basketball_bouncestop");
519         SpawnBall();
520 }
521
522 void spawnfunc_nexball_football (void)
523 {
524         self.classname = "nexball_football";
525         self.solid = SOLID_TRIGGER;
526         balls |= BALL_FOOT;
527         self.bouncefactor = cvar("g_nexball_football_bouncefactor");
528         self.bouncestop = cvar("g_nexball_football_bouncestop");
529         SpawnBall();
530 }
531
532 void SpawnGoal (void)
533 {
534         if(!g_nexball) { remove(self); return; }
535         EXACTTRIGGER_INIT;
536         self.classname = "nexball_goal";
537         if (!self.noise)
538                 self.noise = "ctf/respawn.wav";
539         precache_sound(self.noise);
540         self.touch = GoalTouch;
541 }
542
543 void spawnfunc_nexball_redgoal (void)
544 {
545         self.team = COLOR_TEAM1;
546         SpawnGoal();
547 }
548 void spawnfunc_nexball_bluegoal (void)
549 {
550         self.team = COLOR_TEAM2;
551         SpawnGoal();
552 }
553 void spawnfunc_nexball_yellowgoal (void)
554 {
555         self.team = COLOR_TEAM3;
556         SpawnGoal();
557 }
558 void spawnfunc_nexball_pinkgoal (void)
559 {
560         self.team = COLOR_TEAM4;
561         SpawnGoal();
562 }
563
564 void spawnfunc_nexball_fault (void)
565 {
566         self.team = GOAL_FAULT;
567         if (!self.noise)
568                 self.noise = "misc/typehit.wav";
569         SpawnGoal();
570 }
571
572 void spawnfunc_nexball_out (void)
573 {
574         self.team = GOAL_OUT;
575         if (!self.noise)
576                 self.noise = "misc/typehit.wav";
577         SpawnGoal();
578 }
579
580 //
581 //Spawnfuncs preserved for compatibility
582 //
583
584 void spawnfunc_ball            (void) { spawnfunc_nexball_football(); }
585 void spawnfunc_ball_football   (void) { spawnfunc_nexball_football(); }
586 void spawnfunc_ball_basketball (void) { spawnfunc_nexball_basketball(); }
587 // The "red goal" is defended by blue team. A ball in there counts as a point for red.
588 void spawnfunc_ball_redgoal    (void) { spawnfunc_nexball_bluegoal(); } // I blame Revenant
589 void spawnfunc_ball_bluegoal   (void) { spawnfunc_nexball_redgoal(); }  // but he didn't mean to cause trouble :p
590 void spawnfunc_ball_fault      (void) { spawnfunc_nexball_fault(); }
591 void spawnfunc_ball_bound      (void) { spawnfunc_nexball_out(); }
592
593 //=======================//
594 //      Weapon code      //
595 //=======================//
596
597 void W_Nexball_Touch (void)
598 {
599         local entity ball, attacker;
600         attacker = self.owner;
601
602         PROJECTILE_TOUCH;
603         if(attacker.team != other.team || g_nexball_basketball_teamsteal)
604         if((ball = other.ballcarried) && (attacker.classname == "player" || attacker.classname == "gib"))
605         {
606                 other.velocity = other.velocity + normalize(self.velocity) * other.damageforcescale * cvar("g_balance_nexball_secondary_force");
607                 other.flags &~= FL_ONGROUND;
608                 if(!attacker.ballcarried)
609                 {
610                         LogNB("stole", attacker);
611                         sound (other, CHAN_AUTO, ball.noise2, VOL_BASE, ATTN_NORM);
612
613                         if(attacker.team == other.team && time > attacker.teamkill_complain)
614                         {
615                                 attacker.teamkill_complain = time + 5;
616                                 attacker.teamkill_soundtime = time + 0.4;
617                                 attacker.teamkill_soundsource = other;
618                         }
619
620                         GiveBall(attacker, other.ballcarried);
621                 }
622         }
623         remove(self);
624 }
625
626 void W_Nexball_Attack (float t)
627 {
628         local entity ball;
629         local float mul, mi, ma;
630         if (!(ball = self.ballcarried))
631                 return;
632
633         W_SetupShot (self, FALSE, 4, "nexball/shoot1.wav",0);
634         tracebox(w_shotorg, BALL_MINS, BALL_MAXS, w_shotorg, MOVE_WORLDONLY, world);
635         if(trace_startsolid)
636         {
637                 if(self.metertime)
638                         self.metertime = 0; // Shot failed, hide the power meter
639                 return;
640         }
641
642         //Calculate multiplier
643         if (t < 0)
644                 mul = 1;
645         else
646         {
647                 mi = cvar("g_nexball_basketball_meter_minpower");
648                 ma = max(mi, cvar("g_nexball_basketball_meter_maxpower")); // avoid confusion
649                 //One triangle wave period with 1 as max
650                 mul = 2 * mod(t, g_nexball_meter_period) / g_nexball_meter_period;
651                 if (mul > 1)
652                         mul = 2 - mul;
653                 mul = mi + (ma - mi) * mul; // range from the minimal power to the maximal power
654         }
655         DropBall (ball, w_shotorg, W_CalculateProjectileVelocity(self.velocity, w_shotdir * cvar("g_balance_nexball_primary_speed") * mul));
656         //TODO: use the speed_up cvar too ??
657 }
658
659 void W_Nexball_Attack2 (void)
660 {
661         local entity missile;
662         if (!(balls & BALL_BASKET))
663                 return;
664         W_SetupShot (self, FALSE, 2, "nexball/shoot2.wav",0);
665 //      pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
666         missile = spawn ();
667
668         missile.owner = self;
669         missile.classname = "ballstealer";
670
671         missile.movetype = MOVETYPE_FLY;
672         PROJECTILE_MAKETRIGGER(missile);
673
674         setmodel (missile, "models/elaser.mdl"); // precision set below
675         setsize (missile, '0 0 0', '0 0 0');
676         setorigin (missile, w_shotorg);
677
678         W_SetupProjectileVelocity(missile, cvar("g_balance_nexball_secondary_speed"), 0);
679         missile.angles = vectoangles (missile.velocity);
680         missile.touch = W_Nexball_Touch;
681         missile.think = SUB_Remove;
682         missile.nextthink = time + cvar("g_balance_nexball_secondary_lifetime"); //FIXME: use a distance instead?
683
684         missile.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
685         missile.flags = FL_PROJECTILE;
686 }
687
688 float w_nexball_weapon(float req)
689 {
690         if (req == WR_THINK)
691         {
692                 if (self.BUTTON_ATCK)
693                 if (weapon_prepareattack(0, cvar("g_balance_nexball_primary_refire")))
694                 if (cvar("g_nexball_basketball_meter"))
695                 {
696                         if (self.ballcarried && !self.metertime)
697                                 self.metertime = time;
698                         else
699                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nexball_primary_animtime"), w_ready);
700                 }
701                 else
702                 {
703                         W_Nexball_Attack(-1);
704                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nexball_primary_animtime"), w_ready);
705                 }
706                 if (self.BUTTON_ATCK2)
707                 if (weapon_prepareattack(1, cvar("g_balance_nexball_secondary_refire")))
708                 {
709                         W_Nexball_Attack2();
710                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_nexball_secondary_animtime"), w_ready);
711                 }
712
713                 if (!self.BUTTON_ATCK && self.metertime && self.ballcarried)
714                 {
715                         W_Nexball_Attack(time - self.metertime);
716                         // DropBall or stealing will set metertime back to 0
717                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nexball_primary_animtime"), w_ready);
718                 }
719         }
720         else if (req == WR_PRECACHE)
721         {
722                 precache_model ("models/weapons/g_porto.md3");
723                 precache_model ("models/weapons/v_porto.md3");
724                 precache_model ("models/weapons/h_porto.dpm");
725                 precache_model ("models/elaser.mdl");
726                 precache_sound ("nexball/shoot1.wav");
727                 precache_sound ("nexball/shoot2.wav");
728         }
729         else if (req == WR_SETUP)
730                 weapon_setup(WEP_PORTO);
731         else if (req == WR_SUICIDEMESSAGE)
732         {
733                 w_deathtypestring = "is a weirdo";
734         }
735         else if (req == WR_KILLMESSAGE)
736         {
737                 w_deathtypestring = "got killed by #'s black magic";
738         }
739         // No need to check WR_CHECKAMMO* or WR_AIM, it should always return TRUE
740         return TRUE;
741 }