qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27
  28 #include "weapons/weaponstats.qh"
  29
  30 #include "../common/animdecide.qh"
  31
  32 void Drop_Special_Items(entity player)
  33 {
  34         // called when the player has become stuck or frozen
  35         // so objective items aren't stuck with the player
  36
  37         MUTATOR_CALLHOOK(DropSpecialItems, player);
  38 }
  39
  40 void CopyBody_Think(entity this)
  41 {
  42         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  43         {
  44                 this.CopyBody_think(this);
  45                 if(wasfreed(this))
  46                         return;
  47                 this.CopyBody_nextthink = this.nextthink;
  48                 this.CopyBody_think = getthink(this);
  49                 setthink(this, CopyBody_Think);
  50         }
  51         CSQCMODEL_AUTOUPDATE(this);
  52         this.nextthink = time;
  53 }
  54 void CopyBody(entity this, float keepvelocity)
  55 {
  56         if (this.effects & EF_NODRAW)
  57                 return;
  58         entity clone = new(body);
  59         clone.enemy = this;
  60         clone.lip = this.lip;
  61         clone.colormap = this.colormap;
  62         clone.iscreature = this.iscreature;
  63         clone.teleportable = this.teleportable;
  64         clone.damagedbycontents = this.damagedbycontents;
  65         if(clone.damagedbycontents)
  66                 IL_PUSH(g_damagedbycontents, clone);
  67         clone.angles = this.angles;
  68         clone.v_angle = this.v_angle;
  69         clone.avelocity = this.avelocity;
  70         clone.damageforcescale = this.damageforcescale;
  71         clone.effects = this.effects;
  72         clone.glowmod = this.glowmod;
  73         clone.event_damage = this.event_damage;
  74         clone.anim_state = this.anim_state;
  75         clone.anim_time = this.anim_time;
  76         clone.anim_lower_action = this.anim_lower_action;
  77         clone.anim_lower_time = this.anim_lower_time;
  78         clone.anim_upper_action = this.anim_upper_action;
  79         clone.anim_upper_time = this.anim_upper_time;
  80         clone.anim_implicit_state = this.anim_implicit_state;
  81         clone.anim_implicit_time = this.anim_implicit_time;
  82         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  83         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  84         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  85         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  86         clone.dphitcontentsmask = this.dphitcontentsmask;
  87         clone.death_time = this.death_time;
  88         clone.pain_finished = this.pain_finished;
  89         clone.health = this.health;
  90         clone.armorvalue = this.armorvalue;
  91         clone.armortype = this.armortype;
  92         clone.model = this.model;
  93         clone.modelindex = this.modelindex;
  94         clone.skin = this.skin;
  95         clone.species = this.species;
  96         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  97         set_movetype(clone, this.move_movetype);
  98         clone.solid = this.solid;
  99         clone.ballistics_density = this.ballistics_density;
 100         clone.takedamage = this.takedamage;
 101         setcefc(clone, getcefc(this));
 102         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 103         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 104         if (keepvelocity == 1)
 105                 clone.velocity = this.velocity;
 106         clone.oldvelocity = clone.velocity;
 107         clone.alpha = this.alpha;
 108         clone.fade_time = this.fade_time;
 109         clone.fade_rate = this.fade_rate;
 110         //clone.weapon = this.weapon;
 111         setorigin(clone, this.origin);
 112         setsize(clone, this.mins, this.maxs);
 113         clone.prevorigin = this.origin;
 114         clone.reset = SUB_Remove;
 115         clone._ps = this._ps;
 116
 117         Drag_MoveDrag(this, clone);
 118
 119         if(clone.colormap <= maxclients && clone.colormap > 0)
 120                 clone.colormap = 1024 + this.clientcolors;
 121
 122         CSQCMODEL_AUTOINIT(clone);
 123         clone.CopyBody_nextthink = this.nextthink;
 124         clone.CopyBody_think = getthink(this);
 125         clone.nextthink = time;
 126         setthink(clone, CopyBody_Think);
 127         // "bake" the current animation frame for clones (they don't get clientside animation)
 128         animdecide_load_if_needed(clone);
 129         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 130
 131         IL_PUSH(g_clones, clone);
 132
 133         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 134 }
 135
 136 void player_setupanimsformodel(entity this)
 137 {
 138         // load animation info
 139         animdecide_load_if_needed(this);
 140         animdecide_setstate(this, 0, false);
 141 }
 142
 143 void player_anim(entity this)
 144 {
 145         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 146         if(IS_DEAD(this)) {
 147                 if (!deadbits) {
 148                         // Decide on which death animation to use.
 149                         if(random() < 0.5)
 150                                 deadbits = ANIMSTATE_DEAD1;
 151                         else
 152                                 deadbits = ANIMSTATE_DEAD2;
 153                 }
 154         } else {
 155                 // Clear a previous death animation.
 156                 deadbits = 0;
 157         }
 158         int animbits = deadbits;
 159         if(STAT(FROZEN, this))
 160                 animbits |= ANIMSTATE_FROZEN;
 161         if(this.move_movetype == MOVETYPE_FOLLOW)
 162                 animbits |= ANIMSTATE_FOLLOW;
 163         if(this.crouch)
 164                 animbits |= ANIMSTATE_DUCK;
 165         animdecide_setstate(this, animbits, false);
 166         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 167 }
 168
 169 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 170 {
 171         float take, save;
 172         vector v;
 173         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 174
 175         // damage resistance (ignore most of the damage from a bullet or similar)
 176         damage = max(damage - 5, 1);
 177
 178         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 179         take = v.x;
 180         save = v.y;
 181
 182         if(sound_allowed(MSG_BROADCAST, attacker))
 183         {
 184                 if (save > 10)
 185                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 186                 else if (take > 30)
 187                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 188                 else if (take > 10)
 189                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 190         }
 191
 192         if (take > 50)
 193                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 194         if (take > 100)
 195                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 196
 197         this.armorvalue = this.armorvalue - save;
 198         this.health = this.health - take;
 199         // pause regeneration for 5 seconds
 200         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 201
 202         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 203         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 204         this.dmg_inflictor = inflictor;
 205
 206         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 207         {
 208                 // don't use any animations as a gib
 209                 this.frame = 0;
 210                 // view just above the floor
 211                 this.view_ofs = '0 0 4';
 212
 213                 Violence_GibSplash(this, 1, 1, attacker);
 214                 this.alpha = -1;
 215                 this.solid = SOLID_NOT; // restore later
 216                 this.takedamage = DAMAGE_NO; // restore later
 217                 if(this.damagedbycontents)
 218                         IL_REMOVE(g_damagedbycontents, this);
 219                 this.damagedbycontents = false;
 220         }
 221 }
 222
 223 void calculate_player_respawn_time(entity this)
 224 {
 225         if(g_ca)
 226                 return;
 227
 228         float gametype_setting_tmp;
 229         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 230         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 231         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 232         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 233         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 234         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 235
 236         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 237         if (teamplay)
 238         {
 239                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 240                         if(it.team == this.team)
 241                                 ++pcount;
 242                 ));
 243                 if (sdelay_small_count == 0)
 244                         sdelay_small_count = 1;
 245                 if (sdelay_large_count == 0)
 246                         sdelay_large_count = 1;
 247         }
 248         else
 249         {
 250                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 251                         ++pcount;
 252                 ));
 253                 if (sdelay_small_count == 0)
 254                 {
 255                         if (g_cts)
 256                         {
 257                                 // Players play independently. No point in requiring enemies.
 258                                 sdelay_small_count = 1;
 259                         }
 260                         else
 261                         {
 262                                 // Players play AGAINST each other. Enemies required.
 263                                 sdelay_small_count = 2;
 264                         }
 265                 }
 266                 if (sdelay_large_count == 0)
 267                 {
 268                         if (g_cts)
 269                         {
 270                                 // Players play independently. No point in requiring enemies.
 271                                 sdelay_large_count = 1;
 272                         }
 273                         else
 274                         {
 275                                 // Players play AGAINST each other. Enemies required.
 276                                 sdelay_large_count = 2;
 277                         }
 278                 }
 279         }
 280
 281         float sdelay;
 282
 283         if (pcount <= sdelay_small_count)
 284                 sdelay = sdelay_small;
 285         else if (pcount >= sdelay_large_count)
 286                 sdelay = sdelay_large;
 287         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 288                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 289
 290         if(waves)
 291                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 292         else
 293                 this.respawn_time = time + sdelay;
 294
 295         if(sdelay < sdelay_max)
 296                 this.respawn_time_max = time + sdelay_max;
 297         else
 298                 this.respawn_time_max = this.respawn_time;
 299
 300         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 301                 this.respawn_countdown = 10; // first number to count down from is 10
 302         else
 303                 this.respawn_countdown = -1; // do not count down
 304
 305         if(autocvar_g_forced_respawn)
 306                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 307 }
 308
 309 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 310 {
 311         float take, save, dh, da;
 312         vector v;
 313         float valid_damage_for_weaponstats;
 314         float excess;
 315
 316         dh = max(this.health, 0);
 317         da = max(this.armorvalue, 0);
 318
 319         if(!DEATH_ISSPECIAL(deathtype))
 320         {
 321                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
 322                 if(this != attacker)
 323                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 324         }
 325
 326         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 327         {
 328                 // tuba causes blood to come out of the ears
 329                 vector ear1, ear2;
 330                 vector d;
 331                 float f;
 332                 ear1 = this.origin;
 333                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 334                 ear2 = ear1;
 335                 makevectors(this.angles);
 336                 ear1 += v_right * -10;
 337                 ear2 += v_right * +10;
 338                 d = inflictor.origin - this.origin;
 339                 if (d)
 340                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 341                 else
 342                         f = 0;  // Assum ecenter.
 343                 force = v_right * vlen(force);
 344                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 345                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 346                 if(f > 0)
 347                 {
 348                         hitloc = ear1;
 349                         force = force * -1;
 350                 }
 351                 else
 352                 {
 353                         hitloc = ear2;
 354                         // force is already good
 355                 }
 356         }
 357         else
 358                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 359
 360
 361         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 362         take = v.x;
 363         save = v.y;
 364
 365         if(attacker == this)
 366         {
 367                 // don't reset pushltime for this damage as it may be an attempt to
 368                 // escape a lava pit or similar
 369                 //this.pushltime = 0;
 370                 this.istypefrag = 0;
 371         }
 372         else if(IS_PLAYER(attacker))
 373         {
 374                 this.pusher = attacker;
 375                 this.pushltime = time + autocvar_g_maxpushtime;
 376                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 377         }
 378         else if(time < this.pushltime)
 379         {
 380                 attacker = this.pusher;
 381                 this.pushltime = max(this.pushltime, time + 0.6);
 382         }
 383         else
 384         {
 385                 this.pushltime = 0;
 386                 this.istypefrag = 0;
 387         }
 388
 389         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 390         {
 391                 vector v = healtharmor_applydamage(this.armorvalue, max(0, autocvar_g_spawnshield_blockdamage), deathtype, damage);
 392                 take = v.x;
 393                 save = v.y;
 394         }
 395
 396         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 397         take = bound(0, M_ARGV(4, float), this.health);
 398         save = bound(0, M_ARGV(5, float), this.armorvalue);
 399         excess = max(0, damage - take - save);
 400
 401         if(sound_allowed(MSG_BROADCAST, attacker))
 402         {
 403                 if (save > 10)
 404                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 405                 else if (take > 30)
 406                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 407                 else if (take > 10)
 408                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 409         }
 410
 411         if (take > 50)
 412                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 413         if (take > 100)
 414                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 415
 416         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 417         {
 418                 if (!(this.flags & FL_GODMODE))
 419                 {
 420                         this.armorvalue = this.armorvalue - save;
 421                         this.health = this.health - take;
 422                         // pause regeneration for 5 seconds
 423                         if(take)
 424                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 425
 426                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 427                         {
 428                                 this.pain_finished = time + 0.5;        //Supajoe
 429
 430                                 if(autocvar_sv_gentle < 1) {
 431                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 432                                         {
 433                                                 if (!this.animstate_override)
 434                                                 {
 435                                                         if (random() > 0.5)
 436                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 437                                                         else
 438                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 439                                                 }
 440                                         }
 441
 442                                         if(sound_allowed(MSG_BROADCAST, attacker))
 443                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
 444                                         if(this.health > 1)
 445                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 446                                         {
 447                                                 if(deathtype == DEATH_FALL.m_id)
 448                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 449                                                 else if(this.health > 75)
 450                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 451                                                 else if(this.health > 50)
 452                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 453                                                 else if(this.health > 25)
 454                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 455                                                 else
 456                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 457                                         }
 458                                 }
 459                         }
 460
 461                         // throw off bot aim temporarily
 462                         float shake;
 463                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 464                         {
 465                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 466                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 467                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 468                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 469                         }
 470                 }
 471                 else
 472                         this.max_armorvalue += (save + take);
 473         }
 474         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 475         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 476         this.dmg_inflictor = inflictor;
 477
 478         if (this != attacker) {
 479                 float realdmg = damage - excess;
 480                 if (IS_PLAYER(attacker)) {
 481                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 482                 }
 483                 if (IS_PLAYER(this)) {
 484                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 485                 }
 486         }
 487
 488         bool abot = (IS_BOT_CLIENT(attacker));
 489         bool vbot = (IS_BOT_CLIENT(this));
 490
 491         valid_damage_for_weaponstats = 0;
 492         Weapon awep = WEP_Null;
 493
 494         if(vbot || IS_REAL_CLIENT(this))
 495         if(abot || IS_REAL_CLIENT(attacker))
 496         if(attacker && this != attacker)
 497         if(DIFF_TEAM(this, attacker))
 498         {
 499                 if(DEATH_ISSPECIAL(deathtype))
 500                         awep = PS(attacker).m_weapon;
 501                 else
 502                         awep = DEATH_WEAPONOF(deathtype);
 503                 valid_damage_for_weaponstats = 1;
 504         }
 505
 506         dh = dh - max(this.health, 0);
 507         da = da - max(this.armorvalue, 0);
 508         if(valid_damage_for_weaponstats)
 509         {
 510                 WeaponStats_LogDamage(awep.m_id, abot, PS(this).m_weapon.m_id, vbot, dh + da);
 511         }
 512         if (damage)
 513         {
 514                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 515         }
 516
 517         if (this.health < 1)
 518         {
 519                 float defer_ClientKill_Now_TeamChange;
 520                 defer_ClientKill_Now_TeamChange = false;
 521
 522                 if(this.alivetime)
 523                 {
 524                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 525                         this.alivetime = 0;
 526                 }
 527
 528                 if(valid_damage_for_weaponstats)
 529                         WeaponStats_LogKill(awep.m_id, abot, PS(this).m_weapon.m_id, vbot);
 530
 531                 if(autocvar_sv_gentle < 1)
 532                 if(sound_allowed(MSG_BROADCAST, attacker))
 533                 {
 534                         if(deathtype == DEATH_DROWN.m_id)
 535                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 536                         else
 537                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 538                 }
 539
 540                 // get rid of kill indicator
 541                 if(this.killindicator)
 542                 {
 543                         delete(this.killindicator);
 544                         this.killindicator = NULL;
 545                         if(this.killindicator_teamchange)
 546                                 defer_ClientKill_Now_TeamChange = true;
 547
 548                         if(this.classname == "body")
 549                         if(deathtype == DEATH_KILL.m_id)
 550                         {
 551                                 // for the lemmings fans, a small harmless explosion
 552                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 553                         }
 554                 }
 555
 556                 // print an obituary message
 557                 if(this.classname != "body")
 558                         Obituary (attacker, inflictor, this, deathtype);
 559
 560         // increment frag counter for used weapon type
 561         Weapon w = DEATH_WEAPONOF(deathtype);
 562                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 563                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 564
 565                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 566                 excess = M_ARGV(4, float);
 567
 568                 Weapon wep = PS(this).m_weapon;
 569                 /*for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 570                 {
 571                         .entity weaponentity = weaponentities[slot];
 572                         wep.wr_playerdeath(wep, this, weaponentity);
 573                 }*/
 574                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 575                 wep.wr_playerdeath(wep, this, weaponentity);
 576
 577                 RemoveGrapplingHook(this);
 578
 579                 Portal_ClearAllLater(this);
 580
 581                 this.fixangle = true;
 582
 583                 if(defer_ClientKill_Now_TeamChange)
 584                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 585
 586                 // player could have been miraculously resuscitated ;)
 587                 // e.g. players in freezetag get frozen, they don't really die
 588                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 589                         return;
 590
 591                 // when we get here, player actually dies
 592
 593                 Unfreeze(this); // remove any icy remains
 594                 this.health = 0; // Unfreeze resets health, so we need to set it back
 595
 596                 // clear waypoints
 597                 WaypointSprite_PlayerDead(this);
 598                 // throw a weapon
 599                 SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, PS(this).m_switchweapon.m_id);
 600
 601                 // become fully visible
 602                 this.alpha = default_player_alpha;
 603                 // make the corpse upright (not tilted)
 604                 this.angles_x = 0;
 605                 this.angles_z = 0;
 606                 // don't spin
 607                 this.avelocity = '0 0 0';
 608                 // view from the floor
 609                 this.view_ofs = '0 0 -8';
 610                 // toss the corpse
 611                 set_movetype(this, MOVETYPE_TOSS);
 612                 // shootable corpse
 613                 this.solid = SOLID_CORPSE;
 614                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 615                 // don't stick to the floor
 616                 UNSET_ONGROUND(this);
 617                 // dying animation
 618                 this.deadflag = DEAD_DYING;
 619
 620                 // when to allow respawn
 621                 calculate_player_respawn_time(this);
 622
 623                 this.death_time = time;
 624                 if (random() < 0.5)
 625                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 626                 else
 627                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 628                 if (this.maxs.z > 5)
 629                 {
 630                         this.maxs_z = 5;
 631                         setsize(this, this.mins, this.maxs);
 632                 }
 633                 // set damage function to corpse damage
 634                 this.event_damage = PlayerCorpseDamage;
 635                 // call the corpse damage function just in case it wants to gib
 636                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 637
 638                 // set up to fade out later
 639                 SUB_SetFade (this, time + 6 + random (), 1);
 640                 // reset body think wrapper broken by SUB_SetFade
 641                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 642                         this.CopyBody_think = getthink(this);
 643                         this.CopyBody_nextthink = this.nextthink;
 644                         setthink(this, CopyBody_Think);
 645                         this.nextthink = time;
 646                 }
 647
 648                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 649                         // remove corpse
 650                         // clones don't run any animation code any more, so we must gib them when they die :(
 651                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 652                 }
 653
 654                 // reset fields the weapons may use just in case
 655                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 656                         it.wr_resetplayer(it, this);
 657                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 658                         {
 659                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 660                         }
 661                 ));
 662         }
 663 }
 664
 665 void MoveToTeam(entity client, int team_colour, int type)
 666 {
 667         int lockteams_backup = lockteams;  // backup any team lock
 668         lockteams = 0;  // disable locked teams
 669         TeamchangeFrags(client);  // move the players frags
 670         SetPlayerColors(client, team_colour - 1);  // set the players colour
 671         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 672         lockteams = lockteams_backup;  // restore the team lock
 673         LogTeamchange(client.playerid, client.team, type);
 674 }
 675
 676 /** print(), but only print if the server is not local */
 677 void dedicated_print(string input)
 678 {
 679         if (server_is_dedicated) print(input);
 680 }
 681
 682 /**
 683  * message "": do not say, just test flood control
 684  * return value:
 685  *   1 = accept
 686  *   0 = reject
 687  *  -1 = fake accept
 688  */
 689 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 690 {
 691         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 692         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 693
 694         msgin = formatmessage(source, msgin);
 695
 696     string colorstr;
 697         if (!IS_PLAYER(source))
 698                 colorstr = "^0"; // black for spectators
 699         else if(teamplay)
 700                 colorstr = Team_ColorCode(source.team);
 701         else
 702         {
 703                 colorstr = "";
 704                 teamsay = false;
 705         }
 706
 707         if(intermission_running)
 708                 teamsay = false;
 709
 710     if (!source) {
 711                 colorstr = "";
 712                 teamsay = false;
 713     }
 714
 715         if(msgin != "")
 716                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 717
 718         /*
 719          * using bprint solves this... me stupid
 720         // how can we prevent the message from appearing in a listen server?
 721         // for now, just give "say" back and only handle say_team
 722         if(!teamsay)
 723         {
 724                 clientcommand(source, strcat("say ", msgin));
 725                 return;
 726         }
 727         */
 728
 729     string namestr = "";
 730     if (source)
 731         namestr = autocvar_g_chat_teamcolors ? playername(source) : source.netname;
 732
 733     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 734
 735     string msgstr, cmsgstr;
 736     string privatemsgprefix = string_null;
 737     int privatemsgprefixlen = 0;
 738         if (msgin == "") {
 739         msgstr = cmsgstr = "";
 740         } else {
 741                 if(privatesay)
 742                 {
 743                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 744                         privatemsgprefixlen = strlen(msgstr);
 745                         msgstr = strcat(msgstr, msgin);
 746                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 747                         if(autocvar_g_chat_teamcolors)
 748                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 749                         else
 750                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 751                 }
 752                 else if(teamsay)
 753                 {
 754                         if(strstrofs(msgin, "/me", 0) >= 0)
 755                         {
 756                                 //msgin = strreplace("/me", "", msgin);
 757                                 //msgin = substring(msgin, 3, strlen(msgin));
 758                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 759                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 760                         }
 761                         else
 762                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 763                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 764                 }
 765                 else
 766                 {
 767                         if(strstrofs(msgin, "/me", 0) >= 0)
 768                         {
 769                                 //msgin = strreplace("/me", "", msgin);
 770                                 //msgin = substring(msgin, 3, strlen(msgin));
 771                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 772                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 773                         }
 774                         else {
 775                 msgstr = "\{1}";
 776                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 777                 msgstr = strcat(msgstr, msgin);
 778             }
 779                         cmsgstr = "";
 780                 }
 781                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 782         }
 783
 784         string fullmsgstr = msgstr;
 785         string fullcmsgstr = cmsgstr;
 786
 787         // FLOOD CONTROL
 788         int flood = 0;
 789         var .float flood_field = floodcontrol_chat;
 790         if(floodcontrol)
 791         {
 792                 float flood_spl;
 793                 float flood_burst;
 794                 float flood_lmax;
 795                 float lines;
 796                 if(privatesay)
 797                 {
 798                         flood_spl = autocvar_g_chat_flood_spl_tell;
 799                         flood_burst = autocvar_g_chat_flood_burst_tell;
 800                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 801                         flood_field = floodcontrol_chattell;
 802                 }
 803                 else if(teamsay)
 804                 {
 805                         flood_spl = autocvar_g_chat_flood_spl_team;
 806                         flood_burst = autocvar_g_chat_flood_burst_team;
 807                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 808                         flood_field = floodcontrol_chatteam;
 809                 }
 810                 else
 811                 {
 812                         flood_spl = autocvar_g_chat_flood_spl;
 813                         flood_burst = autocvar_g_chat_flood_burst;
 814                         flood_lmax = autocvar_g_chat_flood_lmax;
 815                         flood_field = floodcontrol_chat;
 816                 }
 817                 flood_burst = max(0, flood_burst - 1);
 818                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 819
 820                 // do flood control for the default line size
 821                 if(msgstr != "")
 822                 {
 823                         getWrappedLine_remaining = msgstr;
 824                         msgstr = "";
 825                         lines = 0;
 826                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 827                         {
 828                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 829                                 ++lines;
 830                         }
 831                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 832
 833                         if(getWrappedLine_remaining != "")
 834                         {
 835                                 msgstr = strcat(msgstr, "\n");
 836                                 flood = 2;
 837                         }
 838
 839                         if (time >= source.(flood_field))
 840                         {
 841                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 842                         }
 843                         else
 844                         {
 845                                 flood = 1;
 846                                 msgstr = fullmsgstr;
 847                         }
 848                 }
 849                 else
 850                 {
 851                         if (time >= source.(flood_field))
 852                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 853                         else
 854                                 flood = 1;
 855                 }
 856
 857                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 858                         source.(flood_field) = flood = 0;
 859         }
 860
 861     string sourcemsgstr, sourcecmsgstr;
 862         if(flood == 2) // cannot happen for empty msgstr
 863         {
 864                 if(autocvar_g_chat_flood_notify_flooder)
 865                 {
 866                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 867                         sourcecmsgstr = "";
 868                 }
 869                 else
 870                 {
 871                         sourcemsgstr = fullmsgstr;
 872                         sourcecmsgstr = fullcmsgstr;
 873                 }
 874                 cmsgstr = "";
 875         }
 876         else
 877         {
 878                 sourcemsgstr = msgstr;
 879                 sourcecmsgstr = cmsgstr;
 880         }
 881
 882         if (!privatesay && source && !IS_PLAYER(source))
 883         {
 884                 if (!intermission_running)
 885                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 886                                 teamsay = -1; // spectators
 887         }
 888
 889         if(flood)
 890                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
 891
 892         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 893         if(privatesay)
 894                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 895
 896     int ret;
 897         if(source.muted)
 898         {
 899                 // always fake the message
 900                 ret = -1;
 901         }
 902         else if(flood == 1)
 903         {
 904                 if (autocvar_g_chat_flood_notify_flooder)
 905                 {
 906                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 907                         ret = 0;
 908                 }
 909                 else
 910                         ret = -1;
 911         }
 912         else
 913         {
 914                 ret = 1;
 915         }
 916
 917         if(sourcemsgstr != "" && ret != 0)
 918         {
 919                 if(ret < 0) // faked message, because the player is muted
 920                 {
 921                         sprint(source, sourcemsgstr);
 922                         if(sourcecmsgstr != "" && !privatesay)
 923                                 centerprint(source, sourcecmsgstr);
 924                 }
 925                 else if(privatesay) // private message, between 2 people only
 926                 {
 927                         sprint(source, sourcemsgstr);
 928                         sprint(privatesay, msgstr);
 929                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 930                         if(cmsgstr != "")
 931                                 centerprint(privatesay, cmsgstr);
 932                 }
 933                 else if ( teamsay && source.active_minigame )
 934                 {
 935                         sprint(source, sourcemsgstr);
 936                         dedicated_print(msgstr); // send to server console too
 937                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame, sprint(it, msgstr));
 938                 }
 939                 else if(teamsay > 0) // team message, only sent to team mates
 940                 {
 941                         sprint(source, sourcemsgstr);
 942                         dedicated_print(msgstr); // send to server console too
 943                         if(sourcecmsgstr != "")
 944                                 centerprint(source, sourcecmsgstr);
 945                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team, {
 946                                 sprint(it, msgstr);
 947                                 if(cmsgstr != "")
 948                                         centerprint(it, cmsgstr);
 949                         });
 950                 }
 951                 else if(teamsay < 0) // spectator message, only sent to spectators
 952                 {
 953                         sprint(source, sourcemsgstr);
 954                         dedicated_print(msgstr); // send to server console too
 955                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 956                 }
 957                 else
 958                 {
 959             if (source) {
 960                 sprint(source, sourcemsgstr);
 961                 dedicated_print(msgstr); // send to server console too
 962                 MX_Say(strcat(playername(source), "^7: ", msgin));
 963             }
 964             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 965         }
 966         }
 967
 968         return ret;
 969 }