qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include <common/effects/all.qh>
   4 #include "bot/api.qh"
   5 #include "cheats.qh"
   6 #include "g_damage.qh"
   7 #include "handicap.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "weapons/throwing.qh"
  12 #include "command/common.qh"
  13 #include "../common/state.qh"
  14 #include "../common/anim.qh"
  15 #include "../common/animdecide.qh"
  16 #include "../common/csqcmodel_settings.qh"
  17 #include "../common/deathtypes/all.qh"
  18 #include "../common/mapobjects/subs.qh"
  19 #include "../common/playerstats.qh"
  20 #include "../lib/csqcmodel/sv_model.qh"
  21
  22 #include "../common/minigames/sv_minigames.qh"
  23
  24 #include "../common/physics/player.qh"
  25 #include "../common/effects/qc/_mod.qh"
  26 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  27 #include "../common/mapobjects/_mod.qh"
  28 #include "../common/wepent.qh"
  29
  30 #include "weapons/weaponstats.qh"
  31
  32 #include "../common/animdecide.qh"
  33
  34 void Drop_Special_Items(entity player)
  35 {
  36         // called when the player has become stuck or frozen
  37         // so objective items aren't stuck with the player
  38
  39         MUTATOR_CALLHOOK(DropSpecialItems, player);
  40 }
  41
  42 void CopyBody_Think(entity this)
  43 {
  44         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  45         {
  46                 this.CopyBody_think(this);
  47                 if(wasfreed(this))
  48                         return;
  49                 this.CopyBody_nextthink = this.nextthink;
  50                 this.CopyBody_think = getthink(this);
  51                 setthink(this, CopyBody_Think);
  52         }
  53         CSQCMODEL_AUTOUPDATE(this);
  54         this.nextthink = time;
  55 }
  56 void CopyBody(entity this, float keepvelocity)
  57 {
  58         if (this.effects & EF_NODRAW)
  59                 return;
  60         entity clone = new(body);
  61         clone.enemy = this;
  62         clone.lip = this.lip;
  63         clone.colormap = this.colormap;
  64         clone.iscreature = this.iscreature;
  65         clone.teleportable = this.teleportable;
  66         clone.damagedbycontents = this.damagedbycontents;
  67         if(clone.damagedbycontents)
  68                 IL_PUSH(g_damagedbycontents, clone);
  69         clone.angles = this.angles;
  70         clone.v_angle = this.v_angle;
  71         clone.avelocity = this.avelocity;
  72         clone.damageforcescale = this.damageforcescale;
  73         clone.effects = this.effects;
  74         clone.glowmod = this.glowmod;
  75         clone.event_damage = this.event_damage;
  76         clone.anim_state = this.anim_state;
  77         clone.anim_time = this.anim_time;
  78         clone.anim_lower_action = this.anim_lower_action;
  79         clone.anim_lower_time = this.anim_lower_time;
  80         clone.anim_upper_action = this.anim_upper_action;
  81         clone.anim_upper_time = this.anim_upper_time;
  82         clone.anim_implicit_state = this.anim_implicit_state;
  83         clone.anim_implicit_time = this.anim_implicit_time;
  84         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  85         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  86         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  87         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  88         clone.dphitcontentsmask = this.dphitcontentsmask;
  89         clone.death_time = this.death_time;
  90         clone.pain_finished = this.pain_finished;
  91         clone.health = this.health;
  92         clone.armorvalue = this.armorvalue;
  93         clone.armortype = this.armortype;
  94         clone.model = this.model;
  95         clone.modelindex = this.modelindex;
  96         clone.skin = this.skin;
  97         clone.species = this.species;
  98         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  99         set_movetype(clone, this.move_movetype);
 100         clone.solid = this.solid;
 101         clone.takedamage = this.takedamage;
 102         setcefc(clone, getcefc(this));
 103         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 104         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 105         if (keepvelocity == 1)
 106                 clone.velocity = this.velocity;
 107         clone.oldvelocity = clone.velocity;
 108         clone.alpha = this.alpha;
 109         clone.fade_time = this.fade_time;
 110         clone.fade_rate = this.fade_rate;
 111         //clone.weapon = this.weapon;
 112         setorigin(clone, this.origin);
 113         setsize(clone, this.mins, this.maxs);
 114         clone.reset = SUB_Remove;
 115         clone._ps = this._ps;
 116
 117         Drag_MoveDrag(this, clone);
 118
 119         if(clone.colormap <= maxclients && clone.colormap > 0)
 120                 clone.colormap = 1024 + this.clientcolors;
 121
 122         CSQCMODEL_AUTOINIT(clone);
 123         clone.CopyBody_nextthink = this.nextthink;
 124         clone.CopyBody_think = getthink(this);
 125         clone.nextthink = time;
 126         setthink(clone, CopyBody_Think);
 127         // "bake" the current animation frame for clones (they don't get clientside animation)
 128         animdecide_load_if_needed(clone);
 129         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 130
 131         IL_PUSH(g_clones, clone);
 132
 133         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 134 }
 135
 136 void player_setupanimsformodel(entity this)
 137 {
 138         // load animation info
 139         animdecide_load_if_needed(this);
 140         animdecide_setstate(this, 0, false);
 141 }
 142
 143 void player_anim(entity this)
 144 {
 145         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 146         if(IS_DEAD(this)) {
 147                 if (!deadbits) {
 148                         // Decide on which death animation to use.
 149                         if(random() < 0.5)
 150                                 deadbits = ANIMSTATE_DEAD1;
 151                         else
 152                                 deadbits = ANIMSTATE_DEAD2;
 153                 }
 154         } else {
 155                 // Clear a previous death animation.
 156                 deadbits = 0;
 157         }
 158         int animbits = deadbits;
 159         if(STAT(FROZEN, this))
 160                 animbits |= ANIMSTATE_FROZEN;
 161         if(this.move_movetype == MOVETYPE_FOLLOW)
 162                 animbits |= ANIMSTATE_FOLLOW;
 163         if(this.crouch)
 164                 animbits |= ANIMSTATE_DUCK;
 165         animdecide_setstate(this, animbits, false);
 166         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 167 }
 168
 169 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 170 {
 171         float take, save;
 172         vector v;
 173         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 174
 175         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 176         take = v.x;
 177         save = v.y;
 178
 179         if(sound_allowed(MSG_BROADCAST, attacker))
 180         {
 181                 if (save > 10)
 182                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 183                 else if (take > 30)
 184                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 185                 else if (take > 10)
 186                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 187         }
 188
 189         if (take > 50)
 190                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 191         if (take > 100)
 192                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 193
 194         this.armorvalue = this.armorvalue - save;
 195         this.health = this.health - take;
 196         // pause regeneration for 5 seconds
 197         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 198
 199         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 200         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 201         this.dmg_inflictor = inflictor;
 202
 203         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 204         {
 205                 // don't use any animations as a gib
 206                 this.frame = 0;
 207                 // view just above the floor
 208                 this.view_ofs = '0 0 4';
 209
 210                 Violence_GibSplash(this, 1, 1, attacker);
 211                 this.alpha = -1;
 212                 this.solid = SOLID_NOT; // restore later
 213                 this.takedamage = DAMAGE_NO; // restore later
 214                 if(this.damagedbycontents)
 215                         IL_REMOVE(g_damagedbycontents, this);
 216                 this.damagedbycontents = false;
 217         }
 218 }
 219
 220 void calculate_player_respawn_time(entity this)
 221 {
 222         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
 223                 return;
 224
 225         float gametype_setting_tmp;
 226         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 227         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 228         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 229         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 230         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 231         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 232
 233         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 234         if (teamplay)
 235         {
 236                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 237                         if(it.team == this.team)
 238                                 ++pcount;
 239                 });
 240                 if (sdelay_small_count == 0)
 241                         sdelay_small_count = 1;
 242                 if (sdelay_large_count == 0)
 243                         sdelay_large_count = 1;
 244         }
 245         else
 246         {
 247                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 248                         ++pcount;
 249                 });
 250                 if (sdelay_small_count == 0)
 251                 {
 252                         if (IS_INDEPENDENT_PLAYER(this))
 253                         {
 254                                 // Players play independently. No point in requiring enemies.
 255                                 sdelay_small_count = 1;
 256                         }
 257                         else
 258                         {
 259                                 // Players play AGAINST each other. Enemies required.
 260                                 sdelay_small_count = 2;
 261                         }
 262                 }
 263                 if (sdelay_large_count == 0)
 264                 {
 265                         if (IS_INDEPENDENT_PLAYER(this))
 266                         {
 267                                 // Players play independently. No point in requiring enemies.
 268                                 sdelay_large_count = 1;
 269                         }
 270                         else
 271                         {
 272                                 // Players play AGAINST each other. Enemies required.
 273                                 sdelay_large_count = 2;
 274                         }
 275                 }
 276         }
 277
 278         float sdelay;
 279
 280         if (pcount <= sdelay_small_count)
 281                 sdelay = sdelay_small;
 282         else if (pcount >= sdelay_large_count)
 283                 sdelay = sdelay_large;
 284         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 285                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 286
 287         if(waves)
 288                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 289         else
 290                 this.respawn_time = time + sdelay;
 291
 292         if(sdelay < sdelay_max)
 293                 this.respawn_time_max = time + sdelay_max;
 294         else
 295                 this.respawn_time_max = this.respawn_time;
 296
 297         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 298                 this.respawn_countdown = 10; // first number to count down from is 10
 299         else
 300                 this.respawn_countdown = -1; // do not count down
 301
 302         if(autocvar_g_forced_respawn)
 303                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 304 }
 305
 306 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 307 {
 308         float take, save, dh, da;
 309         vector v;
 310         float excess;
 311
 312         dh = max(this.health, 0);
 313         da = max(this.armorvalue, 0);
 314
 315         if(!DEATH_ISSPECIAL(deathtype))
 316         {
 317                 damage *= Handicap_GetTotalHandicap(this);
 318                 if (this != attacker && IS_PLAYER(attacker))
 319                 {
 320                         damage /= Handicap_GetTotalHandicap(attacker);
 321                 }
 322         }
 323
 324         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 325                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
 326
 327         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 328         {
 329                 // tuba causes blood to come out of the ears
 330                 vector ear1, ear2;
 331                 vector d;
 332                 float f;
 333                 ear1 = this.origin;
 334                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 335                 ear2 = ear1;
 336                 makevectors(this.angles);
 337                 ear1 += v_right * -10;
 338                 ear2 += v_right * +10;
 339                 d = inflictor.origin - this.origin;
 340                 if (d)
 341                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 342                 else
 343                         f = 0;  // Assum ecenter.
 344                 force = v_right * vlen(force);
 345                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 346                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 347                 if(f > 0)
 348                 {
 349                         hitloc = ear1;
 350                         force = force * -1;
 351                 }
 352                 else
 353                 {
 354                         hitloc = ear2;
 355                         // force is already good
 356                 }
 357         }
 358         else
 359                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 360
 361         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 362         take = v.x;
 363         save = v.y;
 364
 365         if(attacker == this)
 366         {
 367                 // don't reset pushltime for this damage as it may be an attempt to
 368                 // escape a lava pit or similar
 369                 //this.pushltime = 0;
 370                 this.istypefrag = 0;
 371         }
 372         else if(IS_PLAYER(attacker))
 373         {
 374                 this.pusher = attacker;
 375                 this.pushltime = time + autocvar_g_maxpushtime;
 376                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 377         }
 378         else if(time < this.pushltime)
 379         {
 380                 attacker = this.pusher;
 381                 this.pushltime = max(this.pushltime, time + 0.6);
 382         }
 383         else
 384         {
 385                 this.pushltime = 0;
 386                 this.istypefrag = 0;
 387         }
 388
 389         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 390         take = bound(0, M_ARGV(4, float), this.health);
 391         save = bound(0, M_ARGV(5, float), this.armorvalue);
 392         excess = max(0, damage - take - save);
 393
 394         if(sound_allowed(MSG_BROADCAST, attacker))
 395         {
 396                 if (save > 10)
 397                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 398                 else if (take > 30)
 399                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 400                 else if (take > 10)
 401                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 402         }
 403
 404         if (take > 50)
 405                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 406         if (take > 100)
 407                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 408
 409         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 410         {
 411                 if (!(this.flags & FL_GODMODE))
 412                 {
 413                         this.armorvalue = this.armorvalue - save;
 414                         this.health = this.health - take;
 415                         // pause regeneration for 5 seconds
 416                         if(take)
 417                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 418
 419                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 420                         {
 421                                 this.pain_finished = time + 0.5;        //Supajoe
 422
 423                                 if(autocvar_sv_gentle < 1) {
 424                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 425                                         {
 426                                                 if (!this.animstate_override)
 427                                                 {
 428                                                         if (random() > 0.5)
 429                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 430                                                         else
 431                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 432                                                 }
 433                                         }
 434
 435                                         if(sound_allowed(MSG_BROADCAST, attacker))
 436                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
 437                                         if(this.health > 1)
 438                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 439                                         {
 440                                                 if(deathtype == DEATH_FALL.m_id)
 441                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 442                                                 else if(this.health > 75)
 443                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 444                                                 else if(this.health > 50)
 445                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 446                                                 else if(this.health > 25)
 447                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 448                                                 else
 449                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 450                                         }
 451                                 }
 452                         }
 453
 454                         // throw off bot aim temporarily
 455                         float shake;
 456                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 457                         {
 458                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 459                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 460                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 461                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 462                         }
 463                 }
 464                 else
 465                         this.max_armorvalue += (save + take);
 466         }
 467         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 468         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 469         this.dmg_inflictor = inflictor;
 470
 471         if (this != attacker) {
 472                 float realdmg = damage - excess;
 473                 if (IS_PLAYER(attacker)) {
 474                         GameRules_scoring_add(attacker, DMG, realdmg);
 475                 }
 476                 if (IS_PLAYER(this)) {
 477                         GameRules_scoring_add(this, DMGTAKEN, realdmg);
 478                 }
 479         }
 480
 481         bool abot = (IS_BOT_CLIENT(attacker));
 482         bool vbot = (IS_BOT_CLIENT(this));
 483
 484         bool valid_damage_for_weaponstats = false;
 485         Weapon awep = WEP_Null;
 486
 487         if(vbot || IS_REAL_CLIENT(this))
 488         if(abot || IS_REAL_CLIENT(attacker))
 489         if(attacker && this != attacker)
 490         if(DIFF_TEAM(this, attacker))
 491         {
 492                 if(DEATH_ISSPECIAL(deathtype))
 493                         awep = attacker.(weaponentity).m_weapon;
 494                 else
 495                         awep = DEATH_WEAPONOF(deathtype);
 496                 valid_damage_for_weaponstats = true;
 497         }
 498
 499         dh = dh - max(this.health, 0);
 500         da = da - max(this.armorvalue, 0);
 501         if(valid_damage_for_weaponstats)
 502         {
 503                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 504         }
 505
 506         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 507
 508         if (this.health < 1)
 509         {
 510                 float defer_ClientKill_Now_TeamChange;
 511                 defer_ClientKill_Now_TeamChange = false;
 512
 513                 if(this.alivetime)
 514                 {
 515                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 516                         this.alivetime = 0;
 517                 }
 518
 519                 if(valid_damage_for_weaponstats)
 520                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 521
 522                 if(autocvar_sv_gentle < 1)
 523                 if(sound_allowed(MSG_BROADCAST, attacker))
 524                 {
 525                         if(deathtype == DEATH_DROWN.m_id)
 526                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 527                         else
 528                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 529                 }
 530
 531                 // get rid of kill indicator
 532                 if(this.killindicator)
 533                 {
 534                         delete(this.killindicator);
 535                         this.killindicator = NULL;
 536                         if(this.killindicator_teamchange)
 537                                 defer_ClientKill_Now_TeamChange = true;
 538
 539                         if(this.classname == "body")
 540                         if(deathtype == DEATH_KILL.m_id)
 541                         {
 542                                 // for the lemmings fans, a small harmless explosion
 543                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 544                         }
 545                 }
 546
 547                 // print an obituary message
 548                 if(this.classname != "body")
 549                         Obituary (attacker, inflictor, this, deathtype, weaponentity);
 550
 551         // increment frag counter for used weapon type
 552         Weapon w = DEATH_WEAPONOF(deathtype);
 553                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 554                         CS(attacker).accuracy.(accuracy_frags[w.m_id-1]) += 1;
 555
 556                 this.respawn_time = 0;
 557                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 558                 damage = M_ARGV(4, float);
 559                 excess = max(0, damage - take - save);
 560
 561                 //Weapon wep = this.(weaponentity).m_weapon;
 562                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 563                 {
 564                         .entity went = weaponentities[slot];
 565                         if(!this.(went))
 566                                 continue; // TODO: clones have no weapon, but we don't want to have to check this all the time
 567                         Weapon wep = this.(went).m_weapon;
 568                         wep.wr_playerdeath(wep, this, went);
 569                 }
 570
 571                 RemoveGrapplingHooks(this);
 572
 573                 Portal_ClearAllLater(this);
 574
 575                 this.fixangle = true;
 576
 577                 if(defer_ClientKill_Now_TeamChange)
 578                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 579
 580                 // player could have been miraculously resuscitated ;)
 581                 // e.g. players in freezetag get frozen, they don't really die
 582                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 583                         return;
 584
 585                 if (!this.respawn_time) // can be set in the mutator hook PlayerDies
 586                         calculate_player_respawn_time(this);
 587
 588                 // when we get here, player actually dies
 589
 590                 Unfreeze(this); // remove any icy remains
 591                 this.health = 0; // Unfreeze resets health, so we need to set it back
 592
 593                 // clear waypoints
 594                 WaypointSprite_PlayerDead(this);
 595                 // throw a weapon
 596                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 597                 {
 598                         .entity went = weaponentities[slot];
 599                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
 600                 }
 601
 602                 // become fully visible
 603                 this.alpha = default_player_alpha;
 604                 // make the corpse upright (not tilted)
 605                 this.angles_x = 0;
 606                 this.angles_z = 0;
 607                 // don't spin
 608                 this.avelocity = '0 0 0';
 609                 // view from the floor
 610                 this.view_ofs = '0 0 -8';
 611                 // toss the corpse
 612                 set_movetype(this, MOVETYPE_TOSS);
 613                 // shootable corpse
 614                 this.solid = SOLID_CORPSE;
 615                 PS(this).ballistics_density = autocvar_g_ballistics_density_corpse;
 616                 // don't stick to the floor
 617                 UNSET_ONGROUND(this);
 618                 // dying animation
 619                 this.deadflag = DEAD_DYING;
 620
 621                 STAT(MOVEVARS_SPECIALCOMMAND, this) = false; // sweet release
 622
 623                 this.death_time = time;
 624                 if (random() < 0.5)
 625                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 626                 else
 627                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 628
 629                 // set damage function to corpse damage
 630                 this.event_damage = PlayerCorpseDamage;
 631                 // call the corpse damage function just in case it wants to gib
 632                 this.event_damage(this, inflictor, attacker, excess, deathtype, weaponentity, hitloc, force);
 633
 634                 // set up to fade out later
 635                 SUB_SetFade (this, time + 6 + random (), 1);
 636                 // reset body think wrapper broken by SUB_SetFade
 637                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 638                         this.CopyBody_think = getthink(this);
 639                         this.CopyBody_nextthink = this.nextthink;
 640                         setthink(this, CopyBody_Think);
 641                         this.nextthink = time;
 642                 }
 643
 644                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 645                         // remove corpse
 646                         // clones don't run any animation code any more, so we must gib them when they die :(
 647                         this.event_damage(this, inflictor, attacker, autocvar_sv_gibhealth + 1, deathtype, weaponentity, hitloc, force);
 648                 }
 649
 650                 // reset fields the weapons may use just in case
 651                 if(this.classname != "body")
 652                 {
 653                         FOREACH(Weapons, it != WEP_Null,
 654                         {
 655                                 it.wr_resetplayer(it, this);
 656                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 657                                 {
 658                                         ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 659                                 }
 660                         });
 661                 }
 662                 MUTATOR_CALLHOOK(PlayerDied, this);
 663         }
 664 }
 665
 666 bool MoveToTeam(entity client, int team_colour, int type)
 667 {
 668         int lockteams_backup = lockteams;  // backup any team lock
 669         lockteams = 0;  // disable locked teams
 670         TeamchangeFrags(client);  // move the players frags
 671         if (!SetPlayerTeamSimple(client, team_colour))
 672         {
 673                 return false;
 674         }
 675         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, DMG_NOWEP, client.origin, '0 0 0');  // kill the player
 676         lockteams = lockteams_backup;  // restore the team lock
 677         LogTeamchange(client.playerid, client.team, type);
 678         return true;
 679 }
 680
 681 /** print(), but only print if the server is not local */
 682 void dedicated_print(string input)
 683 {
 684         if (server_is_dedicated) print(input);
 685 }
 686
 687 void PrintToChat(entity player, string text)
 688 {
 689         text = strcat("\{1}^7", text, "\n");
 690         sprint(player, text);
 691 }
 692
 693 void DebugPrintToChat(entity player, string text)
 694 {
 695         if (autocvar_developer)
 696         {
 697                 PrintToChat(player, text);
 698         }
 699 }
 700
 701 void PrintToChatAll(string text)
 702 {
 703         text = strcat("\{1}^7", text, "\n");
 704         bprint(text);
 705 }
 706
 707 void DebugPrintToChatAll(string text)
 708 {
 709         if (autocvar_developer)
 710         {
 711                 PrintToChatAll(text);
 712         }
 713 }
 714
 715 void PrintToChatTeam(int teamnum, string text)
 716 {
 717         text = strcat("\{1}^7", text, "\n");
 718         FOREACH_CLIENT(IS_REAL_CLIENT(it),
 719         {
 720                 if (it.team == teamnum)
 721                 {
 722                         sprint(it, text);
 723                 }
 724         });
 725 }
 726
 727 void DebugPrintToChatTeam(int teamnum, string text)
 728 {
 729         if (autocvar_developer)
 730         {
 731                 PrintToChatTeam(teamnum, text);
 732         }
 733 }
 734
 735 /**
 736  * message "": do not say, just test flood control
 737  * return value:
 738  *   1 = accept
 739  *   0 = reject
 740  *  -1 = fake accept
 741  */
 742 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 743 {
 744         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 745         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 746
 747     if(source)
 748                 msgin = formatmessage(source, msgin);
 749
 750     string colorstr;
 751         if (!IS_PLAYER(source))
 752                 colorstr = "^0"; // black for spectators
 753         else if(teamplay)
 754                 colorstr = Team_ColorCode(source.team);
 755         else
 756         {
 757                 colorstr = "";
 758                 teamsay = false;
 759         }
 760
 761         if(game_stopped)
 762                 teamsay = false;
 763
 764     if (!source) {
 765                 colorstr = "";
 766                 teamsay = false;
 767     }
 768
 769         if(msgin != "")
 770                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 771
 772         /*
 773          * using bprint solves this... me stupid
 774         // how can we prevent the message from appearing in a listen server?
 775         // for now, just give "say" back and only handle say_team
 776         if(!teamsay)
 777         {
 778                 clientcommand(source, strcat("say ", msgin));
 779                 return;
 780         }
 781         */
 782
 783     string namestr = "";
 784     if (source)
 785         namestr = playername(source, autocvar_g_chat_teamcolors);
 786
 787     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 788
 789     string msgstr, cmsgstr;
 790     string privatemsgprefix = string_null;
 791     int privatemsgprefixlen = 0;
 792         if (msgin == "") {
 793         msgstr = cmsgstr = "";
 794         } else {
 795                 if(privatesay)
 796                 {
 797                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 798                         privatemsgprefixlen = strlen(msgstr);
 799                         msgstr = strcat(msgstr, msgin);
 800                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 801                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
 802                 }
 803                 else if(teamsay)
 804                 {
 805                         if(strstrofs(msgin, "/me", 0) >= 0)
 806                         {
 807                                 //msgin = strreplace("/me", "", msgin);
 808                                 //msgin = substring(msgin, 3, strlen(msgin));
 809                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 810                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 811                         }
 812                         else
 813                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 814                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 815                 }
 816                 else
 817                 {
 818                         if(strstrofs(msgin, "/me", 0) >= 0)
 819                         {
 820                                 //msgin = strreplace("/me", "", msgin);
 821                                 //msgin = substring(msgin, 3, strlen(msgin));
 822                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 823                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 824                         }
 825                         else {
 826                 msgstr = "\{1}";
 827                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 828                 msgstr = strcat(msgstr, msgin);
 829             }
 830                         cmsgstr = "";
 831                 }
 832                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 833         }
 834
 835         string fullmsgstr = msgstr;
 836         string fullcmsgstr = cmsgstr;
 837
 838         // FLOOD CONTROL
 839         int flood = 0;
 840         var .float flood_field = floodcontrol_chat;
 841         if(floodcontrol && source)
 842         {
 843                 float flood_spl;
 844                 float flood_burst;
 845                 float flood_lmax;
 846                 float lines;
 847                 if(privatesay)
 848                 {
 849                         flood_spl = autocvar_g_chat_flood_spl_tell;
 850                         flood_burst = autocvar_g_chat_flood_burst_tell;
 851                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 852                         flood_field = floodcontrol_chattell;
 853                 }
 854                 else if(teamsay)
 855                 {
 856                         flood_spl = autocvar_g_chat_flood_spl_team;
 857                         flood_burst = autocvar_g_chat_flood_burst_team;
 858                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 859                         flood_field = floodcontrol_chatteam;
 860                 }
 861                 else
 862                 {
 863                         flood_spl = autocvar_g_chat_flood_spl;
 864                         flood_burst = autocvar_g_chat_flood_burst;
 865                         flood_lmax = autocvar_g_chat_flood_lmax;
 866                         flood_field = floodcontrol_chat;
 867                 }
 868                 flood_burst = max(0, flood_burst - 1);
 869                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 870
 871                 // do flood control for the default line size
 872                 if(msgstr != "")
 873                 {
 874                         getWrappedLine_remaining = msgstr;
 875                         msgstr = "";
 876                         lines = 0;
 877                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 878                         {
 879                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 880                                 ++lines;
 881                         }
 882                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 883
 884                         if(getWrappedLine_remaining != "")
 885                         {
 886                                 msgstr = strcat(msgstr, "\n");
 887                                 flood = 2;
 888                         }
 889
 890                         if (time >= source.(flood_field))
 891                         {
 892                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 893                         }
 894                         else
 895                         {
 896                                 flood = 1;
 897                                 msgstr = fullmsgstr;
 898                         }
 899                 }
 900                 else
 901                 {
 902                         if (time >= source.(flood_field))
 903                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 904                         else
 905                                 flood = 1;
 906                 }
 907
 908                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 909                         source.(flood_field) = flood = 0;
 910         }
 911
 912     string sourcemsgstr, sourcecmsgstr;
 913         if(flood == 2) // cannot happen for empty msgstr
 914         {
 915                 if(autocvar_g_chat_flood_notify_flooder)
 916                 {
 917                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 918                         sourcecmsgstr = "";
 919                 }
 920                 else
 921                 {
 922                         sourcemsgstr = fullmsgstr;
 923                         sourcecmsgstr = fullcmsgstr;
 924                 }
 925                 cmsgstr = "";
 926         }
 927         else
 928         {
 929                 sourcemsgstr = msgstr;
 930                 sourcecmsgstr = cmsgstr;
 931         }
 932
 933         if (!privatesay && source && !IS_PLAYER(source))
 934         {
 935                 if (!game_stopped)
 936                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 937                         teamsay = -1; // spectators
 938         }
 939
 940         if(flood)
 941                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
 942
 943         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 944         if(privatesay)
 945                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 946
 947     int ret;
 948         if(source && CS(source).muted)
 949         {
 950                 // always fake the message
 951                 ret = -1;
 952         }
 953         else if(flood == 1)
 954         {
 955                 if (autocvar_g_chat_flood_notify_flooder)
 956                 {
 957                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 958                         ret = 0;
 959                 }
 960                 else
 961                         ret = -1;
 962         }
 963         else
 964         {
 965                 ret = 1;
 966         }
 967
 968         if (privatesay && source && !IS_PLAYER(source))
 969         {
 970                 if (!game_stopped)
 971                 if ((privatesay && IS_PLAYER(privatesay)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
 972                         ret = -1; // just hide the message completely
 973         }
 974
 975         MUTATOR_CALLHOOK(ChatMessage, source, ret);
 976         ret = M_ARGV(1, int);
 977
 978         if(sourcemsgstr != "" && ret != 0)
 979         {
 980                 if(ret < 0) // faked message, because the player is muted
 981                 {
 982                         sprint(source, sourcemsgstr);
 983                         if(sourcecmsgstr != "" && !privatesay)
 984                                 centerprint(source, sourcecmsgstr);
 985                 }
 986                 else if(privatesay) // private message, between 2 people only
 987                 {
 988                         sprint(source, sourcemsgstr);
 989                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 990                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
 991                         {
 992                                 sprint(privatesay, msgstr);
 993                                 if(cmsgstr != "")
 994                                         centerprint(privatesay, cmsgstr);
 995                         }
 996                 }
 997                 else if ( teamsay && CS(source).active_minigame )
 998                 {
 999                         sprint(source, sourcemsgstr);
1000                         dedicated_print(msgstr); // send to server console too
1001                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1002                 }
1003                 else if(teamsay > 0) // team message, only sent to team mates
1004                 {
1005                         sprint(source, sourcemsgstr);
1006                         dedicated_print(msgstr); // send to server console too
1007                         if(sourcecmsgstr != "")
1008                                 centerprint(source, sourcecmsgstr);
1009                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1010                                 sprint(it, msgstr);
1011                                 if(cmsgstr != "")
1012                                         centerprint(it, cmsgstr);
1013                         });
1014                 }
1015                 else if(teamsay < 0) // spectator message, only sent to spectators
1016                 {
1017                         sprint(source, sourcemsgstr);
1018                         dedicated_print(msgstr); // send to server console too
1019                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1020                 }
1021                 else
1022                 {
1023             if (source) {
1024                 sprint(source, sourcemsgstr);
1025                 dedicated_print(msgstr); // send to server console too
1026                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1027             }
1028             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1029         }
1030         }
1031
1032         return ret;
1033 }