qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27
  28 #include "weapons/weaponstats.qh"
  29
  30 #include "../common/animdecide.qh"
  31
  32 void Drop_Special_Items(entity player)
  33 {
  34         // called when the player has become stuck or frozen
  35         // so objective items aren't stuck with the player
  36
  37         MUTATOR_CALLHOOK(DropSpecialItems, player);
  38 }
  39
  40 void CopyBody_Think(entity this)
  41 {
  42         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  43         {
  44                 this.CopyBody_think(this);
  45                 if(wasfreed(this))
  46                         return;
  47                 this.CopyBody_nextthink = this.nextthink;
  48                 this.CopyBody_think = getthink(this);
  49                 setthink(this, CopyBody_Think);
  50         }
  51         CSQCMODEL_AUTOUPDATE(this);
  52         this.nextthink = time;
  53 }
  54 void CopyBody(entity this, float keepvelocity)
  55 {
  56         if (this.effects & EF_NODRAW)
  57                 return;
  58         entity clone = new(body);
  59         clone.enemy = this;
  60         clone.lip = this.lip;
  61         clone.colormap = this.colormap;
  62         clone.iscreature = this.iscreature;
  63         clone.teleportable = this.teleportable;
  64         clone.damagedbycontents = this.damagedbycontents;
  65         clone.angles = this.angles;
  66         clone.v_angle = this.v_angle;
  67         clone.avelocity = this.avelocity;
  68         clone.damageforcescale = this.damageforcescale;
  69         clone.effects = this.effects;
  70         clone.glowmod = this.glowmod;
  71         clone.event_damage = this.event_damage;
  72         clone.anim_state = this.anim_state;
  73         clone.anim_time = this.anim_time;
  74         clone.anim_lower_action = this.anim_lower_action;
  75         clone.anim_lower_time = this.anim_lower_time;
  76         clone.anim_upper_action = this.anim_upper_action;
  77         clone.anim_upper_time = this.anim_upper_time;
  78         clone.anim_implicit_state = this.anim_implicit_state;
  79         clone.anim_implicit_time = this.anim_implicit_time;
  80         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  81         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  82         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  83         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  84         clone.dphitcontentsmask = this.dphitcontentsmask;
  85         clone.death_time = this.death_time;
  86         clone.pain_finished = this.pain_finished;
  87         clone.health = this.health;
  88         clone.armorvalue = this.armorvalue;
  89         clone.armortype = this.armortype;
  90         clone.model = this.model;
  91         clone.modelindex = this.modelindex;
  92         clone.skin = this.skin;
  93         clone.species = this.species;
  94         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  95         set_movetype(clone, this.move_movetype);
  96         clone.solid = this.solid;
  97         clone.ballistics_density = this.ballistics_density;
  98         clone.takedamage = this.takedamage;
  99         setcefc(clone, getcefc(this));
 100         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 101         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 102         if (keepvelocity == 1)
 103                 clone.velocity = this.velocity;
 104         clone.oldvelocity = clone.velocity;
 105         clone.alpha = this.alpha;
 106         clone.fade_time = this.fade_time;
 107         clone.fade_rate = this.fade_rate;
 108         //clone.weapon = this.weapon;
 109         setorigin(clone, this.origin);
 110         setsize(clone, this.mins, this.maxs);
 111         clone.prevorigin = this.origin;
 112         clone.reset = SUB_Remove;
 113         clone._ps = this._ps;
 114
 115         Drag_MoveDrag(this, clone);
 116
 117         if(clone.colormap <= maxclients && clone.colormap > 0)
 118                 clone.colormap = 1024 + this.clientcolors;
 119
 120         CSQCMODEL_AUTOINIT(clone);
 121         clone.CopyBody_nextthink = this.nextthink;
 122         clone.CopyBody_think = getthink(this);
 123         clone.nextthink = time;
 124         setthink(clone, CopyBody_Think);
 125         // "bake" the current animation frame for clones (they don't get clientside animation)
 126         animdecide_load_if_needed(clone);
 127         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 128
 129         IL_PUSH(g_clones, clone);
 130
 131         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 132 }
 133
 134 void player_setupanimsformodel(entity this)
 135 {
 136         // load animation info
 137         animdecide_load_if_needed(this);
 138         animdecide_setstate(this, 0, false);
 139 }
 140
 141 void player_anim(entity this)
 142 {
 143         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 144         if(IS_DEAD(this)) {
 145                 if (!deadbits) {
 146                         // Decide on which death animation to use.
 147                         if(random() < 0.5)
 148                                 deadbits = ANIMSTATE_DEAD1;
 149                         else
 150                                 deadbits = ANIMSTATE_DEAD2;
 151                 }
 152         } else {
 153                 // Clear a previous death animation.
 154                 deadbits = 0;
 155         }
 156         int animbits = deadbits;
 157         if(STAT(FROZEN, this))
 158                 animbits |= ANIMSTATE_FROZEN;
 159         if(this.move_movetype == MOVETYPE_FOLLOW)
 160                 animbits |= ANIMSTATE_FOLLOW;
 161         if(this.crouch)
 162                 animbits |= ANIMSTATE_DUCK;
 163         animdecide_setstate(this, animbits, false);
 164         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 165 }
 166
 167 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 168 {
 169         float take, save;
 170         vector v;
 171         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 172
 173         // damage resistance (ignore most of the damage from a bullet or similar)
 174         damage = max(damage - 5, 1);
 175
 176         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 177         take = v.x;
 178         save = v.y;
 179
 180         if(sound_allowed(MSG_BROADCAST, attacker))
 181         {
 182                 if (save > 10)
 183                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 184                 else if (take > 30)
 185                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 186                 else if (take > 10)
 187                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 188         }
 189
 190         if (take > 50)
 191                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 192         if (take > 100)
 193                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 194
 195         this.armorvalue = this.armorvalue - save;
 196         this.health = this.health - take;
 197         // pause regeneration for 5 seconds
 198         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 199
 200         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 201         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 202         this.dmg_inflictor = inflictor;
 203
 204         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 205         {
 206                 // don't use any animations as a gib
 207                 this.frame = 0;
 208                 // view just above the floor
 209                 this.view_ofs = '0 0 4';
 210
 211                 Violence_GibSplash(this, 1, 1, attacker);
 212                 this.alpha = -1;
 213                 this.solid = SOLID_NOT; // restore later
 214                 this.takedamage = DAMAGE_NO; // restore later
 215                 this.damagedbycontents = false;
 216         }
 217 }
 218
 219 void calculate_player_respawn_time(entity this)
 220 {
 221         if(g_ca)
 222                 return;
 223
 224         float gametype_setting_tmp;
 225         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 226         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 227         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 228         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 229         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 230         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 231
 232         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 233         if (teamplay)
 234         {
 235                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 236                         if(it.team == this.team)
 237                                 ++pcount;
 238                 ));
 239                 if (sdelay_small_count == 0)
 240                         sdelay_small_count = 1;
 241                 if (sdelay_large_count == 0)
 242                         sdelay_large_count = 1;
 243         }
 244         else
 245         {
 246                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 247                         ++pcount;
 248                 ));
 249                 if (sdelay_small_count == 0)
 250                 {
 251                         if (g_cts)
 252                         {
 253                                 // Players play independently. No point in requiring enemies.
 254                                 sdelay_small_count = 1;
 255                         }
 256                         else
 257                         {
 258                                 // Players play AGAINST each other. Enemies required.
 259                                 sdelay_small_count = 2;
 260                         }
 261                 }
 262                 if (sdelay_large_count == 0)
 263                 {
 264                         if (g_cts)
 265                         {
 266                                 // Players play independently. No point in requiring enemies.
 267                                 sdelay_large_count = 1;
 268                         }
 269                         else
 270                         {
 271                                 // Players play AGAINST each other. Enemies required.
 272                                 sdelay_large_count = 2;
 273                         }
 274                 }
 275         }
 276
 277         float sdelay;
 278
 279         if (pcount <= sdelay_small_count)
 280                 sdelay = sdelay_small;
 281         else if (pcount >= sdelay_large_count)
 282                 sdelay = sdelay_large;
 283         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 284                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 285
 286         if(waves)
 287                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 288         else
 289                 this.respawn_time = time + sdelay;
 290
 291         if(sdelay < sdelay_max)
 292                 this.respawn_time_max = time + sdelay_max;
 293         else
 294                 this.respawn_time_max = this.respawn_time;
 295
 296         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 297                 this.respawn_countdown = 10; // first number to count down from is 10
 298         else
 299                 this.respawn_countdown = -1; // do not count down
 300
 301         if(autocvar_g_forced_respawn)
 302                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 303 }
 304
 305 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 306 {
 307         float take, save, dh, da;
 308         vector v;
 309         float valid_damage_for_weaponstats;
 310         float excess;
 311
 312         dh = max(this.health, 0);
 313         da = max(this.armorvalue, 0);
 314
 315         if(!DEATH_ISSPECIAL(deathtype))
 316         {
 317                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
 318                 if(this != attacker)
 319                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 320         }
 321
 322         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 323         {
 324                 // tuba causes blood to come out of the ears
 325                 vector ear1, ear2;
 326                 vector d;
 327                 float f;
 328                 ear1 = this.origin;
 329                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 330                 ear2 = ear1;
 331                 makevectors(this.angles);
 332                 ear1 += v_right * -10;
 333                 ear2 += v_right * +10;
 334                 d = inflictor.origin - this.origin;
 335                 if (d)
 336                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 337                 else
 338                         f = 0;  // Assum ecenter.
 339                 force = v_right * vlen(force);
 340                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 341                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 342                 if(f > 0)
 343                 {
 344                         hitloc = ear1;
 345                         force = force * -1;
 346                 }
 347                 else
 348                 {
 349                         hitloc = ear2;
 350                         // force is already good
 351                 }
 352         }
 353         else
 354                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 355
 356
 357         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 358         take = v.x;
 359         save = v.y;
 360
 361         if(attacker == this)
 362         {
 363                 // don't reset pushltime for this damage as it may be an attempt to
 364                 // escape a lava pit or similar
 365                 //this.pushltime = 0;
 366                 this.istypefrag = 0;
 367         }
 368         else if(IS_PLAYER(attacker))
 369         {
 370                 this.pusher = attacker;
 371                 this.pushltime = time + autocvar_g_maxpushtime;
 372                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 373         }
 374         else if(time < this.pushltime)
 375         {
 376                 attacker = this.pusher;
 377                 this.pushltime = max(this.pushltime, time + 0.6);
 378         }
 379         else
 380         {
 381                 this.pushltime = 0;
 382                 this.istypefrag = 0;
 383         }
 384
 385         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 386         {
 387                 vector v = healtharmor_applydamage(this.armorvalue, max(0, autocvar_g_spawnshield_blockdamage), deathtype, damage);
 388                 take = v.x;
 389                 save = v.y;
 390         }
 391
 392         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 393         take = bound(0, M_ARGV(4, float), this.health);
 394         save = bound(0, M_ARGV(5, float), this.armorvalue);
 395         excess = max(0, damage - take - save);
 396
 397         if(sound_allowed(MSG_BROADCAST, attacker))
 398         {
 399                 if (save > 10)
 400                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 401                 else if (take > 30)
 402                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 403                 else if (take > 10)
 404                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 405         }
 406
 407         if (take > 50)
 408                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 409         if (take > 100)
 410                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 411
 412         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 413         {
 414                 if (!(this.flags & FL_GODMODE))
 415                 {
 416                         this.armorvalue = this.armorvalue - save;
 417                         this.health = this.health - take;
 418                         // pause regeneration for 5 seconds
 419                         if(take)
 420                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 421
 422                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 423                         {
 424                                 this.pain_finished = time + 0.5;        //Supajoe
 425
 426                                 if(autocvar_sv_gentle < 1) {
 427                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 428                                         {
 429                                                 if (!this.animstate_override)
 430                                                 {
 431                                                         if (random() > 0.5)
 432                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 433                                                         else
 434                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 435                                                 }
 436                                         }
 437
 438                                         if(sound_allowed(MSG_BROADCAST, attacker))
 439                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
 440                                         if(this.health > 1)
 441                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 442                                         {
 443                                                 if(deathtype == DEATH_FALL.m_id)
 444                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 445                                                 else if(this.health > 75)
 446                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 447                                                 else if(this.health > 50)
 448                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 449                                                 else if(this.health > 25)
 450                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 451                                                 else
 452                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 453                                         }
 454                                 }
 455                         }
 456
 457                         // throw off bot aim temporarily
 458                         float shake;
 459                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 460                         {
 461                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 462                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 463                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 464                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 465                         }
 466                 }
 467                 else
 468                         this.max_armorvalue += (save + take);
 469         }
 470         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 471         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 472         this.dmg_inflictor = inflictor;
 473
 474         if (this != attacker) {
 475                 float realdmg = damage - excess;
 476                 if (IS_PLAYER(attacker)) {
 477                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 478                 }
 479                 if (IS_PLAYER(this)) {
 480                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 481                 }
 482         }
 483
 484         bool abot = (IS_BOT_CLIENT(attacker));
 485         bool vbot = (IS_BOT_CLIENT(this));
 486
 487         valid_damage_for_weaponstats = 0;
 488         Weapon awep = WEP_Null;
 489         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 490
 491         if(vbot || IS_REAL_CLIENT(this))
 492         if(abot || IS_REAL_CLIENT(attacker))
 493         if(attacker && this != attacker)
 494         if(DIFF_TEAM(this, attacker))
 495         {
 496                 if(DEATH_ISSPECIAL(deathtype))
 497                         awep = attacker.(weaponentity).m_weapon;
 498                 else
 499                         awep = DEATH_WEAPONOF(deathtype);
 500                 valid_damage_for_weaponstats = 1;
 501         }
 502
 503         dh = dh - max(this.health, 0);
 504         da = da - max(this.armorvalue, 0);
 505         if(valid_damage_for_weaponstats)
 506         {
 507                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 508         }
 509         if (dh + da)
 510         {
 511                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype);
 512         }
 513
 514         if (this.health < 1)
 515         {
 516                 float defer_ClientKill_Now_TeamChange;
 517                 defer_ClientKill_Now_TeamChange = false;
 518
 519                 if(this.alivetime)
 520                 {
 521                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 522                         this.alivetime = 0;
 523                 }
 524
 525                 if(valid_damage_for_weaponstats)
 526                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 527
 528                 if(autocvar_sv_gentle < 1)
 529                 if(sound_allowed(MSG_BROADCAST, attacker))
 530                 {
 531                         if(deathtype == DEATH_DROWN.m_id)
 532                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 533                         else
 534                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 535                 }
 536
 537                 // get rid of kill indicator
 538                 if(this.killindicator)
 539                 {
 540                         delete(this.killindicator);
 541                         this.killindicator = NULL;
 542                         if(this.killindicator_teamchange)
 543                                 defer_ClientKill_Now_TeamChange = true;
 544
 545                         if(this.classname == "body")
 546                         if(deathtype == DEATH_KILL.m_id)
 547                         {
 548                                 // for the lemmings fans, a small harmless explosion
 549                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 550                         }
 551                 }
 552
 553                 // print an obituary message
 554                 if(this.classname != "body")
 555                         Obituary (attacker, inflictor, this, deathtype);
 556
 557         // increment frag counter for used weapon type
 558         Weapon w = DEATH_WEAPONOF(deathtype);
 559                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 560                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 561
 562                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 563                 excess = M_ARGV(4, float);
 564
 565                 Weapon wep = this.(weaponentity).m_weapon;
 566                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 567                 {
 568                         .entity wepent = weaponentities[slot];
 569                         wep.wr_playerdeath(wep, this, wepent);
 570                 }
 571
 572                 RemoveGrapplingHooks(this);
 573
 574                 Portal_ClearAllLater(this);
 575
 576                 this.fixangle = true;
 577
 578                 if(defer_ClientKill_Now_TeamChange)
 579                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 580
 581                 // player could have been miraculously resuscitated ;)
 582                 // e.g. players in freezetag get frozen, they don't really die
 583                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 584                         return;
 585
 586                 // when we get here, player actually dies
 587
 588                 Unfreeze(this); // remove any icy remains
 589                 this.health = 0; // Unfreeze resets health, so we need to set it back
 590
 591                 // clear waypoints
 592                 WaypointSprite_PlayerDead(this);
 593                 // throw a weapon
 594                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 595                 {
 596                         .entity wepent = weaponentities[slot];
 597                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(wepent).m_switchweapon.m_id, wepent);
 598                 }
 599
 600                 // become fully visible
 601                 this.alpha = default_player_alpha;
 602                 // make the corpse upright (not tilted)
 603                 this.angles_x = 0;
 604                 this.angles_z = 0;
 605                 // don't spin
 606                 this.avelocity = '0 0 0';
 607                 // view from the floor
 608                 this.view_ofs = '0 0 -8';
 609                 // toss the corpse
 610                 set_movetype(this, MOVETYPE_TOSS);
 611                 // shootable corpse
 612                 this.solid = SOLID_CORPSE;
 613                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 614                 // don't stick to the floor
 615                 UNSET_ONGROUND(this);
 616                 // dying animation
 617                 this.deadflag = DEAD_DYING;
 618
 619                 // when to allow respawn
 620                 calculate_player_respawn_time(this);
 621
 622                 this.death_time = time;
 623                 if (random() < 0.5)
 624                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 625                 else
 626                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 627                 if (this.maxs.z > 5)
 628                 {
 629                         this.maxs_z = 5;
 630                         setsize(this, this.mins, this.maxs);
 631                 }
 632                 // set damage function to corpse damage
 633                 this.event_damage = PlayerCorpseDamage;
 634                 // call the corpse damage function just in case it wants to gib
 635                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 636
 637                 // set up to fade out later
 638                 SUB_SetFade (this, time + 6 + random (), 1);
 639                 // reset body think wrapper broken by SUB_SetFade
 640                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 641                         this.CopyBody_think = getthink(this);
 642                         this.CopyBody_nextthink = this.nextthink;
 643                         setthink(this, CopyBody_Think);
 644                         this.nextthink = time;
 645                 }
 646
 647                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 648                         // remove corpse
 649                         // clones don't run any animation code any more, so we must gib them when they die :(
 650                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 651                 }
 652
 653                 // reset fields the weapons may use just in case
 654                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 655                         it.wr_resetplayer(it, this);
 656                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 657                         {
 658                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 659                         }
 660                 ));
 661         }
 662 }
 663
 664 void MoveToTeam(entity client, int team_colour, int type)
 665 {
 666         int lockteams_backup = lockteams;  // backup any team lock
 667         lockteams = 0;  // disable locked teams
 668         TeamchangeFrags(client);  // move the players frags
 669         SetPlayerColors(client, team_colour - 1);  // set the players colour
 670         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 671         lockteams = lockteams_backup;  // restore the team lock
 672         LogTeamchange(client.playerid, client.team, type);
 673 }
 674
 675 /** print(), but only print if the server is not local */
 676 void dedicated_print(string input)
 677 {
 678         if (server_is_dedicated) print(input);
 679 }
 680
 681 /**
 682  * message "": do not say, just test flood control
 683  * return value:
 684  *   1 = accept
 685  *   0 = reject
 686  *  -1 = fake accept
 687  */
 688 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 689 {
 690         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 691         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 692
 693         msgin = formatmessage(source, msgin);
 694
 695     string colorstr;
 696         if (!IS_PLAYER(source))
 697                 colorstr = "^0"; // black for spectators
 698         else if(teamplay)
 699                 colorstr = Team_ColorCode(source.team);
 700         else
 701         {
 702                 colorstr = "";
 703                 teamsay = false;
 704         }
 705
 706         if(intermission_running)
 707                 teamsay = false;
 708
 709     if (!source) {
 710                 colorstr = "";
 711                 teamsay = false;
 712     }
 713
 714         if(msgin != "")
 715                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 716
 717         /*
 718          * using bprint solves this... me stupid
 719         // how can we prevent the message from appearing in a listen server?
 720         // for now, just give "say" back and only handle say_team
 721         if(!teamsay)
 722         {
 723                 clientcommand(source, strcat("say ", msgin));
 724                 return;
 725         }
 726         */
 727
 728     string namestr = "";
 729     if (source)
 730         namestr = autocvar_g_chat_teamcolors ? playername(source) : source.netname;
 731
 732     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 733
 734     string msgstr, cmsgstr;
 735     string privatemsgprefix = string_null;
 736     int privatemsgprefixlen = 0;
 737         if (msgin == "") {
 738         msgstr = cmsgstr = "";
 739         } else {
 740                 if(privatesay)
 741                 {
 742                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 743                         privatemsgprefixlen = strlen(msgstr);
 744                         msgstr = strcat(msgstr, msgin);
 745                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 746                         if(autocvar_g_chat_teamcolors)
 747                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 748                         else
 749                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 750                 }
 751                 else if(teamsay)
 752                 {
 753                         if(strstrofs(msgin, "/me", 0) >= 0)
 754                         {
 755                                 //msgin = strreplace("/me", "", msgin);
 756                                 //msgin = substring(msgin, 3, strlen(msgin));
 757                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 758                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 759                         }
 760                         else
 761                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 762                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 763                 }
 764                 else
 765                 {
 766                         if(strstrofs(msgin, "/me", 0) >= 0)
 767                         {
 768                                 //msgin = strreplace("/me", "", msgin);
 769                                 //msgin = substring(msgin, 3, strlen(msgin));
 770                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 771                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 772                         }
 773                         else {
 774                 msgstr = "\{1}";
 775                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 776                 msgstr = strcat(msgstr, msgin);
 777             }
 778                         cmsgstr = "";
 779                 }
 780                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 781         }
 782
 783         string fullmsgstr = msgstr;
 784         string fullcmsgstr = cmsgstr;
 785
 786         // FLOOD CONTROL
 787         int flood = 0;
 788         var .float flood_field = floodcontrol_chat;
 789         if(floodcontrol)
 790         {
 791                 float flood_spl;
 792                 float flood_burst;
 793                 float flood_lmax;
 794                 float lines;
 795                 if(privatesay)
 796                 {
 797                         flood_spl = autocvar_g_chat_flood_spl_tell;
 798                         flood_burst = autocvar_g_chat_flood_burst_tell;
 799                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 800                         flood_field = floodcontrol_chattell;
 801                 }
 802                 else if(teamsay)
 803                 {
 804                         flood_spl = autocvar_g_chat_flood_spl_team;
 805                         flood_burst = autocvar_g_chat_flood_burst_team;
 806                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 807                         flood_field = floodcontrol_chatteam;
 808                 }
 809                 else
 810                 {
 811                         flood_spl = autocvar_g_chat_flood_spl;
 812                         flood_burst = autocvar_g_chat_flood_burst;
 813                         flood_lmax = autocvar_g_chat_flood_lmax;
 814                         flood_field = floodcontrol_chat;
 815                 }
 816                 flood_burst = max(0, flood_burst - 1);
 817                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 818
 819                 // do flood control for the default line size
 820                 if(msgstr != "")
 821                 {
 822                         getWrappedLine_remaining = msgstr;
 823                         msgstr = "";
 824                         lines = 0;
 825                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 826                         {
 827                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 828                                 ++lines;
 829                         }
 830                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 831
 832                         if(getWrappedLine_remaining != "")
 833                         {
 834                                 msgstr = strcat(msgstr, "\n");
 835                                 flood = 2;
 836                         }
 837
 838                         if (time >= source.(flood_field))
 839                         {
 840                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 841                         }
 842                         else
 843                         {
 844                                 flood = 1;
 845                                 msgstr = fullmsgstr;
 846                         }
 847                 }
 848                 else
 849                 {
 850                         if (time >= source.(flood_field))
 851                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 852                         else
 853                                 flood = 1;
 854                 }
 855
 856                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 857                         source.(flood_field) = flood = 0;
 858         }
 859
 860     string sourcemsgstr, sourcecmsgstr;
 861         if(flood == 2) // cannot happen for empty msgstr
 862         {
 863                 if(autocvar_g_chat_flood_notify_flooder)
 864                 {
 865                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 866                         sourcecmsgstr = "";
 867                 }
 868                 else
 869                 {
 870                         sourcemsgstr = fullmsgstr;
 871                         sourcecmsgstr = fullcmsgstr;
 872                 }
 873                 cmsgstr = "";
 874         }
 875         else
 876         {
 877                 sourcemsgstr = msgstr;
 878                 sourcecmsgstr = cmsgstr;
 879         }
 880
 881         if (!privatesay && source && !IS_PLAYER(source))
 882         {
 883                 if (!intermission_running)
 884                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 885                                 teamsay = -1; // spectators
 886         }
 887
 888         if(flood)
 889                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
 890
 891         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 892         if(privatesay)
 893                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 894
 895     int ret;
 896         if(source.muted)
 897         {
 898                 // always fake the message
 899                 ret = -1;
 900         }
 901         else if(flood == 1)
 902         {
 903                 if (autocvar_g_chat_flood_notify_flooder)
 904                 {
 905                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 906                         ret = 0;
 907                 }
 908                 else
 909                         ret = -1;
 910         }
 911         else
 912         {
 913                 ret = 1;
 914         }
 915
 916         if(sourcemsgstr != "" && ret != 0)
 917         {
 918                 if(ret < 0) // faked message, because the player is muted
 919                 {
 920                         sprint(source, sourcemsgstr);
 921                         if(sourcecmsgstr != "" && !privatesay)
 922                                 centerprint(source, sourcecmsgstr);
 923                 }
 924                 else if(privatesay) // private message, between 2 people only
 925                 {
 926                         sprint(source, sourcemsgstr);
 927                         sprint(privatesay, msgstr);
 928                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 929                         if(cmsgstr != "")
 930                                 centerprint(privatesay, cmsgstr);
 931                 }
 932                 else if ( teamsay && source.active_minigame )
 933                 {
 934                         sprint(source, sourcemsgstr);
 935                         dedicated_print(msgstr); // send to server console too
 936                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame, sprint(it, msgstr));
 937                 }
 938                 else if(teamsay > 0) // team message, only sent to team mates
 939                 {
 940                         sprint(source, sourcemsgstr);
 941                         dedicated_print(msgstr); // send to server console too
 942                         if(sourcecmsgstr != "")
 943                                 centerprint(source, sourcecmsgstr);
 944                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team, {
 945                                 sprint(it, msgstr);
 946                                 if(cmsgstr != "")
 947                                         centerprint(it, cmsgstr);
 948                         });
 949                 }
 950                 else if(teamsay < 0) // spectator message, only sent to spectators
 951                 {
 952                         sprint(source, sourcemsgstr);
 953                         dedicated_print(msgstr); // send to server console too
 954                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 955                 }
 956                 else
 957                 {
 958             if (source) {
 959                 sprint(source, sourcemsgstr);
 960                 dedicated_print(msgstr); // send to server console too
 961                 MX_Say(strcat(playername(source), "^7: ", msgin));
 962             }
 963             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 964         }
 965         }
 966
 967         return ret;
 968 }