qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27 #include "../common/wepent.qh"
  28
  29 #include "weapons/weaponstats.qh"
  30
  31 #include "../common/animdecide.qh"
  32
  33 void Drop_Special_Items(entity player)
  34 {
  35         // called when the player has become stuck or frozen
  36         // so objective items aren't stuck with the player
  37
  38         MUTATOR_CALLHOOK(DropSpecialItems, player);
  39 }
  40
  41 void CopyBody_Think(entity this)
  42 {
  43         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  44         {
  45                 this.CopyBody_think(this);
  46                 if(wasfreed(this))
  47                         return;
  48                 this.CopyBody_nextthink = this.nextthink;
  49                 this.CopyBody_think = getthink(this);
  50                 setthink(this, CopyBody_Think);
  51         }
  52         CSQCMODEL_AUTOUPDATE(this);
  53         this.nextthink = time;
  54 }
  55 void CopyBody(entity this, float keepvelocity)
  56 {
  57         if (this.effects & EF_NODRAW)
  58                 return;
  59         entity clone = new(body);
  60         clone.enemy = this;
  61         clone.lip = this.lip;
  62         clone.colormap = this.colormap;
  63         clone.iscreature = this.iscreature;
  64         clone.teleportable = this.teleportable;
  65         clone.damagedbycontents = this.damagedbycontents;
  66         if(clone.damagedbycontents)
  67                 IL_PUSH(g_damagedbycontents, clone);
  68         clone.angles = this.angles;
  69         clone.v_angle = this.v_angle;
  70         clone.avelocity = this.avelocity;
  71         clone.damageforcescale = this.damageforcescale;
  72         clone.effects = this.effects;
  73         clone.glowmod = this.glowmod;
  74         clone.event_damage = this.event_damage;
  75         clone.anim_state = this.anim_state;
  76         clone.anim_time = this.anim_time;
  77         clone.anim_lower_action = this.anim_lower_action;
  78         clone.anim_lower_time = this.anim_lower_time;
  79         clone.anim_upper_action = this.anim_upper_action;
  80         clone.anim_upper_time = this.anim_upper_time;
  81         clone.anim_implicit_state = this.anim_implicit_state;
  82         clone.anim_implicit_time = this.anim_implicit_time;
  83         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  84         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  85         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  86         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  87         clone.dphitcontentsmask = this.dphitcontentsmask;
  88         clone.death_time = this.death_time;
  89         clone.pain_finished = this.pain_finished;
  90         clone.health = this.health;
  91         clone.armorvalue = this.armorvalue;
  92         clone.armortype = this.armortype;
  93         clone.model = this.model;
  94         clone.modelindex = this.modelindex;
  95         clone.skin = this.skin;
  96         clone.species = this.species;
  97         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  98         set_movetype(clone, this.move_movetype);
  99         clone.solid = this.solid;
 100         clone.ballistics_density = this.ballistics_density;
 101         clone.takedamage = this.takedamage;
 102         setcefc(clone, getcefc(this));
 103         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 104         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 105         if (keepvelocity == 1)
 106                 clone.velocity = this.velocity;
 107         clone.oldvelocity = clone.velocity;
 108         clone.alpha = this.alpha;
 109         clone.fade_time = this.fade_time;
 110         clone.fade_rate = this.fade_rate;
 111         //clone.weapon = this.weapon;
 112         setorigin(clone, this.origin);
 113         setsize(clone, this.mins, this.maxs);
 114         clone.prevorigin = this.origin;
 115         clone.reset = SUB_Remove;
 116         clone._ps = this._ps;
 117
 118         Drag_MoveDrag(this, clone);
 119
 120         if(clone.colormap <= maxclients && clone.colormap > 0)
 121                 clone.colormap = 1024 + this.clientcolors;
 122
 123         CSQCMODEL_AUTOINIT(clone);
 124         clone.CopyBody_nextthink = this.nextthink;
 125         clone.CopyBody_think = getthink(this);
 126         clone.nextthink = time;
 127         setthink(clone, CopyBody_Think);
 128         // "bake" the current animation frame for clones (they don't get clientside animation)
 129         animdecide_load_if_needed(clone);
 130         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 131
 132         IL_PUSH(g_clones, clone);
 133
 134         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 135 }
 136
 137 void player_setupanimsformodel(entity this)
 138 {
 139         // load animation info
 140         animdecide_load_if_needed(this);
 141         animdecide_setstate(this, 0, false);
 142 }
 143
 144 void player_anim(entity this)
 145 {
 146         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 147         if(IS_DEAD(this)) {
 148                 if (!deadbits) {
 149                         // Decide on which death animation to use.
 150                         if(random() < 0.5)
 151                                 deadbits = ANIMSTATE_DEAD1;
 152                         else
 153                                 deadbits = ANIMSTATE_DEAD2;
 154                 }
 155         } else {
 156                 // Clear a previous death animation.
 157                 deadbits = 0;
 158         }
 159         int animbits = deadbits;
 160         if(STAT(FROZEN, this))
 161                 animbits |= ANIMSTATE_FROZEN;
 162         if(this.move_movetype == MOVETYPE_FOLLOW)
 163                 animbits |= ANIMSTATE_FOLLOW;
 164         if(this.crouch)
 165                 animbits |= ANIMSTATE_DUCK;
 166         animdecide_setstate(this, animbits, false);
 167         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 168 }
 169
 170 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 171 {
 172         float take, save;
 173         vector v;
 174         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 175
 176         // damage resistance (ignore most of the damage from a bullet or similar)
 177         damage = max(damage - 5, 1);
 178
 179         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 180         take = v.x;
 181         save = v.y;
 182
 183         if(sound_allowed(MSG_BROADCAST, attacker))
 184         {
 185                 if (save > 10)
 186                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 187                 else if (take > 30)
 188                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 189                 else if (take > 10)
 190                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 191         }
 192
 193         if (take > 50)
 194                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 195         if (take > 100)
 196                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 197
 198         this.armorvalue = this.armorvalue - save;
 199         this.health = this.health - take;
 200         // pause regeneration for 5 seconds
 201         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 202
 203         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 204         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 205         this.dmg_inflictor = inflictor;
 206
 207         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 208         {
 209                 // don't use any animations as a gib
 210                 this.frame = 0;
 211                 // view just above the floor
 212                 this.view_ofs = '0 0 4';
 213
 214                 Violence_GibSplash(this, 1, 1, attacker);
 215                 this.alpha = -1;
 216                 this.solid = SOLID_NOT; // restore later
 217                 this.takedamage = DAMAGE_NO; // restore later
 218                 if(this.damagedbycontents)
 219                         IL_REMOVE(g_damagedbycontents, this);
 220                 this.damagedbycontents = false;
 221         }
 222 }
 223
 224 void calculate_player_respawn_time(entity this)
 225 {
 226         if(g_ca)
 227                 return;
 228
 229         float gametype_setting_tmp;
 230         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 231         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 232         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 233         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 234         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 235         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 236
 237         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 238         if (teamplay)
 239         {
 240                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 241                         if(it.team == this.team)
 242                                 ++pcount;
 243                 ));
 244                 if (sdelay_small_count == 0)
 245                         sdelay_small_count = 1;
 246                 if (sdelay_large_count == 0)
 247                         sdelay_large_count = 1;
 248         }
 249         else
 250         {
 251                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 252                         ++pcount;
 253                 ));
 254                 if (sdelay_small_count == 0)
 255                 {
 256                         if (IS_INDEPENDENT_PLAYER(this))
 257                         {
 258                                 // Players play independently. No point in requiring enemies.
 259                                 sdelay_small_count = 1;
 260                         }
 261                         else
 262                         {
 263                                 // Players play AGAINST each other. Enemies required.
 264                                 sdelay_small_count = 2;
 265                         }
 266                 }
 267                 if (sdelay_large_count == 0)
 268                 {
 269                         if (IS_INDEPENDENT_PLAYER(this))
 270                         {
 271                                 // Players play independently. No point in requiring enemies.
 272                                 sdelay_large_count = 1;
 273                         }
 274                         else
 275                         {
 276                                 // Players play AGAINST each other. Enemies required.
 277                                 sdelay_large_count = 2;
 278                         }
 279                 }
 280         }
 281
 282         float sdelay;
 283
 284         if (pcount <= sdelay_small_count)
 285                 sdelay = sdelay_small;
 286         else if (pcount >= sdelay_large_count)
 287                 sdelay = sdelay_large;
 288         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 289                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 290
 291         if(waves)
 292                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 293         else
 294                 this.respawn_time = time + sdelay;
 295
 296         if(sdelay < sdelay_max)
 297                 this.respawn_time_max = time + sdelay_max;
 298         else
 299                 this.respawn_time_max = this.respawn_time;
 300
 301         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 302                 this.respawn_countdown = 10; // first number to count down from is 10
 303         else
 304                 this.respawn_countdown = -1; // do not count down
 305
 306         if(autocvar_g_forced_respawn)
 307                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 308 }
 309
 310 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 311 {
 312         float take, save, dh, da;
 313         vector v;
 314         float excess;
 315
 316         dh = max(this.health, 0);
 317         da = max(this.armorvalue, 0);
 318
 319         if(!DEATH_ISSPECIAL(deathtype))
 320         {
 321                 damage *= bound(1.0, this.cvar_cl_handicap, 10.0);
 322                 if(this != attacker)
 323                         damage /= bound(1.0, attacker.cvar_cl_handicap, 10.0);
 324         }
 325
 326         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 327                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
 328
 329         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 330         {
 331                 // tuba causes blood to come out of the ears
 332                 vector ear1, ear2;
 333                 vector d;
 334                 float f;
 335                 ear1 = this.origin;
 336                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 337                 ear2 = ear1;
 338                 makevectors(this.angles);
 339                 ear1 += v_right * -10;
 340                 ear2 += v_right * +10;
 341                 d = inflictor.origin - this.origin;
 342                 if (d)
 343                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 344                 else
 345                         f = 0;  // Assum ecenter.
 346                 force = v_right * vlen(force);
 347                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 348                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 349                 if(f > 0)
 350                 {
 351                         hitloc = ear1;
 352                         force = force * -1;
 353                 }
 354                 else
 355                 {
 356                         hitloc = ear2;
 357                         // force is already good
 358                 }
 359         }
 360         else
 361                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 362
 363         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 364         take = v.x;
 365         save = v.y;
 366
 367         if(attacker == this)
 368         {
 369                 // don't reset pushltime for this damage as it may be an attempt to
 370                 // escape a lava pit or similar
 371                 //this.pushltime = 0;
 372                 this.istypefrag = 0;
 373         }
 374         else if(IS_PLAYER(attacker))
 375         {
 376                 this.pusher = attacker;
 377                 this.pushltime = time + autocvar_g_maxpushtime;
 378                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 379         }
 380         else if(time < this.pushltime)
 381         {
 382                 attacker = this.pusher;
 383                 this.pushltime = max(this.pushltime, time + 0.6);
 384         }
 385         else
 386         {
 387                 this.pushltime = 0;
 388                 this.istypefrag = 0;
 389         }
 390
 391         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 392         take = bound(0, M_ARGV(4, float), this.health);
 393         save = bound(0, M_ARGV(5, float), this.armorvalue);
 394         excess = max(0, damage - take - save);
 395
 396         if(sound_allowed(MSG_BROADCAST, attacker))
 397         {
 398                 if (save > 10)
 399                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 400                 else if (take > 30)
 401                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 402                 else if (take > 10)
 403                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 404         }
 405
 406         if (take > 50)
 407                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 408         if (take > 100)
 409                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 410
 411         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 412         {
 413                 if (!(this.flags & FL_GODMODE))
 414                 {
 415                         this.armorvalue = this.armorvalue - save;
 416                         this.health = this.health - take;
 417                         // pause regeneration for 5 seconds
 418                         if(take)
 419                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 420
 421                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 422                         {
 423                                 this.pain_finished = time + 0.5;        //Supajoe
 424
 425                                 if(autocvar_sv_gentle < 1) {
 426                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 427                                         {
 428                                                 if (!this.animstate_override)
 429                                                 {
 430                                                         if (random() > 0.5)
 431                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 432                                                         else
 433                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 434                                                 }
 435                                         }
 436
 437                                         if(sound_allowed(MSG_BROADCAST, attacker))
 438                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
 439                                         if(this.health > 1)
 440                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 441                                         {
 442                                                 if(deathtype == DEATH_FALL.m_id)
 443                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 444                                                 else if(this.health > 75)
 445                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 446                                                 else if(this.health > 50)
 447                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 448                                                 else if(this.health > 25)
 449                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 450                                                 else
 451                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 452                                         }
 453                                 }
 454                         }
 455
 456                         // throw off bot aim temporarily
 457                         float shake;
 458                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 459                         {
 460                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 461                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 462                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 463                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 464                         }
 465                 }
 466                 else
 467                         this.max_armorvalue += (save + take);
 468         }
 469         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 470         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 471         this.dmg_inflictor = inflictor;
 472
 473         if (this != attacker) {
 474                 float realdmg = damage - excess;
 475                 if (IS_PLAYER(attacker)) {
 476                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 477                 }
 478                 if (IS_PLAYER(this)) {
 479                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 480                 }
 481         }
 482
 483         bool abot = (IS_BOT_CLIENT(attacker));
 484         bool vbot = (IS_BOT_CLIENT(this));
 485
 486         bool valid_damage_for_weaponstats = false;
 487         Weapon awep = WEP_Null;
 488         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 489
 490         if(vbot || IS_REAL_CLIENT(this))
 491         if(abot || IS_REAL_CLIENT(attacker))
 492         if(attacker && this != attacker)
 493         if(DIFF_TEAM(this, attacker))
 494         {
 495                 if(DEATH_ISSPECIAL(deathtype))
 496                         awep = attacker.(weaponentity).m_weapon;
 497                 else
 498                         awep = DEATH_WEAPONOF(deathtype);
 499                 valid_damage_for_weaponstats = true;
 500         }
 501
 502         dh = dh - max(this.health, 0);
 503         da = da - max(this.armorvalue, 0);
 504         if(valid_damage_for_weaponstats)
 505         {
 506                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 507         }
 508
 509         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 510
 511         if (this.health < 1)
 512         {
 513                 float defer_ClientKill_Now_TeamChange;
 514                 defer_ClientKill_Now_TeamChange = false;
 515
 516                 if(this.alivetime)
 517                 {
 518                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 519                         this.alivetime = 0;
 520                 }
 521
 522                 if(valid_damage_for_weaponstats)
 523                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 524
 525                 if(autocvar_sv_gentle < 1)
 526                 if(sound_allowed(MSG_BROADCAST, attacker))
 527                 {
 528                         if(deathtype == DEATH_DROWN.m_id)
 529                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 530                         else
 531                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 532                 }
 533
 534                 // get rid of kill indicator
 535                 if(this.killindicator)
 536                 {
 537                         delete(this.killindicator);
 538                         this.killindicator = NULL;
 539                         if(this.killindicator_teamchange)
 540                                 defer_ClientKill_Now_TeamChange = true;
 541
 542                         if(this.classname == "body")
 543                         if(deathtype == DEATH_KILL.m_id)
 544                         {
 545                                 // for the lemmings fans, a small harmless explosion
 546                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 547                         }
 548                 }
 549
 550                 // print an obituary message
 551                 if(this.classname != "body")
 552                         Obituary (attacker, inflictor, this, deathtype);
 553
 554         // increment frag counter for used weapon type
 555         Weapon w = DEATH_WEAPONOF(deathtype);
 556                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 557                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 558
 559                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 560                 excess = M_ARGV(4, float);
 561
 562                 //Weapon wep = this.(weaponentity).m_weapon;
 563                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 564                 {
 565                         .entity went = weaponentities[slot];
 566                         if(!this.(weaponentity))
 567                                 continue; // TODO: clones have no weapon, but we don't want to have to check this all the time
 568                         Weapon wep = this.(weaponentity).m_weapon;
 569                         wep.wr_playerdeath(wep, this, went);
 570                 }
 571
 572                 RemoveGrapplingHooks(this);
 573
 574                 Portal_ClearAllLater(this);
 575
 576                 this.fixangle = true;
 577
 578                 if(defer_ClientKill_Now_TeamChange)
 579                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 580
 581                 // player could have been miraculously resuscitated ;)
 582                 // e.g. players in freezetag get frozen, they don't really die
 583                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 584                         return;
 585
 586                 // when we get here, player actually dies
 587
 588                 Unfreeze(this); // remove any icy remains
 589                 this.health = 0; // Unfreeze resets health, so we need to set it back
 590
 591                 // clear waypoints
 592                 WaypointSprite_PlayerDead(this);
 593                 // throw a weapon
 594                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 595                 {
 596                         .entity went = weaponentities[slot];
 597                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
 598                 }
 599
 600                 // become fully visible
 601                 this.alpha = default_player_alpha;
 602                 // make the corpse upright (not tilted)
 603                 this.angles_x = 0;
 604                 this.angles_z = 0;
 605                 // don't spin
 606                 this.avelocity = '0 0 0';
 607                 // view from the floor
 608                 this.view_ofs = '0 0 -8';
 609                 // toss the corpse
 610                 set_movetype(this, MOVETYPE_TOSS);
 611                 // shootable corpse
 612                 this.solid = SOLID_CORPSE;
 613                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 614                 // don't stick to the floor
 615                 UNSET_ONGROUND(this);
 616                 // dying animation
 617                 this.deadflag = DEAD_DYING;
 618
 619                 // when to allow respawn
 620                 calculate_player_respawn_time(this);
 621
 622                 this.death_time = time;
 623                 if (random() < 0.5)
 624                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 625                 else
 626                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 627                 if (this.maxs.z > 5)
 628                 {
 629                         this.maxs_z = 5;
 630                         setsize(this, this.mins, this.maxs);
 631                 }
 632                 // set damage function to corpse damage
 633                 this.event_damage = PlayerCorpseDamage;
 634                 // call the corpse damage function just in case it wants to gib
 635                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 636
 637                 // set up to fade out later
 638                 SUB_SetFade (this, time + 6 + random (), 1);
 639                 // reset body think wrapper broken by SUB_SetFade
 640                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 641                         this.CopyBody_think = getthink(this);
 642                         this.CopyBody_nextthink = this.nextthink;
 643                         setthink(this, CopyBody_Think);
 644                         this.nextthink = time;
 645                 }
 646
 647                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 648                         // remove corpse
 649                         // clones don't run any animation code any more, so we must gib them when they die :(
 650                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 651                 }
 652
 653                 // reset fields the weapons may use just in case
 654                 if(this.classname != "body")
 655                 {
 656                         FOREACH(Weapons, it != WEP_Null,
 657                         {
 658                                 it.wr_resetplayer(it, this);
 659                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 660                                 {
 661                                         ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 662                                 }
 663                         });
 664                 }
 665                 MUTATOR_CALLHOOK(PlayerDied, this);
 666         }
 667 }
 668
 669 void MoveToTeam(entity client, int team_colour, int type)
 670 {
 671         int lockteams_backup = lockteams;  // backup any team lock
 672         lockteams = 0;  // disable locked teams
 673         TeamchangeFrags(client);  // move the players frags
 674         SetPlayerColors(client, team_colour - 1);  // set the players colour
 675         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 676         lockteams = lockteams_backup;  // restore the team lock
 677         LogTeamchange(client.playerid, client.team, type);
 678 }
 679
 680 /** print(), but only print if the server is not local */
 681 void dedicated_print(string input)
 682 {
 683         if (server_is_dedicated) print(input);
 684 }
 685
 686 void PrintToChat(entity player, string text)
 687 {
 688         text = strcat("\{1}^7", text, "\n");
 689         sprint(player, text);
 690 }
 691
 692 void DebugPrintToChat(entity player, string text)
 693 {
 694         if (autocvar_developer)
 695         {
 696                 PrintToChat(player, text);
 697         }
 698 }
 699
 700 void PrintToChatAll(string text)
 701 {
 702         text = strcat("\{1}^7", text, "\n");
 703         bprint(text);
 704 }
 705
 706 void DebugPrintToChatAll(string text)
 707 {
 708         if (autocvar_developer)
 709         {
 710                 PrintToChatAll(text);
 711         }
 712 }
 713
 714 void PrintToChatTeam(int teamnum, string text)
 715 {
 716         text = strcat("\{1}^7", text, "\n");
 717         FOREACH_CLIENT(IS_REAL_CLIENT(it),
 718         {
 719                 if (it.team == teamnum)
 720                 {
 721                         sprint(it, text);
 722                 }
 723         });
 724 }
 725
 726 void DebugPrintToChatTeam(int teamnum, string text)
 727 {
 728         if (autocvar_developer)
 729         {
 730                 PrintToChatTeam(teamnum, text);
 731         }
 732 }
 733
 734 /**
 735  * message "": do not say, just test flood control
 736  * return value:
 737  *   1 = accept
 738  *   0 = reject
 739  *  -1 = fake accept
 740  */
 741 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 742 {
 743         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 744         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 745
 746         msgin = formatmessage(source, msgin);
 747
 748     string colorstr;
 749         if (!IS_PLAYER(source))
 750                 colorstr = "^0"; // black for spectators
 751         else if(teamplay)
 752                 colorstr = Team_ColorCode(source.team);
 753         else
 754         {
 755                 colorstr = "";
 756                 teamsay = false;
 757         }
 758
 759         if(game_stopped)
 760                 teamsay = false;
 761
 762     if (!source) {
 763                 colorstr = "";
 764                 teamsay = false;
 765     }
 766
 767         if(msgin != "")
 768                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 769
 770         /*
 771          * using bprint solves this... me stupid
 772         // how can we prevent the message from appearing in a listen server?
 773         // for now, just give "say" back and only handle say_team
 774         if(!teamsay)
 775         {
 776                 clientcommand(source, strcat("say ", msgin));
 777                 return;
 778         }
 779         */
 780
 781     string namestr = "";
 782     if (source)
 783         namestr = playername(source, autocvar_g_chat_teamcolors);
 784
 785     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 786
 787     string msgstr, cmsgstr;
 788     string privatemsgprefix = string_null;
 789     int privatemsgprefixlen = 0;
 790         if (msgin == "") {
 791         msgstr = cmsgstr = "";
 792         } else {
 793                 if(privatesay)
 794                 {
 795                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 796                         privatemsgprefixlen = strlen(msgstr);
 797                         msgstr = strcat(msgstr, msgin);
 798                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 799                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
 800                 }
 801                 else if(teamsay)
 802                 {
 803                         if(strstrofs(msgin, "/me", 0) >= 0)
 804                         {
 805                                 //msgin = strreplace("/me", "", msgin);
 806                                 //msgin = substring(msgin, 3, strlen(msgin));
 807                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 808                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 809                         }
 810                         else
 811                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 812                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 813                 }
 814                 else
 815                 {
 816                         if(strstrofs(msgin, "/me", 0) >= 0)
 817                         {
 818                                 //msgin = strreplace("/me", "", msgin);
 819                                 //msgin = substring(msgin, 3, strlen(msgin));
 820                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 821                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 822                         }
 823                         else {
 824                 msgstr = "\{1}";
 825                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 826                 msgstr = strcat(msgstr, msgin);
 827             }
 828                         cmsgstr = "";
 829                 }
 830                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 831         }
 832
 833         string fullmsgstr = msgstr;
 834         string fullcmsgstr = cmsgstr;
 835
 836         // FLOOD CONTROL
 837         int flood = 0;
 838         var .float flood_field = floodcontrol_chat;
 839         if(floodcontrol)
 840         {
 841                 float flood_spl;
 842                 float flood_burst;
 843                 float flood_lmax;
 844                 float lines;
 845                 if(privatesay)
 846                 {
 847                         flood_spl = autocvar_g_chat_flood_spl_tell;
 848                         flood_burst = autocvar_g_chat_flood_burst_tell;
 849                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 850                         flood_field = floodcontrol_chattell;
 851                 }
 852                 else if(teamsay)
 853                 {
 854                         flood_spl = autocvar_g_chat_flood_spl_team;
 855                         flood_burst = autocvar_g_chat_flood_burst_team;
 856                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 857                         flood_field = floodcontrol_chatteam;
 858                 }
 859                 else
 860                 {
 861                         flood_spl = autocvar_g_chat_flood_spl;
 862                         flood_burst = autocvar_g_chat_flood_burst;
 863                         flood_lmax = autocvar_g_chat_flood_lmax;
 864                         flood_field = floodcontrol_chat;
 865                 }
 866                 flood_burst = max(0, flood_burst - 1);
 867                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 868
 869                 // do flood control for the default line size
 870                 if(msgstr != "")
 871                 {
 872                         getWrappedLine_remaining = msgstr;
 873                         msgstr = "";
 874                         lines = 0;
 875                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 876                         {
 877                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 878                                 ++lines;
 879                         }
 880                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 881
 882                         if(getWrappedLine_remaining != "")
 883                         {
 884                                 msgstr = strcat(msgstr, "\n");
 885                                 flood = 2;
 886                         }
 887
 888                         if (time >= source.(flood_field))
 889                         {
 890                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 891                         }
 892                         else
 893                         {
 894                                 flood = 1;
 895                                 msgstr = fullmsgstr;
 896                         }
 897                 }
 898                 else
 899                 {
 900                         if (time >= source.(flood_field))
 901                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 902                         else
 903                                 flood = 1;
 904                 }
 905
 906                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 907                         source.(flood_field) = flood = 0;
 908         }
 909
 910     string sourcemsgstr, sourcecmsgstr;
 911         if(flood == 2) // cannot happen for empty msgstr
 912         {
 913                 if(autocvar_g_chat_flood_notify_flooder)
 914                 {
 915                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 916                         sourcecmsgstr = "";
 917                 }
 918                 else
 919                 {
 920                         sourcemsgstr = fullmsgstr;
 921                         sourcecmsgstr = fullcmsgstr;
 922                 }
 923                 cmsgstr = "";
 924         }
 925         else
 926         {
 927                 sourcemsgstr = msgstr;
 928                 sourcecmsgstr = cmsgstr;
 929         }
 930
 931         if (!privatesay && source && !IS_PLAYER(source))
 932         {
 933                 if (!game_stopped)
 934                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 935                         teamsay = -1; // spectators
 936         }
 937
 938         if(flood)
 939                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.\n");
 940
 941         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 942         if(privatesay)
 943                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 944
 945     int ret;
 946         if(source.muted)
 947         {
 948                 // always fake the message
 949                 ret = -1;
 950         }
 951         else if(flood == 1)
 952         {
 953                 if (autocvar_g_chat_flood_notify_flooder)
 954                 {
 955                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 956                         ret = 0;
 957                 }
 958                 else
 959                         ret = -1;
 960         }
 961         else
 962         {
 963                 ret = 1;
 964         }
 965
 966         if (privatesay && source && !IS_PLAYER(source))
 967         {
 968                 if (!game_stopped)
 969                 if ((privatesay && !IS_PLAYER(privatesay)) || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 970                         ret = -1; // just hide the message completely
 971         }
 972
 973         MUTATOR_CALLHOOK(ChatMessage, source, ret);
 974         ret = M_ARGV(1, int);
 975
 976         if(sourcemsgstr != "" && ret != 0)
 977         {
 978                 if(ret < 0) // faked message, because the player is muted
 979                 {
 980                         sprint(source, sourcemsgstr);
 981                         if(sourcecmsgstr != "" && !privatesay)
 982                                 centerprint(source, sourcecmsgstr);
 983                 }
 984                 else if(privatesay) // private message, between 2 people only
 985                 {
 986                         sprint(source, sourcemsgstr);
 987                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 988                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
 989                         {
 990                                 sprint(privatesay, msgstr);
 991                                 if(cmsgstr != "")
 992                                         centerprint(privatesay, cmsgstr);
 993                         }
 994                 }
 995                 else if ( teamsay && source.active_minigame )
 996                 {
 997                         sprint(source, sourcemsgstr);
 998                         dedicated_print(msgstr); // send to server console too
 999                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1000                 }
1001                 else if(teamsay > 0) // team message, only sent to team mates
1002                 {
1003                         sprint(source, sourcemsgstr);
1004                         dedicated_print(msgstr); // send to server console too
1005                         if(sourcecmsgstr != "")
1006                                 centerprint(source, sourcecmsgstr);
1007                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1008                                 sprint(it, msgstr);
1009                                 if(cmsgstr != "")
1010                                         centerprint(it, cmsgstr);
1011                         });
1012                 }
1013                 else if(teamsay < 0) // spectator message, only sent to spectators
1014                 {
1015                         sprint(source, sourcemsgstr);
1016                         dedicated_print(msgstr); // send to server console too
1017                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1018                 }
1019                 else
1020                 {
1021             if (source) {
1022                 sprint(source, sourcemsgstr);
1023                 dedicated_print(msgstr); // send to server console too
1024                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1025             }
1026             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1027         }
1028         }
1029
1030         return ret;
1031 }