qcsrc/server/portals.qc

   1 #define PORTALS_ARE_NOT_SOLID
   2
   3 #define SAFENUDGE '1 1 1'
   4 #define SAFERNUDGE '8 8 8'
   5
   6 .vector portal_transform;
   7 .vector portal_safe_origin;
   8 .float portal_wants_to_vanish;
   9 .float portal_activatetime;
  10 .float savemodelindex;
  11
  12 float PlayerEdgeDistance(entity p, vector v)
  13 {
  14         vector vbest;
  15
  16         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  17         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  18         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  19
  20         return vbest * v;
  21 }
  22
  23 vector Portal_ApplyTransformToPlayerAngle(vector transform, vector vangle)
  24 {
  25         vector old_forward, old_up;
  26         vector old_yawforward;
  27         vector new_forward, new_up;
  28         vector new_yawforward;
  29
  30         vector ang;
  31         ang = vangle;
  32         /*
  33            ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  34            ang = AnglesTransform_ApplyToVAngles(transform, ang);
  35          */
  36
  37         // PLAYERS use different math
  38 #ifndef POSITIVE_PITCH_IS_DOWN
  39         ang_x = -ang_x;
  40 #endif
  41
  42         //print("reference: ", vtos(AnglesTransform_ApplyToVAngles(transform, ang)), "\n");
  43
  44         fixedmakevectors(ang);
  45         old_forward = v_forward;
  46         old_up = v_up;
  47         fixedmakevectors(ang_y * '0 1 0');
  48         old_yawforward = v_forward;
  49
  50         // their aiming directions are portalled...
  51         new_forward = AnglesTransform_Apply(transform, old_forward);
  52         new_up = AnglesTransform_Apply(transform, old_up);
  53         new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
  54
  55         // but now find a new sense of direction
  56         // this is NOT easy!
  57         // assume new_forward points straight up.
  58         // What is our yaw?
  59         //
  60         // new_up could now point forward OR backward... which direction to choose?
  61
  62         if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
  63         {
  64                 // new_yawforward and new_yawup define the new aiming half-circle
  65                 // we "just" need to find out whether new_up or -new_up is in that half circle
  66                 ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
  67                 if(new_up * new_yawforward < 0)
  68                         new_up = -1 * new_up;
  69                 ang_y = vectoyaw(new_up); // this vector is the yaw we want
  70                 //print("UP/DOWN path: ", vtos(ang), "\n");
  71         }
  72         else
  73         {
  74                 // good angles; here, "forward" suffices
  75                 ang = fixedvectoangles(new_forward);
  76                 //print("GOOD path: ", vtos(ang), "\n");
  77         }
  78
  79 #ifndef POSITIVE_PITCH_IS_DOWN
  80         ang_x = -ang_x;
  81 #endif
  82         ang_z = vangle_z;
  83         return ang;
  84 }
  85
  86 .vector right_vector;
  87 float Portal_TeleportPlayer(entity teleporter, entity player)
  88 {
  89         vector from, to, safe, step, transform, ang, newvel;
  90         float planeshift, s, t;
  91
  92         if not(teleporter.enemy)
  93         {
  94                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  95                 return 0;
  96         }
  97
  98         from = teleporter.origin;
  99         transform = teleporter.portal_transform;
 100
 101         to = teleporter.enemy.origin;
 102         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
 103         newvel = AnglesTransform_Apply(transform, player.velocity);
 104         // this now is INSIDE the plane... can't use that
 105
 106         // shift it out
 107         fixedmakevectors(teleporter.enemy.mangle);
 108
 109         // first shift it ON the plane if needed
 110         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 111         /*
 112         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 113                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 114                 to += newvel * (planeshift / (newvel * v_forward));
 115         else
 116         */
 117                 to += v_forward * planeshift;
 118
 119         s = (to - teleporter.enemy.origin) * v_right;
 120         t = (to - teleporter.enemy.origin) * v_up;
 121         s = bound(-48, s, 48);
 122         t = bound(-48, t, 48);
 123         to = teleporter.enemy.origin
 124            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 125            +     s                                        * v_right
 126            +     t                                        * v_up;
 127
 128         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 129         step = to + ((safe - to) * v_forward) * v_forward;
 130         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 131         if(trace_startsolid)
 132         {
 133                 print("'safe' teleport location is not safe!\n");
 134                 // FAIL TODO why does this happen?
 135                 return 0;
 136         }
 137         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 138         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 139         if(trace_startsolid)
 140         {
 141                 print("trace_endpos in solid, this can't be!\n");
 142                 // FAIL TODO why does this happen? (reported by MrBougo)
 143                 return 0;
 144         }
 145         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 146         //print(vtos(to), "\n");
 147
 148         // ang_x stuff works around weird quake angles
 149         if(player.classname == "player")
 150                 ang = Portal_ApplyTransformToPlayerAngle(transform, player.v_angle);
 151         else
 152                 ang = AnglesTransform_ApplyToAngles(transform, player.angles);
 153
 154         // factor -1 allows chaining portals, but may be weird
 155         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 156
 157         if(player.flagcarried)
 158                 DropFlag(player.flagcarried, player, world);
 159
 160         if not(teleporter.enemy)
 161         {
 162                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 163                 return 0;
 164         }
 165
 166         tdeath_hit = 0;
 167         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax, TELEPORT_FLAGS_PORTAL);
 168         if(tdeath_hit)
 169         {
 170                 // telefrag within 1 second of portal creation = amazing
 171                 if(time < teleporter.teleport_time + 1)
 172                         AnnounceTo(player, "amazing");
 173         }
 174
 175         if not(teleporter.enemy)
 176         {
 177                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 178                 return 0;
 179         }
 180
 181         // reset fade counter
 182         teleporter.portal_wants_to_vanish = 0;
 183         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 184         teleporter.health = autocvar_g_balance_portal_health;
 185         teleporter.enemy.health = autocvar_g_balance_portal_health;
 186
 187         return 1;
 188 }
 189
 190 float Portal_FindSafeOrigin(entity portal)
 191 {
 192         vector o;
 193         o = portal.origin;
 194         portal.mins = PL_MIN - SAFERNUDGE;
 195         portal.maxs = PL_MAX + SAFERNUDGE;
 196         fixedmakevectors(portal.mangle);
 197         portal.origin += 16 * v_forward;
 198         if(!move_out_of_solid(portal))
 199         {
 200 #ifdef DEBUG
 201                 print("NO SAFE ORIGIN\n");
 202 #endif
 203                 return 0;
 204         }
 205         portal.portal_safe_origin = portal.origin;
 206         setorigin(portal, o);
 207         return 1;
 208 }
 209
 210 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 211 {
 212         float dist, distpersec, delta;
 213         vector v;
 214
 215         dist = (eorg - porg) * pnorm;
 216         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 217         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 218         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 219         if(dist < -1) // other side?
 220                 return 0;
 221 #ifdef PORTALS_ARE_NOT_SOLID
 222         distpersec = evel * pnorm;
 223         if(distpersec >= 0) // going away from the portal?
 224                 return 0;
 225         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 226         delta = dist / distpersec;
 227         v = eorg - evel * delta - porg;
 228         v = v - pnorm * (pnorm * v);
 229         return vlen(v) < psize;
 230 #else
 231         return 1;
 232 #endif
 233 }
 234
 235 void Portal_Touch()
 236 {
 237         vector g;
 238
 239 #ifdef PORTALS_ARE_NOT_SOLID
 240         // portal is being removed?
 241         if(self.solid != SOLID_TRIGGER)
 242                 return; // possibly engine bug
 243
 244         if(other.classname == "player")
 245                 return; // handled by think
 246 #endif
 247
 248         if(other.classname == "item_flag_team")
 249                 return; // never portal these
 250
 251         if(other.classname == "grapplinghook")
 252                 return; // handled by think
 253
 254         if(!self.enemy)
 255                 error("Portal_Touch called for a broken portal\n");
 256
 257 #ifdef PORTALS_ARE_NOT_SOLID
 258         if(trace_fraction < 1)
 259                 return; // only handle TouchAreaGrid ones (only these can teleport)
 260 #else
 261         if(trace_fraction >= 1)
 262                 return; // only handle impacts
 263 #endif
 264
 265         if(other.classname == "porto")
 266         {
 267                 if(other.portal_id == self.portal_id)
 268                         return;
 269         }
 270         if(time < self.portal_activatetime)
 271                 if(other == self.aiment)
 272                 {
 273                         self.portal_activatetime = time + 0.1;
 274                         return;
 275                 }
 276         if(other != self.aiment)
 277                 if(other.classname == "player")
 278                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 279                                 return; // cannot go through someone else's portal
 280         if(other.aiment != self.aiment)
 281                 if(other.aiment.classname == "player")
 282                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 283                                 return; // cannot go through someone else's portal
 284         fixedmakevectors(self.mangle);
 285         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 286         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 287                 return;
 288
 289         /*
 290         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 291         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 292         {
 293                 // can't teleport this
 294                 return;
 295         }
 296         */
 297
 298         if(Portal_TeleportPlayer(self, other))
 299                 if(other.classname == "porto")
 300                         if(other.effects & EF_RED)
 301                                 other.effects += EF_BLUE - EF_RED;
 302 }
 303
 304 void Portal_Think();
 305 void Portal_MakeBrokenPortal(entity portal)
 306 {
 307         portal.skin = 2;
 308         portal.solid = SOLID_NOT;
 309         portal.touch = SUB_Null;
 310         portal.think = SUB_Null;
 311         portal.effects = 0;
 312         portal.nextthink = 0;
 313         portal.takedamage = DAMAGE_NO;
 314 }
 315
 316 void Portal_MakeWaitingPortal(entity portal)
 317 {
 318         portal.skin = 2;
 319         portal.solid = SOLID_NOT;
 320         portal.touch = SUB_Null;
 321         portal.think = SUB_Null;
 322         portal.effects = EF_ADDITIVE;
 323         portal.nextthink = 0;
 324         portal.takedamage = DAMAGE_YES;
 325 }
 326
 327 void Portal_MakeInPortal(entity portal)
 328 {
 329         portal.skin = 0;
 330         portal.solid = SOLID_NOT; // this is done when connecting them!
 331         portal.touch = Portal_Touch;
 332         portal.think = Portal_Think;
 333         portal.effects = EF_RED;
 334         portal.nextthink = time;
 335         portal.takedamage = DAMAGE_NO;
 336 }
 337
 338 void Portal_MakeOutPortal(entity portal)
 339 {
 340         portal.skin = 1;
 341         portal.solid = SOLID_NOT;
 342         portal.touch = SUB_Null;
 343         portal.think = SUB_Null;
 344         portal.effects = EF_STARDUST | EF_BLUE;
 345         portal.nextthink = 0;
 346         portal.takedamage = DAMAGE_YES;
 347 }
 348
 349 void Portal_Disconnect(entity teleporter, entity destination)
 350 {
 351         teleporter.enemy = world;
 352         destination.enemy = world;
 353         Portal_MakeBrokenPortal(teleporter);
 354         Portal_MakeBrokenPortal(destination);
 355 }
 356
 357 void Portal_Connect(entity teleporter, entity destination)
 358 {
 359         teleporter.portal_transform = AnglesTransform_RightDivide(AnglesTransform_TurnDirectionFR(destination.mangle), teleporter.mangle);
 360
 361         teleporter.enemy = destination;
 362         destination.enemy = teleporter;
 363         Portal_MakeInPortal(teleporter);
 364         Portal_MakeOutPortal(destination);
 365         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 366         destination.fade_time = teleporter.fade_time;
 367         teleporter.portal_wants_to_vanish = 0;
 368         destination.portal_wants_to_vanish = 0;
 369         teleporter.teleport_time = time;
 370 #ifdef PORTALS_ARE_NOT_SOLID
 371         teleporter.solid = SOLID_TRIGGER;
 372 #else
 373         teleporter.solid = SOLID_BSP;
 374 #endif
 375 }
 376
 377 void Portal_Remove(entity portal, float killed)
 378 {
 379         entity e;
 380         e = portal.enemy;
 381
 382         if(e)
 383         {
 384                 Portal_Disconnect(portal, e);
 385                 Portal_Remove(e, killed);
 386         }
 387
 388         if(portal == portal.aiment.portal_in)
 389                 portal.aiment.portal_in = world;
 390         if(portal == portal.aiment.portal_out)
 391                 portal.aiment.portal_out = world;
 392         //portal.aiment = world;
 393
 394         // makes the portal vanish
 395         if(killed)
 396         {
 397                 fixedmakevectors(portal.mangle);
 398                 sound(portal, CH_SHOTS, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 399                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 400                 remove(portal);
 401         }
 402         else
 403         {
 404                 Portal_MakeBrokenPortal(portal);
 405                 sound(portal, CH_SHOTS, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 406                 SUB_SetFade(portal, time, 0.5);
 407         }
 408 }
 409
 410 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 411 {
 412         if(deathtype == DEATH_TELEFRAG)
 413                 return;
 414         if(attacker != self.aiment)
 415                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 416                         return;
 417         self.health -= damage;
 418         if(self.health < 0)
 419                 Portal_Remove(self, 1);
 420 }
 421
 422 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 423 {
 424         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 425                 return;
 426
 427         // if e would hit the portal in a frame...
 428         // already teleport him
 429         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 430         if(trace_ent == self)
 431                 Portal_TeleportPlayer(self, e);
 432 }
 433
 434 void Portal_Think()
 435 {
 436         entity e, o;
 437         vector g;
 438
 439 #ifdef PORTALS_ARE_NOT_SOLID
 440         // portal is being removed?
 441         if(self.solid != SOLID_TRIGGER)
 442                 return; // possibly engine bug
 443
 444         if(!self.enemy)
 445                 error("Portal_Think called for a broken portal\n");
 446
 447         o = self.aiment;
 448         self.solid = SOLID_BBOX;
 449         self.aiment = world;
 450
 451         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 452
 453         fixedmakevectors(self.mangle);
 454
 455         FOR_EACH_PLAYER(e)
 456         {
 457                 if(e != o)
 458                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 459                                 continue; // cannot go through someone else's portal
 460
 461                 if(e != o || time >= self.portal_activatetime)
 462                         Portal_Think_TryTeleportPlayer(e, g);
 463
 464                 if(e.hook)
 465                         Portal_Think_TryTeleportPlayer(e.hook, g);
 466         }
 467         self.solid = SOLID_TRIGGER;
 468         self.aiment = o;
 469 #endif
 470
 471         self.nextthink = time;
 472
 473         if(time > self.fade_time)
 474                 Portal_Remove(self, 0);
 475 }
 476
 477 float Portal_Customize()
 478 {
 479         if(other.classname == "spectator")
 480                 other = other.enemy;
 481         if(other == self.aiment)
 482         {
 483                 self.modelindex = self.savemodelindex;
 484         }
 485         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 486         {
 487                 self.modelindex = 0;
 488         }
 489         else
 490         {
 491                 self.modelindex = self.savemodelindex;
 492         }
 493         return TRUE;
 494 }
 495
 496 // cleanup:
 497 //   when creating in-portal:
 498 //     disconnect
 499 //     clear existing in-portal
 500 //     set as in-portal
 501 //     connect
 502 //   when creating out-portal:
 503 //     disconnect
 504 //     clear existing out-portal
 505 //     set as out-portal
 506 //   when player dies:
 507 //     disconnect portals
 508 //     clear both portals
 509 //   after timeout of in-portal:
 510 //     disconnect portals
 511 //     clear both portals
 512 //   TODO: ensure only one portal shot at once
 513 float Portal_SetInPortal(entity own, entity portal)
 514 {
 515         if(own.portal_in)
 516         {
 517                 if(own.portal_out)
 518                         Portal_Disconnect(own.portal_in, own.portal_out);
 519                 Portal_Remove(own.portal_in, 0);
 520         }
 521         own.portal_in = portal;
 522         if(own.portal_out)
 523         {
 524                 own.portal_out.portal_id = portal.portal_id;
 525                 Portal_Connect(own.portal_in, own.portal_out);
 526         }
 527         return 2;
 528 }
 529 float Portal_SetOutPortal(entity own, entity portal)
 530 {
 531         if(own.portal_out)
 532         {
 533                 if(own.portal_in)
 534                         Portal_Disconnect(own.portal_in, own.portal_out);
 535                 Portal_Remove(own.portal_out, 0);
 536         }
 537         own.portal_out = portal;
 538         if(own.portal_in)
 539         {
 540                 own.portal_in.portal_id = portal.portal_id;
 541                 Portal_Connect(own.portal_in, own.portal_out);
 542         }
 543         return 1;
 544 }
 545 void Portal_ClearAll_PortalsOnly(entity own)
 546 {
 547         if(own.portal_in)
 548                 Portal_Remove(own.portal_in, 0);
 549         if(own.portal_out)
 550                 Portal_Remove(own.portal_out, 0);
 551 }
 552 void Portal_ClearAll(entity own)
 553 {
 554         Portal_ClearAll_PortalsOnly(own);
 555         W_Porto_Remove(own);
 556 }
 557 void Portal_RemoveLater_Think()
 558 {
 559         Portal_Remove(self, self.cnt);
 560 }
 561 void Portal_RemoveLater(entity portal, float kill)
 562 {
 563         Portal_MakeBrokenPortal(portal);
 564         portal.cnt = kill;
 565         portal.think = Portal_RemoveLater_Think;
 566         portal.nextthink = time;
 567 }
 568 void Portal_ClearAllLater_PortalsOnly(entity own)
 569 {
 570         if(own.portal_in)
 571                 Portal_RemoveLater(own.portal_in, 0);
 572         if(own.portal_out)
 573                 Portal_RemoveLater(own.portal_out, 0);
 574 }
 575 void Portal_ClearAllLater(entity own)
 576 {
 577         Portal_ClearAllLater_PortalsOnly(own);
 578         W_Porto_Remove(own);
 579 }
 580 void Portal_ClearWithID(entity own, float id)
 581 {
 582         if(own.portal_in)
 583                 if(own.portal_in.portal_id == id)
 584                 {
 585                         if(own.portal_out)
 586                                 Portal_Disconnect(own.portal_in, own.portal_out);
 587                         Portal_Remove(own.portal_in, 0);
 588                 }
 589         if(own.portal_out)
 590                 if(own.portal_out.portal_id == id)
 591                 {
 592                         if(own.portal_in)
 593                                 Portal_Disconnect(own.portal_in, own.portal_out);
 594                         Portal_Remove(own.portal_out, 0);
 595                 }
 596 }
 597
 598 entity Portal_Spawn(entity own, vector org, vector ang)
 599 {
 600         entity portal;
 601
 602         fixedmakevectors(ang);
 603         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 604                 return world;
 605
 606         portal = spawn();
 607         portal.classname = "portal";
 608         portal.aiment = own;
 609         setorigin(portal, org);
 610         portal.mangle = ang;
 611         portal.angles = ang;
 612         portal.angles_x = -portal.angles_x; // is a bmodel
 613         portal.think = Portal_Think;
 614         portal.nextthink = 0;
 615         portal.portal_activatetime = time + 0.1;
 616         portal.takedamage = DAMAGE_AIM;
 617         portal.event_damage = Portal_Damage;
 618         portal.fade_time = time + autocvar_g_balance_portal_lifetime;
 619         portal.health = autocvar_g_balance_portal_health;
 620         setmodel(portal, "models/portal.md3");
 621         portal.savemodelindex = portal.modelindex;
 622         portal.customizeentityforclient = Portal_Customize;
 623
 624         if(!Portal_FindSafeOrigin(portal))
 625         {
 626                 remove(portal);
 627                 return world;
 628         }
 629
 630         setsize(portal, '-48 -48 -48', '48 48 48');
 631         Portal_MakeWaitingPortal(portal);
 632
 633         return portal;
 634 }
 635
 636 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 637 {
 638         entity portal;
 639         vector ang;
 640         vector org;
 641
 642         org = trace_endpos;
 643         ang = fixedvectoangles2(trace_plane_normal, dir);
 644         fixedmakevectors(ang);
 645
 646         portal = Portal_Spawn(own, org, ang);
 647         if(!portal)
 648                 return 0;
 649
 650         portal.portal_id = portal_id_val;
 651         Portal_SetInPortal(own, portal);
 652
 653         return 1;
 654 }
 655
 656 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 657 {
 658         entity portal;
 659         vector ang;
 660         vector org;
 661
 662         org = trace_endpos;
 663         ang = fixedvectoangles2(trace_plane_normal, dir);
 664         fixedmakevectors(ang);
 665
 666         portal = Portal_Spawn(own, org, ang);
 667         if(!portal)
 668                 return 0;
 669
 670         portal.portal_id = portal_id_val;
 671         Portal_SetOutPortal(own, portal);
 672
 673         return 1;
 674 }