qcsrc/server/race.qc

   1 #include "race.qh"
   2
   3 #include "client.qh"
   4 #include "portals.qh"
   5 #include "scores.qh"
   6 #include "spawnpoints.qh"
   7 #include "bot/api.qh"
   8 #include "command/getreplies.qh"
   9 #include "../common/deathtypes/all.qh"
  10 #include "../common/notifications/all.qh"
  11 #include "../common/mapinfo.qh"
  12 #include <common/net_linked.qh>
  13 #include "../common/triggers/subs.qh"
  14 #include "../lib/warpzone/util_server.qh"
  15 #include "../lib/warpzone/common.qh"
  16 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  17
  18 IntrusiveList g_race_targets;
  19 STATIC_INIT(g_race_targets) { g_race_targets = IL_NEW(); }
  20
  21 void race_InitSpectator()
  22 {
  23         if(g_race_qualifying)
  24                 if(msg_entity.enemy.race_laptime)
  25                         race_SendNextCheckpoint(msg_entity.enemy, 1);
  26 }
  27
  28 void W_Porto_Fail(entity this, float failhard);
  29
  30 float race_readTime(string map, float pos)
  31 {
  32         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  33
  34         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
  35 }
  36
  37 string race_readUID(string map, float pos)
  38 {
  39         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  40
  41         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
  42 }
  43
  44 float race_readPos(string map, float t)
  45 {
  46         for(int i = 1; i <= RANKINGS_CNT; ++i)
  47         {
  48                 int mytime = race_readTime(map, i);
  49                 if(!mytime || mytime > t)
  50                         return i;
  51         }
  52
  53         return 0; // pos is zero if unranked
  54 }
  55
  56 void race_writeTime(string map, float t, string myuid)
  57 {
  58         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  59
  60         float newpos;
  61         newpos = race_readPos(map, t);
  62
  63         float i, prevpos = 0;
  64         for(i = 1; i <= RANKINGS_CNT; ++i)
  65         {
  66                 if(race_readUID(map, i) == myuid)
  67                         prevpos = i;
  68         }
  69         if (prevpos)
  70         {
  71                 // player improved his existing record, only have to iterate on ranks between new and old recs
  72                 for (i = prevpos; i > newpos; --i)
  73                 {
  74                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  75                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  76                 }
  77         }
  78         else
  79         {
  80                 // player has no ranked record yet
  81                 for (i = RANKINGS_CNT; i > newpos; --i)
  82                 {
  83                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  84                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  85                 }
  86         }
  87
  88         // store new time itself
  89         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
  90         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
  91 }
  92
  93 string race_readName(string map, float pos)
  94 {
  95         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  96
  97         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
  98 }
  99
 100
 101 const float MAX_CHECKPOINTS = 255;
 102
 103 spawnfunc(target_checkpoint);
 104
 105 .float race_penalty;
 106 .float race_penalty_accumulator;
 107 .string race_penalty_reason;
 108 .float race_checkpoint; // player: next checkpoint that has to be reached
 109 .entity race_lastpenalty;
 110
 111 .entity sprite;
 112
 113 float race_checkpoint_records[MAX_CHECKPOINTS];
 114 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
 115 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
 116 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
 117 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
 118
 119 float race_highest_checkpoint;
 120 float race_timed_checkpoint;
 121
 122 float defrag_ents;
 123 float defragcpexists;
 124
 125 float race_NextCheckpoint(float f)
 126 {
 127         if(f >= race_highest_checkpoint)
 128                 return 0;
 129         else
 130                 return f + 1;
 131 }
 132
 133 float race_PreviousCheckpoint(float f)
 134 {
 135         if(f == -1)
 136                 return 0;
 137         else if(f == 0)
 138                 return race_highest_checkpoint;
 139         else
 140                 return f - 1;
 141 }
 142
 143 // encode as:
 144 //   0 = common start/finish
 145 // 254 = start
 146 // 255 = finish
 147 float race_CheckpointNetworkID(float f)
 148 {
 149         if(race_timed_checkpoint)
 150         {
 151                 if(f == 0)
 152                         return 254; // start
 153                 else if(f == race_timed_checkpoint)
 154                         return 255; // finish
 155         }
 156         return f;
 157 }
 158
 159 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
 160 {
 161         float recordtime;
 162         string recordholder;
 163         float cp;
 164
 165         if(!e.race_laptime)
 166                 return;
 167
 168         cp = e.race_checkpoint;
 169         recordtime = race_checkpoint_records[cp];
 170         recordholder = race_checkpoint_recordholders[cp];
 171         if(recordholder == e.netname)
 172                 recordholder = "";
 173
 174         if(!IS_REAL_CLIENT(e))
 175                 return;
 176
 177         if(!spec)
 178                 msg_entity = e;
 179         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 180                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 181                 if(spec)
 182                 {
 183                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
 184                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
 185                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
 186                 }
 187                 else
 188                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
 189                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
 190                 WriteInt24_t(MSG_ONE, recordtime);
 191                 WriteString(MSG_ONE, recordholder);
 192         });
 193 }
 194
 195 void race_send_recordtime(float msg)
 196 {
 197         // send the server best time
 198         WriteHeader(msg, TE_CSQC_RACE);
 199         WriteByte(msg, RACE_NET_SERVER_RECORD);
 200         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
 201 }
 202
 203
 204 void race_send_speedaward(float msg)
 205 {
 206         // send the best speed of the round
 207         WriteHeader(msg, TE_CSQC_RACE);
 208         WriteByte(msg, RACE_NET_SPEED_AWARD);
 209         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 210         WriteString(msg, speedaward_holder);
 211 }
 212
 213 void race_send_speedaward_alltimebest(float msg)
 214 {
 215         // send the best speed
 216         WriteHeader(msg, TE_CSQC_RACE);
 217         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 218         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 219         WriteString(msg, speedaward_alltimebest_holder);
 220 }
 221
 222 void race_SendRankings(float pos, float prevpos, float del, float msg)
 223 {
 224         WriteHeader(msg, TE_CSQC_RACE);
 225         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
 226         WriteShort(msg, pos);
 227         WriteShort(msg, prevpos);
 228         WriteShort(msg, del);
 229         WriteString(msg, race_readName(GetMapname(), pos));
 230         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
 231 }
 232
 233 void race_SendStatus(float id, entity e)
 234 {
 235         if(!IS_REAL_CLIENT(e))
 236                 return;
 237
 238         float msg;
 239         if (id == 0)
 240                 msg = MSG_ONE;
 241         else
 242                 msg = MSG_ALL;
 243         msg_entity = e;
 244         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 245                 WriteHeader(msg, TE_CSQC_RACE);
 246                 WriteByte(msg, RACE_NET_SERVER_STATUS);
 247                 WriteShort(msg, id);
 248                 WriteString(msg, e.netname);
 249         });
 250 }
 251
 252 void race_setTime(string map, float t, string myuid, string mynetname, entity e, bool showmessage)
 253 {
 254         // netname only used TEMPORARILY for printing
 255         int newpos = race_readPos(map, t);
 256
 257         int player_prevpos = 0;
 258         for(int i = 1; i <= RANKINGS_CNT; ++i)
 259         {
 260                 if(race_readUID(map, i) == myuid)
 261                         player_prevpos = i;
 262         }
 263
 264         float oldrec;
 265         string oldrec_holder;
 266         if (player_prevpos && (player_prevpos < newpos || !newpos))
 267         {
 268                 oldrec = race_readTime(GetMapname(), player_prevpos);
 269                 race_SendStatus(0, e); // "fail"
 270                 if(showmessage)
 271                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
 272                 return;
 273         }
 274         else if (!newpos)
 275         {
 276                 // no ranking, time worse than the worst ranked
 277                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
 278                 race_SendStatus(0, e); // "fail"
 279                 if(showmessage)
 280                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
 281                 return;
 282         }
 283
 284         // if we didn't hit a return yet, we have a new record!
 285
 286         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
 287         if(myuid == "")
 288         {
 289                 if(showmessage)
 290                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
 291                 return;
 292         }
 293
 294         if(uid2name(myuid) == "^1Unregistered Player")
 295         {
 296                 if(showmessage)
 297                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_NAME, mynetname, t);
 298                 return;
 299         }
 300
 301         oldrec = race_readTime(GetMapname(), newpos);
 302         oldrec_holder = race_readName(GetMapname(), newpos);
 303
 304         // store new ranking
 305         race_writeTime(GetMapname(), t, myuid);
 306
 307         if (newpos == 1 && showmessage)
 308         {
 309                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
 310                 race_send_recordtime(MSG_ALL);
 311         }
 312
 313         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
 314         if(rankings_reply)
 315                 strunzone(rankings_reply);
 316         rankings_reply = strzone(getrankings());
 317
 318         if(newpos == player_prevpos)
 319         {
 320                 if(showmessage)
 321                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
 322                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 323                 else { race_SendStatus(1, e); } // "new time"
 324         }
 325         else if(oldrec == 0)
 326         {
 327                 if(showmessage)
 328                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
 329                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 330                 else { race_SendStatus(2, e); } // "new rank"
 331         }
 332         else
 333         {
 334                 if(showmessage)
 335                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
 336                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 337                 else { race_SendStatus(2, e); } // "new rank"
 338         }
 339 }
 340
 341 void race_deleteTime(string map, float pos)
 342 {
 343         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 344
 345         for(int i = pos; i <= RANKINGS_CNT; ++i)
 346         {
 347                 string therank = ftos(i);
 348                 if (i == RANKINGS_CNT)
 349                 {
 350                         db_remove(ServerProgsDB, strcat(map, rr, "time", therank));
 351                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank));
 352                 }
 353                 else
 354                 {
 355                         db_put(ServerProgsDB, strcat(map, rr, "time", therank), ftos(race_readTime(GetMapname(), i+1)));
 356                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank), race_readUID(GetMapname(), i+1));
 357                 }
 358         }
 359
 360         race_SendRankings(pos, 0, 1, MSG_ALL);
 361         if(pos == 1)
 362                 race_send_recordtime(MSG_ALL);
 363
 364         if(rankings_reply)
 365                 strunzone(rankings_reply);
 366         rankings_reply = strzone(getrankings());
 367 }
 368
 369 void race_SendTime(entity e, float cp, float t, float tvalid)
 370 {
 371         float snew, l;
 372
 373         if(g_race_qualifying)
 374                 t += e.race_penalty_accumulator;
 375
 376         t = TIME_ENCODE(t); // make integer
 377
 378         if(tvalid)
 379         if(cp == race_timed_checkpoint) // finish line
 380         if (!e.race_completed)
 381         {
 382                 float s;
 383                 if(g_race_qualifying)
 384                 {
 385                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 386                         if(!s || t < s)
 387                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 388                 }
 389                 else
 390                 {
 391                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 392                         if(!s || t < s)
 393                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 394
 395                         s = PlayerScore_Add(e, SP_RACE_TIME, 0);
 396                         snew = TIME_ENCODE(time - game_starttime);
 397                         PlayerScore_Add(e, SP_RACE_TIME, snew - s);
 398                         l = PlayerTeamScore_Add(e, SP_RACE_LAPS, ST_RACE_LAPS, 1);
 399
 400                         if(autocvar_fraglimit)
 401                                 if(l >= autocvar_fraglimit)
 402                                         race_StartCompleting();
 403
 404                         if(race_completing)
 405                         {
 406                                 e.race_completed = 1;
 407                                 MAKE_INDEPENDENT_PLAYER(e);
 408                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FINISHED, e.netname);
 409                                 ClientData_Touch(e);
 410                         }
 411                 }
 412         }
 413
 414         float recordtime;
 415         string recordholder;
 416         if(g_race_qualifying)
 417         {
 418                 if(tvalid)
 419                 {
 420                         recordtime = race_checkpoint_records[cp];
 421                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
 422                         if(recordholder == e.netname)
 423                                 recordholder = "";
 424
 425                         if(t != 0)
 426                         {
 427                                 if(cp == race_timed_checkpoint)
 428                                 {
 429                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e, true);
 430                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
 431                                 }
 432                                 if(t < recordtime || recordtime == 0)
 433                                 {
 434                                         race_checkpoint_records[cp] = t;
 435                                         if(race_checkpoint_recordholders[cp])
 436                                                 strunzone(race_checkpoint_recordholders[cp]);
 437                                         race_checkpoint_recordholders[cp] = strzone(e.netname);
 438                                         if(g_race_qualifying)
 439                                         {
 440                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, LAMBDA(race_SendNextCheckpoint(it, 0)));
 441                                         }
 442                                 }
 443                         }
 444                 }
 445                 else
 446                 {
 447                         // dummies
 448                         t = 0;
 449                         recordtime = 0;
 450                         recordholder = "";
 451                 }
 452
 453                 if(IS_REAL_CLIENT(e))
 454                 {
 455                         msg_entity = e;
 456                         if(g_race_qualifying)
 457                         {
 458                                 WRITESPECTATABLE_MSG_ONE(msg_entity, {
 459                                         WriteHeader(MSG_ONE, TE_CSQC_RACE);
 460                                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
 461                                         WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 462                                         WriteInt24_t(MSG_ONE, t); // time to that intermediate
 463                                         WriteInt24_t(MSG_ONE, recordtime); // previously best time
 464                                         WriteString(MSG_ONE, recordholder); // record holder
 465                                 });
 466                         }
 467                 }
 468         }
 469         else // RACE! Not Qualifying
 470         {
 471                 float mylaps, lother, othtime;
 472                 entity oth;
 473                 oth = race_checkpoint_lastplayers[cp];
 474                 if(oth)
 475                 {
 476                         mylaps = PlayerScore_Add(e, SP_RACE_LAPS, 0);
 477                         lother = race_checkpoint_lastlaps[cp];
 478                         othtime = race_checkpoint_lasttimes[cp];
 479                 }
 480                 else
 481                         mylaps = lother = othtime = 0;
 482
 483                 if(IS_REAL_CLIENT(e))
 484                 {
 485                         msg_entity = e;
 486                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 487                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 488                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
 489                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 490                                 if(e == oth)
 491                                 {
 492                                         WriteInt24_t(MSG_ONE, 0);
 493                                         WriteByte(MSG_ONE, 0);
 494                                         WriteString(MSG_ONE, "");
 495                                 }
 496                                 else
 497                                 {
 498                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
 499                                         WriteByte(MSG_ONE, mylaps - lother);
 500                                         WriteString(MSG_ONE, oth.netname); // record holder
 501                                 }
 502                         });
 503                 }
 504
 505                 race_checkpoint_lastplayers[cp] = e;
 506                 race_checkpoint_lasttimes[cp] = time;
 507                 race_checkpoint_lastlaps[cp] = mylaps;
 508
 509                 if(IS_REAL_CLIENT(oth))
 510                 {
 511                         msg_entity = oth;
 512                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 513                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 514                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
 515                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 516                                 if(e == oth)
 517                                 {
 518                                         WriteInt24_t(MSG_ONE, 0);
 519                                         WriteByte(MSG_ONE, 0);
 520                                         WriteString(MSG_ONE, "");
 521                                 }
 522                                 else
 523                                 {
 524                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
 525                                         WriteByte(MSG_ONE, lother - mylaps);
 526                                         WriteString(MSG_ONE, e.netname); // record holder
 527                                 }
 528                         });
 529                 }
 530         }
 531 }
 532
 533 void race_ClearTime(entity e)
 534 {
 535         e.race_checkpoint = 0;
 536         e.race_laptime = 0;
 537         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
 538         e.race_penalty_accumulator = 0;
 539         e.race_lastpenalty = NULL;
 540
 541         if(!IS_REAL_CLIENT(e))
 542                 return;
 543
 544         msg_entity = e;
 545         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 546                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 547                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
 548         });
 549 }
 550
 551 void dumpsurface(entity e)
 552 {
 553         float n, si, ni;
 554         vector norm, vec;
 555         LOG_INFO("Surfaces of ", etos(e), ":\n");
 556
 557         LOG_INFO("TEST = ", ftos(getsurfacenearpoint(e, '0 0 0')), "\n");
 558
 559         for(si = 0; ; ++si)
 560         {
 561                 n = getsurfacenumpoints(e, si);
 562                 if(n <= 0)
 563                         break;
 564                 LOG_INFO("  Surface ", ftos(si), ":\n");
 565                 norm = getsurfacenormal(e, si);
 566                 LOG_INFO("    Normal = ", vtos(norm), "\n");
 567                 for(ni = 0; ni < n; ++ni)
 568                 {
 569                         vec = getsurfacepoint(e, si, ni);
 570                         LOG_INFO("    Point ", ftos(ni), " = ", vtos(vec), " (", ftos(norm * vec), ")\n");
 571                 }
 572         }
 573 }
 574
 575 void checkpoint_passed(entity this, entity player)
 576 {
 577         if(player.personal && autocvar_g_allow_checkpoints)
 578                 return; // practice mode!
 579
 580         string oldmsg;
 581         entity cp;
 582
 583         if(player.classname == "porto")
 584         {
 585                 // do not allow portalling through checkpoints
 586                 trace_plane_normal = normalize(-1 * player.velocity);
 587                 W_Porto_Fail(player, 0);
 588                 return;
 589         }
 590
 591         /*
 592          * Trigger targets
 593          */
 594         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
 595         {
 596                 oldmsg = this.message;
 597                 this.message = "";
 598                 SUB_UseTargets(this, player, player);
 599                 this.message = oldmsg;
 600         }
 601
 602         if (!IS_PLAYER(player))
 603                 return;
 604
 605         /*
 606          * Remove unauthorized equipment
 607          */
 608         Portal_ClearAll(player);
 609
 610         player.porto_forbidden = 2; // decreased by 1 each StartFrame
 611
 612         if(defrag_ents)
 613         {
 614                 if(this.race_checkpoint == -2)
 615                 {
 616                         this.race_checkpoint = player.race_checkpoint;
 617                 }
 618
 619                 float largest_cp_id = 0;
 620                 float cp_amount = 0;
 621                 for(cp = NULL; (cp = find(cp, classname, "target_checkpoint"));)
 622                 {
 623                         cp_amount += 1;
 624                         if(cp.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
 625                         {
 626                                 largest_cp_id = cp.race_checkpoint;
 627                                 for(cp = NULL; (cp = find(cp, classname, "target_stopTimer"));)
 628                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 629                                 race_highest_checkpoint = largest_cp_id + 1;
 630                                 race_timed_checkpoint = largest_cp_id + 1;
 631
 632                                 for(cp = NULL; (cp = find(cp, classname, "target_checkpoint"));)
 633                                 {
 634                                         if(cp.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
 635                                                 defragcpexists = -1;
 636                                 }
 637                         }
 638                 }
 639                 if(cp_amount == 0)
 640                 {
 641                         for(cp = NULL; (cp = find(cp, classname, "target_stopTimer"));)
 642                                 cp.race_checkpoint = 1;
 643                         race_highest_checkpoint = 1;
 644                         race_timed_checkpoint = 1;
 645                 }
 646         }
 647
 648         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
 649         {
 650                 if(this.race_penalty)
 651                 {
 652                         if(player.race_lastpenalty != this)
 653                         {
 654                                 player.race_lastpenalty = this;
 655                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
 656                         }
 657                 }
 658
 659                 if(player.race_penalty)
 660                         return;
 661
 662                 /*
 663                  * Trigger targets
 664                  */
 665                 if(this.spawnflags & 2)
 666                 {
 667                         oldmsg = this.message;
 668                         this.message = "";
 669                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
 670                         this.message = oldmsg;
 671                 }
 672
 673                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
 674                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
 675                 player.race_respawn_checkpoint = this.race_checkpoint;
 676                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
 677                 player.race_started = 1;
 678
 679                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
 680
 681                 if(!this.race_checkpoint) // start line
 682                 {
 683                         player.race_laptime = time;
 684                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
 685                         player.race_penalty_accumulator = 0;
 686                         player.race_lastpenalty = NULL;
 687                 }
 688
 689                 if(g_race_qualifying)
 690                         race_SendNextCheckpoint(player, 0);
 691
 692                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
 693                 {
 694                         float fh;
 695                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
 696                         if(fh >= 0)
 697                         {
 698                                 for(cp = NULL; (cp = find(cp, classname, "target_checkpoint"));)
 699                                 fputs(fh, strcat(cp.targetname, " ", ftos(cp.race_checkpoint), "\n"));
 700                         }
 701                         fclose(fh);
 702                 }
 703         }
 704         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
 705         {
 706                 // ignored
 707         }
 708         else
 709         {
 710                 if(this.spawnflags & 4)
 711                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, player.origin, '0 0 0');
 712         }
 713 }
 714
 715 void checkpoint_touch(entity this, entity toucher)
 716 {
 717         EXACTTRIGGER_TOUCH(this, toucher);
 718         checkpoint_passed(this, toucher);
 719 }
 720
 721 void checkpoint_use(entity this, entity actor, entity trigger)
 722 {
 723         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
 724                 return;
 725
 726         checkpoint_passed(this, actor);
 727 }
 728
 729 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
 730 {
 731         entity own = this.owner;
 732         if(this.realowner)
 733                 own = this.realowner; // target support
 734
 735         if(view.race_checkpoint == -1 || own.race_checkpoint == -2)
 736                 return true;
 737         else if(view.race_checkpoint == own.race_checkpoint)
 738                 return true;
 739         else
 740                 return false;
 741 }
 742
 743 void trigger_race_checkpoint_verify(entity this)
 744 {
 745     static bool have_verified;
 746         if (have_verified) return;
 747         have_verified = true;
 748
 749         bool qual = g_race_qualifying;
 750
 751         int pl_race_checkpoint = 0;
 752         int pl_race_place = 0;
 753
 754         if (g_race) {
 755                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
 756                         pl_race_checkpoint = race_NextCheckpoint(i);
 757
 758                         // race only (middle of the race)
 759                         g_race_qualifying = false;
 760                         pl_race_place = 0;
 761                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 762                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
 763             }
 764
 765                         if (i == 0) {
 766                                 // qualifying only
 767                                 g_race_qualifying = 1;
 768                                 pl_race_place = race_lowest_place_spawn;
 769                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 770                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 771                 }
 772
 773                                 // race only (initial spawn)
 774                                 g_race_qualifying = 0;
 775                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
 776                                         pl_race_place = p;
 777                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 778                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
 779                     }
 780                                 }
 781                         }
 782                 }
 783         } else if (!defrag_ents) {
 784                 // qualifying only
 785                 pl_race_checkpoint = race_NextCheckpoint(0);
 786                 g_race_qualifying = 1;
 787                 pl_race_place = race_lowest_place_spawn;
 788                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 789                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 790         }
 791         } else {
 792                 pl_race_checkpoint = race_NextCheckpoint(0);
 793                 g_race_qualifying = 1;
 794                 pl_race_place = 0; // there's only one spawn on defrag maps
 795
 796                 // check if a defragcp file already exists, then read it and apply the checkpoint order
 797                 float fh;
 798                 float len;
 799                 string l;
 800
 801                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
 802                 if (fh >= 0) {
 803                         while ((l = fgets(fh))) {
 804                                 len = tokenize_console(l);
 805                                 if (len != 2) {
 806                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
 807                                         continue;
 808                                 }
 809                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 810                                         if (argv(0) == cp.targetname) {
 811                                                 cp.race_checkpoint = stof(argv(1));
 812                     }
 813                 }
 814                         }
 815                         fclose(fh);
 816                 }
 817         }
 818
 819         g_race_qualifying = qual;
 820
 821         IL_EACH(g_race_targets, true,
 822         {
 823                 entity cpt = it;
 824                 FOREACH_ENTITY_STRING(target, cpt.targetname,
 825                 {
 826                         vector org = (it.absmin + it.absmax) * 0.5;
 827                         if(cpt.race_checkpoint == 0)
 828                                 WaypointSprite_SpawnFixed(WP_RaceStart, org, it, sprite, RADARICON_NONE);
 829                         else
 830                                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, org, it, sprite, RADARICON_NONE);
 831
 832                         it.sprite.realowner = cpt;
 833                         it.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 834                 });
 835         });
 836
 837         if (race_timed_checkpoint) {
 838                 if (defrag_ents) {
 839                         IL_EACH(g_race_targets, true,
 840                         {
 841                                 entity cpt = it;
 842                                 if(it.classname == "target_startTimer" || it.classname == "target_stopTimer") {
 843                                         FOREACH_ENTITY_STRING(target, cpt.targetname, {
 844                                                 WaypointSprite_UpdateSprites(it.sprite, ((cpt.classname == "target_startTimer") ? WP_RaceStart : WP_RaceFinish), WP_Null, WP_Null);
 845                                         });
 846                                 }
 847                                 if(it.classname == "target_checkpoint") {
 848                                         if(it.race_checkpoint == -2)
 849                                                 defragcpexists = -1; // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
 850                                 }
 851                         });
 852                         if (defragcpexists != -1) {
 853                                 float largest_cp_id = 0;
 854                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 855                                         if (cp.race_checkpoint > largest_cp_id) {
 856                                                 largest_cp_id = cp.race_checkpoint;
 857                     }
 858                 }
 859                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 860                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 861                 }
 862                                 race_highest_checkpoint = largest_cp_id + 1;
 863                                 race_timed_checkpoint = largest_cp_id + 1;
 864                         } else {
 865                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 866                                         cp.race_checkpoint = 255; // finish line
 867                 }
 868                                 race_highest_checkpoint = 255;
 869                                 race_timed_checkpoint = 255;
 870                         }
 871                 } else {
 872                         IL_EACH(g_racecheckpoints, it.sprite,
 873                         {
 874                                 if (it.race_checkpoint == 0) {
 875                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceStart, WP_Null, WP_Null);
 876                 } else if (it.race_checkpoint == race_timed_checkpoint) {
 877                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceFinish, WP_Null, WP_Null);
 878                                 }
 879             });
 880                 }
 881         }
 882
 883         if (defrag_ents) {
 884                 for (entity trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); ) {
 885                         for (entity targ = NULL; (targ = find(targ, targetname, trigger.target)); ) {
 886                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
 887                                         trigger.wait = 0;
 888                                         trigger.delay = 0;
 889                                         targ.wait = 0;
 890                                         targ.delay = 0;
 891
 892                     // These just make the game crash on some maps with oddly shaped triggers.
 893                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
 894                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
 895                     // (happened on item triggers too)
 896                     //
 897                                         //targ.wait = -2;
 898                                         //targ.delay = 0;
 899
 900                                         //setsize(targ, trigger.mins, trigger.maxs);
 901                                         //setorigin(targ, trigger.origin);
 902                                         //remove(trigger);
 903                                 }
 904             }
 905         }
 906         }
 907 }
 908
 909 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
 910 {
 911         if(g_race_qualifying)
 912         {
 913                 // spawn at first
 914                 if(this.race_checkpoint != 0)
 915                         return '-1 0 0';
 916                 if(spot.race_place != race_lowest_place_spawn)
 917                         return '-1 0 0';
 918         }
 919         else
 920         {
 921                 if(this.race_checkpoint != player.race_respawn_checkpoint)
 922                         return '-1 0 0';
 923                 // try reusing the previous spawn
 924                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
 925                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
 926                 if(this.race_checkpoint == 0)
 927                 {
 928                         int pl = player.race_place;
 929                         if(pl > race_highest_place_spawn)
 930                                 pl = 0;
 931                         if(pl == 0 && !player.race_started)
 932                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 933                         if(spot.race_place != pl)
 934                                 return '-1 0 0';
 935                 }
 936         }
 937         return current;
 938 }
 939
 940 spawnfunc(trigger_race_checkpoint)
 941 {
 942         vector o;
 943         if(!g_race && !g_cts) { delete(this); return; }
 944
 945         EXACTTRIGGER_INIT;
 946
 947         this.use = checkpoint_use;
 948         if (!(this.spawnflags & 1))
 949                 settouch(this, checkpoint_touch);
 950
 951         o = (this.absmin + this.absmax) * 0.5;
 952         tracebox(o, PL_MIN_CONST, PL_MAX_CONST, o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
 953         waypoint_spawnforitem_force(this, trace_endpos);
 954         this.nearestwaypointtimeout = -1;
 955
 956         if(this.message == "")
 957                 this.message = "went backwards";
 958         if (this.message2 == "")
 959                 this.message2 = "was pushed backwards by";
 960         if (this.race_penalty_reason == "")
 961                 this.race_penalty_reason = "missing a checkpoint";
 962
 963         this.race_checkpoint = this.cnt;
 964
 965         if(this.race_checkpoint > race_highest_checkpoint)
 966         {
 967                 race_highest_checkpoint = this.race_checkpoint;
 968                 if(this.spawnflags & 8)
 969                         race_timed_checkpoint = this.race_checkpoint;
 970                 else
 971                         race_timed_checkpoint = 0;
 972         }
 973
 974         if(!this.race_penalty)
 975         {
 976                 if(this.race_checkpoint)
 977                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
 978                 else
 979                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
 980         }
 981
 982         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 983         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
 984
 985         IL_PUSH(g_racecheckpoints, this);
 986
 987         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
 988 }
 989
 990 spawnfunc(target_checkpoint) // defrag entity
 991 {
 992         if(!g_race && !g_cts) { delete(this); return; }
 993         defrag_ents = 1;
 994
 995         // if this is targeted, then it probably isn't a trigger
 996         bool is_trigger = !boolean(!this.nottargeted && this.targetname != "");
 997
 998         if(is_trigger)
 999                 EXACTTRIGGER_INIT;
1000
1001         this.use = checkpoint_use;
1002         if (is_trigger && !(this.spawnflags & 1))
1003                 settouch(this, checkpoint_touch);
1004
1005         vector org = this.origin;
1006
1007         // bots should only pathfind to this if it is a valid touchable trigger
1008         if(is_trigger)
1009         {
1010                 org = (this.absmin + this.absmax) * 0.5;
1011                 tracebox(org, PL_MIN_CONST, PL_MAX_CONST, org - '0 0 1' * (org.z - this.absmin.z), MOVE_NORMAL, this);
1012                 waypoint_spawnforitem_force(this, trace_endpos);
1013                 this.nearestwaypointtimeout = -1;
1014         }
1015
1016         if(this.message == "")
1017                 this.message = "went backwards";
1018         if (this.message2 == "")
1019                 this.message2 = "was pushed backwards by";
1020         if (this.race_penalty_reason == "")
1021                 this.race_penalty_reason = "missing a checkpoint";
1022
1023         if(this.classname == "target_startTimer")
1024                 this.race_checkpoint = 0;
1025         else
1026                 this.race_checkpoint = -2;
1027
1028         race_timed_checkpoint = 1;
1029
1030         IL_PUSH(g_race_targets, this);
1031
1032         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
1033 }
1034
1035 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
1036 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
1037
1038 void race_AbandonRaceCheck(entity p)
1039 {
1040         if(race_completing && !p.race_completed)
1041         {
1042                 p.race_completed = 1;
1043                 MAKE_INDEPENDENT_PLAYER(p);
1044                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1045                 ClientData_Touch(p);
1046         }
1047 }
1048
1049 void race_StartCompleting()
1050 {
1051         race_completing = 1;
1052         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), LAMBDA(race_AbandonRaceCheck(it)));
1053 }
1054
1055 void race_PreparePlayer(entity this)
1056 {
1057         race_ClearTime(this);
1058         this.race_place = 0;
1059         this.race_started = 0;
1060         this.race_respawn_checkpoint = 0;
1061         this.race_respawn_spotref = NULL;
1062 }
1063
1064 void race_RetractPlayer(entity this)
1065 {
1066         if(!g_race && !g_cts)
1067                 return;
1068         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1069                 race_ClearTime(this);
1070         this.race_checkpoint = this.race_respawn_checkpoint;
1071 }
1072
1073 spawnfunc(info_player_race)
1074 {
1075         if(!g_race && !g_cts) { delete(this); return; }
1076         ++race_spawns;
1077         spawnfunc_info_player_deathmatch(this);
1078
1079         if(this.race_place > race_highest_place_spawn)
1080                 race_highest_place_spawn = this.race_place;
1081         if(this.race_place < race_lowest_place_spawn)
1082                 race_lowest_place_spawn = this.race_place;
1083 }
1084
1085 void race_ClearRecords()
1086 {
1087         float i;
1088
1089         for(i = 0; i < MAX_CHECKPOINTS; ++i)
1090         {
1091                 race_checkpoint_records[i] = 0;
1092                 if(race_checkpoint_recordholders[i])
1093                         strunzone(race_checkpoint_recordholders[i]);
1094                 race_checkpoint_recordholders[i] = string_null;
1095         }
1096
1097         FOREACH_CLIENT(true, LAMBDA(
1098                 float p = it.race_place;
1099                 race_PreparePlayer(it);
1100                 it.race_place = p;
1101         ));
1102 }
1103
1104 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1105 {
1106         if(g_race_qualifying)
1107         {
1108                 pl.race_penalty_accumulator += penalty;
1109                 if(IS_REAL_CLIENT(pl))
1110                 {
1111                         msg_entity = pl;
1112                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1113                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1114                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1115                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1116                                 WriteString(MSG_ONE, reason);
1117                         });
1118                 }
1119         }
1120         else
1121         {
1122                 pl.race_penalty = time + penalty;
1123                 if(IS_REAL_CLIENT(pl))
1124                 {
1125                         msg_entity = pl;
1126                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1127                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1128                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1129                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1130                                 WriteString(MSG_ONE, reason);
1131                         });
1132                 }
1133         }
1134 }
1135
1136 void penalty_touch(entity this, entity toucher)
1137 {
1138         EXACTTRIGGER_TOUCH(this, toucher);
1139         if(toucher.race_lastpenalty != this)
1140         {
1141                 toucher.race_lastpenalty = this;
1142                 race_ImposePenaltyTime(toucher, this.race_penalty, this.race_penalty_reason);
1143         }
1144 }
1145
1146 void penalty_use(entity this, entity actor, entity trigger)
1147 {
1148         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1149 }
1150
1151 spawnfunc(trigger_race_penalty)
1152 {
1153         // TODO: find out why this wasnt done:
1154         //if(!g_cts && !g_race) { remove(this); return; }
1155
1156         EXACTTRIGGER_INIT;
1157
1158         this.use = penalty_use;
1159         if (!(this.spawnflags & 1))
1160                 settouch(this, penalty_touch);
1161
1162         if (this.race_penalty_reason == "")
1163                 this.race_penalty_reason = "missing a checkpoint";
1164         if (!this.race_penalty)
1165                 this.race_penalty = 5;
1166 }
1167
1168 float race_GetFractionalLapCount(entity e)
1169 {
1170         // interesting metrics (idea by KrimZon) to maybe sort players in the
1171         // scoreboard, immediately updates when overtaking
1172         //
1173         // requires the track to be built so you never get farther away from the
1174         // next checkpoint, though, and current Xonotic race maps are not built that
1175         // way
1176         //
1177         // also, this code is slow and would need optimization (i.e. "next CP"
1178         // links on CP entities)
1179
1180         float l;
1181         l = PlayerScore_Add(e, SP_RACE_LAPS, 0);
1182         if(e.race_completed)
1183                 return l; // not fractional
1184
1185         vector o0, o1;
1186         float bestfraction, fraction;
1187         entity lastcp;
1188         float nextcpindex, lastcpindex;
1189
1190         nextcpindex = max(e.race_checkpoint, 0);
1191         lastcpindex = e.race_respawn_checkpoint;
1192         lastcp = e.race_respawn_spotref;
1193
1194         if(nextcpindex == lastcpindex)
1195                 return l; // finish
1196
1197         bestfraction = 1;
1198         IL_EACH(g_racecheckpoints, true,
1199         {
1200                 if(it.race_checkpoint != lastcpindex)
1201                         continue;
1202                 if(lastcp)
1203                         if(it != lastcp)
1204                                 continue;
1205                 o0 = (it.absmin + it.absmax) * 0.5;
1206                 IL_EACH(g_racecheckpoints, true,
1207                 {
1208                         if(it.race_checkpoint != nextcpindex)
1209                                 continue;
1210                         o1 = (it.absmin + it.absmax) * 0.5;
1211                         if(o0 == o1)
1212                                 continue;
1213                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1214                         if(fraction < bestfraction)
1215                                 bestfraction = fraction;
1216                 });
1217         });
1218
1219         // we are at CP "nextcpindex - bestfraction"
1220         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1221         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1222         float c, nc;
1223         nc = race_highest_checkpoint + 1;
1224         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1225
1226         return l + c / nc;
1227 }