qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include "command/common.qh"
   4 #include "mutators/_mod.qh"
   5 #include <common/net_linked.qh>
   6 #include "../common/playerstats.qh"
   7 #include "../common/teams.qh"
   8
   9 .entity scorekeeper;
  10 entity teamscorekeepers[16];
  11 float teamscores_entities_count;
  12 var .float scores_primary;
  13 var .float teamscores_primary;
  14 float scores_flags_primary;
  15 float teamscores_flags_primary;
  16
  17 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, float strict) // returns: cmp value, best prio
  18 {
  19         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  20                 return previous;
  21         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  22                 return previous;
  23         if (t1.(field) == t2.(field))
  24                 return previous;
  25
  26         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  27
  28         if(fieldflags & SFL_ZERO_IS_WORST)
  29         {
  30                 if (t1.(field) == 0)
  31                 {
  32                         previous.x = -1;
  33                         return previous;
  34                 }
  35                 else if (t2.(field) == 0)
  36                 {
  37                         previous.x = +1;
  38                         return previous;
  39                 }
  40         }
  41
  42         if (fieldflags & SFL_LOWER_IS_BETTER)
  43                 previous.x = (t2.(field) - t1.(field));
  44         else
  45                 previous.x = (t1.(field) - t2.(field));
  46
  47         return previous;
  48 }
  49
  50 /*
  51  * teamscore entities
  52  */
  53
  54 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  55 {
  56         float i, p, longflags;
  57
  58         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  59         int t = this.team - 1;
  60         assert(t, eprint(this));
  61         WriteByte(MSG_ENTITY, t);
  62
  63         longflags = 0;
  64         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  65                 if(this.(teamscores(i)) > 127 || this.(teamscores(i)) <= -128)
  66                         longflags |= p;
  67
  68 #if MAX_TEAMSCORE <= 8
  69         WriteByte(MSG_ENTITY, sendflags);
  70         WriteByte(MSG_ENTITY, longflags);
  71 #else
  72         WriteShort(MSG_ENTITY, sendflags);
  73         WriteShort(MSG_ENTITY, longflags);
  74 #endif
  75         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  76                 if(sendflags & p)
  77                 {
  78                         if(longflags & p)
  79                                 WriteInt24_t(MSG_ENTITY, this.(teamscores(i)));
  80                         else
  81                                 WriteChar(MSG_ENTITY, this.(teamscores(i)));
  82                 }
  83
  84         return true;
  85 }
  86
  87 void TeamScore_Spawn(float t, string name)
  88 {
  89         entity ts = new_pure(csqc_score_team);
  90         ts.netname = name; // not used yet, FIXME
  91         ts.team = t;
  92         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
  93         teamscorekeepers[t - 1] = ts;
  94         ++teamscores_entities_count;
  95         PlayerStats_GameReport_AddTeam(t);
  96 }
  97
  98 float TeamScore_AddToTeam(float t, float scorefield, float score)
  99 {
 100         entity s;
 101
 102         if(game_stopped)
 103                 score = 0;
 104
 105         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 106         if(t <= 0 || t >= 16)
 107         {
 108                 if(game_stopped)
 109                         return 0;
 110                 error("Adding score to invalid team!");
 111         }
 112         s = teamscorekeepers[t - 1];
 113         if(!s)
 114         {
 115                 if(game_stopped)
 116                         return 0;
 117                 error("Adding score to unknown team!");
 118         }
 119         if(score)
 120                 if(teamscores_label(scorefield) != "")
 121                         s.SendFlags |= (2 ** scorefield);
 122         return (s.(teamscores(scorefield)) += score);
 123 }
 124
 125 float TeamScore_Add(entity player, float scorefield, float score)
 126 {
 127         return TeamScore_AddToTeam(player.team, scorefield, score);
 128 }
 129
 130 float TeamScore_Compare(entity t1, entity t2, float strict)
 131 {
 132         if(!t1 || !t2) return (!t2) - !t1;
 133
 134         vector result = '0 0 0';
 135         float i;
 136         for(i = 0; i < MAX_TEAMSCORE; ++i)
 137         {
 138                 var .float f;
 139                 f = teamscores(i);
 140                 result = ScoreField_Compare(t1, t2, f, teamscores_flags(i), result, strict);
 141         }
 142
 143         if (result.x == 0 && strict)
 144                 result.x = t1.team - t2.team;
 145
 146         return result.x;
 147 }
 148
 149 /*
 150  * the scoreinfo entity
 151  */
 152
 153 void ScoreInfo_SetLabel_PlayerScore(PlayerScoreField i, string label, float scoreflags)
 154 {
 155         scores_label(i) = label;
 156         scores_flags(i) = scoreflags;
 157         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 158         {
 159                 scores_primary = scores(i);
 160                 scores_flags_primary = scoreflags;
 161         }
 162         if(label != "")
 163         {
 164                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 165                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 166         }
 167 }
 168
 169 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 170 {
 171         teamscores_label(i) = label;
 172         teamscores_flags(i) = scoreflags;
 173         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 174         {
 175                 teamscores_primary = teamscores(i);
 176                 teamscores_flags_primary = scoreflags;
 177         }
 178         if(label != "")
 179         {
 180                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 181                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 182         }
 183 }
 184
 185 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 186 {
 187         float i;
 188         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 189         WriteRegistered(Gametypes, MSG_ENTITY, MapInfo_LoadedGametype);
 190         FOREACH(Scores, true, {
 191                 WriteString(MSG_ENTITY, scores_label(it));
 192                 WriteByte(MSG_ENTITY, scores_flags(it));
 193         });
 194         for(i = 0; i < MAX_TEAMSCORE; ++i)
 195         {
 196                 WriteString(MSG_ENTITY, teamscores_label(i));
 197                 WriteByte(MSG_ENTITY, teamscores_flags(i));
 198         }
 199         return true;
 200 }
 201
 202 void ScoreInfo_Init(int teams)
 203 {
 204         if(scores_initialized)
 205         {
 206                 scores_initialized.SendFlags |= 1; // force a resend
 207         }
 208         else
 209         {
 210                 scores_initialized = new_pure(ent_client_scoreinfo);
 211                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 212         }
 213         if(teams & BIT(0))
 214                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 215         if(teams & BIT(1))
 216                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 217         if(teams & BIT(2))
 218                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 219         if(teams & BIT(3))
 220                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 221 }
 222
 223 /*
 224  * per-player score entities
 225  */
 226
 227 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 228 {
 229         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 230         WriteByte(MSG_ENTITY, etof(this.owner));
 231
 232         int longflags = 0;
 233         FOREACH(Scores, true, {
 234             int p = 1 << (i % 16);
 235                 if (this.(scores(it)) > 127 || this.(scores(it)) <= -128)
 236                         longflags |= p;
 237     });
 238
 239         WriteShort(MSG_ENTITY, sendflags);
 240         WriteShort(MSG_ENTITY, longflags);
 241         FOREACH(Scores, true, {
 242             int p = 1 << (i % 16);
 243                 if (sendflags & p)
 244                 {
 245                         if(longflags & p)
 246                                 WriteInt24_t(MSG_ENTITY, this.(scores(it)));
 247                         else
 248                                 WriteChar(MSG_ENTITY, this.(scores(it)));
 249                 }
 250     });
 251
 252         return true;
 253 }
 254
 255 float PlayerScore_Clear(entity player)
 256 {
 257         entity sk;
 258
 259         if(teamscores_entities_count)
 260                 return 0;
 261
 262         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 263
 264         sk = player.scorekeeper;
 265         FOREACH(Scores, true, {
 266                 if(sk.(scores(it)) != 0)
 267                         if(scores_label(it) != "")
 268                                 sk.SendFlags |= (2 ** (i % 16));
 269                 if(i != SP_ELO.m_id)
 270                         sk.(scores(it)) = 0;
 271         });
 272
 273         return 1;
 274 }
 275
 276 void Score_ClearAll()
 277 {
 278         entity sk;
 279         float t;
 280         FOREACH_CLIENTSLOT(true, {
 281                 sk = it.scorekeeper;
 282                 if (!sk) continue;
 283                 FOREACH(Scores, true, {
 284                         if(sk.(scores(it)) != 0)
 285                                 if(scores_label(it) != "")
 286                                         sk.SendFlags |= (2 ** (i % 16));
 287                         if(i != SP_ELO.m_id)
 288                                 sk.(scores(it)) = 0;
 289                 });
 290         });
 291         for(t = 0; t < 16; ++t)
 292         {
 293                 sk = teamscorekeepers[t];
 294                 if(!sk)
 295                         continue;
 296                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 297                 {
 298                         if(sk.(teamscores(j)) != 0)
 299                                 if(teamscores_label(j) != "")
 300                                         sk.SendFlags |= (2 ** j);
 301                         sk.(teamscores(j)) = 0;
 302                 }
 303         }
 304 }
 305
 306 void PlayerScore_Attach(entity player)
 307 {
 308         if(player.scorekeeper)
 309                 error("player already has a scorekeeper");
 310         entity sk = new_pure(scorekeeper);
 311         sk.owner = player;
 312         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 313         player.scorekeeper = sk;
 314 }
 315
 316 void PlayerScore_Detach(entity player)
 317 {
 318         if(!player.scorekeeper)
 319                 error("player has no scorekeeper");
 320         delete(player.scorekeeper);
 321         player.scorekeeper = NULL;
 322 }
 323
 324 float PlayerScore_Add(entity player, PlayerScoreField scorefield, float score)
 325 {
 326         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 327         score = M_ARGV(1, float);
 328
 329         if(game_stopped)
 330         if(!mutator_returnvalue)
 331                 score = 0;
 332
 333         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 334         entity s = player.scorekeeper;
 335         if(!s)
 336         {
 337                 if(game_stopped)
 338                         return 0;
 339                 LOG_WARN("Adding score to unknown player!");
 340                 return 0;
 341         }
 342         if(score)
 343                 if(scores_label(scorefield) != "")
 344                         s.SendFlags |= (2 ** (scorefield.m_id % 16));
 345         if(!warmup_stage)
 346                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
 347         return (s.(scores(scorefield)) += score);
 348 }
 349
 350 float PlayerTeamScore_Add(entity player, PlayerScoreField pscorefield, float tscorefield, float score)
 351 {
 352         float r;
 353         r = PlayerScore_Add(player, pscorefield, score);
 354         if(teamscores_entities_count) // only for teamplay
 355                 r = TeamScore_Add(player, tscorefield, score);
 356         return r;
 357 }
 358
 359 float PlayerScore_Compare(entity t1, entity t2, float strict)
 360 {
 361         if(!t1 || !t2) return (!t2) - !t1;
 362
 363         vector result = '0 0 0';
 364         FOREACH(Scores, true, {
 365                 var .float f = scores(it);
 366                 result = ScoreField_Compare(t1, t2, f, scores_flags(it), result, strict);
 367         });
 368
 369         if (result.x == 0 && strict)
 370                 result.x = etof(t1.owner) - etof(t2.owner);
 371
 372         return result.x;
 373 }
 374
 375 void WinningConditionHelper(entity this)
 376 {
 377         float c;
 378         string s;
 379         float fullstatus;
 380         entity winnerscorekeeper;
 381         entity secondscorekeeper;
 382         entity sk;
 383
 384         // format:
 385         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 386         // score labels always start with a symbol or with lower case
 387         // so to match pure, match for :P0:
 388         // to match full, match for :S0:
 389
 390         fullstatus = autocvar_g_full_getstatus_responses;
 391
 392         s = GetGametype();
 393         s = strcat(s, ":", autocvar_g_xonoticversion);
 394         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 395         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 396         s = strcat(s, ":F", ftos(serverflags));
 397         s = strcat(s, ":M", modname);
 398         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 399
 400         if(teamscores_entities_count)
 401         {
 402                 float t;
 403
 404                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 405                 for(t = 0; t < 16; ++t)
 406                         if(teamscorekeepers[t])
 407                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 408
 409                 WinningConditionHelper_winnerteam = -1;
 410                 WinningConditionHelper_secondteam = -1;
 411                 winnerscorekeeper = NULL;
 412                 secondscorekeeper = NULL;
 413                 for(t = 0; t < 16; ++t)
 414                 {
 415                         sk = teamscorekeepers[t];
 416                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 417                         if(c < 0)
 418                         {
 419                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 420                                 WinningConditionHelper_winnerteam = t + 1;
 421                                 secondscorekeeper = winnerscorekeeper;
 422                                 winnerscorekeeper = sk;
 423                         }
 424                         else
 425                         {
 426                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 427                                 if(c < 0)
 428                                 {
 429                                         WinningConditionHelper_secondteam = t + 1;
 430                                         secondscorekeeper = sk;
 431                                 }
 432                         }
 433                 }
 434
 435                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 436                 if(WinningConditionHelper_equality)
 437                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 438
 439                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 440                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 441                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 442                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 443
 444                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 445                 WinningConditionHelper_second = NULL; // not supported in teamplay
 446         }
 447         else
 448         {
 449                 WinningConditionHelper_winner = NULL;
 450                 WinningConditionHelper_second = NULL;
 451                 winnerscorekeeper = NULL;
 452                 secondscorekeeper = NULL;
 453                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 454                         sk = it.scorekeeper;
 455                         c = PlayerScore_Compare(winnerscorekeeper, sk, 1);
 456                         if(c < 0)
 457                         {
 458                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 459                                 WinningConditionHelper_winner = it;
 460                                 secondscorekeeper = winnerscorekeeper;
 461                                 winnerscorekeeper = sk;
 462                         }
 463                         else
 464                         {
 465                                 c = PlayerScore_Compare(secondscorekeeper, sk, 1);
 466                                 if(c < 0)
 467                                 {
 468                                         WinningConditionHelper_second = it;
 469                                         secondscorekeeper = sk;
 470                                 }
 471                         }
 472                 ));
 473
 474                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 475                 if(WinningConditionHelper_equality)
 476                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 477
 478                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 479                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 480                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 481                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 482
 483                 WinningConditionHelper_winnerteam = -1; // no teamplay
 484                 WinningConditionHelper_secondteam = -1; // no teamplay
 485         }
 486
 487         if(WinningConditionHelper_topscore == 0)
 488         {
 489                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 490                 {
 491                         if(WinningConditionHelper_lowerisbetter)
 492                                 WinningConditionHelper_topscore = 999999999;
 493                         else
 494                                 WinningConditionHelper_topscore = -999999999;
 495                 }
 496                 WinningConditionHelper_equality = 0;
 497         }
 498
 499         if(WinningConditionHelper_secondscore == 0)
 500         {
 501                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 502                 {
 503                         if(WinningConditionHelper_lowerisbetter)
 504                                 WinningConditionHelper_secondscore = 999999999;
 505                         else
 506                                 WinningConditionHelper_secondscore = -999999999;
 507                 }
 508         }
 509
 510         if(worldstatus)
 511                 strunzone(worldstatus);
 512         worldstatus = strzone(s);
 513
 514         FOREACH_CLIENT(true, LAMBDA(
 515                 string s = "";
 516                 if(fullstatus)
 517                 {
 518                         s = GetPlayerScoreString(it, 1);
 519                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 520                         if(!IS_PLAYER(it) && !MUTATOR_CALLHOOK(GetPlayerStatus, it))
 521                                 s = strcat(s, ":spectator");
 522                 }
 523                 else
 524                 {
 525                         if (IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
 526                                 s = GetPlayerScoreString(it, 2);
 527                         else
 528                                 s = "-666";
 529                 }
 530
 531                 if(it.clientstatus)
 532                         strunzone(it.clientstatus);
 533                 it.clientstatus = strzone(s);
 534         ));
 535 }
 536
 537 string GetScoreLogLabel(string label, float fl)
 538 {
 539         if(fl & SFL_LOWER_IS_BETTER)
 540                 label = strcat(label, "<");
 541         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 542                 label = strcat(label, "!!");
 543         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 544                 label = strcat(label, "!");
 545         return label;
 546 }
 547
 548 string GetPlayerScoreString(entity pl, float shortString)
 549 {
 550         string out;
 551         entity sk;
 552         float f;
 553         string l;
 554
 555         out = "";
 556         if(!pl)
 557         {
 558                 // label
 559                 FOREACH(Scores, true, {
 560                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 561                         {
 562                                 f = scores_flags(it);
 563                                 l = scores_label(it);
 564                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 565                         }
 566         });
 567                 if(shortString < 2)
 568                 FOREACH(Scores, true, {
 569                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 570                         {
 571                                 f = scores_flags(it);
 572                                 l = scores_label(it);
 573                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 574                         }
 575         });
 576                 if(shortString < 1)
 577                 FOREACH(Scores, true, {
 578                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 579                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 580                         {
 581                                 f = scores_flags(it);
 582                                 l = scores_label(it);
 583                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 584                         }
 585         });
 586                 out = substring(out, 0, strlen(out) - 1);
 587         }
 588         else if((sk = pl.scorekeeper))
 589         {
 590                 FOREACH(Scores, true, {
 591                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 592                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 593         });
 594                 if(shortString < 2)
 595                 FOREACH(Scores, true, {
 596                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 597                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 598         });
 599                 if(shortString < 1)
 600                 FOREACH(Scores, true, {
 601                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 602                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 603                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 604         });
 605                 out = substring(out, 0, strlen(out) - 1);
 606         }
 607         return out;
 608 }
 609
 610 string GetTeamScoreString(float tm, float shortString)
 611 {
 612         string out;
 613         entity sk;
 614         float i, f;
 615         string l;
 616
 617         out = "";
 618         if(tm == 0)
 619         {
 620                 // label
 621                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 622                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 623                         {
 624                                 f = teamscores_flags(i);
 625                                 l = teamscores_label(i);
 626                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 627                         }
 628                 if(shortString < 2)
 629                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 630                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 631                         {
 632                                 f = teamscores_flags(i);
 633                                 l = teamscores_label(i);
 634                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 635                         }
 636                 if(shortString < 1)
 637                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 638                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 639                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 640                         {
 641                                 f = teamscores_flags(i);
 642                                 l = teamscores_label(i);
 643                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 644                         }
 645                 out = substring(out, 0, strlen(out) - 1);
 646         }
 647         else if((sk = teamscorekeepers[tm - 1]))
 648         {
 649                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 650                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 651                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 652                 if(shortString < 2)
 653                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 654                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 655                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 656                 if(shortString < 1)
 657                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 658                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 659                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 660                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 661                 out = substring(out, 0, strlen(out) - 1);
 662         }
 663         return out;
 664 }
 665
 666 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, float strict)
 667 {
 668         if(teams && teamscores_entities_count)
 669         {
 670                 if(p1.team != p2.team)
 671                 {
 672                         entity t1, t2;
 673                         float r;
 674                         t1 = teamscorekeepers[p1.team - 1];
 675                         t2 = teamscorekeepers[p2.team - 1];
 676                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 677                         return r;
 678                 }
 679                 if(teams < 0)
 680                         return 0;
 681         }
 682
 683         return PlayerScore_Compare(p1.scorekeeper, p2.scorekeeper, strict);
 684 }
 685
 686 entity PlayerScore_Sort(.float field, float teams, float strict, float nospectators)
 687 {
 688         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 689         float i, j;
 690
 691         plist = NULL;
 692
 693         FOREACH_CLIENT(true, LAMBDA(it.(field) = 0));
 694
 695         FOREACH_CLIENT(it.scorekeeper,
 696         {
 697                 if(nospectators)
 698                         if(it.frags == FRAGS_SPECTATOR)
 699                                 continue;
 700
 701                 it.chain = plist;
 702                 plist = it;
 703         });
 704         // Now plist points to the whole list.
 705
 706         pfirst = plast = NULL;
 707
 708         i = j = 0;
 709         while(plist)
 710         {
 711                 pprev = pbestprev = NULL;
 712                 pbest = plist;
 713                 for(p = plist; (pprev = p), (p = p.chain); )
 714                 {
 715                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 716                         {
 717                                 pbest = p;
 718                                 pbestprev = pprev;
 719                         }
 720                 }
 721
 722                 // remove pbest out of the chain
 723                 if(pbestprev == NULL)
 724                         plist = pbest.chain;
 725                 else
 726                         pbestprev.chain = pbest.chain;
 727                 pbest.chain = NULL;
 728
 729                 ++i;
 730                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, 0))
 731                         j = i;
 732
 733                 pbest.(field) = j;
 734
 735                 if (!pfirst)
 736                         pfirst = pbest;
 737                 if(plast)
 738                         plast.chain = pbest;
 739                 plast = pbest;
 740         }
 741
 742         return pfirst;
 743 }
 744
 745 float TeamScore_GetCompareValue(float t)
 746 {
 747         float s;
 748         entity sk;
 749
 750         if(t <= 0 || t >= 16)
 751         {
 752                 if(game_stopped)
 753                         return 0;
 754                 error("Reading score of invalid team!");
 755         }
 756
 757         sk = teamscorekeepers[t - 1];
 758         if (!sk)
 759                 return -999999999;
 760         s = sk.teamscores_primary;
 761         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 762                 if(!s)
 763                         return -999999999;
 764         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 765                 s = -s;
 766         return s;
 767 }
 768
 769 const float NAMEWIDTH = 22;
 770 const float SCORESWIDTH = 58;
 771 // TODO put this somewhere in common?
 772 string Score_NicePrint_ItemColor(float vflags)
 773 {
 774         if(vflags & SFL_SORT_PRIO_PRIMARY)
 775                 return "^3";
 776         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 777                 return "^5";
 778         else
 779                 return "^7";
 780 }
 781
 782 void Score_NicePrint_Team(entity to, float t, float w)
 783 {
 784         string s, s2;
 785         float i;
 786         entity sk;
 787         float fl, sc;
 788         s = "";
 789
 790         sk = teamscorekeepers[t - 1];
 791         if(sk)
 792         {
 793                 s = strcat(s, Team_ColoredFullName(t));
 794                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 795                         if(teamscores_label(i) != "")
 796                         {
 797                                 fl = teamscores_flags(i);
 798                                 sc = sk.(teamscores(i));
 799                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 800                         }
 801         }
 802         else
 803                 s = "Scores:";
 804
 805         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 806
 807         FOREACH(Scores, true, {
 808                 if(scores_label(it) != "")
 809                 {
 810                         fl = scores_flags(it);
 811                         s2 = scores_label(it);
 812                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 813                 }
 814     });
 815
 816         print_to(to, s);
 817 }
 818
 819 void Score_NicePrint_Player(entity to, entity p, float w)
 820 {
 821         string s;
 822         float i;
 823         entity sk;
 824         float fl, sc;
 825         s = "  ";
 826
 827         sk = p.scorekeeper;
 828
 829         s = strcat(s, playername(p, false));
 830         for (;;)
 831         {
 832                 i = strlennocol(s) - NAMEWIDTH;
 833                 if(i > 0)
 834                         s = substring(s, 0, strlen(s) - i);
 835                 else
 836                 {
 837                         s = strcat(s, strpad(i, ""));
 838                         break;
 839                 }
 840         }
 841
 842         FOREACH(Scores, true, {
 843                 if(scores_label(it) != "")
 844                 {
 845                         fl = scores_flags(it);
 846                         sc = sk.(scores(it));
 847                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 848                 }
 849     });
 850
 851         print_to(to, s);
 852 }
 853
 854 void Score_NicePrint_Spectators(entity to)
 855 {
 856         print_to(to, "Spectators:");
 857 }
 858
 859 void Score_NicePrint_Spectator(entity to, entity p)
 860 {
 861         print_to(to, strcat("  ", playername(p, false)));
 862 }
 863
 864 .float score_dummyfield;
 865 void Score_NicePrint(entity to)
 866 {
 867         entity p;
 868         float w;
 869
 870         int t = 0;
 871         FOREACH(Scores, true, {
 872                 if(scores_label(it) != "")
 873                         ++t;
 874     });
 875         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 876
 877         p = PlayerScore_Sort(score_dummyfield, 1, 1, 0);
 878         t = -1;
 879
 880         if(!teamscores_entities_count)
 881                 Score_NicePrint_Team(to, t, w);
 882         while(p)
 883         {
 884                 if(teamscores_entities_count)
 885                         if(t != p.team)
 886                                 Score_NicePrint_Team(to, p.team, w);
 887                 Score_NicePrint_Player(to, p, w);
 888                 t = p.team;
 889                 p = p.chain;
 890         }
 891
 892         t = 0;
 893         FOREACH_CLIENT(!IS_PLAYER(it), LAMBDA(
 894                 if (!t)
 895                         Score_NicePrint_Spectators(to);
 896                 Score_NicePrint_Spectator(to, it);
 897                 t = 1;
 898         ));
 899 }
 900
 901 void PlayerScore_PlayerStats(entity p)
 902 {
 903         entity s = p.scorekeeper;
 904         FOREACH(Scores, true, {
 905                 if(s.(scores(it)) != 0)
 906                         if(scores_label(it) != "")
 907                                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_SCOREBOARD, scores_label(it)), s.(scores(it)));
 908     });
 909 }
 910
 911 void PlayerScore_TeamStats()
 912 {
 913         entity sk;
 914         float t, i;
 915         for(t = 0; t < 16; ++t)
 916         {
 917                 sk = teamscorekeepers[t];
 918                 if(!sk)
 919                         continue;
 920                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 921                         if(sk.(teamscores(i)) != 0)
 922                                 if(teamscores_label(i) != "")
 923                                         // the +1 is important here!
 924                                         PS_GR_T_ADDVAL(t+1, strcat(PLAYERSTATS_SCOREBOARD, teamscores_label(i)), sk.(teamscores(i)));
 925         }
 926 }