qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include "command/common.qh"
   4 #include "mutators/all.qh"
   5 #include "../common/playerstats.qh"
   6 #include "../common/teams.qh"
   7
   8 .entity scorekeeper;
   9 entity teamscorekeepers[16];
  10 string scores_label[MAX_SCORE];
  11 float scores_flags[MAX_SCORE];
  12 string teamscores_label[MAX_TEAMSCORE];
  13 float teamscores_flags[MAX_TEAMSCORE];
  14 float teamscores_entities_count;
  15 var .float scores_primary;
  16 var .float teamscores_primary;
  17 float scores_flags_primary;
  18 float teamscores_flags_primary;
  19
  20 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, float strict) // returns: cmp value, best prio
  21 {
  22         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  23                 return previous;
  24         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  25                 return previous;
  26         if (t1.(field) == t2.(field))
  27                 return previous;
  28
  29         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  30
  31         if(fieldflags & SFL_ZERO_IS_WORST)
  32         {
  33                 if (t1.(field) == 0)
  34                 {
  35                         previous.x = -1;
  36                         return previous;
  37                 }
  38                 else if (t2.(field) == 0)
  39                 {
  40                         previous.x = +1;
  41                         return previous;
  42                 }
  43         }
  44
  45         if (fieldflags & SFL_LOWER_IS_BETTER)
  46                 previous.x = (t2.(field) - t1.(field));
  47         else
  48                 previous.x = (t1.(field) - t2.(field));
  49
  50         return previous;
  51 }
  52
  53 /*
  54  * teamscore entities
  55  */
  56
  57 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  58 {
  59         float i, p, longflags;
  60
  61         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  62         int t = this.team - 1;
  63         assert(t, eprint(this));
  64         WriteByte(MSG_ENTITY, t);
  65
  66         longflags = 0;
  67         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  68                 if(self.(teamscores[i]) > 127 || self.(teamscores[i]) <= -128)
  69                         longflags |= p;
  70
  71 #if MAX_TEAMSCORE <= 8
  72         WriteByte(MSG_ENTITY, sendflags);
  73         WriteByte(MSG_ENTITY, longflags);
  74 #else
  75         WriteShort(MSG_ENTITY, sendflags);
  76         WriteShort(MSG_ENTITY, longflags);
  77 #endif
  78         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  79                 if(sendflags & p)
  80                 {
  81                         if(longflags & p)
  82                                 WriteInt24_t(MSG_ENTITY, self.(teamscores[i]));
  83                         else
  84                                 WriteChar(MSG_ENTITY, self.(teamscores[i]));
  85                 }
  86
  87         return true;
  88 }
  89
  90 void TeamScore_Spawn(float t, string name)
  91 {
  92         entity ts = new(csqc_score_team);
  93         make_pure(ts);
  94         ts.netname = name; // not used yet, FIXME
  95         ts.team = t;
  96         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
  97         teamscorekeepers[t - 1] = ts;
  98         ++teamscores_entities_count;
  99         PlayerStats_GameReport_AddTeam(t);
 100 }
 101
 102 float TeamScore_AddToTeam(float t, float scorefield, float score)
 103 {
 104         entity s;
 105
 106         if(gameover)
 107                 score = 0;
 108
 109         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 110         if(t <= 0 || t >= 16)
 111         {
 112                 if(gameover)
 113                         return 0;
 114                 error("Adding score to invalid team!");
 115         }
 116         s = teamscorekeepers[t - 1];
 117         if(!s)
 118         {
 119                 if(gameover)
 120                         return 0;
 121                 error("Adding score to unknown team!");
 122         }
 123         if(score)
 124                 if(teamscores_label[scorefield] != "")
 125                         s.SendFlags |= pow(2, scorefield);
 126         return (s.(teamscores[scorefield]) += score);
 127 }
 128
 129 float TeamScore_Add(entity player, float scorefield, float score)
 130 {
 131         return TeamScore_AddToTeam(player.team, scorefield, score);
 132 }
 133
 134 float TeamScore_Compare(entity t1, entity t2, float strict)
 135 {
 136         if(!t1 || !t2) return (!t2) - !t1;
 137
 138         vector result = '0 0 0';
 139         float i;
 140         for(i = 0; i < MAX_TEAMSCORE; ++i)
 141         {
 142                 var .float f;
 143                 f = teamscores[i];
 144                 result = ScoreField_Compare(t1, t2, f, teamscores_flags[i], result, strict);
 145         }
 146
 147         if (result.x == 0 && strict)
 148                 result.x = t1.team - t2.team;
 149
 150         return result.x;
 151 }
 152
 153 /*
 154  * the scoreinfo entity
 155  */
 156
 157 void ScoreInfo_SetLabel_PlayerScore(float i, string label, float scoreflags)
 158 {
 159         scores_label[i] = label;
 160         scores_flags[i] = scoreflags;
 161         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 162         {
 163                 scores_primary = scores[i];
 164                 scores_flags_primary = scoreflags;
 165         }
 166         if(label != "")
 167         {
 168                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 169                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 170         }
 171 }
 172
 173 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 174 {
 175         teamscores_label[i] = label;
 176         teamscores_flags[i] = scoreflags;
 177         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 178         {
 179                 teamscores_primary = teamscores[i];
 180                 teamscores_flags_primary = scoreflags;
 181         }
 182         if(label != "")
 183         {
 184                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 185                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 186         }
 187 }
 188
 189 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 190 {
 191         float i;
 192         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 193         WriteInt24_t(MSG_ENTITY, MapInfo_LoadedGametype);
 194         for(i = 0; i < MAX_SCORE; ++i)
 195         {
 196                 WriteString(MSG_ENTITY, scores_label[i]);
 197                 WriteByte(MSG_ENTITY, scores_flags[i]);
 198         }
 199         for(i = 0; i < MAX_TEAMSCORE; ++i)
 200         {
 201                 WriteString(MSG_ENTITY, teamscores_label[i]);
 202                 WriteByte(MSG_ENTITY, teamscores_flags[i]);
 203         }
 204         return true;
 205 }
 206
 207 void ScoreInfo_Init(float teams)
 208 {
 209         if(scores_initialized)
 210         {
 211                 scores_initialized.SendFlags |= 1; // force a resend
 212         }
 213         else
 214         {
 215                 scores_initialized = new(ent_client_scoreinfo);
 216                 make_pure(scores_initialized);
 217                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 218         }
 219         if(teams >= 1)
 220                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 221         if(teams >= 2)
 222                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 223         if(teams >= 3)
 224                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 225         if(teams >= 4)
 226                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 227 }
 228
 229 /*
 230  * per-player score entities
 231  */
 232
 233 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 234 {
 235         float i, p, longflags;
 236
 237         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 238         WriteByte(MSG_ENTITY, etof(self.owner));
 239
 240         longflags = 0;
 241         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 242                 if(self.(scores[i]) > 127 || self.(scores[i]) <= -128)
 243                         longflags |= p;
 244
 245 #if MAX_SCORE <= 8
 246         WriteByte(MSG_ENTITY, sendflags);
 247         WriteByte(MSG_ENTITY, longflags);
 248 #else
 249         WriteShort(MSG_ENTITY, sendflags);
 250         WriteShort(MSG_ENTITY, longflags);
 251 #endif
 252         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 253                 if(sendflags & p)
 254                 {
 255                         if(longflags & p)
 256                                 WriteInt24_t(MSG_ENTITY, self.(scores[i]));
 257                         else
 258                                 WriteChar(MSG_ENTITY, self.(scores[i]));
 259                 }
 260
 261         return true;
 262 }
 263
 264 float PlayerScore_Clear(entity player)
 265 {
 266         entity sk;
 267         float i;
 268
 269         if(teamscores_entities_count)
 270                 return 0;
 271
 272         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 273
 274         sk = player.scorekeeper;
 275         for(i = 0; i < MAX_SCORE; ++i)
 276         {
 277                 if(sk.(scores[i]) != 0)
 278                         if(scores_label[i] != "")
 279                                 sk.SendFlags |= pow(2, i);
 280                 sk.(scores[i]) = 0;
 281         }
 282
 283         return 1;
 284 }
 285
 286 void Score_ClearAll()
 287 {
 288         entity sk;
 289         float t;
 290         FOREACH_CLIENTSLOT(true,
 291         {
 292                 sk = it.scorekeeper;
 293                 if(!sk)
 294                         continue;
 295                 for(int j = 0; j < MAX_SCORE; ++j)
 296                 {
 297                         if(sk.(scores[j]) != 0)
 298                                 if(scores_label[j] != "")
 299                                         sk.SendFlags |= pow(2, j);
 300                         sk.(scores[j]) = 0;
 301                 }
 302         });
 303         for(t = 0; t < 16; ++t)
 304         {
 305                 sk = teamscorekeepers[t];
 306                 if(!sk)
 307                         continue;
 308                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 309                 {
 310                         if(sk.(teamscores[j]) != 0)
 311                                 if(teamscores_label[j] != "")
 312                                         sk.SendFlags |= pow(2, j);
 313                         sk.(teamscores[j]) = 0;
 314                 }
 315         }
 316 }
 317
 318 void PlayerScore_Attach(entity player)
 319 {
 320         if(player.scorekeeper)
 321                 error("player already has a scorekeeper");
 322         entity sk = new(scorekeeper);
 323         make_pure(sk);
 324         sk.owner = player;
 325         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 326         player.scorekeeper = sk;
 327 }
 328
 329 void PlayerScore_Detach(entity player)
 330 {
 331         if(!player.scorekeeper)
 332                 error("player has no scorekeeper");
 333         remove(player.scorekeeper);
 334         player.scorekeeper = world;
 335 }
 336
 337 float PlayerScore_Add(entity player, float scorefield, float score)
 338 {
 339         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score);
 340         score = ret_float;
 341
 342         if(gameover)
 343         if(!mutator_returnvalue)
 344                 score = 0;
 345
 346         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 347         entity s = player.scorekeeper;
 348         if(!s)
 349         {
 350                 if(gameover)
 351                         return 0;
 352                 backtrace("Adding score to unknown player!");
 353                 return 0;
 354         }
 355         if(score)
 356                 if(scores_label[scorefield] != "")
 357                         s.SendFlags |= pow(2, scorefield);
 358         if(!warmup_stage)
 359                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label[scorefield]), score);
 360         return (s.(scores[scorefield]) += score);
 361 }
 362
 363 float PlayerTeamScore_Add(entity player, float pscorefield, float tscorefield, float score)
 364 {
 365         float r;
 366         r = PlayerScore_Add(player, pscorefield, score);
 367         if(teamscores_entities_count) // only for teamplay
 368                 r = TeamScore_Add(player, tscorefield, score);
 369         return r;
 370 }
 371
 372 float PlayerScore_Compare(entity t1, entity t2, float strict)
 373 {
 374         if(!t1 || !t2) return (!t2) - !t1;
 375
 376         vector result = '0 0 0';
 377         float i;
 378         for(i = 0; i < MAX_SCORE; ++i)
 379         {
 380                 var .float f;
 381                 f = scores[i];
 382                 result = ScoreField_Compare(t1, t2, f, scores_flags[i], result, strict);
 383         }
 384
 385         if (result.x == 0 && strict)
 386                 result.x = etof(t1.owner) - etof(t2.owner);
 387
 388         return result.x;
 389 }
 390
 391 void WinningConditionHelper()
 392 {
 393         float c;
 394         string s;
 395         float fullstatus;
 396         entity winnerscorekeeper;
 397         entity secondscorekeeper;
 398         entity sk;
 399
 400         // format:
 401         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 402         // score labels always start with a symbol or with lower case
 403         // so to match pure, match for :P0:
 404         // to match full, match for :S0:
 405
 406         fullstatus = autocvar_g_full_getstatus_responses;
 407
 408         s = GetGametype();
 409         s = strcat(s, ":", autocvar_g_xonoticversion);
 410         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 411         s = strcat(s, ":S", ftos(nJoinAllowed(self, world)));
 412         s = strcat(s, ":F", ftos(serverflags));
 413         s = strcat(s, ":M", modname);
 414         s = strcat(s, "::", GetPlayerScoreString(world, (fullstatus ? 1 : 2)));
 415
 416         if(teamscores_entities_count)
 417         {
 418                 float t;
 419
 420                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 421                 for(t = 0; t < 16; ++t)
 422                         if(teamscorekeepers[t])
 423                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 424
 425                 WinningConditionHelper_winnerteam = -1;
 426                 WinningConditionHelper_secondteam = -1;
 427                 winnerscorekeeper = world;
 428                 secondscorekeeper = world;
 429                 for(t = 0; t < 16; ++t)
 430                 {
 431                         sk = teamscorekeepers[t];
 432                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 433                         if(c < 0)
 434                         {
 435                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 436                                 WinningConditionHelper_winnerteam = t + 1;
 437                                 secondscorekeeper = winnerscorekeeper;
 438                                 winnerscorekeeper = sk;
 439                         }
 440                         else
 441                         {
 442                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 443                                 if(c < 0)
 444                                 {
 445                                         WinningConditionHelper_secondteam = t + 1;
 446                                         secondscorekeeper = sk;
 447                                 }
 448                         }
 449                 }
 450
 451                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 452                 if(WinningConditionHelper_equality)
 453                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 454
 455                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 456                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 457                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 458                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 459
 460                 WinningConditionHelper_winner = world; // not supported in teamplay
 461                 WinningConditionHelper_second = world; // not supported in teamplay
 462         }
 463         else
 464         {
 465                 WinningConditionHelper_winner = world;
 466                 WinningConditionHelper_second = world;
 467                 winnerscorekeeper = world;
 468                 secondscorekeeper = world;
 469                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 470                         sk = it.scorekeeper;
 471                         c = PlayerScore_Compare(winnerscorekeeper, sk, 1);
 472                         if(c < 0)
 473                         {
 474                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 475                                 WinningConditionHelper_winner = it;
 476                                 secondscorekeeper = winnerscorekeeper;
 477                                 winnerscorekeeper = sk;
 478                         }
 479                         else
 480                         {
 481                                 c = PlayerScore_Compare(secondscorekeeper, sk, 1);
 482                                 if(c < 0)
 483                                 {
 484                                         WinningConditionHelper_second = it;
 485                                         secondscorekeeper = sk;
 486                                 }
 487                         }
 488                 ));
 489
 490                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 491                 if(WinningConditionHelper_equality)
 492                         WinningConditionHelper_winner = WinningConditionHelper_second = world;
 493
 494                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 495                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 496                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 497                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 498
 499                 WinningConditionHelper_winnerteam = -1; // no teamplay
 500                 WinningConditionHelper_secondteam = -1; // no teamplay
 501         }
 502
 503         if(WinningConditionHelper_topscore == 0)
 504         {
 505                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 506                 {
 507                         if(WinningConditionHelper_lowerisbetter)
 508                                 WinningConditionHelper_topscore = 999999999;
 509                         else
 510                                 WinningConditionHelper_topscore = -999999999;
 511                 }
 512                 WinningConditionHelper_equality = 0;
 513         }
 514
 515         if(WinningConditionHelper_secondscore == 0)
 516         {
 517                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 518                 {
 519                         if(WinningConditionHelper_lowerisbetter)
 520                                 WinningConditionHelper_secondscore = 999999999;
 521                         else
 522                                 WinningConditionHelper_secondscore = -999999999;
 523                 }
 524         }
 525
 526         if(worldstatus)
 527                 strunzone(worldstatus);
 528         worldstatus = strzone(s);
 529
 530         FOREACH_CLIENT(true, LAMBDA(
 531                 string s = "";
 532                 if(fullstatus)
 533                 {
 534                         s = GetPlayerScoreString(it, 1);
 535                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 536                         ret_string = string_null;
 537                         if(!IS_PLAYER(it) && !MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
 538                                 s = strcat(s, ":spectator");
 539                         if (ret_string) s = strcat(s, ret_string);
 540                 }
 541                 else
 542                 {
 543                         ret_string = string_null;
 544                         if (IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
 545                                 s = GetPlayerScoreString(it, 2);
 546                         else
 547                                 s = "-666";
 548                         if (ret_string) s = strcat(s, ret_string);
 549                 }
 550
 551                 if(it.clientstatus)
 552                         strunzone(it.clientstatus);
 553                 it.clientstatus = strzone(s);
 554         ));
 555 }
 556
 557 string GetScoreLogLabel(string label, float fl)
 558 {
 559         if(fl & SFL_LOWER_IS_BETTER)
 560                 label = strcat(label, "<");
 561         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 562                 label = strcat(label, "!!");
 563         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 564                 label = strcat(label, "!");
 565         return label;
 566 }
 567
 568 string GetPlayerScoreString(entity pl, float shortString)
 569 {
 570         string out;
 571         entity sk;
 572         float i, f;
 573         string l;
 574
 575         out = "";
 576         if(!pl)
 577         {
 578                 // label
 579                 for(i = 0; i < MAX_SCORE; ++i)
 580                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 581                         {
 582                                 f = scores_flags[i];
 583                                 l = scores_label[i];
 584                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 585                         }
 586                 if(shortString < 2)
 587                 for(i = 0; i < MAX_SCORE; ++i)
 588                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 589                         {
 590                                 f = scores_flags[i];
 591                                 l = scores_label[i];
 592                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 593                         }
 594                 if(shortString < 1)
 595                 for(i = 0; i < MAX_SCORE; ++i)
 596                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 597                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 598                         {
 599                                 f = scores_flags[i];
 600                                 l = scores_label[i];
 601                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 602                         }
 603                 out = substring(out, 0, strlen(out) - 1);
 604         }
 605         else if((sk = pl.scorekeeper))
 606         {
 607                 for(i = 0; i < MAX_SCORE; ++i)
 608                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 609                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 610                 if(shortString < 2)
 611                 for(i = 0; i < MAX_SCORE; ++i)
 612                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 613                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 614                 if(shortString < 1)
 615                 for(i = 0; i < MAX_SCORE; ++i)
 616                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 617                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 618                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 619                 out = substring(out, 0, strlen(out) - 1);
 620         }
 621         return out;
 622 }
 623
 624 string GetTeamScoreString(float tm, float shortString)
 625 {
 626         string out;
 627         entity sk;
 628         float i, f;
 629         string l;
 630
 631         out = "";
 632         if(tm == 0)
 633         {
 634                 // label
 635                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 636                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 637                         {
 638                                 f = teamscores_flags[i];
 639                                 l = teamscores_label[i];
 640                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 641                         }
 642                 if(shortString < 2)
 643                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 644                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 645                         {
 646                                 f = teamscores_flags[i];
 647                                 l = teamscores_label[i];
 648                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 649                         }
 650                 if(shortString < 1)
 651                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 652                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 653                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 654                         {
 655                                 f = teamscores_flags[i];
 656                                 l = teamscores_label[i];
 657                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 658                         }
 659                 out = substring(out, 0, strlen(out) - 1);
 660         }
 661         else if((sk = teamscorekeepers[tm - 1]))
 662         {
 663                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 664                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 665                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 666                 if(shortString < 2)
 667                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 668                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 669                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 670                 if(shortString < 1)
 671                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 672                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 673                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 674                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 675                 out = substring(out, 0, strlen(out) - 1);
 676         }
 677         return out;
 678 }
 679
 680 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, float strict)
 681 {
 682         if(teams && teamscores_entities_count)
 683         {
 684                 if(p1.team != p2.team)
 685                 {
 686                         entity t1, t2;
 687                         float r;
 688                         t1 = teamscorekeepers[p1.team - 1];
 689                         t2 = teamscorekeepers[p2.team - 1];
 690                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 691                         return r;
 692                 }
 693                 if(teams < 0)
 694                         return 0;
 695         }
 696
 697         return PlayerScore_Compare(p1.scorekeeper, p2.scorekeeper, strict);
 698 }
 699
 700 entity PlayerScore_Sort(.float field, float teams, float strict, float nospectators)
 701 {
 702         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 703         float i, j;
 704
 705         plist = world;
 706
 707         FOREACH_CLIENT(true, LAMBDA(it.(field) = 0));
 708
 709         FOREACH_CLIENT(it.scorekeeper,
 710         {
 711                 if(nospectators)
 712                         if(it.frags == FRAGS_SPECTATOR)
 713                                 continue;
 714
 715                 it.chain = plist;
 716                 plist = it;
 717         });
 718         // Now plist points to the whole list.
 719
 720         pfirst = plast = world;
 721
 722         i = j = 0;
 723         while(plist)
 724         {
 725                 pprev = pbestprev = world;
 726                 pbest = plist;
 727                 for(p = plist; (pprev = p), (p = p.chain); )
 728                 {
 729                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 730                         {
 731                                 pbest = p;
 732                                 pbestprev = pprev;
 733                         }
 734                 }
 735
 736                 // remove pbest out of the chain
 737                 if(pbestprev == world)
 738                         plist = pbest.chain;
 739                 else
 740                         pbestprev.chain = pbest.chain;
 741                 pbest.chain = world;
 742
 743                 ++i;
 744                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, 0))
 745                         j = i;
 746
 747                 pbest.(field) = j;
 748
 749                 if (!pfirst)
 750                         pfirst = pbest;
 751                 if(plast)
 752                         plast.chain = pbest;
 753                 plast = pbest;
 754         }
 755
 756         return pfirst;
 757 }
 758
 759 float TeamScore_GetCompareValue(float t)
 760 {
 761         float s;
 762         entity sk;
 763
 764         if(t <= 0 || t >= 16)
 765         {
 766                 if(gameover)
 767                         return 0;
 768                 error("Reading score of invalid team!");
 769         }
 770
 771         sk = teamscorekeepers[t - 1];
 772         if (!sk)
 773                 return -999999999;
 774         s = sk.teamscores_primary;
 775         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 776                 if(!s)
 777                         return -999999999;
 778         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 779                 s = -s;
 780         return s;
 781 }
 782
 783 const float NAMEWIDTH = 22;
 784 const float SCORESWIDTH = 58;
 785 // TODO put this somewhere in common?
 786 string Score_NicePrint_ItemColor(float vflags)
 787 {
 788         if(vflags & SFL_SORT_PRIO_PRIMARY)
 789                 return "^3";
 790         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 791                 return "^5";
 792         else
 793                 return "^7";
 794 }
 795
 796 void Score_NicePrint_Team(entity to, float t, float w)
 797 {
 798         string s, s2;
 799         float i;
 800         entity sk;
 801         float fl, sc;
 802         s = "";
 803
 804         sk = teamscorekeepers[t - 1];
 805         if(sk)
 806         {
 807                 s = strcat(s, Team_ColoredFullName(t));
 808                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 809                         if(teamscores_label[i] != "")
 810                         {
 811                                 fl = teamscores_flags[i];
 812                                 sc = sk.(teamscores[i]);
 813                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 814                         }
 815         }
 816         else
 817                 s = "Scores:";
 818
 819         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 820
 821         for(i = 0; i < MAX_SCORE; ++i)
 822                 if(scores_label[i] != "")
 823                 {
 824                         fl = scores_flags[i];
 825                         s2 = scores_label[i];
 826                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 827                 }
 828
 829         print_to(to, s);
 830 }
 831
 832 void Score_NicePrint_Player(entity to, entity p, float w)
 833 {
 834         string s;
 835         float i;
 836         entity sk;
 837         float fl, sc;
 838         s = "  ";
 839
 840         sk = p.scorekeeper;
 841
 842         s = strcat(s, p.netname);
 843         for (;;)
 844         {
 845                 i = strlennocol(s) - NAMEWIDTH;
 846                 if(i > 0)
 847                         s = substring(s, 0, strlen(s) - i);
 848                 else
 849                 {
 850                         s = strcat(s, strpad(i, ""));
 851                         break;
 852                 }
 853         }
 854
 855         for(i = 0; i < MAX_SCORE; ++i)
 856                 if(scores_label[i] != "")
 857                 {
 858                         fl = scores_flags[i];
 859                         sc = sk.(scores[i]);
 860                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 861                 }
 862
 863         print_to(to, s);
 864 }
 865
 866 void Score_NicePrint_Spectators(entity to)
 867 {
 868         print_to(to, "Spectators:");
 869 }
 870
 871 void Score_NicePrint_Spectator(entity to, entity p)
 872 {
 873         print_to(to, strcat("  ", p.netname));
 874 }
 875
 876 .float score_dummyfield;
 877 void Score_NicePrint(entity to)
 878 {
 879         entity p;
 880         float i;
 881         float w;
 882
 883         int t = 0;
 884         for(i = 0; i < MAX_SCORE; ++i)
 885                 if(scores_label[i] != "")
 886                         ++t;
 887         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 888
 889         p = PlayerScore_Sort(score_dummyfield, 1, 1, 0);
 890         t = -1;
 891
 892         if(!teamscores_entities_count)
 893                 Score_NicePrint_Team(to, t, w);
 894         while(p)
 895         {
 896                 if(teamscores_entities_count)
 897                         if(t != p.team)
 898                                 Score_NicePrint_Team(to, p.team, w);
 899                 Score_NicePrint_Player(to, p, w);
 900                 t = p.team;
 901                 p = p.chain;
 902         }
 903
 904         t = 0;
 905         FOREACH_CLIENT(!IS_PLAYER(it), LAMBDA(
 906                 if (!t)
 907                         Score_NicePrint_Spectators(to);
 908                 Score_NicePrint_Spectator(to, it);
 909                 t = 1;
 910         ));
 911 }
 912
 913 void PlayerScore_PlayerStats(entity p)
 914 {
 915         entity s;
 916         float i;
 917         s = p.scorekeeper;
 918
 919         for(i = 0; i < MAX_SCORE; ++i)
 920                 if(s.(scores[i]) != 0)
 921                         if(scores_label[i] != "")
 922                                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_SCOREBOARD, scores_label[i]), s.(scores[i]));
 923 }
 924
 925 void PlayerScore_TeamStats()
 926 {
 927         entity sk;
 928         float t, i;
 929         for(t = 0; t < 16; ++t)
 930         {
 931                 sk = teamscorekeepers[t];
 932                 if(!sk)
 933                         continue;
 934                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 935                         if(sk.(teamscores[i]) != 0)
 936                                 if(teamscores_label[i] != "")
 937                                         // the +1 is important here!
 938                                         PS_GR_T_ADDVAL(t+1, strcat(PLAYERSTATS_SCOREBOARD, teamscores_label[i]), sk.(teamscores[i]));
 939         }
 940 }