qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include "command/common.qh"
   4 #include "mutators/_mod.qh"
   5 #include <common/net_linked.qh>
   6 #include "../common/playerstats.qh"
   7 #include "../common/teams.qh"
   8 #include <common/scores.qh>
   9
  10 .entity scorekeeper;
  11 entity teamscorekeepers[16];
  12 float teamscores_entities_count;
  13 var .float scores_primary;
  14 var .float teamscores_primary;
  15 float scores_flags_primary;
  16 float teamscores_flags_primary;
  17
  18 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, float strict) // returns: cmp value, best prio
  19 {
  20         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  21                 return previous;
  22         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  23                 return previous;
  24         if (t1.(field) == t2.(field))
  25                 return previous;
  26
  27         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  28
  29         if(fieldflags & SFL_ZERO_IS_WORST)
  30         {
  31                 if (t1.(field) == 0)
  32                 {
  33                         previous.x = -1;
  34                         return previous;
  35                 }
  36                 else if (t2.(field) == 0)
  37                 {
  38                         previous.x = +1;
  39                         return previous;
  40                 }
  41         }
  42
  43         if (fieldflags & SFL_LOWER_IS_BETTER)
  44                 previous.x = (t2.(field) - t1.(field));
  45         else
  46                 previous.x = (t1.(field) - t2.(field));
  47
  48         return previous;
  49 }
  50
  51 /*
  52  * teamscore entities
  53  */
  54
  55 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  56 {
  57         float i, longflags;
  58
  59         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  60         int t = this.team - 1;
  61         assert(t, eprint(this));
  62         WriteByte(MSG_ENTITY, t);
  63
  64         longflags = 0;
  65         for(i = 0; i < MAX_TEAMSCORE; ++i)
  66                 if(this.(teamscores(i)) > 127 || this.(teamscores(i)) <= -128)
  67                         longflags |= BIT(i);
  68
  69 #if MAX_TEAMSCORE <= 8
  70         WriteByte(MSG_ENTITY, sendflags);
  71         WriteByte(MSG_ENTITY, longflags);
  72 #else
  73         WriteShort(MSG_ENTITY, sendflags);
  74         WriteShort(MSG_ENTITY, longflags);
  75 #endif
  76         for(i = 0; i < MAX_TEAMSCORE; ++i)
  77                 if(sendflags & BIT(i))
  78                 {
  79                         if(longflags & BIT(i))
  80                                 WriteInt24_t(MSG_ENTITY, this.(teamscores(i)));
  81                         else
  82                                 WriteChar(MSG_ENTITY, this.(teamscores(i)));
  83                 }
  84
  85         return true;
  86 }
  87
  88 void TeamScore_Spawn(float t, string name)
  89 {
  90         entity ts = new_pure(csqc_score_team);
  91         ts.netname = name; // not used yet, FIXME
  92         ts.team = t;
  93         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
  94         teamscorekeepers[t - 1] = ts;
  95         ++teamscores_entities_count;
  96         PlayerStats_GameReport_AddTeam(t);
  97 }
  98
  99 float TeamScore_AddToTeam(float t, float scorefield, float score)
 100 {
 101         entity s;
 102
 103         if(game_stopped)
 104                 score = 0;
 105
 106         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 107         if(t <= 0 || t >= 16)
 108         {
 109                 if(game_stopped)
 110                         return 0;
 111                 error("Adding score to invalid team!");
 112         }
 113         s = teamscorekeepers[t - 1];
 114         if(!s)
 115         {
 116                 if(game_stopped)
 117                         return 0;
 118                 error("Adding score to unknown team!");
 119         }
 120         if(score)
 121                 if(teamscores_label(scorefield) != "")
 122                         s.SendFlags |= (2 ** scorefield);
 123         return (s.(teamscores(scorefield)) += score);
 124 }
 125
 126 float TeamScore_Add(entity player, float scorefield, float score)
 127 {
 128         return TeamScore_AddToTeam(player.team, scorefield, score);
 129 }
 130
 131 float TeamScore_Compare(entity t1, entity t2, float strict)
 132 {
 133         if(!t1 || !t2) return (!t2) - !t1;
 134
 135         vector result = '0 0 0';
 136         float i;
 137         for(i = 0; i < MAX_TEAMSCORE; ++i)
 138         {
 139                 var .float f;
 140                 f = teamscores(i);
 141                 result = ScoreField_Compare(t1, t2, f, teamscores_flags(i), result, strict);
 142         }
 143
 144         if (result.x == 0 && strict)
 145                 result.x = t1.team - t2.team;
 146
 147         return result.x;
 148 }
 149
 150 /*
 151  * the scoreinfo entity
 152  */
 153
 154 void ScoreInfo_SetLabel_PlayerScore(PlayerScoreField i, string label, float scoreflags)
 155 {
 156         scores_label(i) = label;
 157         scores_flags(i) = scoreflags;
 158         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 159         {
 160                 scores_primary = scores(i);
 161                 scores_flags_primary = scoreflags;
 162         }
 163         if(label != "")
 164         {
 165                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 166                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 167         }
 168 }
 169
 170 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 171 {
 172         teamscores_label(i) = label;
 173         teamscores_flags(i) = scoreflags;
 174         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 175         {
 176                 teamscores_primary = teamscores(i);
 177                 teamscores_flags_primary = scoreflags;
 178         }
 179         if(label != "")
 180         {
 181                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 182                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 183         }
 184 }
 185
 186 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 187 {
 188         float i;
 189         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 190         WriteRegistered(Gametypes, MSG_ENTITY, MapInfo_LoadedGametype);
 191         FOREACH(Scores, true, {
 192                 WriteString(MSG_ENTITY, scores_label(it));
 193                 WriteByte(MSG_ENTITY, scores_flags(it));
 194         });
 195         for(i = 0; i < MAX_TEAMSCORE; ++i)
 196         {
 197                 WriteString(MSG_ENTITY, teamscores_label(i));
 198                 WriteByte(MSG_ENTITY, teamscores_flags(i));
 199         }
 200         return true;
 201 }
 202
 203 void ScoreInfo_Init(int teams)
 204 {
 205         if(scores_initialized)
 206         {
 207                 scores_initialized.SendFlags |= 1; // force a resend
 208         }
 209         else
 210         {
 211                 scores_initialized = new_pure(ent_client_scoreinfo);
 212                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 213         }
 214         if(teams & BIT(0))
 215                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 216         if(teams & BIT(1))
 217                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 218         if(teams & BIT(2))
 219                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 220         if(teams & BIT(3))
 221                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 222 }
 223
 224 /*
 225  * per-player score entities
 226  */
 227
 228 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 229 {
 230         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 231         WriteByte(MSG_ENTITY, etof(this.owner));
 232
 233         int longflags = 0;
 234         FOREACH(Scores, true, {
 235             int p = 1 << (i % 16);
 236                 if (this.(scores(it)) > 127 || this.(scores(it)) <= -128)
 237                         longflags |= p;
 238     });
 239
 240         WriteShort(MSG_ENTITY, sendflags);
 241         WriteShort(MSG_ENTITY, longflags);
 242         FOREACH(Scores, true, {
 243             int p = 1 << (i % 16);
 244                 if (sendflags & p)
 245                 {
 246                         if(longflags & p)
 247                                 WriteInt24_t(MSG_ENTITY, this.(scores(it)));
 248                         else
 249                                 WriteChar(MSG_ENTITY, this.(scores(it)));
 250                 }
 251     });
 252
 253         return true;
 254 }
 255
 256 float PlayerScore_Clear(entity player)
 257 {
 258         entity sk;
 259
 260         if(teamscores_entities_count)
 261                 return 0;
 262
 263         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 264
 265         sk = CS(player).scorekeeper;
 266         FOREACH(Scores, true, {
 267                 if(sk.(scores(it)) != 0)
 268                         if(scores_label(it) != "")
 269                                 sk.SendFlags |= (2 ** (i % 16));
 270                 if(i != SP_ELO.m_id)
 271                         sk.(scores(it)) = 0;
 272         });
 273
 274         return 1;
 275 }
 276
 277 void Score_ClearAll()
 278 {
 279         entity sk;
 280         float t;
 281         FOREACH_CLIENTSLOT(true, {
 282                 sk = CS(it).scorekeeper;
 283                 if (!sk) continue;
 284                 FOREACH(Scores, true, {
 285                         if(sk.(scores(it)) != 0)
 286                                 if(scores_label(it) != "")
 287                                         sk.SendFlags |= (2 ** (i % 16));
 288                         if(i != SP_ELO.m_id)
 289                                 sk.(scores(it)) = 0;
 290                 });
 291         });
 292         for(t = 0; t < 16; ++t)
 293         {
 294                 sk = teamscorekeepers[t];
 295                 if(!sk)
 296                         continue;
 297                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 298                 {
 299                         if(sk.(teamscores(j)) != 0)
 300                                 if(teamscores_label(j) != "")
 301                                         sk.SendFlags |= (2 ** j);
 302                         sk.(teamscores(j)) = 0;
 303                 }
 304         }
 305 }
 306
 307 void PlayerScore_Attach(entity player)
 308 {
 309         if(CS(player).scorekeeper)
 310                 error("player already has a scorekeeper");
 311         entity sk = new_pure(scorekeeper);
 312         sk.owner = player;
 313         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 314         CS(player).scorekeeper = sk;
 315 }
 316
 317 void PlayerScore_Detach(entity player)
 318 {
 319         if(!CS(player).scorekeeper)
 320                 error("player has no scorekeeper");
 321         delete(CS(player).scorekeeper);
 322         CS(player).scorekeeper = NULL;
 323 }
 324
 325 float PlayerScore_Add(entity player, PlayerScoreField scorefield, float score)
 326 {
 327         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 328         score = M_ARGV(1, float);
 329
 330         if(game_stopped)
 331         if(!mutator_returnvalue)
 332                 score = 0;
 333
 334         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 335         entity s = CS(player).scorekeeper;
 336         if(!s)
 337         {
 338                 if(game_stopped)
 339                         return 0;
 340                 LOG_WARN("Adding score to unknown player!");
 341                 return 0;
 342         }
 343         if(!score)
 344         {
 345                 return s.(scores(scorefield));
 346         }
 347         if(scores_label(scorefield) != "")
 348                 s.SendFlags |= (2 ** (scorefield.m_id % 16));
 349         if(!warmup_stage)
 350                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
 351         s.(scores(scorefield)) += score;
 352         MUTATOR_CALLHOOK(AddedPlayerScore, scorefield, score, player);
 353         return s.(scores(scorefield));
 354 }
 355
 356 float PlayerTeamScore_Add(entity player, PlayerScoreField pscorefield, float tscorefield, float score)
 357 {
 358         float r;
 359         r = PlayerScore_Add(player, pscorefield, score);
 360         if(teamscores_entities_count) // only for teamplay
 361                 r = TeamScore_Add(player, tscorefield, score);
 362         return r;
 363 }
 364
 365 float PlayerScore_Compare(entity t1, entity t2, float strict)
 366 {
 367         if(!t1 || !t2) return (!t2) - !t1;
 368
 369         vector result = '0 0 0';
 370         FOREACH(Scores, true, {
 371                 var .float f = scores(it);
 372                 result = ScoreField_Compare(t1, t2, f, scores_flags(it), result, strict);
 373         });
 374
 375         if (result.x == 0 && strict)
 376                 result.x = etof(t1.owner) - etof(t2.owner);
 377
 378         return result.x;
 379 }
 380
 381 void WinningConditionHelper(entity this)
 382 {
 383         float c;
 384         string s;
 385         float fullstatus;
 386         entity winnerscorekeeper;
 387         entity secondscorekeeper;
 388         entity sk;
 389
 390         // format:
 391         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 392         // score labels always start with a symbol or with lower case
 393         // so to match pure, match for :P0:
 394         // to match full, match for :S0:
 395
 396         fullstatus = autocvar_g_full_getstatus_responses;
 397
 398         s = GetGametype();
 399         s = strcat(s, ":", autocvar_g_xonoticversion);
 400         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 401         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 402         s = strcat(s, ":F", ftos(serverflags));
 403         s = strcat(s, ":M", modname);
 404         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 405
 406         if(teamscores_entities_count)
 407         {
 408                 float t;
 409
 410                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 411                 for(t = 0; t < 16; ++t)
 412                         if(teamscorekeepers[t])
 413                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 414
 415                 WinningConditionHelper_winnerteam = -1;
 416                 WinningConditionHelper_secondteam = -1;
 417                 winnerscorekeeper = NULL;
 418                 secondscorekeeper = NULL;
 419                 for(t = 0; t < 16; ++t)
 420                 {
 421                         sk = teamscorekeepers[t];
 422                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 423                         if(c < 0)
 424                         {
 425                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 426                                 WinningConditionHelper_winnerteam = t + 1;
 427                                 secondscorekeeper = winnerscorekeeper;
 428                                 winnerscorekeeper = sk;
 429                         }
 430                         else
 431                         {
 432                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 433                                 if(c < 0)
 434                                 {
 435                                         WinningConditionHelper_secondteam = t + 1;
 436                                         secondscorekeeper = sk;
 437                                 }
 438                         }
 439                 }
 440
 441                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 442                 if(WinningConditionHelper_equality)
 443                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 444
 445                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 446                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 447                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 448                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 449
 450                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 451                 WinningConditionHelper_second = NULL; // not supported in teamplay
 452         }
 453         else
 454         {
 455                 WinningConditionHelper_winner = NULL;
 456                 WinningConditionHelper_second = NULL;
 457                 winnerscorekeeper = NULL;
 458                 secondscorekeeper = NULL;
 459                 FOREACH_CLIENT(IS_PLAYER(it), {
 460                         sk = CS(it).scorekeeper;
 461                         c = PlayerScore_Compare(winnerscorekeeper, sk, 1);
 462                         if(c < 0)
 463                         {
 464                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 465                                 WinningConditionHelper_winner = it;
 466                                 secondscorekeeper = winnerscorekeeper;
 467                                 winnerscorekeeper = sk;
 468                         }
 469                         else
 470                         {
 471                                 c = PlayerScore_Compare(secondscorekeeper, sk, 1);
 472                                 if(c < 0)
 473                                 {
 474                                         WinningConditionHelper_second = it;
 475                                         secondscorekeeper = sk;
 476                                 }
 477                         }
 478                 });
 479
 480                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 481                 if(WinningConditionHelper_equality)
 482                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 483
 484                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 485                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 486                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 487                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 488
 489                 WinningConditionHelper_winnerteam = -1; // no teamplay
 490                 WinningConditionHelper_secondteam = -1; // no teamplay
 491         }
 492
 493         if(WinningConditionHelper_topscore == 0)
 494         {
 495                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 496                 {
 497                         if(WinningConditionHelper_lowerisbetter)
 498                                 WinningConditionHelper_topscore = 999999999;
 499                         else
 500                                 WinningConditionHelper_topscore = -999999999;
 501                 }
 502                 WinningConditionHelper_equality = 0;
 503         }
 504
 505         if(WinningConditionHelper_secondscore == 0)
 506         {
 507                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 508                 {
 509                         if(WinningConditionHelper_lowerisbetter)
 510                                 WinningConditionHelper_secondscore = 999999999;
 511                         else
 512                                 WinningConditionHelper_secondscore = -999999999;
 513                 }
 514         }
 515
 516         if(worldstatus)
 517                 strunzone(worldstatus);
 518         worldstatus = strzone(s);
 519
 520         FOREACH_CLIENT(true, {
 521                 string s = "";
 522                 if(fullstatus)
 523                 {
 524                         s = GetPlayerScoreString(it, 1);
 525                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 526                         if(!IS_PLAYER(it) && !MUTATOR_CALLHOOK(GetPlayerStatus, it))
 527                                 s = strcat(s, ":spectator");
 528                 }
 529                 else
 530                 {
 531                         if (IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
 532                                 s = GetPlayerScoreString(it, 2);
 533                         else
 534                                 s = "-666";
 535                 }
 536
 537                 if(it.clientstatus)
 538                         strunzone(it.clientstatus);
 539                 it.clientstatus = strzone(s);
 540         });
 541 }
 542
 543 string GetScoreLogLabel(string label, float fl)
 544 {
 545         if(fl & SFL_LOWER_IS_BETTER)
 546                 label = strcat(label, "<");
 547         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 548                 label = strcat(label, "!!");
 549         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 550                 label = strcat(label, "!");
 551         return label;
 552 }
 553
 554 string GetPlayerScoreString(entity pl, float shortString)
 555 {
 556         string out;
 557         entity sk;
 558         float f;
 559         string l;
 560
 561         out = "";
 562         if(!pl)
 563         {
 564                 // label
 565                 FOREACH(Scores, true, {
 566                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 567                         {
 568                                 f = scores_flags(it);
 569                                 l = scores_label(it);
 570                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 571                         }
 572         });
 573                 if(shortString < 2)
 574                 FOREACH(Scores, true, {
 575                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 576                         {
 577                                 f = scores_flags(it);
 578                                 l = scores_label(it);
 579                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 580                         }
 581         });
 582                 if(shortString < 1)
 583                 FOREACH(Scores, true, {
 584                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 585                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 586                         {
 587                                 f = scores_flags(it);
 588                                 l = scores_label(it);
 589                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 590                         }
 591         });
 592                 out = substring(out, 0, strlen(out) - 1);
 593         }
 594         else if((sk = CS(pl).scorekeeper))
 595         {
 596                 FOREACH(Scores, true, {
 597                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 598                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 599         });
 600                 if(shortString < 2)
 601                 FOREACH(Scores, true, {
 602                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 603                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 604         });
 605                 if(shortString < 1)
 606                 FOREACH(Scores, true, {
 607                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 608                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 609                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 610         });
 611                 out = substring(out, 0, strlen(out) - 1);
 612         }
 613         return out;
 614 }
 615
 616 string GetTeamScoreString(float tm, float shortString)
 617 {
 618         string out;
 619         entity sk;
 620         float i, f;
 621         string l;
 622
 623         out = "";
 624         if(tm == 0)
 625         {
 626                 // label
 627                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 628                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 629                         {
 630                                 f = teamscores_flags(i);
 631                                 l = teamscores_label(i);
 632                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 633                         }
 634                 if(shortString < 2)
 635                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 636                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 637                         {
 638                                 f = teamscores_flags(i);
 639                                 l = teamscores_label(i);
 640                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 641                         }
 642                 if(shortString < 1)
 643                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 644                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 645                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 646                         {
 647                                 f = teamscores_flags(i);
 648                                 l = teamscores_label(i);
 649                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 650                         }
 651                 out = substring(out, 0, strlen(out) - 1);
 652         }
 653         else if((sk = teamscorekeepers[tm - 1]))
 654         {
 655                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 656                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 657                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 658                 if(shortString < 2)
 659                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 660                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 661                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 662                 if(shortString < 1)
 663                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 664                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 665                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 666                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 667                 out = substring(out, 0, strlen(out) - 1);
 668         }
 669         return out;
 670 }
 671
 672 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, float strict)
 673 {
 674         if(teams && teamscores_entities_count)
 675         {
 676                 if(p1.team != p2.team)
 677                 {
 678                         entity t1, t2;
 679                         float r;
 680                         t1 = teamscorekeepers[p1.team - 1];
 681                         t2 = teamscorekeepers[p2.team - 1];
 682                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 683                         return r;
 684                 }
 685                 if(teams < 0)
 686                         return 0;
 687         }
 688
 689         return PlayerScore_Compare(CS(p1).scorekeeper, CS(p2).scorekeeper, strict);
 690 }
 691
 692 entity PlayerScore_Sort(.float field, float teams, float strict, float nospectators)
 693 {
 694         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 695         float i, j;
 696
 697         plist = NULL;
 698
 699         FOREACH_CLIENT(true, { it.(field) = 0; });
 700
 701         FOREACH_CLIENT(CS(it).scorekeeper,
 702         {
 703                 if(nospectators)
 704                         if(it.frags == FRAGS_SPECTATOR)
 705                                 continue;
 706
 707                 it.chain = plist;
 708                 plist = it;
 709         });
 710         // Now plist points to the whole list.
 711
 712         pfirst = plast = NULL;
 713
 714         i = j = 0;
 715         while(plist)
 716         {
 717                 pprev = pbestprev = NULL;
 718                 pbest = plist;
 719                 for(p = plist; (pprev = p), (p = p.chain); )
 720                 {
 721                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 722                         {
 723                                 pbest = p;
 724                                 pbestprev = pprev;
 725                         }
 726                 }
 727
 728                 // remove pbest out of the chain
 729                 if(pbestprev == NULL)
 730                         plist = pbest.chain;
 731                 else
 732                         pbestprev.chain = pbest.chain;
 733                 pbest.chain = NULL;
 734
 735                 ++i;
 736                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, 0))
 737                         j = i;
 738
 739                 pbest.(field) = j;
 740
 741                 if (!pfirst)
 742                         pfirst = pbest;
 743                 if(plast)
 744                         plast.chain = pbest;
 745                 plast = pbest;
 746         }
 747
 748         return pfirst;
 749 }
 750
 751 float TeamScore_GetCompareValue(float t)
 752 {
 753         float s;
 754         entity sk;
 755
 756         if(t <= 0 || t >= 16)
 757         {
 758                 if(game_stopped)
 759                         return 0;
 760                 error("Reading score of invalid team!");
 761         }
 762
 763         sk = teamscorekeepers[t - 1];
 764         if (!sk)
 765                 return -999999999;
 766         s = sk.teamscores_primary;
 767         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 768                 if(!s)
 769                         return -999999999;
 770         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 771                 s = -s;
 772         return s;
 773 }
 774
 775 const float NAMEWIDTH = 22;
 776 const float SCORESWIDTH = 58;
 777 // TODO put this somewhere in common?
 778 string Score_NicePrint_ItemColor(float vflags)
 779 {
 780         if(vflags & SFL_SORT_PRIO_PRIMARY)
 781                 return "^3";
 782         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 783                 return "^5";
 784         else
 785                 return "^7";
 786 }
 787
 788 void Score_NicePrint_Team(entity to, float t, float w)
 789 {
 790         string s, s2;
 791         float i;
 792         entity sk;
 793         float fl, sc;
 794         s = "";
 795
 796         sk = teamscorekeepers[t - 1];
 797         if(sk)
 798         {
 799                 s = strcat(s, Team_ColoredFullName(t));
 800                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 801                         if(teamscores_label(i) != "")
 802                         {
 803                                 fl = teamscores_flags(i);
 804                                 sc = sk.(teamscores(i));
 805                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 806                         }
 807         }
 808         else
 809                 s = "Scores:";
 810
 811         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 812
 813         FOREACH(Scores, true, {
 814                 if(scores_label(it) != "")
 815                 {
 816                         fl = scores_flags(it);
 817                         s2 = scores_label(it);
 818                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 819                 }
 820     });
 821
 822         print_to(to, s);
 823 }
 824
 825 void Score_NicePrint_Player(entity to, entity p, float w)
 826 {
 827         string s;
 828         float i;
 829         entity sk;
 830         float fl, sc;
 831         s = "  ";
 832
 833         sk = CS(p).scorekeeper;
 834
 835         s = strcat(s, playername(p, false));
 836         for (;;)
 837         {
 838                 i = strlennocol(s) - NAMEWIDTH;
 839                 if(i > 0)
 840                         s = substring(s, 0, strlen(s) - i);
 841                 else
 842                 {
 843                         s = strcat(s, strpad(i, ""));
 844                         break;
 845                 }
 846         }
 847
 848         FOREACH(Scores, true, {
 849                 if(scores_label(it) != "")
 850                 {
 851                         fl = scores_flags(it);
 852                         sc = sk.(scores(it));
 853                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 854                 }
 855     });
 856
 857         print_to(to, s);
 858 }
 859
 860 void Score_NicePrint_Spectators(entity to)
 861 {
 862         print_to(to, "Spectators:");
 863 }
 864
 865 void Score_NicePrint_Spectator(entity to, entity p)
 866 {
 867         print_to(to, strcat("  ", playername(p, false)));
 868 }
 869
 870 .float score_dummyfield;
 871 void Score_NicePrint(entity to)
 872 {
 873         entity p;
 874         float w;
 875
 876         int t = 0;
 877         FOREACH(Scores, true, {
 878                 if(scores_label(it) != "")
 879                         ++t;
 880     });
 881         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 882
 883         p = PlayerScore_Sort(score_dummyfield, 1, 1, 0);
 884         t = -1;
 885
 886         if(!teamscores_entities_count)
 887                 Score_NicePrint_Team(to, t, w);
 888         while(p)
 889         {
 890                 if(teamscores_entities_count)
 891                         if(t != p.team)
 892                                 Score_NicePrint_Team(to, p.team, w);
 893                 Score_NicePrint_Player(to, p, w);
 894                 t = p.team;
 895                 p = p.chain;
 896         }
 897
 898         t = 0;
 899         FOREACH_CLIENT(!IS_PLAYER(it), {
 900                 if (!t)
 901                         Score_NicePrint_Spectators(to);
 902                 Score_NicePrint_Spectator(to, it);
 903                 t = 1;
 904         });
 905 }
 906
 907 void PlayerScore_PlayerStats(entity p)
 908 {
 909         entity s = CS(p).scorekeeper;
 910         FOREACH(Scores, true, {
 911                 if(s.(scores(it)) != 0)
 912                         if(scores_label(it) != "")
 913                                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_SCOREBOARD, scores_label(it)), s.(scores(it)));
 914     });
 915 }
 916
 917 void PlayerScore_TeamStats()
 918 {
 919         entity sk;
 920         float t, i;
 921         for(t = 0; t < 16; ++t)
 922         {
 923                 sk = teamscorekeepers[t];
 924                 if(!sk)
 925                         continue;
 926                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 927                         if(sk.(teamscores(i)) != 0)
 928                                 if(teamscores_label(i) != "")
 929                                         // the +1 is important here!
 930                                         PS_GR_T_ADDVAL(t+1, strcat(PLAYERSTATS_SCOREBOARD, teamscores_label(i)), sk.(teamscores(i)));
 931         }
 932 }