qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/mutators/base.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/playerstats.qh>
   7 #include <common/scores.qh>
   8 #include <common/state.qh>
   9 #include <common/stats.qh>
  10 #include <common/teams.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <server/client.qh>
  13 #include <server/command/common.qh>
  14 #include <server/intermission.qh>
  15 #include <server/mutators/_mod.qh>
  16 #include <server/round_handler.qh>
  17 #include <server/world.qh>
  18
  19 .entity scorekeeper;
  20 entity teamscorekeepers[16];
  21 float teamscores_entities_count;
  22 var .float scores_primary;
  23 var .float teamscores_primary;
  24 float scores_flags_primary;
  25 float teamscores_flags_primary;
  26
  27 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, bool strict) // returns: cmp value, best prio
  28 {
  29         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  30                 return previous;
  31         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  32                 return previous;
  33         if (t1.(field) == t2.(field))
  34                 return previous;
  35
  36         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  37
  38         if(fieldflags & SFL_ZERO_IS_WORST)
  39         {
  40                 if (t1.(field) == 0)
  41                 {
  42                         previous.x = -1;
  43                         return previous;
  44                 }
  45                 else if (t2.(field) == 0)
  46                 {
  47                         previous.x = +1;
  48                         return previous;
  49                 }
  50         }
  51
  52         if (fieldflags & SFL_LOWER_IS_BETTER)
  53                 previous.x = (t2.(field) - t1.(field));
  54         else
  55                 previous.x = (t1.(field) - t2.(field));
  56
  57         return previous;
  58 }
  59
  60 /*
  61  * teamscore entities
  62  */
  63
  64 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  65 {
  66         float i, longflags;
  67
  68         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  69         int t = this.team - 1;
  70         assert(t, eprint(this));
  71         WriteByte(MSG_ENTITY, t);
  72
  73         longflags = 0;
  74         for(i = 0; i < MAX_TEAMSCORE; ++i)
  75                 if(this.(teamscores(i)) > 127 || this.(teamscores(i)) <= -128)
  76                         longflags |= BIT(i);
  77
  78 #if MAX_TEAMSCORE <= 8
  79         WriteByte(MSG_ENTITY, sendflags);
  80         WriteByte(MSG_ENTITY, longflags);
  81 #else
  82         WriteShort(MSG_ENTITY, sendflags);
  83         WriteShort(MSG_ENTITY, longflags);
  84 #endif
  85         for(i = 0; i < MAX_TEAMSCORE; ++i)
  86                 if(sendflags & BIT(i))
  87                 {
  88                         if(longflags & BIT(i))
  89                                 WriteInt24_t(MSG_ENTITY, this.(teamscores(i)));
  90                         else
  91                                 WriteChar(MSG_ENTITY, this.(teamscores(i)));
  92                 }
  93
  94         return true;
  95 }
  96
  97 void TeamScore_Spawn(float t, string name)
  98 {
  99         entity ts = new_pure(csqc_score_team);
 100         ts.netname = name; // not used yet, FIXME
 101         ts.team = t;
 102         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
 103         teamscorekeepers[t - 1] = ts;
 104         ++teamscores_entities_count;
 105         PlayerStats_GameReport_AddTeam(t);
 106 }
 107
 108 float TeamScore_AddToTeam(int t, float scorefield, float score)
 109 {
 110         entity s;
 111
 112         if(game_stopped)
 113         {
 114                 score = 0;
 115         }
 116
 117         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 118         if(t <= 0 || t >= 16)
 119         {
 120                 if(game_stopped)
 121                         return 0;
 122                 error("Adding score to invalid team!");
 123         }
 124         s = teamscorekeepers[t - 1];
 125         if(!s)
 126         {
 127                 if(game_stopped)
 128                         return 0;
 129                 error("Adding score to unknown team!");
 130         }
 131         if(score)
 132                 if(teamscores_label(scorefield) != "")
 133                         s.SendFlags |= BIT(scorefield);
 134         return (s.(teamscores(scorefield)) += score);
 135 }
 136
 137 float TeamScore_Add(entity player, float scorefield, float score)
 138 {
 139         return TeamScore_AddToTeam(player.team, scorefield, score);
 140 }
 141
 142 float TeamScore_Compare(entity t1, entity t2, bool strict)
 143 {
 144         if(!t1 || !t2) return (!t2) - !t1;
 145
 146         vector result = '0 0 0';
 147         float i;
 148         for(i = 0; i < MAX_TEAMSCORE; ++i)
 149         {
 150                 var .float f;
 151                 f = teamscores(i);
 152                 result = ScoreField_Compare(t1, t2, f, teamscores_flags(i), result, strict);
 153         }
 154
 155         if (result.x == 0 && strict)
 156                 result.x = t1.team - t2.team;
 157
 158         return result.x;
 159 }
 160
 161 /*
 162  * the scoreinfo entity
 163  */
 164
 165 void ScoreInfo_SetLabel_PlayerScore(PlayerScoreField i, string label, float scoreflags)
 166 {
 167         scores_label(i) = label;
 168         scores_flags(i) = scoreflags;
 169         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 170         {
 171                 scores_primary = scores(i);
 172                 scores_flags_primary = scoreflags;
 173         }
 174         if(label != "")
 175         {
 176                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 177                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 178         }
 179 }
 180
 181 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 182 {
 183         teamscores_label(i) = label;
 184         teamscores_flags(i) = scoreflags;
 185         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 186         {
 187                 teamscores_primary = teamscores(i);
 188                 teamscores_flags_primary = scoreflags;
 189         }
 190         if(label != "")
 191         {
 192                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 193                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 194         }
 195 }
 196
 197 .bool welcome_msg_already_sent_on_connection;
 198 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 199 {
 200         float i;
 201         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 202         WriteRegistered(Gametypes, MSG_ENTITY, MapInfo_LoadedGametype);
 203         FOREACH(Scores, true, {
 204                 WriteString(MSG_ENTITY, scores_label(it));
 205                 WriteByte(MSG_ENTITY, scores_flags(it));
 206         });
 207         for(i = 0; i < MAX_TEAMSCORE; ++i)
 208         {
 209                 WriteString(MSG_ENTITY, teamscores_label(i));
 210                 WriteByte(MSG_ENTITY, teamscores_flags(i));
 211         }
 212         bool welcome_msg_too = (!to.welcome_msg_already_sent_on_connection);
 213         WriteByte(MSG_ENTITY, welcome_msg_too);
 214         // welcome message is sent here because it needs to know the gametype
 215         if (welcome_msg_too)
 216         {
 217                 SendWelcomemessage_msg_type(this, false, MSG_ENTITY);
 218                 to.welcome_msg_already_sent_on_connection = true;
 219         }
 220         return true;
 221 }
 222
 223 void ScoreInfo_Init(int teams)
 224 {
 225         if(scores_initialized)
 226         {
 227                 scores_initialized.SendFlags |= 1; // force a resend
 228         }
 229         else
 230         {
 231                 scores_initialized = new_pure(ent_client_scoreinfo);
 232                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 233         }
 234         if(teams & BIT(0))
 235                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 236         if(teams & BIT(1))
 237                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 238         if(teams & BIT(2))
 239                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 240         if(teams & BIT(3))
 241                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 242 }
 243
 244 /*
 245  * per-player score entities
 246  */
 247
 248 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 249 {
 250         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 251         WriteByte(MSG_ENTITY, etof(this.owner));
 252
 253         int longflags = 0;
 254         FOREACH(Scores, true, {
 255             int p = 1 << (i % 16);
 256                 if (this.(scores(it)) > 127 || this.(scores(it)) <= -128)
 257                         longflags |= p;
 258     });
 259
 260         WriteShort(MSG_ENTITY, sendflags);
 261         WriteShort(MSG_ENTITY, longflags);
 262         FOREACH(Scores, true, {
 263             int p = 1 << (i % 16);
 264                 if (sendflags & p)
 265                 {
 266                         if(longflags & p)
 267                                 WriteInt24_t(MSG_ENTITY, this.(scores(it)));
 268                         else
 269                                 WriteChar(MSG_ENTITY, this.(scores(it)));
 270                 }
 271     });
 272
 273         return true;
 274 }
 275
 276 float PlayerScore_Clear(entity player)
 277 {
 278         entity sk;
 279
 280         if(teamscores_entities_count)
 281                 return 0;
 282
 283         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 284
 285         sk = CS(player).scorekeeper;
 286         FOREACH(Scores, true, {
 287                 if(sk.(scores(it)) != 0)
 288                         if(scores_label(it) != "")
 289                                 sk.SendFlags |= BIT(i % 16);
 290                 if(i != SP_ELO.m_id)
 291                         sk.(scores(it)) = 0;
 292         });
 293
 294         return 1;
 295 }
 296
 297 void Score_ClearAll()
 298 {
 299         entity sk;
 300         float t;
 301         FOREACH_CLIENTSLOT(true, {
 302                 sk = CS(it).scorekeeper;
 303                 if (!sk) continue;
 304                 FOREACH(Scores, true, {
 305                         if(sk.(scores(it)) != 0)
 306                                 if(scores_label(it) != "")
 307                                         sk.SendFlags |= BIT(i % 16);
 308                         if(i != SP_ELO.m_id)
 309                                 sk.(scores(it)) = 0;
 310                 });
 311         });
 312         for(t = 0; t < 16; ++t)
 313         {
 314                 sk = teamscorekeepers[t];
 315                 if(!sk)
 316                         continue;
 317                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 318                 {
 319                         if(sk.(teamscores(j)) != 0)
 320                                 if(teamscores_label(j) != "")
 321                                         sk.SendFlags |= BIT(j);
 322                         sk.(teamscores(j)) = 0;
 323                 }
 324         }
 325 }
 326
 327 void PlayerScore_Attach(entity player)
 328 {
 329         if(CS(player).scorekeeper)
 330                 error("player already has a scorekeeper");
 331         entity sk = new_pure(scorekeeper);
 332         sk.owner = player;
 333         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 334         CS(player).scorekeeper = sk;
 335 }
 336
 337 void PlayerScore_Detach(entity player)
 338 {
 339         if(!CS(player).scorekeeper)
 340                 error("player has no scorekeeper");
 341         delete(CS(player).scorekeeper);
 342         CS(player).scorekeeper = NULL;
 343 }
 344
 345 float PlayerScore_Add(entity player, PlayerScoreField scorefield, float score)
 346 {
 347         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 348         score = M_ARGV(1, float);
 349
 350         if(!mutator_returnvalue && game_stopped)
 351         {
 352                 score = 0;
 353         }
 354
 355         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 356         entity s = CS(player).scorekeeper;
 357         if(!s)
 358         {
 359                 if(game_stopped)
 360                         return 0;
 361                 LOG_WARN("Adding score to unknown player!");
 362                 return 0;
 363         }
 364         if(!score)
 365         {
 366                 return s.(scores(scorefield));
 367         }
 368         if(scores_label(scorefield) != "")
 369                 s.SendFlags |= BIT(scorefield.m_id % 16);
 370         if(!warmup_stage)
 371                 PlayerStats_GameReport_Event_Player(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
 372         s.(scores(scorefield)) += score;
 373         MUTATOR_CALLHOOK(AddedPlayerScore, scorefield, score, player);
 374         return s.(scores(scorefield));
 375 }
 376
 377 float PlayerScore_Set(entity player, PlayerScoreField scorefield, float score)
 378 {
 379         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 380         entity s = CS(player).scorekeeper;
 381         if(!s)
 382         {
 383                 if(game_stopped)
 384                         return 0;
 385                 LOG_WARN("Setting score of unknown player!");
 386                 return 0;
 387         }
 388
 389         float oldscore = s.(scores(scorefield));
 390         if(oldscore == score)
 391                 return oldscore;
 392
 393         if(scores_label(scorefield) != "")
 394                 s.SendFlags |= BIT(scorefield.m_id % 16);
 395         s.(scores(scorefield)) = score;
 396         return s.(scores(scorefield));
 397 }
 398
 399 float PlayerTeamScore_Add(entity player, PlayerScoreField pscorefield, float tscorefield, float score)
 400 {
 401         float r;
 402         r = PlayerScore_Add(player, pscorefield, score);
 403         if(teamscores_entities_count) // only for teamplay
 404                 r = TeamScore_Add(player, tscorefield, score);
 405         return r;
 406 }
 407
 408 float PlayerScore_Compare(entity t1, entity t2, bool strict)
 409 {
 410         if(!t1 || !t2) return (!t2) - !t1;
 411
 412         vector result = '0 0 0';
 413         FOREACH(Scores, true, {
 414                 var .float f = scores(it);
 415                 result = ScoreField_Compare(t1, t2, f, scores_flags(it), result, strict);
 416         });
 417
 418         if (result.x == 0 && strict)
 419                 result.x = t1.owner.playerid - t2.owner.playerid;
 420
 421         return result.x;
 422 }
 423
 424 void WinningConditionHelper(entity this)
 425 {
 426         float c;
 427         string s;
 428         float fullstatus;
 429         entity winnerscorekeeper;
 430         entity secondscorekeeper;
 431         entity sk;
 432
 433         // format:
 434         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 435         // score labels always start with a symbol or with lower case
 436         // so to match pure, match for :P0:
 437         // to match full, match for :S0:
 438
 439         fullstatus = autocvar_g_full_getstatus_responses;
 440
 441         s = GetGametype();
 442         s = strcat(s, ":", autocvar_g_xonoticversion);
 443         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 444         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 445         s = strcat(s, ":F", ftos(serverflags));
 446         s = strcat(s, ":T", sv_termsofservice_url_escaped);
 447         s = strcat(s, ":M", modname);
 448         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 449
 450         if(teamscores_entities_count)
 451         {
 452                 float t;
 453
 454                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 455                 for(t = 0; t < 16; ++t)
 456                         if(teamscorekeepers[t])
 457                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 458
 459                 WinningConditionHelper_winnerteam = -1;
 460                 WinningConditionHelper_secondteam = -1;
 461                 winnerscorekeeper = NULL;
 462                 secondscorekeeper = NULL;
 463                 for(t = 0; t < 16; ++t)
 464                 {
 465                         sk = teamscorekeepers[t];
 466                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 467                         if(c < 0)
 468                         {
 469                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 470                                 WinningConditionHelper_winnerteam = t + 1;
 471                                 secondscorekeeper = winnerscorekeeper;
 472                                 winnerscorekeeper = sk;
 473                         }
 474                         else
 475                         {
 476                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 477                                 if(c < 0)
 478                                 {
 479                                         WinningConditionHelper_secondteam = t + 1;
 480                                         secondscorekeeper = sk;
 481                                 }
 482                         }
 483                 }
 484
 485                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 486                 if(WinningConditionHelper_equality)
 487                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 488
 489                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 490                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 491                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 492                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 493
 494                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 495                 WinningConditionHelper_second = NULL; // not supported in teamplay
 496         }
 497         else
 498         {
 499                 WinningConditionHelper_winner = NULL;
 500                 WinningConditionHelper_second = NULL;
 501                 winnerscorekeeper = NULL;
 502                 secondscorekeeper = NULL;
 503                 FOREACH_CLIENT(IS_PLAYER(it), {
 504                         sk = CS(it).scorekeeper;
 505                         c = PlayerScore_Compare(winnerscorekeeper, sk, true);
 506                         if(c < 0)
 507                         {
 508                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 509                                 WinningConditionHelper_winner = it;
 510                                 secondscorekeeper = winnerscorekeeper;
 511                                 winnerscorekeeper = sk;
 512                         }
 513                         else
 514                         {
 515                                 c = PlayerScore_Compare(secondscorekeeper, sk, true);
 516                                 if(c < 0)
 517                                 {
 518                                         WinningConditionHelper_second = it;
 519                                         secondscorekeeper = sk;
 520                                 }
 521                         }
 522                 });
 523
 524                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, false) == 0);
 525                 if(WinningConditionHelper_equality)
 526                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 527
 528                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 529                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 530                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 531                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 532
 533                 WinningConditionHelper_winnerteam = -1; // no teamplay
 534                 WinningConditionHelper_secondteam = -1; // no teamplay
 535         }
 536
 537         if(WinningConditionHelper_topscore == 0)
 538         {
 539                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 540                 {
 541                         if(WinningConditionHelper_lowerisbetter)
 542                                 WinningConditionHelper_topscore = 999999999;
 543                         else
 544                                 WinningConditionHelper_topscore = -999999999;
 545                 }
 546                 if(player_count == 0) // special case: empty servers DO end the match at a 0:0 tie
 547                         WinningConditionHelper_equality = 0;
 548         }
 549
 550         if(WinningConditionHelper_secondscore == 0)
 551         {
 552                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 553                 {
 554                         if(WinningConditionHelper_lowerisbetter)
 555                                 WinningConditionHelper_secondscore = 999999999;
 556                         else
 557                                 WinningConditionHelper_secondscore = -999999999;
 558                 }
 559         }
 560
 561         strcpy(worldstatus, s);
 562
 563         FOREACH_CLIENT(true, {
 564                 string s = "";
 565                 if(fullstatus)
 566                 {
 567                         s = GetPlayerScoreString(it, 1);
 568                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 569                         if(!(IS_PLAYER(it) || INGAME_JOINED(it)))
 570                                 s = strcat(s, ":spectator");
 571                 }
 572                 else
 573                 {
 574                         if (IS_PLAYER(it) || INGAME_JOINED(it))
 575                                 s = GetPlayerScoreString(it, 2);
 576                         else
 577                                 s = "-666";
 578                 }
 579
 580                 strcpy(it.clientstatus, s);
 581         });
 582 }
 583
 584 string GetScoreLogLabel(string label, float fl)
 585 {
 586         if(fl & SFL_LOWER_IS_BETTER)
 587                 label = strcat(label, "<");
 588         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 589                 label = strcat(label, "!!");
 590         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 591                 label = strcat(label, "!");
 592         return label;
 593 }
 594
 595 string GetPlayerScoreString(entity pl, float shortString)
 596 {
 597         string out;
 598         entity sk;
 599         float f;
 600         string l;
 601
 602         out = "";
 603         if(!pl)
 604         {
 605                 // label
 606                 FOREACH(Scores, true, {
 607                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 608                         {
 609                                 f = scores_flags(it);
 610                                 l = scores_label(it);
 611                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 612                         }
 613         });
 614                 if(shortString < 2)
 615                 FOREACH(Scores, true, {
 616                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 617                         {
 618                                 f = scores_flags(it);
 619                                 l = scores_label(it);
 620                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 621                         }
 622         });
 623                 if(shortString < 1)
 624                 FOREACH(Scores, true, {
 625                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 626                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 627                         {
 628                                 f = scores_flags(it);
 629                                 l = scores_label(it);
 630                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 631                         }
 632         });
 633                 out = substring(out, 0, strlen(out) - 1);
 634         }
 635         else if((sk = CS(pl).scorekeeper))
 636         {
 637                 FOREACH(Scores, true, {
 638                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 639                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 640         });
 641                 if(shortString < 2)
 642                 FOREACH(Scores, true, {
 643                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 644                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 645         });
 646                 if(shortString < 1)
 647                 FOREACH(Scores, true, {
 648                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 649                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 650                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 651         });
 652                 out = substring(out, 0, strlen(out) - 1);
 653         }
 654         return out;
 655 }
 656
 657 string GetTeamScoreString(float tm, float shortString)
 658 {
 659         string out;
 660         entity sk;
 661         float i, f;
 662         string l;
 663
 664         out = "";
 665         if(tm == 0)
 666         {
 667                 // label
 668                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 669                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 670                         {
 671                                 f = teamscores_flags(i);
 672                                 l = teamscores_label(i);
 673                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 674                         }
 675                 if(shortString < 2)
 676                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 677                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 678                         {
 679                                 f = teamscores_flags(i);
 680                                 l = teamscores_label(i);
 681                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 682                         }
 683                 if(shortString < 1)
 684                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 685                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 686                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 687                         {
 688                                 f = teamscores_flags(i);
 689                                 l = teamscores_label(i);
 690                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 691                         }
 692                 out = substring(out, 0, strlen(out) - 1);
 693         }
 694         else if((sk = teamscorekeepers[tm - 1]))
 695         {
 696                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 697                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 698                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 699                 if(shortString < 2)
 700                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 701                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 702                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 703                 if(shortString < 1)
 704                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 705                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 706                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 707                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 708                 out = substring(out, 0, strlen(out) - 1);
 709         }
 710         return out;
 711 }
 712
 713 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, bool strict)
 714 {
 715         if(teams && teamscores_entities_count)
 716         {
 717                 if(p1.team != p2.team)
 718                 {
 719                         entity t1, t2;
 720                         float r;
 721                         t1 = teamscorekeepers[p1.team - 1];
 722                         t2 = teamscorekeepers[p2.team - 1];
 723                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 724                         return r;
 725                 }
 726                 if(teams < 0)
 727                         return 0;
 728         }
 729
 730         return PlayerScore_Compare(CS(p1).scorekeeper, CS(p2).scorekeeper, strict);
 731 }
 732
 733 entity PlayerScore_Sort(.float field, int teams, bool strict, bool nospectators)
 734 {
 735         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 736         float i, j;
 737
 738         plist = NULL;
 739
 740         FOREACH_CLIENT(true, { it.(field) = 0; });
 741
 742         FOREACH_CLIENT(CS(it).scorekeeper,
 743         {
 744                 if(nospectators)
 745                         if(it.frags == FRAGS_SPECTATOR)
 746                                 continue;
 747
 748                 it.chain = plist;
 749                 plist = it;
 750         });
 751         // Now plist points to the whole list.
 752
 753         pfirst = plast = NULL;
 754
 755         i = j = 0;
 756         while(plist)
 757         {
 758                 pprev = pbestprev = NULL;
 759                 pbest = plist;
 760                 for(p = plist; (pprev = p), (p = p.chain); )
 761                 {
 762                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 763                         {
 764                                 pbest = p;
 765                                 pbestprev = pprev;
 766                         }
 767                 }
 768
 769                 // remove pbest out of the chain
 770                 if(pbestprev == NULL)
 771                         plist = pbest.chain;
 772                 else
 773                         pbestprev.chain = pbest.chain;
 774                 pbest.chain = NULL;
 775
 776                 ++i;
 777                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, strict))
 778                         j = i;
 779
 780                 pbest.(field) = j;
 781
 782                 if (!pfirst)
 783                         pfirst = pbest;
 784                 if(plast)
 785                         plast.chain = pbest;
 786                 plast = pbest;
 787         }
 788
 789         return pfirst;
 790 }
 791
 792 float TeamScore_GetCompareValue(float t)
 793 {
 794         float s;
 795         entity sk;
 796
 797         if(t <= 0 || t >= 16)
 798         {
 799                 if(game_stopped)
 800                         return 0;
 801                 error("Reading score of invalid team!");
 802         }
 803
 804         sk = teamscorekeepers[t - 1];
 805         if (!sk)
 806                 return -999999999;
 807         s = sk.teamscores_primary;
 808         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 809                 if(!s)
 810                         return -999999999;
 811         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 812                 s = -s;
 813         return s;
 814 }
 815
 816 const float NAMEWIDTH = 22;
 817 const float SCORESWIDTH = 58;
 818 // TODO put this somewhere in common?
 819 string Score_NicePrint_ItemColor(float vflags)
 820 {
 821         if(vflags & SFL_SORT_PRIO_PRIMARY)
 822                 return "^3";
 823         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 824                 return "^5";
 825         else
 826                 return "^7";
 827 }
 828
 829 void Score_NicePrint_Team(entity to, float t, float w)
 830 {
 831         string s, s2;
 832         float i;
 833         entity sk;
 834         float fl, sc;
 835         s = "";
 836
 837         sk = teamscorekeepers[t - 1];
 838         if(sk)
 839         {
 840                 s = strcat(s, Team_ColoredFullName(t));
 841                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 842                         if(teamscores_label(i) != "")
 843                         {
 844                                 fl = teamscores_flags(i);
 845                                 sc = sk.(teamscores(i));
 846                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 847                         }
 848         }
 849         else
 850                 s = "Scores:";
 851
 852         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 853
 854         FOREACH(Scores, true, {
 855                 if(scores_label(it) != "")
 856                 {
 857                         fl = scores_flags(it);
 858                         s2 = scores_label(it);
 859                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 860                 }
 861     });
 862
 863         print_to(to, s);
 864 }
 865
 866 void Score_NicePrint_Player(entity to, entity p, float w)
 867 {
 868         string s;
 869         float i;
 870         entity sk;
 871         float fl, sc;
 872         s = "  ";
 873
 874         sk = CS(p).scorekeeper;
 875
 876         s = strcat(s, playername(p.netname, p.team, false));
 877         for (;;)
 878         {
 879                 i = strlennocol(s) - NAMEWIDTH;
 880                 if(i > 0)
 881                         s = substring(s, 0, strlen(s) - i);
 882                 else
 883                 {
 884                         s = strcat(s, strpad(i, ""));
 885                         break;
 886                 }
 887         }
 888
 889         FOREACH(Scores, true, {
 890                 if(scores_label(it) != "")
 891                 {
 892                         fl = scores_flags(it);
 893                         sc = sk.(scores(it));
 894                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 895                 }
 896     });
 897
 898         print_to(to, s);
 899 }
 900
 901 void Score_NicePrint_Spectators(entity to)
 902 {
 903         print_to(to, "Spectators:");
 904 }
 905
 906 void Score_NicePrint_Spectator(entity to, entity p)
 907 {
 908         print_to(to, strcat("  ", playername(p.netname, p.team, false)));
 909 }
 910
 911 .float score_dummyfield;
 912 void Score_NicePrint(entity to)
 913 {
 914         entity p;
 915         float w;
 916
 917         int t = 0;
 918         FOREACH(Scores, true, {
 919                 if(scores_label(it) != "")
 920                         ++t;
 921     });
 922         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 923
 924         p = PlayerScore_Sort(score_dummyfield, 1, true, false);
 925         t = -1;
 926
 927         if(!teamscores_entities_count)
 928                 Score_NicePrint_Team(to, t, w);
 929         while(p)
 930         {
 931                 if(teamscores_entities_count)
 932                         if(t != p.team)
 933                                 Score_NicePrint_Team(to, p.team, w);
 934                 Score_NicePrint_Player(to, p, w);
 935                 t = p.team;
 936                 p = p.chain;
 937         }
 938
 939         t = 0;
 940         FOREACH_CLIENT(!IS_PLAYER(it), {
 941                 if (!t)
 942                         Score_NicePrint_Spectators(to);
 943                 Score_NicePrint_Spectator(to, it);
 944                 t = 1;
 945         });
 946 }
 947
 948 void PlayerScore_PlayerStats(entity p)
 949 {
 950         entity s = CS(p).scorekeeper;
 951         FOREACH(Scores, true, {
 952                 if(s.(scores(it)) != 0 && scores_label(it) != "")
 953                         PlayerStats_GameReport_Event_Player(s.owner,
 954                                 strcat(PLAYERSTATS_SCOREBOARD, scores_label(it)), s.(scores(it)));
 955         });
 956 }
 957
 958 void PlayerScore_TeamStats()
 959 {
 960         entity sk;
 961         float t, i;
 962         for(t = 0; t < 16; ++t)
 963         {
 964                 sk = teamscorekeepers[t];
 965                 if(!sk)
 966                         continue;
 967                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 968                         if(sk.(teamscores(i)) != 0 && teamscores_label(i) != "")
 969                                 // the +1 is important here!
 970                                 PlayerStats_GameReport_Event_Team(t+1,
 971                                         strcat(PLAYERSTATS_SCOREBOARD, teamscores_label(i)), sk.(teamscores(i)));
 972         }
 973 }