qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/mutators/base.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/playerstats.qh>
   7 #include <common/scores.qh>
   8 #include <common/state.qh>
   9 #include <common/stats.qh>
  10 #include <common/teams.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <server/client.qh>
  13 #include <server/command/common.qh>
  14 #include <server/intermission.qh>
  15 #include <server/mutators/_mod.qh>
  16 #include <server/round_handler.qh>
  17 #include <server/world.qh>
  18
  19 .entity scorekeeper;
  20 entity teamscorekeepers[16];
  21 float teamscores_entities_count;
  22 var .float scores_primary;
  23 var .float teamscores_primary;
  24 float scores_flags_primary;
  25 float teamscores_flags_primary;
  26
  27 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, bool strict) // returns: cmp value, best prio
  28 {
  29         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  30                 return previous;
  31         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  32                 return previous;
  33         if (t1.(field) == t2.(field))
  34                 return previous;
  35
  36         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  37
  38         if(fieldflags & SFL_ZERO_IS_WORST)
  39         {
  40                 if (t1.(field) == 0)
  41                 {
  42                         previous.x = -1;
  43                         return previous;
  44                 }
  45                 else if (t2.(field) == 0)
  46                 {
  47                         previous.x = +1;
  48                         return previous;
  49                 }
  50         }
  51
  52         if (fieldflags & SFL_LOWER_IS_BETTER)
  53                 previous.x = (t2.(field) - t1.(field));
  54         else
  55                 previous.x = (t1.(field) - t2.(field));
  56
  57         return previous;
  58 }
  59
  60 /*
  61  * teamscore entities
  62  */
  63
  64 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  65 {
  66         float i, longflags;
  67
  68         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  69         int t = this.team - 1;
  70         assert(t, eprint(this));
  71         WriteByte(MSG_ENTITY, t);
  72
  73         longflags = 0;
  74         for(i = 0; i < MAX_TEAMSCORE; ++i)
  75                 if(this.(teamscores(i)) > 127 || this.(teamscores(i)) <= -128)
  76                         longflags |= BIT(i);
  77
  78 #if MAX_TEAMSCORE <= 8
  79         WriteByte(MSG_ENTITY, sendflags);
  80         WriteByte(MSG_ENTITY, longflags);
  81 #else
  82         WriteShort(MSG_ENTITY, sendflags);
  83         WriteShort(MSG_ENTITY, longflags);
  84 #endif
  85         for(i = 0; i < MAX_TEAMSCORE; ++i)
  86                 if(sendflags & BIT(i))
  87                 {
  88                         if(longflags & BIT(i))
  89                                 WriteInt24_t(MSG_ENTITY, this.(teamscores(i)));
  90                         else
  91                                 WriteChar(MSG_ENTITY, this.(teamscores(i)));
  92                 }
  93
  94         return true;
  95 }
  96
  97 void TeamScore_Spawn(float t, string name)
  98 {
  99         entity ts = new_pure(csqc_score_team);
 100         ts.netname = name; // not used yet, FIXME
 101         ts.team = t;
 102         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
 103         teamscorekeepers[t - 1] = ts;
 104         ++teamscores_entities_count;
 105         PlayerStats_GameReport_AddTeam(t);
 106 }
 107
 108 float TeamScore_AddToTeam(int t, float scorefield, float score)
 109 {
 110         entity s;
 111
 112         if(game_stopped)
 113         {
 114                 score = 0;
 115         }
 116
 117         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 118         if(t <= 0 || t >= 16)
 119         {
 120                 if(game_stopped)
 121                         return 0;
 122                 error("Adding score to invalid team!");
 123         }
 124         s = teamscorekeepers[t - 1];
 125         if(!s)
 126         {
 127                 if(game_stopped)
 128                         return 0;
 129                 error("Adding score to unknown team!");
 130         }
 131         if(score)
 132                 if(teamscores_label(scorefield) != "")
 133                         s.SendFlags |= BIT(scorefield);
 134         return (s.(teamscores(scorefield)) += score);
 135 }
 136
 137 float TeamScore_Add(entity player, float scorefield, float score)
 138 {
 139         return TeamScore_AddToTeam(player.team, scorefield, score);
 140 }
 141
 142 float TeamScore_Compare(entity t1, entity t2, bool strict)
 143 {
 144         if(!t1 || !t2) return (!t2) - !t1;
 145
 146         vector result = '0 0 0';
 147         float i;
 148         for(i = 0; i < MAX_TEAMSCORE; ++i)
 149         {
 150                 var .float f;
 151                 f = teamscores(i);
 152                 result = ScoreField_Compare(t1, t2, f, teamscores_flags(i), result, strict);
 153         }
 154
 155         if (result.x == 0 && strict)
 156                 result.x = t1.team - t2.team;
 157
 158         return result.x;
 159 }
 160
 161 /*
 162  * the scoreinfo entity
 163  */
 164
 165 void ScoreInfo_SetLabel_PlayerScore(PlayerScoreField i, string label, float scoreflags)
 166 {
 167         scores_label(i) = label;
 168         scores_flags(i) = scoreflags;
 169         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 170         {
 171                 scores_primary = scores(i);
 172                 scores_flags_primary = scoreflags;
 173         }
 174         if(label != "")
 175         {
 176                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 177                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 178         }
 179 }
 180
 181 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 182 {
 183         teamscores_label(i) = label;
 184         teamscores_flags(i) = scoreflags;
 185         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 186         {
 187                 teamscores_primary = teamscores(i);
 188                 teamscores_flags_primary = scoreflags;
 189         }
 190         if(label != "")
 191         {
 192                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 193                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 194         }
 195 }
 196
 197 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 198 {
 199         float i;
 200         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 201         WriteRegistered(Gametypes, MSG_ENTITY, MapInfo_LoadedGametype);
 202         FOREACH(Scores, true, {
 203                 WriteString(MSG_ENTITY, scores_label(it));
 204                 WriteByte(MSG_ENTITY, scores_flags(it));
 205         });
 206         for(i = 0; i < MAX_TEAMSCORE; ++i)
 207         {
 208                 WriteString(MSG_ENTITY, teamscores_label(i));
 209                 WriteByte(MSG_ENTITY, teamscores_flags(i));
 210         }
 211         // prevent sending the welcome message again when score types are sent again because the scoring system has changed
 212         // it can happen in some game modes like Race when the qualyfing session ends and the race starts
 213         // NOTE: CS(this) is not initialized yet when a local client connects to a local dedicated server
 214         bool welcome_msg_too = (!CS(this) || time < CS(this).jointime + 5);
 215         WriteByte(MSG_ENTITY, welcome_msg_too);
 216         // welcome message is sent here because it needs to know the gametype
 217         if (welcome_msg_too)
 218                 SendWelcomemessage_msg_type(this, false, MSG_ENTITY);
 219         return true;
 220 }
 221
 222 void ScoreInfo_Init(int teams)
 223 {
 224         if(scores_initialized)
 225         {
 226                 scores_initialized.SendFlags |= 1; // force a resend
 227         }
 228         else
 229         {
 230                 scores_initialized = new_pure(ent_client_scoreinfo);
 231                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 232         }
 233         if(teams & BIT(0))
 234                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 235         if(teams & BIT(1))
 236                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 237         if(teams & BIT(2))
 238                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 239         if(teams & BIT(3))
 240                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 241 }
 242
 243 /*
 244  * per-player score entities
 245  */
 246
 247 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 248 {
 249         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 250         WriteByte(MSG_ENTITY, etof(this.owner));
 251
 252         int longflags = 0;
 253         FOREACH(Scores, true, {
 254             int p = 1 << (i % 16);
 255                 if (this.(scores(it)) > 127 || this.(scores(it)) <= -128)
 256                         longflags |= p;
 257     });
 258
 259         WriteShort(MSG_ENTITY, sendflags);
 260         WriteShort(MSG_ENTITY, longflags);
 261         FOREACH(Scores, true, {
 262             int p = 1 << (i % 16);
 263                 if (sendflags & p)
 264                 {
 265                         if(longflags & p)
 266                                 WriteInt24_t(MSG_ENTITY, this.(scores(it)));
 267                         else
 268                                 WriteChar(MSG_ENTITY, this.(scores(it)));
 269                 }
 270     });
 271
 272         return true;
 273 }
 274
 275 float PlayerScore_Clear(entity player)
 276 {
 277         entity sk;
 278
 279         if(teamscores_entities_count)
 280                 return 0;
 281
 282         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 283
 284         sk = CS(player).scorekeeper;
 285         FOREACH(Scores, true, {
 286                 if(sk.(scores(it)) != 0)
 287                         if(scores_label(it) != "")
 288                                 sk.SendFlags |= BIT(i % 16);
 289                 if(i != SP_ELO.m_id)
 290                         sk.(scores(it)) = 0;
 291         });
 292
 293         return 1;
 294 }
 295
 296 void Score_ClearAll()
 297 {
 298         entity sk;
 299         float t;
 300         FOREACH_CLIENTSLOT(true, {
 301                 sk = CS(it).scorekeeper;
 302                 if (!sk) continue;
 303                 FOREACH(Scores, true, {
 304                         if(sk.(scores(it)) != 0)
 305                                 if(scores_label(it) != "")
 306                                         sk.SendFlags |= BIT(i % 16);
 307                         if(i != SP_ELO.m_id)
 308                                 sk.(scores(it)) = 0;
 309                 });
 310         });
 311         for(t = 0; t < 16; ++t)
 312         {
 313                 sk = teamscorekeepers[t];
 314                 if(!sk)
 315                         continue;
 316                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 317                 {
 318                         if(sk.(teamscores(j)) != 0)
 319                                 if(teamscores_label(j) != "")
 320                                         sk.SendFlags |= BIT(j);
 321                         sk.(teamscores(j)) = 0;
 322                 }
 323         }
 324 }
 325
 326 void PlayerScore_Attach(entity player)
 327 {
 328         if(CS(player).scorekeeper)
 329                 error("player already has a scorekeeper");
 330         entity sk = new_pure(scorekeeper);
 331         sk.owner = player;
 332         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 333         CS(player).scorekeeper = sk;
 334 }
 335
 336 void PlayerScore_Detach(entity player)
 337 {
 338         if(!CS(player).scorekeeper)
 339                 error("player has no scorekeeper");
 340         delete(CS(player).scorekeeper);
 341         CS(player).scorekeeper = NULL;
 342 }
 343
 344 float PlayerScore_Add(entity player, PlayerScoreField scorefield, float score)
 345 {
 346         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 347         score = M_ARGV(1, float);
 348
 349         if(!mutator_returnvalue && game_stopped)
 350         {
 351                 score = 0;
 352         }
 353
 354         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 355         entity s = CS(player).scorekeeper;
 356         if(!s)
 357         {
 358                 if(game_stopped)
 359                         return 0;
 360                 LOG_WARN("Adding score to unknown player!");
 361                 return 0;
 362         }
 363         if(!score)
 364         {
 365                 return s.(scores(scorefield));
 366         }
 367         if(scores_label(scorefield) != "")
 368                 s.SendFlags |= BIT(scorefield.m_id % 16);
 369         if(!warmup_stage)
 370                 PlayerStats_GameReport_Event_Player(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
 371         s.(scores(scorefield)) += score;
 372         MUTATOR_CALLHOOK(AddedPlayerScore, scorefield, score, player);
 373         return s.(scores(scorefield));
 374 }
 375
 376 float PlayerScore_Set(entity player, PlayerScoreField scorefield, float score)
 377 {
 378         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 379         entity s = CS(player).scorekeeper;
 380         if(!s)
 381         {
 382                 if(game_stopped)
 383                         return 0;
 384                 LOG_WARN("Setting score of unknown player!");
 385                 return 0;
 386         }
 387
 388         float oldscore = s.(scores(scorefield));
 389         if(oldscore == score)
 390                 return oldscore;
 391
 392         if(scores_label(scorefield) != "")
 393                 s.SendFlags |= BIT(scorefield.m_id % 16);
 394         s.(scores(scorefield)) = score;
 395         return s.(scores(scorefield));
 396 }
 397
 398 float PlayerTeamScore_Add(entity player, PlayerScoreField pscorefield, float tscorefield, float score)
 399 {
 400         float r;
 401         r = PlayerScore_Add(player, pscorefield, score);
 402         if(teamscores_entities_count) // only for teamplay
 403                 r = TeamScore_Add(player, tscorefield, score);
 404         return r;
 405 }
 406
 407 float PlayerScore_Compare(entity t1, entity t2, bool strict)
 408 {
 409         if(!t1 || !t2) return (!t2) - !t1;
 410
 411         vector result = '0 0 0';
 412         FOREACH(Scores, true, {
 413                 var .float f = scores(it);
 414                 result = ScoreField_Compare(t1, t2, f, scores_flags(it), result, strict);
 415         });
 416
 417         if (result.x == 0 && strict)
 418                 result.x = t1.owner.playerid - t2.owner.playerid;
 419
 420         return result.x;
 421 }
 422
 423 void WinningConditionHelper(entity this)
 424 {
 425         float c;
 426         string s;
 427         float fullstatus;
 428         entity winnerscorekeeper;
 429         entity secondscorekeeper;
 430         entity sk;
 431
 432         // format:
 433         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 434         // score labels always start with a symbol or with lower case
 435         // so to match pure, match for :P0:
 436         // to match full, match for :S0:
 437
 438         fullstatus = autocvar_g_full_getstatus_responses;
 439
 440         s = GetGametype();
 441         s = strcat(s, ":", autocvar_g_xonoticversion);
 442         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 443         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 444         s = strcat(s, ":F", ftos(serverflags));
 445         s = strcat(s, ":T", sv_termsofservice_url_escaped);
 446         s = strcat(s, ":M", modname);
 447         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 448
 449         if(teamscores_entities_count)
 450         {
 451                 float t;
 452
 453                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 454                 for(t = 0; t < 16; ++t)
 455                         if(teamscorekeepers[t])
 456                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 457
 458                 WinningConditionHelper_winnerteam = -1;
 459                 WinningConditionHelper_secondteam = -1;
 460                 winnerscorekeeper = NULL;
 461                 secondscorekeeper = NULL;
 462                 for(t = 0; t < 16; ++t)
 463                 {
 464                         sk = teamscorekeepers[t];
 465                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 466                         if(c < 0)
 467                         {
 468                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 469                                 WinningConditionHelper_winnerteam = t + 1;
 470                                 secondscorekeeper = winnerscorekeeper;
 471                                 winnerscorekeeper = sk;
 472                         }
 473                         else
 474                         {
 475                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 476                                 if(c < 0)
 477                                 {
 478                                         WinningConditionHelper_secondteam = t + 1;
 479                                         secondscorekeeper = sk;
 480                                 }
 481                         }
 482                 }
 483
 484                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 485                 if(WinningConditionHelper_equality)
 486                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 487
 488                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 489                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 490                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 491                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 492
 493                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 494                 WinningConditionHelper_second = NULL; // not supported in teamplay
 495         }
 496         else
 497         {
 498                 WinningConditionHelper_winner = NULL;
 499                 WinningConditionHelper_second = NULL;
 500                 winnerscorekeeper = NULL;
 501                 secondscorekeeper = NULL;
 502                 FOREACH_CLIENT(IS_PLAYER(it), {
 503                         sk = CS(it).scorekeeper;
 504                         c = PlayerScore_Compare(winnerscorekeeper, sk, true);
 505                         if(c < 0)
 506                         {
 507                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 508                                 WinningConditionHelper_winner = it;
 509                                 secondscorekeeper = winnerscorekeeper;
 510                                 winnerscorekeeper = sk;
 511                         }
 512                         else
 513                         {
 514                                 c = PlayerScore_Compare(secondscorekeeper, sk, true);
 515                                 if(c < 0)
 516                                 {
 517                                         WinningConditionHelper_second = it;
 518                                         secondscorekeeper = sk;
 519                                 }
 520                         }
 521                 });
 522
 523                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, false) == 0);
 524                 if(WinningConditionHelper_equality)
 525                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 526
 527                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 528                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 529                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 530                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 531
 532                 WinningConditionHelper_winnerteam = -1; // no teamplay
 533                 WinningConditionHelper_secondteam = -1; // no teamplay
 534         }
 535
 536         if(WinningConditionHelper_topscore == 0)
 537         {
 538                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 539                 {
 540                         if(WinningConditionHelper_lowerisbetter)
 541                                 WinningConditionHelper_topscore = 999999999;
 542                         else
 543                                 WinningConditionHelper_topscore = -999999999;
 544                 }
 545                 if(player_count == 0) // special case: empty servers DO end the match at a 0:0 tie
 546                         WinningConditionHelper_equality = 0;
 547         }
 548
 549         if(WinningConditionHelper_secondscore == 0)
 550         {
 551                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 552                 {
 553                         if(WinningConditionHelper_lowerisbetter)
 554                                 WinningConditionHelper_secondscore = 999999999;
 555                         else
 556                                 WinningConditionHelper_secondscore = -999999999;
 557                 }
 558         }
 559
 560         strcpy(worldstatus, s);
 561
 562         FOREACH_CLIENT(true, {
 563                 string s = "";
 564                 if(fullstatus)
 565                 {
 566                         s = GetPlayerScoreString(it, 1);
 567                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 568                         if(!(IS_PLAYER(it) || INGAME_JOINED(it)))
 569                                 s = strcat(s, ":spectator");
 570                 }
 571                 else
 572                 {
 573                         if (IS_PLAYER(it) || INGAME_JOINED(it))
 574                                 s = GetPlayerScoreString(it, 2);
 575                         else
 576                                 s = "-666";
 577                 }
 578
 579                 strcpy(it.clientstatus, s);
 580         });
 581 }
 582
 583 string GetScoreLogLabel(string label, float fl)
 584 {
 585         if(fl & SFL_LOWER_IS_BETTER)
 586                 label = strcat(label, "<");
 587         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 588                 label = strcat(label, "!!");
 589         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 590                 label = strcat(label, "!");
 591         return label;
 592 }
 593
 594 string GetPlayerScoreString(entity pl, float shortString)
 595 {
 596         string out;
 597         entity sk;
 598         float f;
 599         string l;
 600
 601         out = "";
 602         if(!pl)
 603         {
 604                 // label
 605                 FOREACH(Scores, true, {
 606                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 607                         {
 608                                 f = scores_flags(it);
 609                                 l = scores_label(it);
 610                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 611                         }
 612         });
 613                 if(shortString < 2)
 614                 FOREACH(Scores, true, {
 615                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 616                         {
 617                                 f = scores_flags(it);
 618                                 l = scores_label(it);
 619                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 620                         }
 621         });
 622                 if(shortString < 1)
 623                 FOREACH(Scores, true, {
 624                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 625                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 626                         {
 627                                 f = scores_flags(it);
 628                                 l = scores_label(it);
 629                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 630                         }
 631         });
 632                 out = substring(out, 0, strlen(out) - 1);
 633         }
 634         else if((sk = CS(pl).scorekeeper))
 635         {
 636                 FOREACH(Scores, true, {
 637                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 638                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 639         });
 640                 if(shortString < 2)
 641                 FOREACH(Scores, true, {
 642                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 643                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 644         });
 645                 if(shortString < 1)
 646                 FOREACH(Scores, true, {
 647                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 648                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 649                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 650         });
 651                 out = substring(out, 0, strlen(out) - 1);
 652         }
 653         return out;
 654 }
 655
 656 string GetTeamScoreString(float tm, float shortString)
 657 {
 658         string out;
 659         entity sk;
 660         float i, f;
 661         string l;
 662
 663         out = "";
 664         if(tm == 0)
 665         {
 666                 // label
 667                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 668                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 669                         {
 670                                 f = teamscores_flags(i);
 671                                 l = teamscores_label(i);
 672                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 673                         }
 674                 if(shortString < 2)
 675                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 676                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 677                         {
 678                                 f = teamscores_flags(i);
 679                                 l = teamscores_label(i);
 680                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 681                         }
 682                 if(shortString < 1)
 683                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 684                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 685                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 686                         {
 687                                 f = teamscores_flags(i);
 688                                 l = teamscores_label(i);
 689                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 690                         }
 691                 out = substring(out, 0, strlen(out) - 1);
 692         }
 693         else if((sk = teamscorekeepers[tm - 1]))
 694         {
 695                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 696                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 697                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 698                 if(shortString < 2)
 699                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 700                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 701                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 702                 if(shortString < 1)
 703                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 704                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 705                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 706                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 707                 out = substring(out, 0, strlen(out) - 1);
 708         }
 709         return out;
 710 }
 711
 712 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, bool strict)
 713 {
 714         if(teams && teamscores_entities_count)
 715         {
 716                 if(p1.team != p2.team)
 717                 {
 718                         entity t1, t2;
 719                         float r;
 720                         t1 = teamscorekeepers[p1.team - 1];
 721                         t2 = teamscorekeepers[p2.team - 1];
 722                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 723                         return r;
 724                 }
 725                 if(teams < 0)
 726                         return 0;
 727         }
 728
 729         return PlayerScore_Compare(CS(p1).scorekeeper, CS(p2).scorekeeper, strict);
 730 }
 731
 732 entity PlayerScore_Sort(.float field, int teams, bool strict, bool nospectators)
 733 {
 734         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 735         float i, j;
 736
 737         plist = NULL;
 738
 739         FOREACH_CLIENT(true, { it.(field) = 0; });
 740
 741         FOREACH_CLIENT(CS(it).scorekeeper,
 742         {
 743                 if(nospectators)
 744                         if(it.frags == FRAGS_SPECTATOR)
 745                                 continue;
 746
 747                 it.chain = plist;
 748                 plist = it;
 749         });
 750         // Now plist points to the whole list.
 751
 752         pfirst = plast = NULL;
 753
 754         i = j = 0;
 755         while(plist)
 756         {
 757                 pprev = pbestprev = NULL;
 758                 pbest = plist;
 759                 for(p = plist; (pprev = p), (p = p.chain); )
 760                 {
 761                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 762                         {
 763                                 pbest = p;
 764                                 pbestprev = pprev;
 765                         }
 766                 }
 767
 768                 // remove pbest out of the chain
 769                 if(pbestprev == NULL)
 770                         plist = pbest.chain;
 771                 else
 772                         pbestprev.chain = pbest.chain;
 773                 pbest.chain = NULL;
 774
 775                 ++i;
 776                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, strict))
 777                         j = i;
 778
 779                 pbest.(field) = j;
 780
 781                 if (!pfirst)
 782                         pfirst = pbest;
 783                 if(plast)
 784                         plast.chain = pbest;
 785                 plast = pbest;
 786         }
 787
 788         return pfirst;
 789 }
 790
 791 float TeamScore_GetCompareValue(float t)
 792 {
 793         float s;
 794         entity sk;
 795
 796         if(t <= 0 || t >= 16)
 797         {
 798                 if(game_stopped)
 799                         return 0;
 800                 error("Reading score of invalid team!");
 801         }
 802
 803         sk = teamscorekeepers[t - 1];
 804         if (!sk)
 805                 return -999999999;
 806         s = sk.teamscores_primary;
 807         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 808                 if(!s)
 809                         return -999999999;
 810         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 811                 s = -s;
 812         return s;
 813 }
 814
 815 const float NAMEWIDTH = 22;
 816 const float SCORESWIDTH = 58;
 817 // TODO put this somewhere in common?
 818 string Score_NicePrint_ItemColor(float vflags)
 819 {
 820         if(vflags & SFL_SORT_PRIO_PRIMARY)
 821                 return "^3";
 822         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 823                 return "^5";
 824         else
 825                 return "^7";
 826 }
 827
 828 void Score_NicePrint_Team(entity to, float t, float w)
 829 {
 830         string s, s2;
 831         float i;
 832         entity sk;
 833         float fl, sc;
 834         s = "";
 835
 836         sk = teamscorekeepers[t - 1];
 837         if(sk)
 838         {
 839                 s = strcat(s, Team_ColoredFullName(t));
 840                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 841                         if(teamscores_label(i) != "")
 842                         {
 843                                 fl = teamscores_flags(i);
 844                                 sc = sk.(teamscores(i));
 845                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 846                         }
 847         }
 848         else
 849                 s = "Scores:";
 850
 851         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 852
 853         FOREACH(Scores, true, {
 854                 if(scores_label(it) != "")
 855                 {
 856                         fl = scores_flags(it);
 857                         s2 = scores_label(it);
 858                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 859                 }
 860     });
 861
 862         print_to(to, s);
 863 }
 864
 865 void Score_NicePrint_Player(entity to, entity p, float w)
 866 {
 867         string s;
 868         float i;
 869         entity sk;
 870         float fl, sc;
 871         s = "  ";
 872
 873         sk = CS(p).scorekeeper;
 874
 875         s = strcat(s, playername(p.netname, p.team, false));
 876         for (;;)
 877         {
 878                 i = strlennocol(s) - NAMEWIDTH;
 879                 if(i > 0)
 880                         s = substring(s, 0, strlen(s) - i);
 881                 else
 882                 {
 883                         s = strcat(s, strpad(i, ""));
 884                         break;
 885                 }
 886         }
 887
 888         FOREACH(Scores, true, {
 889                 if(scores_label(it) != "")
 890                 {
 891                         fl = scores_flags(it);
 892                         sc = sk.(scores(it));
 893                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 894                 }
 895     });
 896
 897         print_to(to, s);
 898 }
 899
 900 void Score_NicePrint_Spectators(entity to)
 901 {
 902         print_to(to, "Spectators:");
 903 }
 904
 905 void Score_NicePrint_Spectator(entity to, entity p)
 906 {
 907         print_to(to, strcat("  ", playername(p.netname, p.team, false)));
 908 }
 909
 910 .float score_dummyfield;
 911 void Score_NicePrint(entity to)
 912 {
 913         entity p;
 914         float w;
 915
 916         int t = 0;
 917         FOREACH(Scores, true, {
 918                 if(scores_label(it) != "")
 919                         ++t;
 920     });
 921         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 922
 923         p = PlayerScore_Sort(score_dummyfield, 1, true, false);
 924         t = -1;
 925
 926         if(!teamscores_entities_count)
 927                 Score_NicePrint_Team(to, t, w);
 928         while(p)
 929         {
 930                 if(teamscores_entities_count)
 931                         if(t != p.team)
 932                                 Score_NicePrint_Team(to, p.team, w);
 933                 Score_NicePrint_Player(to, p, w);
 934                 t = p.team;
 935                 p = p.chain;
 936         }
 937
 938         t = 0;
 939         FOREACH_CLIENT(!IS_PLAYER(it), {
 940                 if (!t)
 941                         Score_NicePrint_Spectators(to);
 942                 Score_NicePrint_Spectator(to, it);
 943                 t = 1;
 944         });
 945 }
 946
 947 void PlayerScore_PlayerStats(entity p)
 948 {
 949         entity s = CS(p).scorekeeper;
 950         FOREACH(Scores, true, {
 951                 if(s.(scores(it)) != 0 && scores_label(it) != "")
 952                         PlayerStats_GameReport_Event_Player(s.owner,
 953                                 strcat(PLAYERSTATS_SCOREBOARD, scores_label(it)), s.(scores(it)));
 954         });
 955 }
 956
 957 void PlayerScore_TeamStats()
 958 {
 959         entity sk;
 960         float t, i;
 961         for(t = 0; t < 16; ++t)
 962         {
 963                 sk = teamscorekeepers[t];
 964                 if(!sk)
 965                         continue;
 966                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 967                         if(sk.(teamscores(i)) != 0 && teamscores_label(i) != "")
 968                                 // the +1 is important here!
 969                                 PlayerStats_GameReport_Event_Team(t+1,
 970                                         strcat(PLAYERSTATS_SCOREBOARD, teamscores_label(i)), sk.(teamscores(i)));
 971         }
 972 }