qcsrc/server/spawnpoints.qc

   1 #include "spawnpoints.qh"
   2
   3 #include "mutators/_mod.qh"
   4 #include "g_world.qh"
   5 #include "race.qh"
   6 #include "../common/constants.qh"
   7 #include "../common/teams.qh"
   8 #include "../common/triggers/subs.qh"
   9 #include "../common/util.qh"
  10 #include "../lib/warpzone/common.qh"
  11 #include "../lib/warpzone/util_server.qh"
  12
  13 bool SpawnPoint_Send(entity this, entity to, int sf)
  14 {
  15         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNPOINT);
  16
  17         WriteByte(MSG_ENTITY, this.team);
  18         WriteCoord(MSG_ENTITY, this.origin.x);
  19         WriteCoord(MSG_ENTITY, this.origin.y);
  20         WriteCoord(MSG_ENTITY, this.origin.z);
  21
  22         return true;
  23 }
  24
  25 bool SpawnEvent_Send(entity this, entity to, int sf)
  26 {
  27         float send;
  28
  29         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNEVENT);
  30
  31         if(autocvar_g_spawn_alloweffects)
  32         {
  33                 WriteByte(MSG_ENTITY, etof(this.owner));
  34                 WriteCoord(MSG_ENTITY, this.owner.origin.x);
  35                 WriteCoord(MSG_ENTITY, this.owner.origin.y);
  36                 WriteCoord(MSG_ENTITY, this.owner.origin.z);
  37                 send = true;
  38         }
  39         else if((to == this.owner) || (IS_SPEC(to) && (to.enemy == this.owner)) )
  40         {
  41                 WriteByte(MSG_ENTITY, 0);
  42                 send = true;
  43         }
  44         else { send = false; }
  45
  46         return send;
  47 }
  48
  49 .vector spawnpoint_prevorigin;
  50 void spawnpoint_think(entity this)
  51 {
  52         this.nextthink = time + 0.1;
  53         if(this.origin != this.spawnpoint_prevorigin)
  54         {
  55                 this.spawnpoint_prevorigin = this.origin;
  56                 this.SendFlags |= 1;
  57         }
  58 }
  59
  60 void spawnpoint_use(entity this, entity actor, entity trigger)
  61 {
  62         if(teamplay)
  63         if(have_team_spawns > 0)
  64         {
  65                 this.team = actor.team;
  66                 some_spawn_has_been_used = 1;
  67         }
  68         //LOG_INFO("spawnpoint was used!\n");
  69 }
  70
  71 void relocate_spawnpoint(entity this)
  72 {
  73     // nudge off the floor
  74     setorigin(this, this.origin + '0 0 1');
  75
  76     tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, true, this);
  77     if (trace_startsolid)
  78     {
  79         vector o;
  80         o = this.origin;
  81         this.mins = PL_MIN_CONST;
  82         this.maxs = PL_MAX_CONST;
  83         if (!move_out_of_solid(this))
  84             objerror(this, "could not get out of solid at all!");
  85         LOG_INFO("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
  86         LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(this.origin.x - o.x));
  87         LOG_INFO(" ", ftos(this.origin.y - o.y));
  88         LOG_INFO(" ", ftos(this.origin.z - o.z), "'\n");
  89         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
  90         {
  91             if (!spawnpoint_nag)
  92                 LOG_INFO("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
  93             spawnpoint_nag = 1;
  94         }
  95         else
  96         {
  97             setorigin(this, o);
  98             this.mins = this.maxs = '0 0 0';
  99             objerror(this, "player spawn point in solid, mapper sucks!\n");
 100             return;
 101         }
 102     }
 103
 104     this.use = spawnpoint_use;
 105     setthink(this, spawnpoint_think);
 106     this.nextthink = time + 0.5 + random() * 2; // shouldn't need it for a little second
 107     this.team_saved = this.team;
 108     if (!this.cnt)
 109         this.cnt = 1;
 110
 111     if (have_team_spawns != 0)
 112         if (this.team)
 113             have_team_spawns = 1;
 114     have_team_spawns_forteam[this.team] = 1;
 115
 116     if (autocvar_r_showbboxes)
 117     {
 118         // show where spawnpoints point at too
 119         makevectors(this.angles);
 120         entity e = new(info_player_foo);
 121         setorigin(e, this.origin + v_forward * 24);
 122         setsize(e, '-8 -8 -8', '8 8 8');
 123         e.solid = SOLID_TRIGGER;
 124     }
 125
 126         // Don't show team spawns in non-team matches,
 127         // and don't show non-team spawns in team matches.
 128         // (Unless useallspawns is activated)
 129         if(
 130                 !(
 131                         ( // if this passes, there is a DM spawn on a team match
 132                                 teamplay
 133                                 && (this.team != NUM_TEAM_1)
 134                                 && (this.team != NUM_TEAM_2)
 135                                 && (this.team != NUM_TEAM_3)
 136                                 && (this.team != NUM_TEAM_4)
 137                         )
 138                         ||
 139                         ( // if this passes, there is a team spawn on a DM match
 140                                 !teamplay
 141                                 &&
 142                                 (
 143                                         (this.team == NUM_TEAM_1)
 144                                         || (this.team == NUM_TEAM_2)
 145                                         || (this.team == NUM_TEAM_3)
 146                                         || (this.team == NUM_TEAM_4)
 147                                 )
 148                         )
 149                 )
 150                 ||
 151                 autocvar_g_spawn_useallspawns
 152         )
 153         { Net_LinkEntity(this, false, 0, SpawnPoint_Send); }
 154 }
 155
 156 spawnfunc(info_player_survivor)
 157 {
 158         spawnfunc_info_player_deathmatch(this);
 159 }
 160
 161 spawnfunc(info_player_start)
 162 {
 163         spawnfunc_info_player_deathmatch(this);
 164 }
 165
 166 spawnfunc(info_player_deathmatch)
 167 {
 168         this.classname = "info_player_deathmatch";
 169         relocate_spawnpoint(this);
 170 }
 171
 172 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 173 Starting point for a player in team one (Red).
 174 Keys: "angle" viewing angle when spawning. */
 175 spawnfunc(info_player_team1)
 176 {
 177         this.team = NUM_TEAM_1; // red
 178         spawnfunc_info_player_deathmatch(this);
 179 }
 180
 181
 182 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 183 Starting point for a player in team two (Blue).
 184 Keys: "angle" viewing angle when spawning. */
 185 spawnfunc(info_player_team2)
 186 {
 187         this.team = NUM_TEAM_2; // blue
 188         spawnfunc_info_player_deathmatch(this);
 189 }
 190
 191 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 192 Starting point for a player in team three (Yellow).
 193 Keys: "angle" viewing angle when spawning. */
 194 spawnfunc(info_player_team3)
 195 {
 196         this.team = NUM_TEAM_3; // yellow
 197         spawnfunc_info_player_deathmatch(this);
 198 }
 199
 200
 201 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 202 Starting point for a player in team four (Purple).
 203 Keys: "angle" viewing angle when spawning. */
 204 spawnfunc(info_player_team4)
 205 {
 206         this.team = NUM_TEAM_4; // purple
 207         spawnfunc_info_player_deathmatch(this);
 208 }
 209
 210 // Returns:
 211 //   _x: prio (-1 if unusable)
 212 //   _y: weight
 213 vector Spawn_Score(entity this, entity spot, float mindist, float teamcheck)
 214 {
 215         float shortest, thisdist;
 216         float prio;
 217
 218         prio = 0;
 219
 220         // filter out spots for the wrong team
 221         if(teamcheck >= 0)
 222                 if(spot.team != teamcheck)
 223                         return '-1 0 0';
 224
 225         if(race_spawns)
 226                 if(spot.target == "")
 227                         return '-1 0 0';
 228
 229         if(IS_REAL_CLIENT(this))
 230         {
 231                 if(spot.restriction == 1)
 232                         return '-1 0 0';
 233         }
 234         else
 235         {
 236                 if(spot.restriction == 2)
 237                         return '-1 0 0';
 238         }
 239
 240         shortest = vlen(world.maxs - world.mins);
 241         FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 242                 thisdist = vlen(it.origin - spot.origin);
 243                 if (thisdist < shortest)
 244                         shortest = thisdist;
 245         ));
 246         if(shortest > mindist)
 247                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 248
 249         vector spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 250
 251         // filter out spots for assault
 252         if(spot.target != "")
 253         {
 254                 int found = 0;
 255                 for(entity targ = findchain(targetname, spot.target); targ; targ = targ.chain)
 256                 {
 257                         ++found;
 258                         if(targ.spawn_evalfunc)
 259                         {
 260                                 spawn_score = targ.spawn_evalfunc(targ, this, spot, spawn_score);
 261                                 if(spawn_score.x < 0)
 262                                         return spawn_score;
 263                         }
 264                 }
 265
 266                 if(!found)
 267                 {
 268                         LOG_TRACE("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target);
 269                         return '-1 0 0';
 270                 }
 271         }
 272
 273         MUTATOR_CALLHOOK(Spawn_Score, this, spot, spawn_score);
 274         spawn_score = M_ARGV(2, vector);
 275         return spawn_score;
 276 }
 277
 278 void Spawn_ScoreAll(entity this, entity firstspot, float mindist, float teamcheck)
 279 {
 280         entity spot;
 281         for(spot = firstspot; spot; spot = spot.chain)
 282                 spot.spawnpoint_score = Spawn_Score(this, spot, mindist, teamcheck);
 283 }
 284
 285 entity Spawn_FilterOutBadSpots(entity this, entity firstspot, float mindist, float teamcheck)
 286 {
 287         entity spot, spotlist, spotlistend;
 288
 289         spotlist = NULL;
 290         spotlistend = NULL;
 291
 292         Spawn_ScoreAll(this, firstspot, mindist, teamcheck);
 293
 294         for(spot = firstspot; spot; spot = spot.chain)
 295         {
 296                 if(spot.spawnpoint_score.x >= 0) // spawning allowed here
 297                 {
 298                         if(spotlistend)
 299                                 spotlistend.chain = spot;
 300                         spotlistend = spot;
 301                         if(!spotlist)
 302                                 spotlist = spot;
 303                 }
 304         }
 305         if(spotlistend)
 306                 spotlistend.chain = NULL;
 307
 308         return spotlist;
 309 }
 310
 311 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 312 {
 313         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 314         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 315         entity spot;
 316
 317         RandomSelection_Init();
 318         for(spot = firstspot; spot; spot = spot.chain)
 319                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score.y, upper), exponent) * spot.cnt, (spot.spawnpoint_score.y >= lower) * 0.5 + spot.spawnpoint_score.x);
 320
 321         return RandomSelection_chosen_ent;
 322 }
 323
 324 /*
 325 =============
 326 SelectSpawnPoint
 327
 328 Finds a point to respawn
 329 =============
 330 */
 331 entity SelectSpawnPoint(entity this, bool anypoint)
 332 {
 333         float teamcheck;
 334         entity spot, firstspot;
 335
 336         spot = find (NULL, classname, "testplayerstart");
 337         if (spot)
 338                 return spot;
 339
 340         if(anypoint || autocvar_g_spawn_useallspawns)
 341                 teamcheck = -1;
 342         else if(have_team_spawns > 0)
 343         {
 344                 if(have_team_spawns_forteam[this.team] == 0)
 345                 {
 346                         // we request a spawn for a team, and we have team
 347                         // spawns, but that team has no spawns?
 348                         if(have_team_spawns_forteam[0])
 349                                 // try noteam spawns
 350                                 teamcheck = 0;
 351                         else
 352                                 // if not, any spawn has to do
 353                                 teamcheck = -1;
 354                 }
 355                 else
 356                         teamcheck = this.team; // MUST be team
 357         }
 358         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 359                 teamcheck = 0; // MUST be noteam
 360         else
 361                 teamcheck = -1;
 362                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 363
 364
 365         // get the entire list of spots
 366         firstspot = findchain(classname, "info_player_deathmatch");
 367         // filter out the bad ones
 368         // (note this returns the original list if none survived)
 369         if(anypoint)
 370         {
 371                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 372         }
 373         else
 374         {
 375                 firstspot = Spawn_FilterOutBadSpots(this, firstspot, 100, teamcheck);
 376
 377                 // there is 50/50 chance of choosing a random spot or the furthest spot
 378                 // (this means that roughly every other spawn will be furthest, so you
 379                 // usually won't get fragged at spawn twice in a row)
 380                 if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if (!spot)
 387         {
 388                 if(autocvar_spawn_debug)
 389                         GotoNextMap(0);
 390                 else
 391                 {
 392                         if(some_spawn_has_been_used)
 393                                 return NULL; // team can't spawn any more, because of actions of other team
 394                         else
 395                                 error("Cannot find a spawn point - please fix the map!");
 396                 }
 397         }
 398
 399         return spot;
 400 }