qcsrc/server/spawnpoints.qc

   1 #include "spawnpoints.qh"
   2
   3 #include "mutators/_mod.qh"
   4 #include "g_world.qh"
   5 #include "race.qh"
   6 #include "../common/constants.qh"
   7 #include <common/net_linked.qh>
   8 #include "../common/teams.qh"
   9 #include "../common/triggers/subs.qh"
  10 #include "../common/util.qh"
  11 #include "../lib/warpzone/common.qh"
  12 #include "../lib/warpzone/util_server.qh"
  13
  14 bool SpawnPoint_Send(entity this, entity to, int sf)
  15 {
  16         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNPOINT);
  17
  18         WriteByte(MSG_ENTITY, this.team);
  19         WriteCoord(MSG_ENTITY, this.origin.x);
  20         WriteCoord(MSG_ENTITY, this.origin.y);
  21         WriteCoord(MSG_ENTITY, this.origin.z);
  22
  23         return true;
  24 }
  25
  26 bool SpawnEvent_Send(entity this, entity to, int sf)
  27 {
  28         float send;
  29
  30         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNEVENT);
  31
  32         if(autocvar_g_spawn_alloweffects)
  33         {
  34                 WriteByte(MSG_ENTITY, etof(this.owner));
  35                 WriteCoord(MSG_ENTITY, this.owner.origin.x);
  36                 WriteCoord(MSG_ENTITY, this.owner.origin.y);
  37                 WriteCoord(MSG_ENTITY, this.owner.origin.z);
  38                 send = true;
  39         }
  40         else if((to == this.owner) || (IS_SPEC(to) && (to.enemy == this.owner)) )
  41         {
  42                 WriteByte(MSG_ENTITY, 0);
  43                 send = true;
  44         }
  45         else { send = false; }
  46
  47         return send;
  48 }
  49
  50 .vector spawnpoint_prevorigin;
  51 void spawnpoint_think(entity this)
  52 {
  53         this.nextthink = time + 0.1;
  54         if(this.origin != this.spawnpoint_prevorigin)
  55         {
  56                 this.spawnpoint_prevorigin = this.origin;
  57                 this.SendFlags |= 1;
  58         }
  59 }
  60
  61 void spawnpoint_use(entity this, entity actor, entity trigger)
  62 {
  63         if(teamplay)
  64         if(have_team_spawns > 0)
  65         {
  66                 this.team = actor.team;
  67                 some_spawn_has_been_used = true;
  68         }
  69         //LOG_INFO("spawnpoint was used!\n");
  70 }
  71
  72 void relocate_spawnpoint(entity this)
  73 {
  74     // nudge off the floor
  75     setorigin(this, this.origin + '0 0 1');
  76
  77     tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, true, this);
  78     if (trace_startsolid)
  79     {
  80         vector o;
  81         o = this.origin;
  82         this.mins = PL_MIN_CONST;
  83         this.maxs = PL_MAX_CONST;
  84         if (!move_out_of_solid(this))
  85             objerror(this, "could not get out of solid at all!");
  86         LOG_INFO("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
  87         LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(this.origin.x - o.x));
  88         LOG_INFO(" ", ftos(this.origin.y - o.y));
  89         LOG_INFO(" ", ftos(this.origin.z - o.z), "'\n");
  90         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
  91         {
  92             if (!spawnpoint_nag)
  93                 LOG_INFO("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
  94             spawnpoint_nag = 1;
  95         }
  96         else
  97         {
  98             setorigin(this, o);
  99             this.mins = this.maxs = '0 0 0';
 100             objerror(this, "player spawn point in solid, mapper sucks!\n");
 101             return;
 102         }
 103     }
 104
 105     this.use = spawnpoint_use;
 106     setthink(this, spawnpoint_think);
 107     this.nextthink = time + 0.5 + random() * 2; // shouldn't need it for a little second
 108     this.team_saved = this.team;
 109     IL_PUSH(g_saved_team, this);
 110     if (!this.cnt)
 111         this.cnt = 1;
 112
 113     if (have_team_spawns != 0)
 114         if (this.team)
 115             have_team_spawns = 1;
 116     have_team_spawns_forteams |= BIT(this.team);
 117
 118     if (autocvar_r_showbboxes)
 119     {
 120         // show where spawnpoints point at too
 121         makevectors(this.angles);
 122         entity e = new(info_player_foo);
 123         setorigin(e, this.origin + v_forward * 24);
 124         setsize(e, '-8 -8 -8', '8 8 8');
 125         e.solid = SOLID_TRIGGER;
 126     }
 127
 128         // Don't show team spawns in non-team matches,
 129         // and don't show non-team spawns in team matches.
 130         // (Unless useallspawns is activated)
 131         if(
 132                 !(
 133                         ( // if this passes, there is a DM spawn on a team match
 134                                 teamplay
 135                                 && (this.team != NUM_TEAM_1)
 136                                 && (this.team != NUM_TEAM_2)
 137                                 && (this.team != NUM_TEAM_3)
 138                                 && (this.team != NUM_TEAM_4)
 139                         )
 140                         ||
 141                         ( // if this passes, there is a team spawn on a DM match
 142                                 !teamplay
 143                                 &&
 144                                 (
 145                                         (this.team == NUM_TEAM_1)
 146                                         || (this.team == NUM_TEAM_2)
 147                                         || (this.team == NUM_TEAM_3)
 148                                         || (this.team == NUM_TEAM_4)
 149                                 )
 150                         )
 151                 )
 152                 ||
 153                 autocvar_g_spawn_useallspawns
 154         )
 155         { Net_LinkEntity(this, false, 0, SpawnPoint_Send); }
 156 }
 157
 158 spawnfunc(info_player_survivor)
 159 {
 160         spawnfunc_info_player_deathmatch(this);
 161 }
 162
 163 spawnfunc(info_player_start)
 164 {
 165         spawnfunc_info_player_deathmatch(this);
 166 }
 167
 168 spawnfunc(info_player_deathmatch)
 169 {
 170         this.classname = "info_player_deathmatch";
 171         IL_PUSH(g_spawnpoints, this);
 172         relocate_spawnpoint(this);
 173 }
 174
 175 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 176 Starting point for a player in team one (Red).
 177 Keys: "angle" viewing angle when spawning. */
 178 spawnfunc(info_player_team1)
 179 {
 180         this.team = NUM_TEAM_1; // red
 181         spawnfunc_info_player_deathmatch(this);
 182 }
 183
 184
 185 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 186 Starting point for a player in team two (Blue).
 187 Keys: "angle" viewing angle when spawning. */
 188 spawnfunc(info_player_team2)
 189 {
 190         this.team = NUM_TEAM_2; // blue
 191         spawnfunc_info_player_deathmatch(this);
 192 }
 193
 194 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 195 Starting point for a player in team three (Yellow).
 196 Keys: "angle" viewing angle when spawning. */
 197 spawnfunc(info_player_team3)
 198 {
 199         this.team = NUM_TEAM_3; // yellow
 200         spawnfunc_info_player_deathmatch(this);
 201 }
 202
 203
 204 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 205 Starting point for a player in team four (Purple).
 206 Keys: "angle" viewing angle when spawning. */
 207 spawnfunc(info_player_team4)
 208 {
 209         this.team = NUM_TEAM_4; // purple
 210         spawnfunc_info_player_deathmatch(this);
 211 }
 212
 213 // Returns:
 214 //   _x: prio (-1 if unusable)
 215 //   _y: weight
 216 vector Spawn_Score(entity this, entity spot, float mindist, float teamcheck)
 217 {
 218         float shortest, thisdist;
 219         float prio;
 220
 221         prio = 0;
 222
 223         // filter out spots for the wrong team
 224         if(teamcheck >= 0)
 225                 if(spot.team != teamcheck)
 226                         return '-1 0 0';
 227
 228         if(race_spawns)
 229                 if(spot.target == "")
 230                         return '-1 0 0';
 231
 232         if(IS_REAL_CLIENT(this))
 233         {
 234                 if(spot.restriction == 1)
 235                         return '-1 0 0';
 236         }
 237         else
 238         {
 239                 if(spot.restriction == 2)
 240                         return '-1 0 0';
 241         }
 242
 243         shortest = vlen(world.maxs - world.mins);
 244         FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 245                 thisdist = vlen(it.origin - spot.origin);
 246                 if (thisdist < shortest)
 247                         shortest = thisdist;
 248         ));
 249         if(shortest > mindist)
 250                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 251
 252         vector spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 253
 254         // filter out spots for assault
 255         if(spot.target != "")
 256         {
 257                 int found = 0;
 258                 for(entity targ = findchain(targetname, spot.target); targ; targ = targ.chain)
 259                 {
 260                         ++found;
 261                         if(targ.spawn_evalfunc)
 262                         {
 263                                 spawn_score = targ.spawn_evalfunc(targ, this, spot, spawn_score);
 264                                 if(spawn_score.x < 0)
 265                                         return spawn_score;
 266                         }
 267                 }
 268
 269                 if(!found)
 270                 {
 271                         LOG_TRACE("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target);
 272                         return '-1 0 0';
 273                 }
 274         }
 275
 276         MUTATOR_CALLHOOK(Spawn_Score, this, spot, spawn_score);
 277         spawn_score = M_ARGV(2, vector);
 278         return spawn_score;
 279 }
 280
 281 void Spawn_ScoreAll(entity this, entity firstspot, float mindist, float teamcheck)
 282 {
 283         entity spot;
 284         for(spot = firstspot; spot; spot = spot.chain)
 285                 spot.spawnpoint_score = Spawn_Score(this, spot, mindist, teamcheck);
 286 }
 287
 288 entity Spawn_FilterOutBadSpots(entity this, entity firstspot, float mindist, float teamcheck)
 289 {
 290         entity spot, spotlist, spotlistend;
 291
 292         spotlist = NULL;
 293         spotlistend = NULL;
 294
 295         Spawn_ScoreAll(this, firstspot, mindist, teamcheck);
 296
 297         for(spot = firstspot; spot; spot = spot.chain)
 298         {
 299                 if(spot.spawnpoint_score.x >= 0) // spawning allowed here
 300                 {
 301                         if(spotlistend)
 302                                 spotlistend.chain = spot;
 303                         spotlistend = spot;
 304                         if(!spotlist)
 305                                 spotlist = spot;
 306                 }
 307         }
 308         if(spotlistend)
 309                 spotlistend.chain = NULL;
 310
 311         return spotlist;
 312 }
 313
 314 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 315 {
 316         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 317         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 318         entity spot;
 319
 320         RandomSelection_Init();
 321         for(spot = firstspot; spot; spot = spot.chain)
 322                 RandomSelection_AddEnt(spot, (bound(lower, spot.spawnpoint_score.y, upper) ** exponent) * spot.cnt, (spot.spawnpoint_score.y >= lower) * 0.5 + spot.spawnpoint_score.x);
 323
 324         return RandomSelection_chosen_ent;
 325 }
 326
 327 /*
 328 =============
 329 SelectSpawnPoint
 330
 331 Finds a point to respawn
 332 =============
 333 */
 334 entity SelectSpawnPoint(entity this, bool anypoint)
 335 {
 336         float teamcheck;
 337         entity spot, firstspot;
 338
 339         spot = find(NULL, classname, "testplayerstart");
 340         if (spot)
 341                 return spot;
 342
 343         if(anypoint || autocvar_g_spawn_useallspawns)
 344                 teamcheck = -1;
 345         else if(have_team_spawns > 0)
 346         {
 347                 if(!(have_team_spawns_forteams & BIT(this.team)))
 348                 {
 349                         // we request a spawn for a team, and we have team
 350                         // spawns, but that team has no spawns?
 351                         if(have_team_spawns_forteams & BIT(0))
 352                                 // try noteam spawns
 353                                 teamcheck = 0;
 354                         else
 355                                 // if not, any spawn has to do
 356                                 teamcheck = -1;
 357                 }
 358                 else
 359                         teamcheck = this.team; // MUST be team
 360         }
 361         else if(have_team_spawns == 0 && (have_team_spawns_forteams & BIT(0)))
 362                 teamcheck = 0; // MUST be noteam
 363         else
 364                 teamcheck = -1;
 365                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 366
 367
 368         // get the entire list of spots
 369         firstspot = findchain(classname, "info_player_deathmatch");
 370         // filter out the bad ones
 371         // (note this returns the original list if none survived)
 372         if(anypoint)
 373         {
 374                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 375         }
 376         else
 377         {
 378                 firstspot = Spawn_FilterOutBadSpots(this, firstspot, 100, teamcheck);
 379
 380                 // there is 50/50 chance of choosing a random spot or the furthest spot
 381                 // (this means that roughly every other spawn will be furthest, so you
 382                 // usually won't get fragged at spawn twice in a row)
 383                 if (random() > autocvar_g_spawn_furthest)
 384                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 385                 else
 386                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 387         }
 388
 389         if (!spot)
 390         {
 391                 if(autocvar_spawn_debug)
 392                         GotoNextMap(0);
 393                 else
 394                 {
 395                         if(some_spawn_has_been_used)
 396                                 return NULL; // team can't spawn any more, because of actions of other team
 397                         else
 398                                 error("Cannot find a spawn point - please fix the map!");
 399                 }
 400         }
 401
 402         return spot;
 403 }