qcsrc/server/sv_main.qc

   1
   2 #include "anticheat.qh"
   3 #include "g_hook.qh"
   4 #include "g_world.qh"
   5
   6 #include "bot/bot.qh"
   7 #include "bot/waypoints.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/mutators_include.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/mapinfo.qh"
  17 #include "../common/util.qh"
  18
  19 #include "../common/vehicles/all.qh"
  20 #include "../common/weapons/all.qh"
  21
  22 #include "../lib/csqcmodel/sv_model.qh"
  23
  24 #include "../lib/warpzone/common.qh"
  25 #include "../lib/warpzone/server.qh"
  26
  27 .float lastground;
  28 .int state;
  29
  30 void CreatureFrame (void)
  31 {SELFPARAM();
  32         float dm;
  33
  34         for(entity e = world; (e = findfloat(e, damagedbycontents, true)); )
  35         {
  36                 setself(e);
  37                 if (self.movetype == MOVETYPE_NOCLIP) { continue; }
  38
  39                 float vehic = IS_VEHICLE(self);
  40                 float projectile = (self.flags & FL_PROJECTILE);
  41                 float monster = IS_MONSTER(self);
  42
  43                 if (self.watertype <= CONTENT_WATER && self.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  44                 {
  45                         if (!(self.flags & FL_INWATER))
  46                         {
  47                                 self.flags |= FL_INWATER;
  48                                 self.dmgtime = 0;
  49                         }
  50
  51                         if(!vehic && !projectile && !monster) // vehicles, monsters and projectiles don't drown
  52                         {
  53                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  54                                 {
  55                                         if(self.air_finished < time)
  56                                                 PlayerSound(playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
  57                                         self.air_finished = time + autocvar_g_balance_contents_drowndelay;
  58                                         self.dmg = 2;
  59                                 }
  60                                 else if (self.air_finished < time)
  61                                 {       // drown!
  62                                         if (!self.deadflag)
  63                                         if (self.pain_finished < time)
  64                                         {
  65                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, self.origin, '0 0 0');
  66                                                 self.pain_finished = time + 0.5;
  67                                         }
  68                                 }
  69                         }
  70
  71                         if (self.dmgtime < time)
  72                         {
  73                                 self.dmgtime = time + autocvar_g_balance_contents_damagerate;
  74
  75                                 if (projectile)
  76                                 {
  77                                         if (self.watertype == CONTENT_LAVA)
  78                                         {
  79                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA.m_id, self.origin, '0 0 0');
  80                                         }
  81                                         else if (self.watertype == CONTENT_SLIME)
  82                                         {
  83                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME.m_id, self.origin, '0 0 0');
  84                                         }
  85                                 }
  86                                 else
  87                                 {
  88                                         if (self.watertype == CONTENT_LAVA)
  89                                         {
  90                                                 if (self.watersound_finished < time)
  91                                                 {
  92                                                         self.watersound_finished = time + 0.5;
  93                                                         sound (self, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  94                                                 }
  95                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA.m_id, self.origin, '0 0 0');
  96                                         }
  97                                         else if (self.watertype == CONTENT_SLIME)
  98                                         {
  99                                                 if (self.watersound_finished < time)
 100                                                 {
 101                                                         self.watersound_finished = time + 0.5;
 102                                                         sound (self, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
 103                                                 }
 104                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME.m_id, self.origin, '0 0 0');
 105                                         }
 106                                 }
 107                         }
 108                 }
 109                 else
 110                 {
 111                         if (self.flags & FL_INWATER)
 112                         {
 113                                 // play leave water sound
 114                                 self.flags &= ~FL_INWATER;
 115                                 self.dmgtime = 0;
 116                         }
 117                         self.air_finished = time + 12;
 118                         self.dmg = 2;
 119                 }
 120
 121                 if(!vehic && !projectile) // vehicles don't get falling damage
 122                 {
 123                         // check for falling damage
 124                         float velocity_len = vlen(self.velocity);
 125                         if(!self.hook.state)
 126                         {
 127                                 dm = vlen(self.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 128                                 if (self.deadflag)
 129                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 130                                 else
 131                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 132                                 if (dm > 0)
 133                                         Damage (self, world, world, dm, DEATH_FALL.m_id, self.origin, '0 0 0');
 134                         }
 135
 136                         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 137                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR.m_id, self.origin, '0 0 0');
 138                         // play stupid sounds
 139                         if (g_footsteps)
 140                         if (!gameover)
 141                         if (self.flags & FL_ONGROUND)
 142                         if (!self.crouch)
 143                         if (velocity_len > autocvar_sv_maxspeed * 0.6)
 144                         if (!self.deadflag)
 145                         if (time < self.lastground + 0.2)
 146                         {
 147                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
 148                                 {
 149                                         self.nextstep = time + 0.3 + random() * 0.1;
 150                                         trace_dphitq3surfaceflags = 0;
 151                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 152                                         /*
 153                                         if(trace_fraction == 1)
 154                                                 dprint("nohit\n");
 155                                         else
 156                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 157                                         */
 158                                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS))
 159                                         {
 160                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 161                                                         GlobalSound(globalsound_metalstep, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 162                                                 else
 163                                                         GlobalSound(globalsound_step, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 164                                         }
 165                                 }
 166                         }
 167                 }
 168
 169         self.oldvelocity = self.velocity;
 170         }
 171         setself(this);
 172 }
 173
 174
 175 /*
 176 =============
 177 StartFrame
 178
 179 Called before each frame by the server
 180 =============
 181 */
 182
 183 float game_delay;
 184 float game_delay_last;
 185
 186 float RedirectionThink();
 187 void StartFrame (void)
 188 {SELFPARAM();
 189         execute_next_frame();
 190
 191         remove = remove_unsafely; // not during spawning!
 192         serverprevtime = servertime;
 193         servertime = time;
 194         serverframetime = frametime;
 195
 196 #ifdef PROFILING
 197         if(time > client_cefc_accumulatortime + 1)
 198         {
 199                 float t, pp, c_seeing, c_seen;
 200                 entity cl;
 201                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 202                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 203                 c_seeing = 0;
 204                 c_seen = 0;
 205                 FOR_EACH_CLIENT(cl)
 206                 {
 207                         if(IS_REAL_CLIENT(cl))
 208                                 ++c_seeing;
 209                         if(IS_PLAYER(cl))
 210                                 ++c_seen;
 211                 }
 212                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 213                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 214
 215                 client_cefc_accumulatortime = time;
 216                 client_cefc_accumulator = 0;
 217         }
 218 #endif
 219
 220         for(entity e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 221                 CSQCProjectile_Check(e);
 222
 223         if(RedirectionThink())
 224                 return;
 225
 226         UncustomizeEntitiesRun();
 227         InitializeEntitiesRun();
 228
 229         WarpZone_StartFrame();
 230
 231         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 232         if(sys_frametime <= 0)
 233                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 234
 235         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 236                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 237
 238         skill = autocvar_skill;
 239
 240         // detect when the pre-game countdown (if any) has ended and the game has started
 241         game_delay = (time < game_starttime) ? true : false;
 242
 243         if(game_delay_last == true)
 244         if(game_delay == false)
 245         if(autocvar_sv_eventlog)
 246                 GameLogEcho(":startdelay_ended");
 247
 248         game_delay_last = game_delay;
 249
 250         CreatureFrame ();
 251         CheckRules_World ();
 252
 253         // if in warmup stage and limit for warmup is hit start match
 254         if(warmup_stage)
 255         if(!gameover)
 256         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 257          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 258         {
 259                 ReadyRestart();
 260                 return;
 261         }
 262
 263         bot_serverframe();
 264
 265         entity e;
 266         FOR_EACH_PLAYER(e)
 267                 e.porto_forbidden = max(0, e.porto_forbidden - 1);
 268
 269         anticheat_startframe();
 270
 271         MUTATOR_CALLHOOK(SV_StartFrame);
 272 }
 273
 274 .vector originjitter;
 275 .vector anglesjitter;
 276 .float anglejitter;
 277 .string gametypefilter;
 278 .string cvarfilter;
 279 float DoesQ3ARemoveThisEntity();
 280 void SV_OnEntityPreSpawnFunction()
 281 {SELFPARAM();
 282         if (self)
 283         if (self.gametypefilter != "")
 284         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 285         {
 286                 remove(self);
 287                 return;
 288         }
 289         if(self.cvarfilter != "")
 290         {
 291                 float n, i, o, inv;
 292                 string s, k, v;
 293                 inv = 0;
 294
 295                 s = self.cvarfilter;
 296                 if(substring(s, 0, 1) == "+")
 297                 {
 298                         s = substring(s, 1, -1);
 299                 }
 300                 else if(substring(s, 0, 1) == "-")
 301                 {
 302                         inv = 1;
 303                         s = substring(s, 1, -1);
 304                 }
 305
 306                 n = tokenize_console(s);
 307                 for(i = 0; i < n; ++i)
 308                 {
 309                         s = argv(i);
 310                         // syntax:
 311                         // var>x
 312                         // var<x
 313                         // var>=x
 314                         // var<=x
 315                         // var==x
 316                         // var!=x
 317                         // var===x
 318                         // var!==x
 319                         if((o = strstrofs(s, ">=", 0)) >= 0)
 320                         {
 321                                 k = substring(s, 0, o);
 322                                 v = substring(s, o+2, -1);
 323                                 if(cvar(k) < stof(v))
 324                                         goto cvar_fail;
 325                         }
 326                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 327                         {
 328                                 k = substring(s, 0, o);
 329                                 v = substring(s, o+2, -1);
 330                                 if(cvar(k) > stof(v))
 331                                         goto cvar_fail;
 332                         }
 333                         else if((o = strstrofs(s, ">", 0)) >= 0)
 334                         {
 335                                 k = substring(s, 0, o);
 336                                 v = substring(s, o+1, -1);
 337                                 if(cvar(k) <= stof(v))
 338                                         goto cvar_fail;
 339                         }
 340                         else if((o = strstrofs(s, "<", 0)) >= 0)
 341                         {
 342                                 k = substring(s, 0, o);
 343                                 v = substring(s, o+1, -1);
 344                                 if(cvar(k) >= stof(v))
 345                                         goto cvar_fail;
 346                         }
 347                         else if((o = strstrofs(s, "==", 0)) >= 0)
 348                         {
 349                                 k = substring(s, 0, o);
 350                                 v = substring(s, o+2, -1);
 351                                 if(cvar(k) != stof(v))
 352                                         goto cvar_fail;
 353                         }
 354                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 355                         {
 356                                 k = substring(s, 0, o);
 357                                 v = substring(s, o+2, -1);
 358                                 if(cvar(k) == stof(v))
 359                                         goto cvar_fail;
 360                         }
 361                         else if((o = strstrofs(s, "===", 0)) >= 0)
 362                         {
 363                                 k = substring(s, 0, o);
 364                                 v = substring(s, o+2, -1);
 365                                 if(cvar_string(k) != v)
 366                                         goto cvar_fail;
 367                         }
 368                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 369                         {
 370                                 k = substring(s, 0, o);
 371                                 v = substring(s, o+2, -1);
 372                                 if(cvar_string(k) == v)
 373                                         goto cvar_fail;
 374                         }
 375                         else if(substring(s, 0, 1) == "!")
 376                         {
 377                                 k = substring(s, 1, -1);
 378                                 if(cvar(k))
 379                                         goto cvar_fail;
 380                         }
 381                         else
 382                         {
 383                                 k = s;
 384                                 if (!cvar(k))
 385                                         goto cvar_fail;
 386                         }
 387                 }
 388                 inv = !inv;
 389 :cvar_fail
 390                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 391                 if (!inv)
 392                 {
 393                         //print("cvarfilter fail\n");
 394                         remove(self);
 395                         return;
 396                 }
 397         }
 398
 399         if(DoesQ3ARemoveThisEntity())
 400         {
 401                 remove(self);
 402                 return;
 403         }
 404
 405         // support special -1 and -2 angle from radiant
 406         if (self.angles == '0 -1 0')
 407                 self.angles = '-90 0 0';
 408         else if (self.angles == '0 -2 0')
 409                 self.angles = '+90 0 0';
 410
 411         if(self.originjitter.x != 0)
 412                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 413         if(self.originjitter.y != 0)
 414                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 415         if(self.originjitter.z != 0)
 416                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 417         if(self.anglesjitter.x != 0)
 418                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 419         if(self.anglesjitter.y != 0)
 420                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 421         if(self.anglesjitter.z != 0)
 422                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 423         if(self.anglejitter != 0)
 424                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 425
 426         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 427         {
 428                 remove(self);
 429                 return;
 430         }
 431 }
 432
 433 void WarpZone_PostInitialize_Callback(void)
 434 {
 435         // create waypoint links for warpzones
 436         entity e;
 437         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 438         {
 439                 vector src, dst;
 440                 src = (e.absmin + e.absmax) * 0.5;
 441                 makevectors(e.warpzone_angles);
 442                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 443                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 444                 makevectors(e.enemy.warpzone_angles);
 445                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 446                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 447         }
 448 }