qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/_mod.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include <common/weapons/_all.qh>
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         if(this.velocity || this.oldvelocity) // moving or has moved
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 bool have_hook = false;
 103                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 104             {
 105                 .entity weaponentity = weaponentities[slot];
 106                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 107                 {
 108                         have_hook = true;
 109                         break;
 110                 }
 111             }
 112                 if(!have_hook)
 113                 {
 114                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 115                         if (IS_DEAD(this))
 116                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 117                         else
 118                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 119                         if (dm > 0)
 120                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 121                 }
 122
 123                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 124                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 125         }
 126 }
 127
 128 void CreatureFrame_All()
 129 {
 130         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 131         {
 132                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 133                 CreatureFrame_Liquids(it);
 134                 CreatureFrame_FallDamage(it);
 135                 it.oldvelocity = it.velocity;
 136         });
 137 }
 138
 139 void Pause_TryPause(bool ispaused)
 140 {
 141         int n = 0;
 142         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 143                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 144                 ++n;
 145         ));
 146         if (!n) return;
 147         setpause(ispaused);
 148 }
 149
 150 void SV_PausedTic(float elapsedtime)
 151 {
 152         if (!server_is_dedicated) Pause_TryPause(false);
 153 }
 154
 155 /*
 156 =============
 157 StartFrame
 158
 159 Called before each frame by the server
 160 =============
 161 */
 162
 163 float game_delay;
 164 float game_delay_last;
 165
 166 bool autocvar_sv_autopause = false;
 167 float RedirectionThink();
 168 void systems_update();
 169 void sys_phys_update(entity this, float dt);
 170 void StartFrame()
 171 {
 172     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 173     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 174     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 175
 176         execute_next_frame();
 177         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 178
 179         delete_fn = remove_unsafely; // not during spawning!
 180         serverprevtime = servertime;
 181         servertime = time;
 182         serverframetime = frametime;
 183
 184 #ifdef PROFILING
 185         if(time > client_cefc_accumulatortime + 1)
 186         {
 187                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 188                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 189                 int c_seeing = 0;
 190                 int c_seen = 0;
 191                 FOREACH_CLIENT(true, LAMBDA(
 192                         if(IS_REAL_CLIENT(it))
 193                                 ++c_seeing;
 194                         if(IS_PLAYER(it))
 195                                 ++c_seen;
 196                 ));
 197                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 198                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 199
 200                 client_cefc_accumulatortime = time;
 201                 client_cefc_accumulator = 0;
 202         }
 203 #endif
 204
 205         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 206
 207         if (RedirectionThink()) return;
 208
 209         UncustomizeEntitiesRun();
 210         InitializeEntitiesRun();
 211
 212         WarpZone_StartFrame();
 213
 214         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 215         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 216
 217         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 218                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 219
 220         skill = autocvar_skill;
 221
 222         // detect when the pre-game countdown (if any) has ended and the game has started
 223         game_delay = (time < game_starttime);
 224
 225         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 226                 GameLogEcho(":startdelay_ended");
 227
 228         game_delay_last = game_delay;
 229
 230         CreatureFrame_All();
 231         CheckRules_World();
 232
 233         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 234                 ReadyRestart();
 235                 return;
 236         }
 237
 238         bot_serverframe();
 239         anticheat_startframe();
 240         MUTATOR_CALLHOOK(SV_StartFrame);
 241
 242     FOREACH_CLIENT(true, GlobalStats_update(it));
 243     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 244 }
 245
 246 .vector originjitter;
 247 .vector anglesjitter;
 248 .float anglejitter;
 249 .string gametypefilter;
 250 .string cvarfilter;
 251 bool DoesQ3ARemoveThisEntity(entity this);
 252 void SV_OnEntityPreSpawnFunction(entity this)
 253 {
 254         __spawnfunc_expecting = true;
 255         __spawnfunc_expect = this;
 256         if (this)
 257         if (this.gametypefilter != "")
 258         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 259         {
 260                 delete(this);
 261                 __spawnfunc_expecting = false;
 262                 return;
 263         }
 264         if(this.cvarfilter != "")
 265         {
 266                 float n, i, o, inv;
 267                 string s, k, v;
 268                 inv = 0;
 269
 270                 s = this.cvarfilter;
 271                 if(substring(s, 0, 1) == "+")
 272                 {
 273                         s = substring(s, 1, -1);
 274                 }
 275                 else if(substring(s, 0, 1) == "-")
 276                 {
 277                         inv = 1;
 278                         s = substring(s, 1, -1);
 279                 }
 280
 281                 n = tokenize_console(s);
 282                 for(i = 0; i < n; ++i)
 283                 {
 284                         s = argv(i);
 285                         // syntax:
 286                         // var>x
 287                         // var<x
 288                         // var>=x
 289                         // var<=x
 290                         // var==x
 291                         // var!=x
 292                         // var===x
 293                         // var!==x
 294                         if((o = strstrofs(s, ">=", 0)) >= 0)
 295                         {
 296                                 k = substring(s, 0, o);
 297                                 v = substring(s, o+2, -1);
 298                                 if(cvar(k) < stof(v))
 299                                         goto cvar_fail;
 300                         }
 301                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 302                         {
 303                                 k = substring(s, 0, o);
 304                                 v = substring(s, o+2, -1);
 305                                 if(cvar(k) > stof(v))
 306                                         goto cvar_fail;
 307                         }
 308                         else if((o = strstrofs(s, ">", 0)) >= 0)
 309                         {
 310                                 k = substring(s, 0, o);
 311                                 v = substring(s, o+1, -1);
 312                                 if(cvar(k) <= stof(v))
 313                                         goto cvar_fail;
 314                         }
 315                         else if((o = strstrofs(s, "<", 0)) >= 0)
 316                         {
 317                                 k = substring(s, 0, o);
 318                                 v = substring(s, o+1, -1);
 319                                 if(cvar(k) >= stof(v))
 320                                         goto cvar_fail;
 321                         }
 322                         else if((o = strstrofs(s, "==", 0)) >= 0)
 323                         {
 324                                 k = substring(s, 0, o);
 325                                 v = substring(s, o+2, -1);
 326                                 if(cvar(k) != stof(v))
 327                                         goto cvar_fail;
 328                         }
 329                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 330                         {
 331                                 k = substring(s, 0, o);
 332                                 v = substring(s, o+2, -1);
 333                                 if(cvar(k) == stof(v))
 334                                         goto cvar_fail;
 335                         }
 336                         else if((o = strstrofs(s, "===", 0)) >= 0)
 337                         {
 338                                 k = substring(s, 0, o);
 339                                 v = substring(s, o+2, -1);
 340                                 if(cvar_string(k) != v)
 341                                         goto cvar_fail;
 342                         }
 343                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 344                         {
 345                                 k = substring(s, 0, o);
 346                                 v = substring(s, o+2, -1);
 347                                 if(cvar_string(k) == v)
 348                                         goto cvar_fail;
 349                         }
 350                         else if(substring(s, 0, 1) == "!")
 351                         {
 352                                 k = substring(s, 1, -1);
 353                                 if(cvar(k))
 354                                         goto cvar_fail;
 355                         }
 356                         else
 357                         {
 358                                 k = s;
 359                                 if (!cvar(k))
 360                                         goto cvar_fail;
 361                         }
 362                 }
 363                 inv = !inv;
 364 LABEL(cvar_fail)
 365                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 366                 if (!inv)
 367                 {
 368                         //print("cvarfilter fail\n");
 369                         delete(this);
 370                         __spawnfunc_expecting = false;
 371                         return;
 372                 }
 373         }
 374
 375         if(DoesQ3ARemoveThisEntity(this))
 376         {
 377                 delete(this);
 378                 __spawnfunc_expecting = false;
 379                 return;
 380         }
 381
 382         set_movetype(this, this.movetype);
 383
 384         // support special -1 and -2 angle from radiant
 385         if (this.angles == '0 -1 0')
 386                 this.angles = '-90 0 0';
 387         else if (this.angles == '0 -2 0')
 388                 this.angles = '+90 0 0';
 389
 390         if(this.originjitter.x != 0)
 391                 this.origin_x = this.origin.x + (random() * 2 - 1) * this.originjitter.x;
 392         if(this.originjitter.y != 0)
 393                 this.origin_y = this.origin.y + (random() * 2 - 1) * this.originjitter.y;
 394         if(this.originjitter.z != 0)
 395                 this.origin_z = this.origin.z + (random() * 2 - 1) * this.originjitter.z;
 396         if(this.anglesjitter.x != 0)
 397                 this.angles_x = this.angles.x + (random() * 2 - 1) * this.anglesjitter.x;
 398         if(this.anglesjitter.y != 0)
 399                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglesjitter.y;
 400         if(this.anglesjitter.z != 0)
 401                 this.angles_z = this.angles.z + (random() * 2 - 1) * this.anglesjitter.z;
 402         if(this.anglejitter != 0)
 403                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglejitter;
 404
 405         if(MUTATOR_CALLHOOK(OnEntityPreSpawn, this))
 406         {
 407                 delete(this);
 408                 __spawnfunc_expecting = false;
 409                 return;
 410         }
 411 }
 412
 413 void WarpZone_PostInitialize_Callback()
 414 {
 415         // create waypoint links for warpzones
 416         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 417         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 418         {
 419                 vector src, dst;
 420                 src = (e.absmin + e.absmax) * 0.5;
 421                 makevectors(e.warpzone_angles);
 422                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 423                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 424                 makevectors(e.enemy.warpzone_angles);
 425                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 426                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 427         }
 428 }