qcsrc/server/sv_main.qc

   1
   2 void CreatureFrame (void)
   3 {
   4         local entity oldself;
   5         local float dm;
   6         oldself = self;
   7         self = findfloat(world, iscreature, TRUE);
   8         while (self)
   9         {
  10                 if (self.movetype != MOVETYPE_NOCLIP)
  11                 {
  12                         if (self.waterlevel)
  13                         {
  14                                 if (!(self.flags & FL_INWATER))
  15                                 {
  16                                         self.flags |= FL_INWATER;
  17                                         self.dmgtime = 0;
  18                                 }
  19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  20                                 {
  21                                         if(self.air_finished < time + 9)
  22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  23                                         self.air_finished = time + 12;
  24                                         self.dmg = 2;
  25                                 }
  26                                 else if (self.air_finished < time)
  27                                 {       // drown!
  28                                         if (!self.deadflag)
  29                                         if (self.pain_finished < time)
  30                                         {
  31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
  32                                                 self.pain_finished = time + 0.5;
  33                                         }
  34                                 }
  35                                 if (self.dmgtime < time)
  36                                 {
  37                                         self.dmgtime = time + 0.1;
  38                                         if (self.watertype == CONTENT_LAVA)
  39                                         {
  40                                                 if (self.watersound_finished < time)
  41                                                 {
  42                                                         self.watersound_finished = time + 0.5;
  43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  44                                                 }
  45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  46                                         }
  47                                         else if (self.watertype == CONTENT_SLIME)
  48                                         {
  49                                                 if (self.watersound_finished < time)
  50                                                 {
  51                                                         self.watersound_finished = time + 0.5;
  52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  53                                                 }
  54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  55                                         }
  56                                 }
  57                         }
  58                         else
  59                         {
  60                                 if (self.flags & FL_INWATER)
  61                                 {
  62                                         // play leave water sound
  63                                         self.flags &~= FL_INWATER;
  64                                         self.dmgtime = 0;
  65                                 }
  66                                 self.air_finished = time + 12;
  67                                 self.dmg = 2;
  68                         }
  69                         // check for falling damage
  70                         if(!self.hook.state && !g_ca && !(g_cts && !cvar("g_cts_selfdamage")))
  71                         {
  72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  73                                 if (self.deadflag)
  74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");
  75                                 else
  76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));
  77                                 if (dm > 0)
  78                                 {
  79                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
  80                                 }
  81                                 else if(vlen(self.velocity) > 100000 && cvar("developer"))
  82                                 {
  83                                         dprint(strcat(self.netname, " became too fast, please investigate: ", vtos(self.spawnorigin), "\n"));
  84                                         Damage (self, world, world, 50000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
  85                                 }
  86                         }
  87
  88                         // play stupid sounds
  89                         if (g_footsteps)
  90                         if (!gameover)
  91                         if (self.flags & FL_ONGROUND)
  92                         if (vlen(self.velocity) > sv_maxspeed * 0.6)
  93                         if (!self.deadflag)
  94                         if (time < self.lastground + 0.2)
  95                         {
  96                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
  97                                 {
  98                                         self.nextstep = time + 0.3 + random() * 0.1;
  99                                         trace_dphitq3surfaceflags = 0;
 100                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 101                                         /*
 102                                         if(trace_fraction == 1)
 103                                                 dprint("nohit\n");
 104                                         else
 105                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 106                                         */
 107                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 108                                         {
 109                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 110                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 111                                                 else
 112                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 113                                         }
 114                                 }
 115                         }
 116                         self.oldvelocity = self.velocity;
 117                 }
 118                 self = findfloat(self, iscreature, TRUE);
 119         }
 120         self = oldself;
 121 }
 122
 123
 124 /*
 125 =============
 126 StartFrame
 127
 128 Called before each frame by the server
 129 =============
 130 */
 131
 132 float game_delay;
 133 float game_delay_last;
 134
 135 void RuneMatchGivePoints();
 136 float RedirectionThink();
 137 entity SelectSpawnPoint (float anypoint);
 138 void StartFrame (void)
 139 {
 140         remove = remove_unsafely; // not during spawning!
 141         serverprevtime = servertime;
 142         servertime = time;
 143         serverframetime = frametime;
 144
 145 #ifdef PROFILING
 146         if(time > client_cefc_accumulatortime + 1)
 147         {
 148                 float t, pp, c_seeing, c_seen;
 149                 entity cl;
 150                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 151                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 152                 c_seeing = 0;
 153                 c_seen = 0;
 154                 FOR_EACH_CLIENT(cl)
 155                 {
 156                         if(clienttype(cl) == CLIENTTYPE_REAL)
 157                                 ++c_seeing;
 158                         if(cl.classname == "player")
 159                                 ++c_seen;
 160                 }
 161                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 162                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 163
 164                 client_cefc_accumulatortime = time;
 165                 client_cefc_accumulator = 0;
 166         }
 167 #endif
 168
 169         entity e;
 170         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 171                 CSQCProjectile_Check(e);
 172
 173         if(RedirectionThink())
 174                 return;
 175
 176         UncustomizeEntitiesRun();
 177         InitializeEntitiesRun();
 178
 179         WarpZone_StartFrame();
 180
 181         sv_gravity = cvar("sv_gravity");
 182         sv_maxairspeed = cvar("sv_maxairspeed");
 183         sv_maxspeed = cvar ("sv_maxspeed");
 184         sv_friction = cvar ("sv_friction");
 185         sv_accelerate = cvar ("sv_accelerate");
 186         sv_airaccelerate = cvar("sv_airaccelerate");
 187         sv_airaccel_sideways_friction = cvar("sv_airaccel_sideways_friction");
 188         sv_airaccel_qw = cvar("sv_airaccel_qw");
 189         sv_stopspeed = cvar ("sv_stopspeed");
 190         sv_airstopaccelerate = cvar("sv_airstopaccelerate");
 191         sv_airstrafeaccelerate = cvar("sv_airstrafeaccelerate");
 192         sv_maxairstrafespeed = cvar("sv_maxairstrafespeed");
 193         sv_aircontrol = cvar("sv_aircontrol");
 194         sv_aircontrol_power = cvar("sv_aircontrol_power");
 195         sv_warsowbunny_airforwardaccel = cvar("sv_warsowbunny_airforwardaccel");
 196         sv_warsowbunny_accel = cvar("sv_warsowbunny_accel");
 197         sv_warsowbunny_topspeed = cvar("sv_warsowbunny_topspeed");
 198         sv_warsowbunny_turnaccel = cvar("sv_warsowbunny_turnaccel");
 199         sv_warsowbunny_backtosideratio = cvar("sv_warsowbunny_backtosideratio");
 200         teamplay = cvar ("teamplay");
 201         sys_frametime = cvar("sys_ticrate") * cvar("slowmo");
 202
 203         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)
 204                 orig_slowmo = cvar("slowmo"); // slowmo will be restored after the timeout
 205
 206         if(teams_matter && !teamplay)
 207                 teamplay = 3;
 208         if(!teams_matter && teamplay)
 209                 teamplay = 0;
 210
 211         skill = cvar("skill");
 212
 213         Spawnqueue_Check();
 214
 215
 216         // detect when the pre-game countdown (if any) has ended and the game has started
 217         game_delay = (time < game_starttime) ? TRUE : FALSE;
 218
 219         if(game_delay_last == TRUE)
 220         if(game_delay == FALSE)
 221         if(cvar("sv_eventlog"))
 222                         GameLogEcho(":startdelay_ended");
 223
 224         game_delay_last = game_delay;
 225
 226         // if in warmup stage and limit for warmup is hit start match
 227         if (inWarmupStage)
 228         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
 229          || (g_warmup_limit == 0 && cvar("timelimit") != 0 && time >= cvar("timelimit") * 60))
 230         {
 231                 ReadyRestart();
 232                 return;
 233         }
 234
 235         CreatureFrame ();
 236         CheckRules_World ();
 237
 238         AuditTeams();
 239
 240         RuneMatchGivePoints();
 241         bot_serverframe();
 242
 243         if(cvar("spawn_debugview"))
 244         {
 245                 RandomSelection_Init();
 246                 for(self = world; (self = find(self, classname, "player")); )
 247                         RandomSelection_Add(self, 0, string_null, 1, 0);
 248                 self = RandomSelection_chosen_ent;
 249                 SelectSpawnPoint(0);
 250         }
 251
 252         FOR_EACH_PLAYER(self)
 253                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 254 }
 255
 256 .vector originjitter;
 257 .vector anglesjitter;
 258 .float anglejitter;
 259 .string gametypefilter;
 260 .string cvarfilter;
 261 void SV_OnEntityPreSpawnFunction()
 262 {
 263         if(self.gametypefilter != "")
 264         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
 265         {
 266                 remove(self);
 267                 return;
 268         }
 269         if(self.cvarfilter != "")
 270         {
 271                 float n, i, o, inv;
 272                 string s, k, v;
 273                 inv = 0;
 274
 275                 s = self.cvarfilter;
 276                 if(substring(s, 0, 1) == "+")
 277                 {
 278                         s = substring(s, 1, -1);
 279                 }
 280                 else if(substring(s, 0, 1) == "-")
 281                 {
 282                         inv = 1;
 283                         s = substring(s, 1, -1);
 284                 }
 285
 286                 n = tokenize(s);
 287                 for(i = 0; i < n; ++i)
 288                 {
 289                         s = argv(i);
 290                         // syntax:
 291                         // var>x
 292                         // var<x
 293                         // var>=x
 294                         // var<=x
 295                         // var==x
 296                         // var!=x
 297                         // var===x
 298                         // var!==x
 299                         if((o = strstrofs(s, ">=", 0)) >= 0)
 300                         {
 301                                 k = substring(s, 0, o);
 302                                 v = substring(s, o+2, -1);
 303                                 if(cvar(k) < stof(v))
 304                                         goto cvar_fail;
 305                         }
 306                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 307                         {
 308                                 k = substring(s, 0, o);
 309                                 v = substring(s, o+2, -1);
 310                                 if(cvar(k) > stof(v))
 311                                         goto cvar_fail;
 312                         }
 313                         else if((o = strstrofs(s, ">", 0)) >= 0)
 314                         {
 315                                 k = substring(s, 0, o);
 316                                 v = substring(s, o+1, -1);
 317                                 if(cvar(k) <= stof(v))
 318                                         goto cvar_fail;
 319                         }
 320                         else if((o = strstrofs(s, "<", 0)) >= 0)
 321                         {
 322                                 k = substring(s, 0, o);
 323                                 v = substring(s, o+1, -1);
 324                                 if(cvar(k) >= stof(v))
 325                                         goto cvar_fail;
 326                         }
 327                         else if((o = strstrofs(s, "==", 0)) >= 0)
 328                         {
 329                                 k = substring(s, 0, o);
 330                                 v = substring(s, o+2, -1);
 331                                 if(cvar(k) != stof(v))
 332                                         goto cvar_fail;
 333                         }
 334                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 335                         {
 336                                 k = substring(s, 0, o);
 337                                 v = substring(s, o+2, -1);
 338                                 if(cvar(k) == stof(v))
 339                                         goto cvar_fail;
 340                         }
 341                         else if((o = strstrofs(s, "===", 0)) >= 0)
 342                         {
 343                                 k = substring(s, 0, o);
 344                                 v = substring(s, o+2, -1);
 345                                 if(cvar_string(k) != v)
 346                                         goto cvar_fail;
 347                         }
 348                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 349                         {
 350                                 k = substring(s, 0, o);
 351                                 v = substring(s, o+2, -1);
 352                                 if(cvar_string(k) == v)
 353                                         goto cvar_fail;
 354                         }
 355                         else if(substring(s, 0, 1) == "!")
 356                         {
 357                                 k = substring(s, 1, -1);
 358                                 if(cvar(k))
 359                                         goto cvar_fail;
 360                         }
 361                         else
 362                         {
 363                                 k = s;
 364                                 if not(cvar(k))
 365                                         goto cvar_fail;
 366                         }
 367                 }
 368                 inv = !inv;
 369 :cvar_fail
 370                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 371                 if not(inv)
 372                 {
 373                         //print("cvarfilter fail\n");
 374                         remove(self);
 375                         return;
 376                 }
 377         }
 378
 379         // support special -1 and -2 angle from radiant
 380         if (self.angles == '0 -1 0')
 381                 self.angles = '-90 0 0';
 382         else if (self.angles == '0 -2 0')
 383                 self.angles = '+90 0 0';
 384
 385         if(self.originjitter_x != 0)
 386                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 387         if(self.originjitter_y != 0)
 388                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 389         if(self.originjitter_z != 0)
 390                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 391         if(self.anglesjitter_x != 0)
 392                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 393         if(self.anglesjitter_y != 0)
 394                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 395         if(self.anglesjitter_z != 0)
 396                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 397         if(self.anglejitter != 0)
 398                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 399
 400         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 401         {
 402                 remove(self);
 403                 return;
 404         }
 405 }