qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_damage.qh"
   6 #include "g_world.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include <server/mutators/_mod.qh>
  13 #include "weapons/csqcprojectile.qh"
  14 #include <server/compat/quake3.qh>
  15
  16 #include "../common/constants.qh"
  17 #include "../common/deathtypes/all.qh"
  18 #include "../common/debug.qh"
  19 #include "../common/mapinfo.qh"
  20 #include "../common/util.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/weapons/_all.qh>
  25
  26 #include "../lib/csqcmodel/sv_model.qh"
  27
  28 #include "../lib/warpzone/common.qh"
  29 #include "../lib/warpzone/server.qh"
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime >= time)
  34         {
  35                 return;
  36         }
  37
  38         this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  39
  40         if (this.flags & FL_PROJECTILE)
  41         {
  42                 if (this.watertype == CONTENT_LAVA)
  43                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  44                 else if (this.watertype == CONTENT_SLIME)
  45                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  46         }
  47         else
  48         {
  49                 if (this.watertype == CONTENT_LAVA)
  50                 {
  51                         if (this.watersound_finished < time)
  52                         {
  53                                 this.watersound_finished = time + 0.5;
  54                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  55                         }
  56                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  57                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  58                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  59                 }
  60                 else if (this.watertype == CONTENT_SLIME)
  61                 {
  62                         if (this.watersound_finished < time)
  63                         {
  64                                 this.watersound_finished = time + 0.5;
  65                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  66                         }
  67                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  68                 }
  69         }
  70 }
  71
  72 void CreatureFrame_Liquids(entity this)
  73 {
  74         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  75         {
  76                 if (!(this.flags & FL_INWATER))
  77                 {
  78                         this.flags |= FL_INWATER;
  79                         this.dmgtime = 0;
  80                 }
  81
  82                 CreatureFrame_hotliquids(this);
  83         }
  84         else
  85         {
  86                 if (this.flags & FL_INWATER)
  87                 {
  88                         // play leave water sound
  89                         this.flags &= ~FL_INWATER;
  90                         this.dmgtime = 0;
  91                 }
  92                 this.air_finished = time + 12;
  93         }
  94 }
  95
  96 void CreatureFrame_FallDamage(entity this)
  97 {
  98         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
  99                 return; // vehicles and projectiles don't receive fall damage
 100         if(!(this.velocity || this.oldvelocity))
 101                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 102
 103         // check for falling damage
 104         float velocity_len = vlen(this.velocity);
 105         bool have_hook = false;
 106         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 107         {
 108             .entity weaponentity = weaponentities[slot];
 109             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 110             {
 111                 have_hook = true;
 112                 break;
 113             }
 114         }
 115         if(!have_hook)
 116         {
 117                 float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 118                 if (IS_DEAD(this))
 119                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 120                 else
 121                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 122                 if (dm > 0)
 123                 {
 124                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 125                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 126                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 127                 }
 128         }
 129
 130         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 131                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 132 }
 133
 134 void CreatureFrame_All()
 135 {
 136         if(game_stopped || time < game_starttime)
 137                 return;
 138
 139         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 140         {
 141                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 142                 CreatureFrame_Liquids(it);
 143                 CreatureFrame_FallDamage(it);
 144                 it.oldvelocity = it.velocity;
 145         });
 146 }
 147
 148 void Pause_TryPause(bool ispaused)
 149 {
 150         int n = 0;
 151         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 152                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 153                 ++n;
 154         });
 155         if (!n) return;
 156         setpause(ispaused);
 157 }
 158
 159 void SV_PausedTic(float elapsedtime)
 160 {
 161         if (!server_is_dedicated) Pause_TryPause(false);
 162 }
 163
 164 /*
 165 =============
 166 StartFrame
 167
 168 Called before each frame by the server
 169 =============
 170 */
 171
 172 bool game_delay_last;
 173
 174 bool autocvar_sv_autopause = false;
 175 void systems_update();
 176 void sys_phys_update(entity this, float dt);
 177 void StartFrame()
 178 {
 179     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 180     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 181     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 182
 183         execute_next_frame();
 184         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 185
 186         delete_fn = remove_unsafely; // not during spawning!
 187         serverprevtime = servertime;
 188         servertime = time;
 189         serverframetime = frametime;
 190
 191 #ifdef PROFILING
 192         if(time > client_cefc_accumulatortime + 1)
 193         {
 194                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 195                 int c_seeing = 0;
 196                 int c_seen = 0;
 197                 FOREACH_CLIENT(true, {
 198                         if(IS_REAL_CLIENT(it))
 199                                 ++c_seeing;
 200                         if(IS_PLAYER(it))
 201                                 ++c_seen;
 202                 });
 203                 LOG_INFO(
 204                     "CEFC time: ", ftos(t * 1000), "ms; ",
 205             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 206             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 207         );
 208                 client_cefc_accumulatortime = time;
 209                 client_cefc_accumulator = 0;
 210         }
 211 #endif
 212
 213         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 214
 215         if (RedirectionThink()) return;
 216
 217         UncustomizeEntitiesRun();
 218         InitializeEntitiesRun();
 219
 220         WarpZone_StartFrame();
 221
 222         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 223         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 224
 225         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 226                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 227
 228         // detect when the pre-game countdown (if any) has ended and the game has started
 229         bool game_delay = (time < game_starttime);
 230         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 231                 GameLogEcho(":startdelay_ended");
 232         game_delay_last = game_delay;
 233
 234         CreatureFrame_All();
 235         CheckRules_World();
 236
 237         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 238                 ReadyRestart();
 239                 return;
 240         }
 241
 242         bot_serverframe();
 243         anticheat_startframe();
 244         MUTATOR_CALLHOOK(SV_StartFrame);
 245
 246         GlobalStats_updateglobal();
 247     FOREACH_CLIENT(true, GlobalStats_update(it));
 248     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 249 }
 250
 251 .vector originjitter;
 252 .vector anglesjitter;
 253 .float anglejitter;
 254 .string gametypefilter;
 255 .string cvarfilter;
 256
 257 /**
 258  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 259  * +: all must match. this is the default
 260  * -: one must NOT match
 261  *
 262  * var>x
 263  * var<x
 264  * var>=x
 265  * var<=x
 266  * var==x
 267  * var!=x
 268  * var===x
 269  * var!==x
 270  */
 271 bool expr_evaluate(string s)
 272 {
 273     bool ret = false;
 274     if (str2chr(s, 0) == '+') {
 275         s = substring(s, 1, -1);
 276     } else if (str2chr(s, 0) == '-') {
 277         ret = true;
 278         s = substring(s, 1, -1);
 279     }
 280     bool expr_fail = false;
 281     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 282         int o;
 283         string k, v;
 284         s = argv(i);
 285         #define X(expr) \
 286             if (expr) \
 287                 continue; \
 288             expr_fail = true; \
 289             break;
 290
 291         #define BINOP(op, len, expr) \
 292             if ((o = strstrofs(s, op, 0)) >= 0) { \
 293                 k = substring(s, 0, o); \
 294                 v = substring(s, o + len, -1); \
 295                 X(expr); \
 296             }
 297         BINOP(">=", 2, cvar(k) >= stof(v));
 298         BINOP("<=", 2, cvar(k) <= stof(v));
 299         BINOP(">",  1, cvar(k) >  stof(v));
 300         BINOP("<",  1, cvar(k) <  stof(v));
 301         BINOP("==", 2, cvar(k) == stof(v));
 302         BINOP("!=", 2, cvar(k) != stof(v));
 303         BINOP("===", 3, cvar_string(k) == v);
 304         BINOP("!==", 3, cvar_string(k) != v);
 305         {
 306             k = s;
 307             bool b = true;
 308             if (str2chr(k, 0) == '!') {
 309                 k = substring(s, 1, -1);
 310                 b = false;
 311             }
 312             float f = stof(k);
 313             bool isnum = ftos(f) == k;
 314             X(boolean(isnum ? f : cvar(k)) == b);
 315         }
 316         #undef BINOP
 317         #undef X
 318     }
 319     if (!expr_fail) {
 320         ret = !ret;
 321     }
 322     // now ret is true if we want to keep the item, and false if we want to get rid of it
 323     return ret;
 324 }
 325
 326 void SV_OnEntityPreSpawnFunction(entity this)
 327 {
 328         if (this)
 329         if (this.gametypefilter != "")
 330         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 331         {
 332                 delete(this);
 333                 return;
 334         }
 335         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 336                 delete(this);
 337                 return;
 338         }
 339
 340         if (DoesQ3ARemoveThisEntity(this)) {
 341                 delete(this);
 342                 return;
 343         }
 344
 345         set_movetype(this, this.movetype);
 346
 347         if (this.monster_attack) {
 348                 IL_PUSH(g_monster_targets, this);
 349     }
 350
 351         // support special -1 and -2 angle from radiant
 352         if (this.angles == '0 -1 0') {
 353                 this.angles = '-90 0 0';
 354         } else if (this.angles == '0 -2 0') {
 355                 this.angles = '+90 0 0';
 356     }
 357
 358     #define X(out, in) MACRO_BEGIN \
 359         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 360     MACRO_END
 361     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 362     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 363     X(this.angles.y, this.anglejitter);
 364     #undef X
 365
 366         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 367                 delete(this);
 368                 return;
 369         }
 370 }
 371
 372 void WarpZone_PostInitialize_Callback()
 373 {
 374         // create waypoint links for warpzones
 375         entity tracetest_ent = spawn();
 376         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 377         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 378         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 379         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 380                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 381         delete(tracetest_ent);
 382 }
 383
 384 /*
 385 ==================
 386 main
 387
 388 unused but required by the engine
 389 ==================
 390 */
 391 void main ()
 392 {
 393
 394 }