qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/bot.qh"
   8 #include "bot/waypoints.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include "mutators/all.qh"
  13 #include "weapons/csqcprojectile.qh"
  14
  15 #include "../common/constants.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/debug.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/vehicles/all.qh"
  22 #include "../common/weapons/all.qh"
  23
  24 #include "../lib/csqcmodel/sv_model.qh"
  25
  26 #include "../lib/warpzone/common.qh"
  27 #include "../lib/warpzone/server.qh"
  28
  29 .float lastground;
  30 .int state;
  31
  32 void CreatureFrame_hotliquids(entity this)
  33 {
  34         if (this.dmgtime < time)
  35         {
  36                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  37
  38                 if (this.flags & FL_PROJECTILE)
  39                 {
  40                         if (this.watertype == CONTENT_LAVA)
  41                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  42                         else if (this.watertype == CONTENT_SLIME)
  43                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  44                 }
  45                 else
  46                 {
  47                         if (this.watertype == CONTENT_LAVA)
  48                         {
  49                                 if (this.watersound_finished < time)
  50                                 {
  51                                         this.watersound_finished = time + 0.5;
  52                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  53                                 }
  54                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  55                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  56                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  57                         }
  58                         else if (this.watertype == CONTENT_SLIME)
  59                         {
  60                                 if (this.watersound_finished < time)
  61                                 {
  62                                         this.watersound_finished = time + 0.5;
  63                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  64                                 }
  65                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  66                         }
  67                 }
  68         }
  69 }
  70
  71 void CreatureFrame_Liquids(entity this)
  72 {
  73         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  74         {
  75                 if (!(this.flags & FL_INWATER))
  76                 {
  77                         this.flags |= FL_INWATER;
  78                         this.dmgtime = 0;
  79                 }
  80
  81                 CreatureFrame_hotliquids(this);
  82         }
  83         else
  84         {
  85                 if (this.flags & FL_INWATER)
  86                 {
  87                         // play leave water sound
  88                         this.flags &= ~FL_INWATER;
  89                         this.dmgtime = 0;
  90                 }
  91                 this.air_finished = time + 12;
  92                 this.dmg = 2;
  93         }
  94 }
  95
  96 void CreatureFrame_FallDamage(entity this)
  97 {
  98         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  99         if(this.velocity || this.oldvelocity) // moving or has moved
 100         {
 101                 // check for falling damage
 102                 float velocity_len = vlen(this.velocity);
 103                 if(!this.hook.state)
 104                 {
 105                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 106                         if (IS_DEAD(this))
 107                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 108                         else
 109                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 110                         if (dm > 0)
 111                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 112                 }
 113
 114                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 115                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 116         }
 117 }
 118
 119 void CreatureFrame_All()
 120 {
 121         FOREACH_ENTITY_FLOAT(damagedbycontents, true, {
 122                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 123                 CreatureFrame_Liquids(it);
 124                 CreatureFrame_FallDamage(it);
 125                 it.oldvelocity = it.velocity;
 126         });
 127 }
 128
 129 void Pause_TryPause(bool ispaused)
 130 {
 131         int n = 0;
 132         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 133                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 134                 ++n;
 135         ));
 136         if (!n) return;
 137         setpause(ispaused);
 138 }
 139
 140 void SV_PausedTic(float elapsedtime)
 141 {
 142         if (!server_is_dedicated) Pause_TryPause(false);
 143 }
 144
 145 /*
 146 =============
 147 StartFrame
 148
 149 Called before each frame by the server
 150 =============
 151 */
 152
 153 float game_delay;
 154 float game_delay_last;
 155
 156 bool autocvar_sv_autopause = false;
 157 float RedirectionThink();
 158 void systems_update();
 159 void sys_phys_update(entity this, float dt);
 160 void StartFrame()
 161 {
 162     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 163     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 164     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 165
 166         execute_next_frame();
 167         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 168
 169         delete_fn = remove_unsafely; // not during spawning!
 170         serverprevtime = servertime;
 171         servertime = time;
 172         serverframetime = frametime;
 173
 174 #ifdef PROFILING
 175         if(time > client_cefc_accumulatortime + 1)
 176         {
 177                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 178                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 179                 int c_seeing = 0;
 180                 int c_seen = 0;
 181                 FOREACH_CLIENT(true, LAMBDA(
 182                         if(IS_REAL_CLIENT(it))
 183                                 ++c_seeing;
 184                         if(IS_PLAYER(it))
 185                                 ++c_seen;
 186                 ));
 187                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 188                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 189
 190                 client_cefc_accumulatortime = time;
 191                 client_cefc_accumulator = 0;
 192         }
 193 #endif
 194
 195         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, CSQCProjectile_Check(it));
 196
 197         if (RedirectionThink()) return;
 198
 199         UncustomizeEntitiesRun();
 200         InitializeEntitiesRun();
 201
 202         WarpZone_StartFrame();
 203
 204         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 205         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 206
 207         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 208                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 209
 210         skill = autocvar_skill;
 211
 212         // detect when the pre-game countdown (if any) has ended and the game has started
 213         game_delay = (time < game_starttime);
 214
 215         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 216                 GameLogEcho(":startdelay_ended");
 217
 218         game_delay_last = game_delay;
 219
 220         CreatureFrame_All();
 221         CheckRules_World();
 222
 223         if (warmup_stage && !gameover && warmup_limit > 0 && time >= warmup_limit) {
 224                 ReadyRestart();
 225                 return;
 226         }
 227
 228         bot_serverframe();
 229         anticheat_startframe();
 230         MUTATOR_CALLHOOK(SV_StartFrame);
 231
 232     FOREACH_CLIENT(true, GlobalStats_update(it));
 233     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 234 }
 235
 236 .vector originjitter;
 237 .vector anglesjitter;
 238 .float anglejitter;
 239 .string gametypefilter;
 240 .string cvarfilter;
 241 bool DoesQ3ARemoveThisEntity(entity this);
 242 void SV_OnEntityPreSpawnFunction(entity this)
 243 {
 244         __spawnfunc_expecting = true;
 245         __spawnfunc_expect = this;
 246         if (this)
 247         if (this.gametypefilter != "")
 248         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 249         {
 250                 remove(this);
 251                 __spawnfunc_expecting = false;
 252                 return;
 253         }
 254         if(this.cvarfilter != "")
 255         {
 256                 float n, i, o, inv;
 257                 string s, k, v;
 258                 inv = 0;
 259
 260                 s = this.cvarfilter;
 261                 if(substring(s, 0, 1) == "+")
 262                 {
 263                         s = substring(s, 1, -1);
 264                 }
 265                 else if(substring(s, 0, 1) == "-")
 266                 {
 267                         inv = 1;
 268                         s = substring(s, 1, -1);
 269                 }
 270
 271                 n = tokenize_console(s);
 272                 for(i = 0; i < n; ++i)
 273                 {
 274                         s = argv(i);
 275                         // syntax:
 276                         // var>x
 277                         // var<x
 278                         // var>=x
 279                         // var<=x
 280                         // var==x
 281                         // var!=x
 282                         // var===x
 283                         // var!==x
 284                         if((o = strstrofs(s, ">=", 0)) >= 0)
 285                         {
 286                                 k = substring(s, 0, o);
 287                                 v = substring(s, o+2, -1);
 288                                 if(cvar(k) < stof(v))
 289                                         goto cvar_fail;
 290                         }
 291                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 292                         {
 293                                 k = substring(s, 0, o);
 294                                 v = substring(s, o+2, -1);
 295                                 if(cvar(k) > stof(v))
 296                                         goto cvar_fail;
 297                         }
 298                         else if((o = strstrofs(s, ">", 0)) >= 0)
 299                         {
 300                                 k = substring(s, 0, o);
 301                                 v = substring(s, o+1, -1);
 302                                 if(cvar(k) <= stof(v))
 303                                         goto cvar_fail;
 304                         }
 305                         else if((o = strstrofs(s, "<", 0)) >= 0)
 306                         {
 307                                 k = substring(s, 0, o);
 308                                 v = substring(s, o+1, -1);
 309                                 if(cvar(k) >= stof(v))
 310                                         goto cvar_fail;
 311                         }
 312                         else if((o = strstrofs(s, "==", 0)) >= 0)
 313                         {
 314                                 k = substring(s, 0, o);
 315                                 v = substring(s, o+2, -1);
 316                                 if(cvar(k) != stof(v))
 317                                         goto cvar_fail;
 318                         }
 319                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 320                         {
 321                                 k = substring(s, 0, o);
 322                                 v = substring(s, o+2, -1);
 323                                 if(cvar(k) == stof(v))
 324                                         goto cvar_fail;
 325                         }
 326                         else if((o = strstrofs(s, "===", 0)) >= 0)
 327                         {
 328                                 k = substring(s, 0, o);
 329                                 v = substring(s, o+2, -1);
 330                                 if(cvar_string(k) != v)
 331                                         goto cvar_fail;
 332                         }
 333                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 334                         {
 335                                 k = substring(s, 0, o);
 336                                 v = substring(s, o+2, -1);
 337                                 if(cvar_string(k) == v)
 338                                         goto cvar_fail;
 339                         }
 340                         else if(substring(s, 0, 1) == "!")
 341                         {
 342                                 k = substring(s, 1, -1);
 343                                 if(cvar(k))
 344                                         goto cvar_fail;
 345                         }
 346                         else
 347                         {
 348                                 k = s;
 349                                 if (!cvar(k))
 350                                         goto cvar_fail;
 351                         }
 352                 }
 353                 inv = !inv;
 354 LABEL(cvar_fail)
 355                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 356                 if (!inv)
 357                 {
 358                         //print("cvarfilter fail\n");
 359                         remove(this);
 360                         __spawnfunc_expecting = false;
 361                         return;
 362                 }
 363         }
 364
 365         if(DoesQ3ARemoveThisEntity(this))
 366         {
 367                 remove(this);
 368                 __spawnfunc_expecting = false;
 369                 return;
 370         }
 371
 372         this.move_movetype = this.movetype;
 373
 374         // support special -1 and -2 angle from radiant
 375         if (this.angles == '0 -1 0')
 376                 this.angles = '-90 0 0';
 377         else if (this.angles == '0 -2 0')
 378                 this.angles = '+90 0 0';
 379
 380         if(this.originjitter.x != 0)
 381                 this.origin_x = this.origin.x + (random() * 2 - 1) * this.originjitter.x;
 382         if(this.originjitter.y != 0)
 383                 this.origin_y = this.origin.y + (random() * 2 - 1) * this.originjitter.y;
 384         if(this.originjitter.z != 0)
 385                 this.origin_z = this.origin.z + (random() * 2 - 1) * this.originjitter.z;
 386         if(this.anglesjitter.x != 0)
 387                 this.angles_x = this.angles.x + (random() * 2 - 1) * this.anglesjitter.x;
 388         if(this.anglesjitter.y != 0)
 389                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglesjitter.y;
 390         if(this.anglesjitter.z != 0)
 391                 this.angles_z = this.angles.z + (random() * 2 - 1) * this.anglesjitter.z;
 392         if(this.anglejitter != 0)
 393                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglejitter;
 394
 395         if(MUTATOR_CALLHOOK(OnEntityPreSpawn, this))
 396         {
 397                 remove(this);
 398                 __spawnfunc_expecting = false;
 399                 return;
 400         }
 401 }
 402
 403 void WarpZone_PostInitialize_Callback()
 404 {
 405         // create waypoint links for warpzones
 406         entity e;
 407         for(e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 408         {
 409                 vector src, dst;
 410                 src = (e.absmin + e.absmax) * 0.5;
 411                 makevectors(e.warpzone_angles);
 412                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 413                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 414                 makevectors(e.enemy.warpzone_angles);
 415                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 416                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 417         }
 418 }