qcsrc/server/sv_main.qc

   1 void CreatureFrame (void)
   2 {
   3         entity oldself;
   4         float dm;
   5
   6         oldself = self;
   7         for(self = world; (self = findfloat(self, damagedbycontents, TRUE)); )
   8         {
   9                 if (self.movetype == MOVETYPE_NOCLIP) { continue; }
  10
  11                 float vehic = (self.vehicle_flags & VHF_ISVEHICLE);
  12                 float projectile = (self.flags & FL_PROJECTILE);
  13
  14                 if (self.watertype <= CONTENT_WATER && self.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  15                 {
  16                         if (!(self.flags & FL_INWATER))
  17                         {
  18                                 self.flags |= FL_INWATER;
  19                                 self.dmgtime = 0;
  20                         }
  21
  22                         if(!vehic && !projectile) // vehicles and projectiles don't drown
  23                         {
  24                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  25                                 {
  26                                         if(self.air_finished < time)
  27                                                 PlayerSound(playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
  28                                         self.air_finished = time + autocvar_g_balance_contents_drowndelay;
  29                                         self.dmg = 2;
  30                                 }
  31                                 else if (self.air_finished < time)
  32                                 {       // drown!
  33                                         if (!self.deadflag)
  34                                         if (self.pain_finished < time)
  35                                         {
  36                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN, self.origin, '0 0 0');
  37                                                 self.pain_finished = time + 0.5;
  38                                         }
  39                                 }
  40                         }
  41
  42                         if (self.dmgtime < time)
  43                         {
  44                                 self.dmgtime = time + autocvar_g_balance_contents_damagerate;
  45
  46                                 if (!projectile)
  47                                 {
  48                                         if (self.watertype == CONTENT_LAVA)
  49                                         {
  50                                                 if (self.watersound_finished < time)
  51                                                 {
  52                                                         self.watersound_finished = time + 0.5;
  53                                                         sound (self, CH_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  54                                                 }
  55                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  56                                         }
  57                                         else if (self.watertype == CONTENT_SLIME)
  58                                         {
  59                                                 if (self.watersound_finished < time)
  60                                                 {
  61                                                         self.watersound_finished = time + 0.5;
  62                                                         sound (self, CH_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  63                                                 }
  64                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  65                                         }
  66                                 }
  67                                 else if ((self.watertype == CONTENT_LAVA) || (self.watertype == CONTENT_SLIME))
  68                                 {
  69                                         Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  70                                 }
  71                         }
  72                 }
  73                 else
  74                 {
  75                         if (self.flags & FL_INWATER)
  76                         {
  77                                 // play leave water sound
  78                                 self.flags &~= FL_INWATER;
  79                                 self.dmgtime = 0;
  80                         }
  81                         self.air_finished = time + 12;
  82                         self.dmg = 2;
  83                 }
  84
  85                 if(!vehic && !projectile) // vehicles don't get falling damage
  86                 {
  87                         // check for falling damage
  88                         float velocity_len = vlen(self.velocity);
  89                         if(!self.hook.state && !g_ca && !(g_cts && !autocvar_g_cts_selfdamage))
  90                         {
  91                                 dm = vlen(self.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  92                                 if (self.deadflag)
  93                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
  94                                 else
  95                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
  96                                 if (dm > 0)
  97                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
  98                         }
  99
 100                         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 101                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
 102                         // play stupid sounds
 103                         if (g_footsteps)
 104                         if (!gameover)
 105                         if (self.flags & FL_ONGROUND)
 106                         if (velocity_len > autocvar_sv_maxspeed * 0.6)
 107                         if (!self.deadflag)
 108                         if (time < self.lastground + 0.2)
 109                         {
 110                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
 111                                 {
 112                                         self.nextstep = time + 0.3 + random() * 0.1;
 113                                         trace_dphitq3surfaceflags = 0;
 114                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 115                                         /*
 116                                         if(trace_fraction == 1)
 117                                                 dprint("nohit\n");
 118                                         else
 119                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 120                                         */
 121                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 122                                         {
 123                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 124                                                         GlobalSound(globalsound_metalstep, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 125                                                 else
 126                                                         GlobalSound(globalsound_step, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 127                                         }
 128                                 }
 129                         }
 130                 }
 131
 132                 self.oldvelocity = self.velocity;
 133         }
 134         self = oldself;
 135 }
 136
 137
 138 /*
 139 =============
 140 StartFrame
 141
 142 Called before each frame by the server
 143 =============
 144 */
 145
 146 float game_delay;
 147 float game_delay_last;
 148
 149 void RuneMatchGivePoints();
 150 float RedirectionThink();
 151 entity SelectSpawnPoint (float anypoint);
 152 void StartFrame (void)
 153 {
 154         remove = remove_unsafely; // not during spawning!
 155         serverprevtime = servertime;
 156         servertime = time;
 157         serverframetime = frametime;
 158
 159 #ifdef PROFILING
 160         if(time > client_cefc_accumulatortime + 1)
 161         {
 162                 float t, pp, c_seeing, c_seen;
 163                 entity cl;
 164                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 165                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 166                 c_seeing = 0;
 167                 c_seen = 0;
 168                 FOR_EACH_CLIENT(cl)
 169                 {
 170                         if(clienttype(cl) == CLIENTTYPE_REAL)
 171                                 ++c_seeing;
 172                         if(cl.classname == "player")
 173                                 ++c_seen;
 174                 }
 175                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 176                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 177
 178                 client_cefc_accumulatortime = time;
 179                 client_cefc_accumulator = 0;
 180         }
 181 #endif
 182
 183         entity e;
 184         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 185                 CSQCProjectile_Check(e);
 186
 187         if(RedirectionThink())
 188                 return;
 189
 190         UncustomizeEntitiesRun();
 191         InitializeEntitiesRun();
 192
 193         WarpZone_StartFrame();
 194
 195         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 196         if(sys_frametime <= 0)
 197                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 198
 199         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)
 200                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 201
 202         skill = autocvar_skill;
 203
 204         Spawnqueue_Check();
 205
 206
 207         // detect when the pre-game countdown (if any) has ended and the game has started
 208         game_delay = (time < game_starttime) ? TRUE : FALSE;
 209
 210         if(game_delay_last == TRUE)
 211         if(game_delay == FALSE)
 212         if(autocvar_sv_eventlog)
 213                         GameLogEcho(":startdelay_ended");
 214
 215         game_delay_last = game_delay;
 216
 217         // if in warmup stage and limit for warmup is hit start match
 218         if (inWarmupStage)
 219         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
 220          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 221         {
 222                 ReadyRestart();
 223                 return;
 224         }
 225
 226         CreatureFrame ();
 227         CheckRules_World ();
 228
 229         AuditTeams();
 230
 231         RuneMatchGivePoints();
 232         bot_serverframe();
 233
 234         if(autocvar_spawn_debugview)
 235         {
 236                 RandomSelection_Init();
 237                 for(self = world; (self = find(self, classname, "player")); )
 238                         RandomSelection_Add(self, 0, string_null, 1, 0);
 239                 self = RandomSelection_chosen_ent;
 240                 SelectSpawnPoint(0);
 241         }
 242
 243         FOR_EACH_PLAYER(self)
 244                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 245 }
 246
 247 .vector originjitter;
 248 .vector anglesjitter;
 249 .float anglejitter;
 250 .string gametypefilter;
 251 .string cvarfilter;
 252 float DoesQ3ARemoveThisEntity();
 253 void SV_OnEntityPreSpawnFunction()
 254 {
 255         if(self.gametypefilter != "")
 256         if not(isGametypeInFilter(game, teamplay, have_team_spawns, self.gametypefilter))
 257         {
 258                 remove(self);
 259                 return;
 260         }
 261         if(self.cvarfilter != "")
 262         {
 263                 float n, i, o, inv;
 264                 string s, k, v;
 265                 inv = 0;
 266
 267                 s = self.cvarfilter;
 268                 if(substring(s, 0, 1) == "+")
 269                 {
 270                         s = substring(s, 1, -1);
 271                 }
 272                 else if(substring(s, 0, 1) == "-")
 273                 {
 274                         inv = 1;
 275                         s = substring(s, 1, -1);
 276                 }
 277
 278                 n = tokenize(s);
 279                 for(i = 0; i < n; ++i)
 280                 {
 281                         s = argv(i);
 282                         // syntax:
 283                         // var>x
 284                         // var<x
 285                         // var>=x
 286                         // var<=x
 287                         // var==x
 288                         // var!=x
 289                         // var===x
 290                         // var!==x
 291                         if((o = strstrofs(s, ">=", 0)) >= 0)
 292                         {
 293                                 k = substring(s, 0, o);
 294                                 v = substring(s, o+2, -1);
 295                                 if(cvar(k) < stof(v))
 296                                         goto cvar_fail;
 297                         }
 298                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 299                         {
 300                                 k = substring(s, 0, o);
 301                                 v = substring(s, o+2, -1);
 302                                 if(cvar(k) > stof(v))
 303                                         goto cvar_fail;
 304                         }
 305                         else if((o = strstrofs(s, ">", 0)) >= 0)
 306                         {
 307                                 k = substring(s, 0, o);
 308                                 v = substring(s, o+1, -1);
 309                                 if(cvar(k) <= stof(v))
 310                                         goto cvar_fail;
 311                         }
 312                         else if((o = strstrofs(s, "<", 0)) >= 0)
 313                         {
 314                                 k = substring(s, 0, o);
 315                                 v = substring(s, o+1, -1);
 316                                 if(cvar(k) >= stof(v))
 317                                         goto cvar_fail;
 318                         }
 319                         else if((o = strstrofs(s, "==", 0)) >= 0)
 320                         {
 321                                 k = substring(s, 0, o);
 322                                 v = substring(s, o+2, -1);
 323                                 if(cvar(k) != stof(v))
 324                                         goto cvar_fail;
 325                         }
 326                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 327                         {
 328                                 k = substring(s, 0, o);
 329                                 v = substring(s, o+2, -1);
 330                                 if(cvar(k) == stof(v))
 331                                         goto cvar_fail;
 332                         }
 333                         else if((o = strstrofs(s, "===", 0)) >= 0)
 334                         {
 335                                 k = substring(s, 0, o);
 336                                 v = substring(s, o+2, -1);
 337                                 if(cvar_string(k) != v)
 338                                         goto cvar_fail;
 339                         }
 340                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 341                         {
 342                                 k = substring(s, 0, o);
 343                                 v = substring(s, o+2, -1);
 344                                 if(cvar_string(k) == v)
 345                                         goto cvar_fail;
 346                         }
 347                         else if(substring(s, 0, 1) == "!")
 348                         {
 349                                 k = substring(s, 1, -1);
 350                                 if(cvar(k))
 351                                         goto cvar_fail;
 352                         }
 353                         else
 354                         {
 355                                 k = s;
 356                                 if not(cvar(k))
 357                                         goto cvar_fail;
 358                         }
 359                 }
 360                 inv = !inv;
 361 :cvar_fail
 362                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 363                 if not(inv)
 364                 {
 365                         //print("cvarfilter fail\n");
 366                         remove(self);
 367                         return;
 368                 }
 369         }
 370
 371         if(DoesQ3ARemoveThisEntity())
 372         {
 373                 remove(self);
 374                 return;
 375         }
 376
 377         // support special -1 and -2 angle from radiant
 378         if (self.angles == '0 -1 0')
 379                 self.angles = '-90 0 0';
 380         else if (self.angles == '0 -2 0')
 381                 self.angles = '+90 0 0';
 382
 383         if(self.originjitter_x != 0)
 384                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 385         if(self.originjitter_y != 0)
 386                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 387         if(self.originjitter_z != 0)
 388                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 389         if(self.anglesjitter_x != 0)
 390                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 391         if(self.anglesjitter_y != 0)
 392                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 393         if(self.anglesjitter_z != 0)
 394                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 395         if(self.anglejitter != 0)
 396                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 397
 398         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 399         {
 400                 remove(self);
 401                 return;
 402         }
 403 }
 404
 405 void WarpZone_PostInitialize_Callback(void)
 406 {
 407         // create waypoint links for warpzones
 408         entity e;
 409         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 410         {
 411                 vector src, dst;
 412                 src = (e.absmin + e.absmax) * 0.5;
 413                 makevectors(e.warpzone_angles);
 414                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 415                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 416                 makevectors(e.enemy.warpzone_angles);
 417                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 418                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 419         }
 420 }