qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_damage.qh"
   6 #include "g_world.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include <server/mutators/_mod.qh>
  13 #include "weapons/csqcprojectile.qh"
  14
  15 #include "../common/constants.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/debug.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/vehicles/all.qh"
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/weapons/_all.qh>
  24
  25 #include "../lib/csqcmodel/sv_model.qh"
  26
  27 #include "../lib/warpzone/common.qh"
  28 #include "../lib/warpzone/server.qh"
  29
  30 .float lastground;
  31 .int state;
  32
  33 void CreatureFrame_hotliquids(entity this)
  34 {
  35         if (this.dmgtime < time)
  36         {
  37                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  38
  39                 if (this.flags & FL_PROJECTILE)
  40                 {
  41                         if (this.watertype == CONTENT_LAVA)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  43                         else if (this.watertype == CONTENT_SLIME)
  44                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  45                 }
  46                 else
  47                 {
  48                         if (this.watertype == CONTENT_LAVA)
  49                         {
  50                                 if (this.watersound_finished < time)
  51                                 {
  52                                         this.watersound_finished = time + 0.5;
  53                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  54                                 }
  55                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  56                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  57                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  58                         }
  59                         else if (this.watertype == CONTENT_SLIME)
  60                         {
  61                                 if (this.watersound_finished < time)
  62                                 {
  63                                         this.watersound_finished = time + 0.5;
  64                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  65                                 }
  66                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  67                         }
  68                 }
  69         }
  70 }
  71
  72 void CreatureFrame_Liquids(entity this)
  73 {
  74         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  75         {
  76                 if (!(this.flags & FL_INWATER))
  77                 {
  78                         this.flags |= FL_INWATER;
  79                         this.dmgtime = 0;
  80                 }
  81
  82                 CreatureFrame_hotliquids(this);
  83         }
  84         else
  85         {
  86                 if (this.flags & FL_INWATER)
  87                 {
  88                         // play leave water sound
  89                         this.flags &= ~FL_INWATER;
  90                         this.dmgtime = 0;
  91                 }
  92                 this.air_finished = time + 12;
  93         }
  94 }
  95
  96 void CreatureFrame_FallDamage(entity this)
  97 {
  98         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  99         if(this.velocity || this.oldvelocity) // moving or has moved
 100         {
 101                 // check for falling damage
 102                 float velocity_len = vlen(this.velocity);
 103                 bool have_hook = false;
 104                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 105             {
 106                 .entity weaponentity = weaponentities[slot];
 107                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 108                 {
 109                         have_hook = true;
 110                         break;
 111                 }
 112             }
 113                 if(!have_hook)
 114                 {
 115                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 116                         if (IS_DEAD(this))
 117                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 118                         else
 119                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 120                         if (dm > 0)
 121                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 122                 }
 123
 124                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 125                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 126         }
 127 }
 128
 129 void CreatureFrame_All()
 130 {
 131         if(game_stopped || time < game_starttime)
 132                 return;
 133
 134         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 135         {
 136                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 137                 CreatureFrame_Liquids(it);
 138                 CreatureFrame_FallDamage(it);
 139                 it.oldvelocity = it.velocity;
 140         });
 141 }
 142
 143 void Pause_TryPause(bool ispaused)
 144 {
 145         int n = 0;
 146         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 147                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 148                 ++n;
 149         });
 150         if (!n) return;
 151         setpause(ispaused);
 152 }
 153
 154 void SV_PausedTic(float elapsedtime)
 155 {
 156         if (!server_is_dedicated) Pause_TryPause(false);
 157 }
 158
 159 /*
 160 =============
 161 StartFrame
 162
 163 Called before each frame by the server
 164 =============
 165 */
 166
 167 bool game_delay_last;
 168
 169 bool autocvar_sv_autopause = false;
 170 float RedirectionThink();
 171 void systems_update();
 172 void sys_phys_update(entity this, float dt);
 173 void StartFrame()
 174 {
 175     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 176     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 177     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 178
 179         execute_next_frame();
 180         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 181
 182         delete_fn = remove_unsafely; // not during spawning!
 183         serverprevtime = servertime;
 184         servertime = time;
 185         serverframetime = frametime;
 186
 187 #ifdef PROFILING
 188         if(time > client_cefc_accumulatortime + 1)
 189         {
 190                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 191                 int c_seeing = 0;
 192                 int c_seen = 0;
 193                 FOREACH_CLIENT(true, {
 194                         if(IS_REAL_CLIENT(it))
 195                                 ++c_seeing;
 196                         if(IS_PLAYER(it))
 197                                 ++c_seen;
 198                 });
 199                 LOG_INFO(
 200                     "CEFC time: ", ftos(t * 1000), "ms; ",
 201             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 202             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 203         );
 204                 client_cefc_accumulatortime = time;
 205                 client_cefc_accumulator = 0;
 206         }
 207 #endif
 208
 209         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 210
 211         if (RedirectionThink()) return;
 212
 213         UncustomizeEntitiesRun();
 214         InitializeEntitiesRun();
 215
 216         WarpZone_StartFrame();
 217
 218         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 219         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 220
 221         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 222                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 223
 224         // detect when the pre-game countdown (if any) has ended and the game has started
 225         bool game_delay = (time < game_starttime);
 226         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 227                 GameLogEcho(":startdelay_ended");
 228         game_delay_last = game_delay;
 229
 230         CreatureFrame_All();
 231         CheckRules_World();
 232
 233         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 234                 ReadyRestart();
 235                 return;
 236         }
 237
 238         bot_serverframe();
 239         anticheat_startframe();
 240         MUTATOR_CALLHOOK(SV_StartFrame);
 241
 242     FOREACH_CLIENT(true, GlobalStats_update(it));
 243     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 244 }
 245
 246 .vector originjitter;
 247 .vector anglesjitter;
 248 .float anglejitter;
 249 .string gametypefilter;
 250 .string cvarfilter;
 251 bool DoesQ3ARemoveThisEntity(entity this);
 252
 253 /**
 254  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 255  * +: all must match. this is the default
 256  * -: one must NOT match
 257  *
 258  * var>x
 259  * var<x
 260  * var>=x
 261  * var<=x
 262  * var==x
 263  * var!=x
 264  * var===x
 265  * var!==x
 266  */
 267 bool expr_evaluate(string s)
 268 {
 269     bool ret = false;
 270     if (str2chr(s, 0) == '+') {
 271         s = substring(s, 1, -1);
 272     } else if (str2chr(s, 0) == '-') {
 273         ret = true;
 274         s = substring(s, 1, -1);
 275     }
 276     bool expr_fail = false;
 277     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 278         int o;
 279         string k, v;
 280         s = argv(i);
 281         #define X(expr) \
 282             if (expr) { \
 283                 continue; \
 284             } else { \
 285                 expr_fail = true; \
 286                 break; \
 287             }
 288         #define BINOP(op, len, expr) \
 289             if ((o = strstrofs(s, op, 0)) >= 0) { \
 290                 k = substring(s, 0, o); \
 291                 v = substring(s, o + len, -1); \
 292                 X(expr); \
 293             }
 294         BINOP(">=", 2, cvar(k) >= stof(v));
 295         BINOP("<=", 2, cvar(k) <= stof(v));
 296         BINOP(">",  1, cvar(k) >  stof(v));
 297         BINOP("<",  1, cvar(k) <  stof(v));
 298         BINOP("==", 2, cvar(k) == stof(v));
 299         BINOP("!=", 2, cvar(k) != stof(v));
 300         BINOP("===", 3, cvar_string(k) == v);
 301         BINOP("!==", 3, cvar_string(k) != v);
 302         {
 303             k = s;
 304             bool b = true;
 305             if (str2chr(k, 0) == '!') {
 306                 k = substring(s, 1, -1);
 307                 b = false;
 308             }
 309             float f = stof(k);
 310             bool isnum = ftos(f) == k;
 311             X(boolean(isnum ? f : cvar(k)) == b);
 312         }
 313         #undef BINOP
 314         #undef X
 315     }
 316     if (!expr_fail) {
 317         ret = !ret;
 318     }
 319     // now ret is true if we want to keep the item, and false if we want to get rid of it
 320     return ret;
 321 }
 322
 323 void SV_OnEntityPreSpawnFunction(entity this)
 324 {
 325         if (this)
 326         if (this.gametypefilter != "")
 327         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 328         {
 329                 goto cleanup;
 330         }
 331         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 332         goto cleanup;
 333         }
 334
 335         if (DoesQ3ARemoveThisEntity(this)) {
 336                 goto cleanup;
 337         }
 338
 339         set_movetype(this, this.movetype);
 340
 341         if (this.monster_attack) {
 342                 IL_PUSH(g_monster_targets, this);
 343     }
 344
 345         // support special -1 and -2 angle from radiant
 346         if (this.angles == '0 -1 0') {
 347                 this.angles = '-90 0 0';
 348         } else if (this.angles == '0 -2 0') {
 349                 this.angles = '+90 0 0';
 350     }
 351
 352     #define X(out, in) MACRO_BEGIN \
 353         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 354     MACRO_END
 355     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 356     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 357     X(this.angles.y, this.anglejitter);
 358     #undef X
 359
 360         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 361                 goto cleanup;
 362         }
 363         return;
 364 LABEL(cleanup)
 365     delete(this);
 366 }
 367
 368 void WarpZone_PostInitialize_Callback()
 369 {
 370         // create waypoint links for warpzones
 371         entity tracetest_ent = spawn();
 372         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 373         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 374         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 375         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 376         {
 377                 vector src, dst;
 378                 src = (e.absmin + e.absmax) * 0.5;
 379                 makevectors(e.warpzone_angles);
 380                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 381                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 382                 makevectors(e.enemy.warpzone_angles);
 383                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 384                 waypoint_spawnforteleporter_wz(e, src, dst, 0, -v_up, tracetest_ent);
 385         }
 386         delete(tracetest_ent);
 387 }
 388
 389 /*
 390 ==================
 391 main
 392
 393 unused but required by the engine
 394 ==================
 395 */
 396 void main ()
 397 {
 398
 399 }