qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/_mod.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include <common/weapons/_all.qh>
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91         }
  92 }
  93
  94 void CreatureFrame_FallDamage(entity this)
  95 {
  96         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  97         if(this.velocity || this.oldvelocity) // moving or has moved
  98         {
  99                 // check for falling damage
 100                 float velocity_len = vlen(this.velocity);
 101                 bool have_hook = false;
 102                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 103             {
 104                 .entity weaponentity = weaponentities[slot];
 105                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 106                 {
 107                         have_hook = true;
 108                         break;
 109                 }
 110             }
 111                 if(!have_hook)
 112                 {
 113                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 114                         if (IS_DEAD(this))
 115                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 116                         else
 117                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 118                         if (dm > 0)
 119                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 120                 }
 121
 122                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 123                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 124         }
 125 }
 126
 127 void CreatureFrame_All()
 128 {
 129         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 130         {
 131                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 132                 CreatureFrame_Liquids(it);
 133                 CreatureFrame_FallDamage(it);
 134                 it.oldvelocity = it.velocity;
 135         });
 136 }
 137
 138 void Pause_TryPause(bool ispaused)
 139 {
 140         int n = 0;
 141         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 142                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 143                 ++n;
 144         });
 145         if (!n) return;
 146         setpause(ispaused);
 147 }
 148
 149 void SV_PausedTic(float elapsedtime)
 150 {
 151         if (!server_is_dedicated) Pause_TryPause(false);
 152 }
 153
 154 /*
 155 =============
 156 StartFrame
 157
 158 Called before each frame by the server
 159 =============
 160 */
 161
 162 bool game_delay_last;
 163
 164 bool autocvar_sv_autopause = false;
 165 float RedirectionThink();
 166 void systems_update();
 167 void sys_phys_update(entity this, float dt);
 168 void StartFrame()
 169 {
 170     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 171     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 172     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 173
 174         execute_next_frame();
 175         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 176
 177         delete_fn = remove_unsafely; // not during spawning!
 178         serverprevtime = servertime;
 179         servertime = time;
 180         serverframetime = frametime;
 181
 182 #ifdef PROFILING
 183         if(time > client_cefc_accumulatortime + 1)
 184         {
 185                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 186                 int c_seeing = 0;
 187                 int c_seen = 0;
 188                 FOREACH_CLIENT(true, {
 189                         if(IS_REAL_CLIENT(it))
 190                                 ++c_seeing;
 191                         if(IS_PLAYER(it))
 192                                 ++c_seen;
 193                 });
 194                 LOG_INFO(
 195                     "CEFC time: ", ftos(t * 1000), "ms; ",
 196             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 197             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 198         );
 199                 client_cefc_accumulatortime = time;
 200                 client_cefc_accumulator = 0;
 201         }
 202 #endif
 203
 204         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 205
 206         if (RedirectionThink()) return;
 207
 208         UncustomizeEntitiesRun();
 209         InitializeEntitiesRun();
 210
 211         WarpZone_StartFrame();
 212
 213         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 214         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 215
 216         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 217                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 218
 219         skill = autocvar_skill;
 220
 221         // detect when the pre-game countdown (if any) has ended and the game has started
 222         bool game_delay = (time < game_starttime);
 223         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 224                 GameLogEcho(":startdelay_ended");
 225         game_delay_last = game_delay;
 226
 227         CreatureFrame_All();
 228         CheckRules_World();
 229
 230         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 231                 ReadyRestart();
 232                 return;
 233         }
 234
 235         bot_serverframe();
 236         anticheat_startframe();
 237         MUTATOR_CALLHOOK(SV_StartFrame);
 238
 239     FOREACH_CLIENT(true, GlobalStats_update(it));
 240     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 241 }
 242
 243 .vector originjitter;
 244 .vector anglesjitter;
 245 .float anglejitter;
 246 .string gametypefilter;
 247 .string cvarfilter;
 248 bool DoesQ3ARemoveThisEntity(entity this);
 249
 250 /**
 251  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 252  * +: all must match. this is the default
 253  * -: one must NOT match
 254  *
 255  * var>x
 256  * var<x
 257  * var>=x
 258  * var<=x
 259  * var==x
 260  * var!=x
 261  * var===x
 262  * var!==x
 263  */
 264 bool expr_evaluate(string s)
 265 {
 266     bool ret = false;
 267     if (str2chr(s, 0) == '+') {
 268         s = substring(s, 1, -1);
 269     } else if (str2chr(s, 0) == '-') {
 270         ret = true;
 271         s = substring(s, 1, -1);
 272     }
 273     bool expr_fail = false;
 274     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 275         int o;
 276         string k, v;
 277         s = argv(i);
 278         #define X(expr) \
 279             if (expr) { \
 280                 continue; \
 281             } else { \
 282                 expr_fail = true; \
 283                 break; \
 284             }
 285         #define BINOP(op, len, expr) \
 286             if ((o = strstrofs(s, op, 0)) >= 0) { \
 287                 k = substring(s, 0, o); \
 288                 v = substring(s, o + len, -1); \
 289                 X(expr); \
 290             }
 291         BINOP(">=", 2, cvar(k) >= stof(v));
 292         BINOP("<=", 2, cvar(k) <= stof(v));
 293         BINOP(">",  1, cvar(k) >  stof(v));
 294         BINOP("<",  1, cvar(k) <  stof(v));
 295         BINOP("==", 2, cvar(k) == stof(v));
 296         BINOP("!=", 2, cvar(k) != stof(v));
 297         BINOP("===", 3, cvar_string(k) == v);
 298         BINOP("!==", 3, cvar_string(k) != v);
 299         {
 300             k = s;
 301             bool b = true;
 302             if (str2chr(k, 0) == '!') {
 303                 k = substring(s, 1, -1);
 304                 b = false;
 305             }
 306             float f = stof(k);
 307             bool isnum = ftos(f) == k;
 308             X(boolean(isnum ? f : cvar(k)) == b);
 309         }
 310         #undef BINOP
 311         #undef X
 312     }
 313     if (!expr_fail) {
 314         ret = !ret;
 315     }
 316     // now ret is true if we want to keep the item, and false if we want to get rid of it
 317     return ret;
 318 }
 319
 320 void SV_OnEntityPreSpawnFunction(entity this)
 321 {
 322         if (this)
 323         if (this.gametypefilter != "")
 324         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 325         {
 326                 goto cleanup;
 327         }
 328         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 329         goto cleanup;
 330         }
 331
 332         if (DoesQ3ARemoveThisEntity(this)) {
 333                 goto cleanup;
 334         }
 335
 336         set_movetype(this, this.movetype);
 337
 338         if (this.monster_attack) {
 339                 IL_PUSH(g_monster_targets, this);
 340     }
 341
 342         // support special -1 and -2 angle from radiant
 343         if (this.angles == '0 -1 0') {
 344                 this.angles = '-90 0 0';
 345         } else if (this.angles == '0 -2 0') {
 346                 this.angles = '+90 0 0';
 347     }
 348
 349     #define X(out, in) MACRO_BEGIN \
 350         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 351     MACRO_END
 352     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 353     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 354     X(this.angles.y, this.anglejitter);
 355     #undef X
 356
 357         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 358                 goto cleanup;
 359         }
 360         return;
 361 LABEL(cleanup)
 362     builtin_remove(this);
 363 }
 364
 365 void WarpZone_PostInitialize_Callback()
 366 {
 367         // create waypoint links for warpzones
 368         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 369         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 370         {
 371                 vector src, dst;
 372                 src = (e.absmin + e.absmax) * 0.5;
 373                 makevectors(e.warpzone_angles);
 374                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 375                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 376                 makevectors(e.enemy.warpzone_angles);
 377                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 378                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 379         }
 380 }