qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/_mod.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include <common/weapons/_all.qh>
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91         }
  92 }
  93
  94 void CreatureFrame_FallDamage(entity this)
  95 {
  96         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  97         if(this.velocity || this.oldvelocity) // moving or has moved
  98         {
  99                 // check for falling damage
 100                 float velocity_len = vlen(this.velocity);
 101                 bool have_hook = false;
 102                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 103             {
 104                 .entity weaponentity = weaponentities[slot];
 105                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 106                 {
 107                         have_hook = true;
 108                         break;
 109                 }
 110             }
 111                 if(!have_hook)
 112                 {
 113                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 114                         if (IS_DEAD(this))
 115                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 116                         else
 117                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 118                         if (dm > 0)
 119                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 120                 }
 121
 122                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 123                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 124         }
 125 }
 126
 127 void CreatureFrame_All()
 128 {
 129         if(game_stopped || time < game_starttime)
 130                 return;
 131
 132         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 133         {
 134                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 135                 CreatureFrame_Liquids(it);
 136                 CreatureFrame_FallDamage(it);
 137                 it.oldvelocity = it.velocity;
 138         });
 139 }
 140
 141 void Pause_TryPause(bool ispaused)
 142 {
 143         int n = 0;
 144         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 145                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 146                 ++n;
 147         });
 148         if (!n) return;
 149         setpause(ispaused);
 150 }
 151
 152 void SV_PausedTic(float elapsedtime)
 153 {
 154         if (!server_is_dedicated) Pause_TryPause(false);
 155 }
 156
 157 /*
 158 =============
 159 StartFrame
 160
 161 Called before each frame by the server
 162 =============
 163 */
 164
 165 bool game_delay_last;
 166
 167 bool autocvar_sv_autopause = false;
 168 float RedirectionThink();
 169 void systems_update();
 170 void sys_phys_update(entity this, float dt);
 171 void StartFrame()
 172 {
 173     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 174     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 175     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 176
 177         execute_next_frame();
 178         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 179
 180         delete_fn = remove_unsafely; // not during spawning!
 181         serverprevtime = servertime;
 182         servertime = time;
 183         serverframetime = frametime;
 184
 185 #ifdef PROFILING
 186         if(time > client_cefc_accumulatortime + 1)
 187         {
 188                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 189                 int c_seeing = 0;
 190                 int c_seen = 0;
 191                 FOREACH_CLIENT(true, {
 192                         if(IS_REAL_CLIENT(it))
 193                                 ++c_seeing;
 194                         if(IS_PLAYER(it))
 195                                 ++c_seen;
 196                 });
 197                 LOG_INFO(
 198                     "CEFC time: ", ftos(t * 1000), "ms; ",
 199             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 200             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 201         );
 202                 client_cefc_accumulatortime = time;
 203                 client_cefc_accumulator = 0;
 204         }
 205 #endif
 206
 207         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 208
 209         if (RedirectionThink()) return;
 210
 211         UncustomizeEntitiesRun();
 212         InitializeEntitiesRun();
 213
 214         WarpZone_StartFrame();
 215
 216         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 217         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 218
 219         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 220                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 221
 222         // detect when the pre-game countdown (if any) has ended and the game has started
 223         bool game_delay = (time < game_starttime);
 224         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 225                 GameLogEcho(":startdelay_ended");
 226         game_delay_last = game_delay;
 227
 228         CreatureFrame_All();
 229         CheckRules_World();
 230
 231         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 232                 ReadyRestart();
 233                 return;
 234         }
 235
 236         bot_serverframe();
 237         anticheat_startframe();
 238         MUTATOR_CALLHOOK(SV_StartFrame);
 239
 240     FOREACH_CLIENT(true, GlobalStats_update(it));
 241     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 242 }
 243
 244 .vector originjitter;
 245 .vector anglesjitter;
 246 .float anglejitter;
 247 .string gametypefilter;
 248 .string cvarfilter;
 249 bool DoesQ3ARemoveThisEntity(entity this);
 250
 251 /**
 252  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 253  * +: all must match. this is the default
 254  * -: one must NOT match
 255  *
 256  * var>x
 257  * var<x
 258  * var>=x
 259  * var<=x
 260  * var==x
 261  * var!=x
 262  * var===x
 263  * var!==x
 264  */
 265 bool expr_evaluate(string s)
 266 {
 267     bool ret = false;
 268     if (str2chr(s, 0) == '+') {
 269         s = substring(s, 1, -1);
 270     } else if (str2chr(s, 0) == '-') {
 271         ret = true;
 272         s = substring(s, 1, -1);
 273     }
 274     bool expr_fail = false;
 275     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 276         int o;
 277         string k, v;
 278         s = argv(i);
 279         #define X(expr) \
 280             if (expr) { \
 281                 continue; \
 282             } else { \
 283                 expr_fail = true; \
 284                 break; \
 285             }
 286         #define BINOP(op, len, expr) \
 287             if ((o = strstrofs(s, op, 0)) >= 0) { \
 288                 k = substring(s, 0, o); \
 289                 v = substring(s, o + len, -1); \
 290                 X(expr); \
 291             }
 292         BINOP(">=", 2, cvar(k) >= stof(v));
 293         BINOP("<=", 2, cvar(k) <= stof(v));
 294         BINOP(">",  1, cvar(k) >  stof(v));
 295         BINOP("<",  1, cvar(k) <  stof(v));
 296         BINOP("==", 2, cvar(k) == stof(v));
 297         BINOP("!=", 2, cvar(k) != stof(v));
 298         BINOP("===", 3, cvar_string(k) == v);
 299         BINOP("!==", 3, cvar_string(k) != v);
 300         {
 301             k = s;
 302             bool b = true;
 303             if (str2chr(k, 0) == '!') {
 304                 k = substring(s, 1, -1);
 305                 b = false;
 306             }
 307             float f = stof(k);
 308             bool isnum = ftos(f) == k;
 309             X(boolean(isnum ? f : cvar(k)) == b);
 310         }
 311         #undef BINOP
 312         #undef X
 313     }
 314     if (!expr_fail) {
 315         ret = !ret;
 316     }
 317     // now ret is true if we want to keep the item, and false if we want to get rid of it
 318     return ret;
 319 }
 320
 321 void SV_OnEntityPreSpawnFunction(entity this)
 322 {
 323         if (this)
 324         if (this.gametypefilter != "")
 325         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 326         {
 327                 goto cleanup;
 328         }
 329         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 330         goto cleanup;
 331         }
 332
 333         if (DoesQ3ARemoveThisEntity(this)) {
 334                 goto cleanup;
 335         }
 336
 337         set_movetype(this, this.movetype);
 338
 339         if (this.monster_attack) {
 340                 IL_PUSH(g_monster_targets, this);
 341     }
 342
 343         // support special -1 and -2 angle from radiant
 344         if (this.angles == '0 -1 0') {
 345                 this.angles = '-90 0 0';
 346         } else if (this.angles == '0 -2 0') {
 347                 this.angles = '+90 0 0';
 348     }
 349
 350     #define X(out, in) MACRO_BEGIN \
 351         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 352     MACRO_END
 353     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 354     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 355     X(this.angles.y, this.anglejitter);
 356     #undef X
 357
 358         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 359                 goto cleanup;
 360         }
 361         return;
 362 LABEL(cleanup)
 363     builtin_remove(this);
 364 }
 365
 366 void WarpZone_PostInitialize_Callback()
 367 {
 368         // create waypoint links for warpzones
 369         entity tracetest_ent = spawn();
 370         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 371         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 372         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 373         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 374         {
 375                 vector src, dst;
 376                 src = (e.absmin + e.absmax) * 0.5;
 377                 makevectors(e.warpzone_angles);
 378                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 379                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 380                 makevectors(e.enemy.warpzone_angles);
 381                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 382                 waypoint_spawnforteleporter_wz(e, src, dst, 0, -v_up, tracetest_ent);
 383         }
 384         delete(tracetest_ent);
 385 }