qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         if (item.ammo_cells)
 383                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 384                         player.health = 100;
 385                 }
 386
 387                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 388                 {
 389                         pickedup = TRUE;
 390                         player.items |= it;
 391                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 392                 }
 393
 394                 // extralife powerup
 395                 if (item.max_health)
 396                 {
 397                         pickedup = TRUE;
 398                         // sound not available
 399                         // AnnounceTo(player, "_lives");
 400                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 401                         sprint(player, "^3You picked up some extra lives\n");
 402                 }
 403
 404                 // invis powerup
 405                 if (item.strength_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "invisible");
 410                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412
 413                 // speed powerup
 414                 if (item.invincible_finished)
 415                 {
 416                         pickedup = TRUE;
 417                         // sound not available
 418                         // AnnounceTo(player, "speed");
 419                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 420                 }
 421         }
 422         else
 423         {
 424                 // in case the player has autoswitch enabled do the following:
 425                 // if the player is using their best weapon before items are given, they
 426                 // probably want to switch to an even better weapon after items are given
 427                 if (player.autoswitch)
 428                 if (player.switchweapon == w_getbestweapon(player))
 429                         _switchweapon = TRUE;
 430
 431                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 432                         _switchweapon = TRUE;
 433
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 439                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 440                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 441
 442                 if (item.flags & FL_WEAPON)
 443                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && self.pickup_anyway))
 444                 {
 445                         pickedup = TRUE;
 446                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 447                         {
 448                                 e = get_weaponinfo(i);
 449                                 if(it & e.weapons)
 450                                         W_GiveWeapon (player, e.weapon, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         if (_switchweapon)
 487                 if (player.switchweapon != w_getbestweapon(player))
 488                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 489
 490         return 1;
 491 }
 492
 493 void Item_Touch (void)
 494 {
 495         entity e, head;
 496
 497         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 498         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 499         {
 500                 remove(self);
 501                 return;
 502         }
 503         if (other.classname != "player")
 504                 return;
 505         if (other.deadflag)
 506                 return;
 507         if (self.solid != SOLID_TRIGGER)
 508                 return;
 509         if (self.owner == other)
 510                 return;
 511
 512         if (self.classname == "droppedweapon")
 513         {
 514                 self.strength_finished = max(0, self.strength_finished - time);
 515                 self.invincible_finished = max(0, self.invincible_finished - time);
 516                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 517         }
 518
 519         if(!Item_GiveTo(self, other))
 520         {
 521                 if (self.classname == "droppedweapon")
 522                 {
 523                         // undo what we did above
 524                         self.strength_finished += time;
 525                         self.invincible_finished += time;
 526                         self.superweapons_finished += time;
 527                 }
 528                 return;
 529         }
 530
 531         other.last_pickup = time;
 532
 533         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 534         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 535
 536         if (self.classname == "droppedweapon")
 537                 remove (self);
 538         else if not(self.spawnshieldtime)
 539                 return;
 540         else
 541         {
 542                 if(self.team)
 543                 {
 544                         RandomSelection_Init();
 545                         for(head = world; (head = findfloat(head, team, self.team)); )
 546                         {
 547                                 if(head.flags & FL_ITEM)
 548                                 {
 549                                         Item_Show(head, -1);
 550                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 551                                 }
 552                         }
 553                         e = RandomSelection_chosen_ent;
 554                 }
 555                 else
 556                         e = self;
 557                 Item_ScheduleRespawn(e);
 558         }
 559 }
 560
 561 void Item_Reset()
 562 {
 563         Item_Show(self, !self.state);
 564         setorigin (self, self.origin);
 565
 566         if(self.classname != "droppedweapon")
 567         {
 568                 self.think = SUB_Null;
 569                 self.nextthink = 0;
 570
 571                 if((self.flags & FL_POWERUP) | (self.weapons & WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 572                         Item_ScheduleInitialRespawn(self);
 573         }
 574 }
 575
 576 void Item_FindTeam()
 577 {
 578         entity head, e;
 579
 580         if(self.effects & EF_NODRAW)
 581         {
 582                 // marker for item team search
 583                 dprint("Initializing item team ", ftos(self.team), "\n");
 584                 RandomSelection_Init();
 585                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 586                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 587                 e = RandomSelection_chosen_ent;
 588                 e.state = 0;
 589                 Item_Show(e, 1);
 590
 591                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 592                 {
 593                         if(head != e)
 594                         {
 595                                 // make it a non-spawned item
 596                                 Item_Show(head, -1);
 597                                 head.state = 1; // state 1 = initially hidden item
 598                         }
 599                         head.effects &~= EF_NODRAW;
 600                 }
 601
 602                 Item_Reset();
 603         }
 604 }
 605
 606 // Savage: used for item garbage-collection
 607 // TODO: perhaps nice special effect?
 608 void RemoveItem(void)
 609 {
 610         remove(self);
 611 }
 612
 613 // pickup evaluation functions
 614 // these functions decide how desirable an item is to the bots
 615
 616 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 617
 618 float weapon_pickupevalfunc(entity player, entity item)
 619 {
 620         float c, i, j, position;
 621
 622         // See if I have it already
 623         if(player.weapons & item.weapons == item.weapons)
 624         {
 625                 // If I can pick it up
 626                 if(!item.spawnshieldtime)
 627                         c = 0;
 628                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 629                 {
 630                         // Skilled bots will grab more
 631                         c = bound(0, skill / 10, 1) * 0.5;
 632                 }
 633                 else
 634                         c = 0;
 635         }
 636         else
 637                 c = 1;
 638
 639         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 640         if( bot_custom_weapon && c )
 641         {
 642                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 643                 {
 644                         // Find weapon
 645                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 646                                 continue;
 647
 648                         // Find the highest position on any range
 649                         position = -1;
 650                         for(j = 0; j < WEP_LAST ; ++j){
 651                                 if(
 652                                                 bot_weapons_far[j] == i ||
 653                                                 bot_weapons_mid[j] == i ||
 654                                                 bot_weapons_close[j] == i
 655                                   )
 656                                 {
 657                                         position = j;
 658                                         break;
 659                                 }
 660                         }
 661
 662                         // Rate it
 663                         if (position >= 0 )
 664                         {
 665                                 position = WEP_LAST - position;
 666                                 // item.bot_pickupbasevalue is overwritten here
 667                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 668                         }
 669                 }
 670         }
 671
 672         return item.bot_pickupbasevalue * c;
 673 }
 674
 675 float commodity_pickupevalfunc(entity player, entity item)
 676 {
 677         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 678         entity wi;
 679         c = 0;
 680
 681         // Detect needed ammo
 682         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 683         {
 684                 wi = get_weaponinfo(i);
 685
 686                 if not(wi.weapons & player.weapons)
 687                         continue;
 688
 689                 if(wi.items & IT_SHELLS)
 690                         need_shells = TRUE;
 691                 else if(wi.items & IT_NAILS)
 692                         need_nails = TRUE;
 693                 else if(wi.items & IT_ROCKETS)
 694                         need_rockets = TRUE;
 695                 else if(wi.items & IT_CELLS)
 696                         need_cells = TRUE;
 697                 else if(wi.items & IT_FUEL)
 698                         need_cells = TRUE;
 699         }
 700
 701         // TODO: figure out if the player even has the weapon this ammo is for?
 702         // may not affect strategy much though...
 703         // find out how much more ammo/armor/health the player can hold
 704         if (need_shells)
 705         if (item.ammo_shells)
 706         if (player.ammo_shells < g_pickup_shells_max)
 707                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 708         if (need_nails)
 709         if (item.ammo_nails)
 710         if (player.ammo_nails < g_pickup_nails_max)
 711                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 712         if (need_rockets)
 713         if (item.ammo_rockets)
 714         if (player.ammo_rockets < g_pickup_rockets_max)
 715                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 716         if (need_cells)
 717         if (item.ammo_cells)
 718         if (player.ammo_cells < g_pickup_cells_max)
 719                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 720         if (need_fuel)
 721         if (item.ammo_fuel)
 722         if (player.ammo_fuel < g_pickup_fuel_max)
 723                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 724         if (item.armorvalue)
 725         if (player.armorvalue < item.max_armorvalue)
 726                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 727         if (item.health)
 728         if (player.health < item.max_health)
 729                 c = c + max(0, 1 - player.health / item.max_health);
 730
 731         return item.bot_pickupbasevalue * c;
 732 }
 733
 734
 735 .float is_item;
 736 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 737 {
 738         startitem_failed = FALSE;
 739
 740         self.items = itemid;
 741         self.weapons = weaponid;
 742         self.flags = FL_ITEM | itemflags;
 743
 744         // is it a dropped weapon?
 745         if (self.classname == "droppedweapon")
 746         {
 747                 self.reset = SUB_Remove;
 748                 // it's a dropped weapon
 749                 self.movetype = MOVETYPE_TOSS;
 750
 751                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 752                 self.think = RemoveItem;
 753                 self.nextthink = time + 20;
 754
 755                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 756                 /*
 757                 if(self.items == 0)
 758                 if(self.weapons == (self.weapons & WEPBIT_SUPERWEAPONS)) // only superweapons
 759                 if(self.ammo_nails == 0)
 760                 if(self.ammo_cells == 0)
 761                 if(self.ammo_rockets == 0)
 762                 if(self.ammo_shells == 0)
 763                 if(self.ammo_fuel == 0)
 764                 if(self.health == 0)
 765                 if(self.armorvalue == 0)
 766                 */
 767                 {
 768                         // if item is worthless after a timer, have it expire then
 769                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 770                 }
 771
 772                 // don't drop if in a NODROP zone (such as lava)
 773                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 774                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 775                 {
 776                         startitem_failed = TRUE;
 777                         remove(self);
 778                         return;
 779                 }
 780         }
 781         else
 782         {
 783                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 784                 {
 785                         startitem_failed = TRUE;
 786                         remove(self);
 787                         return;
 788                 }
 789
 790                 if(!have_pickup_item())
 791                 {
 792                         startitem_failed = TRUE;
 793                         remove (self);
 794                         return;
 795                 }
 796
 797                 if(self.model != "")
 798                         itemmodel = self.model;
 799                 if(self.item_pickupsound != "")
 800                         pickupsound = self.item_pickupsound;
 801
 802                 self.reset = Item_Reset;
 803                 // it's a level item
 804                 if(self.spawnflags & 1)
 805                         self.noalign = 1;
 806                 if (self.noalign)
 807                         self.movetype = MOVETYPE_NONE;
 808                 else
 809                         self.movetype = MOVETYPE_TOSS;
 810                 // do item filtering according to game mode and other things
 811                 if (!self.noalign)
 812                 {
 813                         // first nudge it off the floor a little bit to avoid math errors
 814                         setorigin(self, self.origin + '0 0 1');
 815                         // set item size before we spawn a spawnfunc_waypoint
 816                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 817                                 setsize (self, '-16 -16 0', '16 16 48');
 818                         else
 819                                 setsize (self, '-16 -16 0', '16 16 32');
 820                         // note droptofloor returns FALSE if stuck/or would fall too far
 821                         droptofloor();
 822                         waypoint_spawnforitem(self);
 823                 }
 824
 825                 /*
 826                  * can't do it that way, as it would break maps
 827                  * TODO make a target_give like entity another way, that perhaps has
 828                  * the weapon name in a key
 829                 if(self.targetname)
 830                 {
 831                         // target_give not yet supported; maybe later
 832                         print("removed targeted ", self.classname, "\n");
 833                         startitem_failed = TRUE;
 834                         remove (self);
 835                         return;
 836                 }
 837                 */
 838
 839                 if(autocvar_spawn_debug >= 2)
 840                 {
 841                         entity otheritem;
 842                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 843                         {
 844                                 if(otheritem.is_item)
 845                                 {
 846                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 847                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 848                                         error("Mapper sucks.");
 849                                 }
 850                         }
 851                         self.is_item = TRUE;
 852                 }
 853
 854                 weaponsInMap |= weaponid;
 855
 856                 precache_model (itemmodel);
 857                 precache_sound (pickupsound);
 858
 859                 precache_sound ("misc/itemrespawncountdown.wav");
 860                 if(!g_minstagib && itemid == IT_STRENGTH)
 861                         precache_sound ("misc/strength_respawn.wav");
 862                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 863                         precache_sound ("misc/shield_respawn.wav");
 864                 else
 865                         precache_sound ("misc/itemrespawn.wav");
 866
 867                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 868                         self.target = "###item###"; // for finding the nearest item using find()
 869         }
 870
 871         self.bot_pickup = TRUE;
 872         self.bot_pickupevalfunc = pickupevalfunc;
 873         self.bot_pickupbasevalue = pickupbasevalue;
 874         self.mdl = itemmodel;
 875         self.item_pickupsound = pickupsound;
 876         if(self.weapons)
 877                 self.weapon = WEP_FIRST + log2of(lowestbit(self.weapons));
 878         else
 879                 self.weapon = 0;
 880         // let mappers override respawntime
 881         if(!self.respawntime) // both set
 882         {
 883                 self.respawntime = defaultrespawntime;
 884                 self.respawntimejitter = defaultrespawntimejitter;
 885         }
 886         self.netname = itemname;
 887         self.touch = Item_Touch;
 888         setmodel (self, self.mdl); // precision set below
 889         self.effects |= EF_LOWPRECISION;
 890         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 891                 setsize (self, '-16 -16 0', '16 16 48');
 892         else
 893                 setsize (self, '-16 -16 0', '16 16 32');
 894         if(itemflags & FL_WEAPON)
 895                 self.modelflags |= MF_ROTATE;
 896
 897         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 898         if (itemflags & FL_WEAPON)
 899         {
 900                 // neutral team color for pickup weapons
 901                 self.colormap = 1024; // color shirt=0 pants=0 grey
 902         }
 903
 904         self.state = 0;
 905         if(self.team)
 906         {
 907                 if(!self.cnt)
 908                         self.cnt = 1; // item probability weight
 909                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 910                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 911         }
 912         else
 913                 Item_Reset();
 914 }
 915
 916 /* replace items in minstagib
 917  * IT_STRENGTH   = invisibility
 918  * IT_NAILS      = extra lives
 919  * IT_INVINCIBLE = speed
 920  */
 921 void minstagib_items (float itemid)
 922 {
 923         float rnd;
 924         self.classname = "minstagib";
 925
 926         // replace rocket launchers and nex guns with ammo cells
 927         if (itemid == IT_CELLS)
 928         {
 929                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 930                 StartItem ("models/items/a_cells.md3",
 931                         "misc/itempickup.wav", 45, 0,
 932                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 933                 return;
 934         }
 935
 936         // randomize
 937         rnd = random() * 3;
 938         if (rnd <= 1)
 939                 itemid = IT_STRENGTH;
 940         else if (rnd <= 2)
 941                 itemid = IT_NAILS;
 942         else
 943                 itemid = IT_INVINCIBLE;
 944
 945         // replace with invis
 946         if (itemid == IT_STRENGTH)
 947         {
 948                 if(!self.strength_finished)
 949                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 950                 StartItem ("models/items/g_strength.md3",
 951                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 952                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 953         }
 954         // replace with extra lives
 955         if (itemid == IT_NAILS)
 956         {
 957                 self.max_health = 1;
 958                 StartItem ("models/items/g_h100.md3",
 959                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 960                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 961         }
 962         // replace with speed
 963         if (itemid == IT_INVINCIBLE)
 964         {
 965                 if(!self.invincible_finished)
 966                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 967                 StartItem ("models/items/g_invincible.md3",
 968                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 969                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 970         }
 971 }
 972
 973 float minst_no_auto_cells;
 974 void minst_remove_item (void) {
 975         if(minst_no_auto_cells)
 976                 remove(self);
 977 }
 978
 979 float weaponswapping;
 980 float internalteam;
 981
 982 void weapon_defaultspawnfunc(float wpn)
 983 {
 984         entity e;
 985         float t;
 986         var .float ammofield;
 987         string s;
 988         entity oldself;
 989         float i, j;
 990         float f;
 991
 992         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 993         {
 994                 e = get_weaponinfo(wpn);
 995                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 996                 if(s == "0")
 997                 {
 998                         remove(self);
 999                         startitem_failed = TRUE;
1000                         return;
1001                 }
1002                 t = tokenize_console(s);
1003                 if(t >= 2)
1004                 {
1005                         self.team = --internalteam;
1006                         oldself = self;
1007                         for(i = 1; i < t; ++i)
1008                         {
1009                                 s = argv(i);
1010                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1011                                 {
1012                                         e = get_weaponinfo(j);
1013                                         if(e.netname == s)
1014                                         {
1015                                                 self = spawn();
1016                                                 copyentity(oldself, self);
1017                                                 self.classname = "replacedweapon";
1018                                                 weapon_defaultspawnfunc(j);
1019                                                 break;
1020                                         }
1021                                 }
1022                                 if(j > WEP_LAST)
1023                                 {
1024                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1025                                 }
1026                         }
1027                         self = oldself;
1028                 }
1029                 if(t >= 1)
1030                 {
1031                         s = argv(0);
1032                         wpn = 0;
1033                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1034                         {
1035                                 e = get_weaponinfo(j);
1036                                 if(e.netname == s)
1037                                 {
1038                                         wpn = j;
1039                                         break;
1040                                 }
1041                         }
1042                         if(j > WEP_LAST)
1043                         {
1044                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1045                         }
1046                 }
1047                 if(wpn == 0)
1048                 {
1049                         remove(self);
1050                         startitem_failed = TRUE;
1051                         return;
1052                 }
1053         }
1054
1055         e = get_weaponinfo(wpn);
1056
1057         if(!self.respawntime)
1058         {
1059                 if(e.weapons & WEPBIT_SUPERWEAPONS)
1060                 {
1061                         self.respawntime = g_pickup_respawntime_superweapon;
1062                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1063                 }
1064                 else
1065                 {
1066                         self.respawntime = g_pickup_respawntime_weapon;
1067                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1068                 }
1069         }
1070
1071         if(e.weapons & WEPBIT_SUPERWEAPONS)
1072                 if(!self.superweapons_finished)
1073                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1074
1075         if(e.items)
1076         {
1077                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1078                 {
1079                         if(e.items & j)
1080                         {
1081                                 ammofield = Item_CounterField(j);
1082                                 if(!self.ammofield)
1083                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1084                         }
1085                 }
1086         }
1087
1088         // pickup anyway
1089         if(g_pickup_weapons_anyway)
1090                 self.pickup_anyway = TRUE;
1091
1092         f = FL_WEAPON;
1093
1094         // no weapon-stay on superweapons
1095         if(e.weapons & WEPBIT_SUPERWEAPONS)
1096                 f |= FL_NO_WEAPON_STAY;
1097
1098         // weapon stay isn't supported for teamed weapons
1099         if(self.team)
1100                 f |= FL_NO_WEAPON_STAY;
1101
1102         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1103         if (self.modelindex) // don't precache if self was removed
1104                 weapon_action(e.weapon, WR_PRECACHE);
1105 }
1106
1107 void spawnfunc_weapon_shotgun (void);
1108 void spawnfunc_weapon_uzi (void) {
1109         if(autocvar_sv_q3acompat_machineshotgunswap)
1110         if(self.classname != "droppedweapon")
1111         {
1112                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1113                 return;
1114         }
1115         weapon_defaultspawnfunc(WEP_UZI);
1116 }
1117
1118 void spawnfunc_weapon_shotgun (void) {
1119         if(autocvar_sv_q3acompat_machineshotgunswap)
1120         if(self.classname != "droppedweapon")
1121         {
1122                 weapon_defaultspawnfunc(WEP_UZI);
1123                 return;
1124         }
1125         weapon_defaultspawnfunc(WEP_SHOTGUN);
1126 }
1127
1128 void spawnfunc_weapon_nex (void)
1129 {
1130         if (g_minstagib)
1131         {
1132                 minstagib_items(IT_CELLS);
1133                 self.think = minst_remove_item;
1134                 self.nextthink = time;
1135                 return;
1136         }
1137         weapon_defaultspawnfunc(WEP_NEX);
1138 }
1139
1140 void spawnfunc_weapon_minstanex (void)
1141 {
1142         if (g_minstagib)
1143         {
1144                 minstagib_items(IT_CELLS);
1145                 self.think = minst_remove_item;
1146                 self.nextthink = time;
1147                 return;
1148         }
1149         weapon_defaultspawnfunc(WEP_MINSTANEX);
1150 }
1151
1152 void spawnfunc_weapon_rocketlauncher (void)
1153 {
1154         if (g_minstagib)
1155         {
1156                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1157                 self.think = minst_remove_item;
1158                 self.nextthink = time;
1159                 return;
1160         }
1161         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1162 }
1163
1164 void spawnfunc_item_rockets (void) {
1165         if(!self.ammo_rockets)
1166                 self.ammo_rockets = g_pickup_rockets;
1167         if(!self.pickup_anyway)
1168                 self.pickup_anyway = g_pickup_ammo_anyway;
1169         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1170 }
1171
1172 void spawnfunc_item_shells (void);
1173 void spawnfunc_item_bullets (void) {
1174         if(!weaponswapping)
1175         if(autocvar_sv_q3acompat_machineshotgunswap)
1176         if(self.classname != "droppedweapon")
1177         {
1178                 weaponswapping = TRUE;
1179                 spawnfunc_item_shells();
1180                 weaponswapping = FALSE;
1181                 return;
1182         }
1183
1184         if(!self.ammo_nails)
1185                 self.ammo_nails = g_pickup_nails;
1186         if(!self.pickup_anyway)
1187                 self.pickup_anyway = g_pickup_ammo_anyway;
1188         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1189 }
1190
1191 void spawnfunc_item_cells (void) {
1192         if(!self.ammo_cells)
1193                 self.ammo_cells = g_pickup_cells;
1194         if(!self.pickup_anyway)
1195                 self.pickup_anyway = g_pickup_ammo_anyway;
1196         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1197 }
1198
1199 void spawnfunc_item_shells (void) {
1200         if(!weaponswapping)
1201         if(autocvar_sv_q3acompat_machineshotgunswap)
1202         if(self.classname != "droppedweapon")
1203         {
1204                 weaponswapping = TRUE;
1205                 spawnfunc_item_bullets();
1206                 weaponswapping = FALSE;
1207                 return;
1208         }
1209
1210         if(!self.ammo_shells)
1211                 self.ammo_shells = g_pickup_shells;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_ammo_anyway;
1214         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1215 }
1216
1217 void spawnfunc_item_armor_small (void) {
1218         if(!self.armorvalue)
1219                 self.armorvalue = g_pickup_armorsmall;
1220         if(!self.max_armorvalue)
1221                 self.max_armorvalue = g_pickup_armorsmall_max;
1222         if(!self.pickup_anyway)
1223                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1224         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1225 }
1226
1227 void spawnfunc_item_armor_medium (void) {
1228         if(!self.armorvalue)
1229                 self.armorvalue = g_pickup_armormedium;
1230         if(!self.max_armorvalue)
1231                 self.max_armorvalue = g_pickup_armormedium_max;
1232         if(!self.pickup_anyway)
1233                 self.pickup_anyway = g_pickup_armormedium_anyway;
1234         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1235 }
1236
1237 void spawnfunc_item_armor_big (void) {
1238         if(!self.armorvalue)
1239                 self.armorvalue = g_pickup_armorbig;
1240         if(!self.max_armorvalue)
1241                 self.max_armorvalue = g_pickup_armorbig_max;
1242         if(!self.pickup_anyway)
1243                 self.pickup_anyway = g_pickup_armorbig_anyway;
1244         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1245 }
1246
1247 void spawnfunc_item_armor_large (void) {
1248         if(!self.armorvalue)
1249                 self.armorvalue = g_pickup_armorlarge;
1250         if(!self.max_armorvalue)
1251                 self.max_armorvalue = g_pickup_armorlarge_max;
1252         if(!self.pickup_anyway)
1253                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1254         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1255 }
1256
1257 void spawnfunc_item_health_small (void) {
1258         if(!self.max_health)
1259                 self.max_health = g_pickup_healthsmall_max;
1260         if(!self.health)
1261                 self.health = g_pickup_healthsmall;
1262         if(!self.pickup_anyway)
1263                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1264         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1265 }
1266
1267 void spawnfunc_item_health_medium (void) {
1268         if(!self.max_health)
1269                 self.max_health = g_pickup_healthmedium_max;
1270         if(!self.health)
1271                 self.health = g_pickup_healthmedium;
1272         if(!self.pickup_anyway)
1273                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1274         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1275 }
1276
1277 void spawnfunc_item_health_large (void) {
1278         if(!self.max_health)
1279                 self.max_health = g_pickup_healthlarge_max;
1280         if(!self.health)
1281                 self.health = g_pickup_healthlarge;
1282         if(!self.pickup_anyway)
1283                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1284         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1285 }
1286
1287 void spawnfunc_item_health_mega (void) {
1288         if(g_minstagib) {
1289                 minstagib_items(IT_NAILS);
1290         } else {
1291                 if(!self.max_health)
1292                         self.max_health = g_pickup_healthmega_max;
1293                 if(!self.health)
1294                         self.health = g_pickup_healthmega;
1295                 if(!self.pickup_anyway)
1296                         self.pickup_anyway = g_pickup_healthmega_anyway;
1297                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1298         }
1299 }
1300
1301 // support old misnamed entities
1302 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1303 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1304 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1305 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1306 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1307
1308 void spawnfunc_item_strength (void) {
1309         if(g_minstagib) {
1310                 minstagib_items(IT_STRENGTH);
1311         } else {
1312                 precache_sound("weapons/strength_fire.wav");
1313                 if(!self.strength_finished)
1314                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1315                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1316         }
1317 }
1318
1319 void spawnfunc_item_invincible (void) {
1320         if(g_minstagib) {
1321                 minstagib_items(IT_INVINCIBLE);
1322         } else {
1323                 if(!self.invincible_finished)
1324                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1325                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1326         }
1327 }
1328
1329 void spawnfunc_item_minst_cells (void) {
1330         if (g_minstagib)
1331         {
1332                 minst_no_auto_cells = 1;
1333                 minstagib_items(IT_CELLS);
1334         }
1335         else
1336                 remove(self);
1337 }
1338
1339 // compatibility:
1340 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1341
1342 float GiveItems(entity e, float beginarg, float endarg);
1343 void target_items_use (void)
1344 {
1345         if(activator.classname == "droppedweapon")
1346         {
1347                 EXACTTRIGGER_TOUCH;
1348                 remove(activator);
1349                 return;
1350         }
1351
1352         if(activator.classname != "player")
1353                 return;
1354         if(activator.deadflag != DEAD_NO)
1355                 return;
1356         EXACTTRIGGER_TOUCH;
1357
1358         entity e;
1359         for(e = world; (e = find(e, classname, "droppedweapon")); )
1360                 if(e.enemy == activator)
1361                         remove(e);
1362
1363         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1364                 centerprint(activator, self.message);
1365 }
1366
1367 void spawnfunc_target_items (void)
1368 {
1369         float n, i, j;
1370         entity e;
1371
1372         self.use = target_items_use;
1373         if(!self.strength_finished)
1374                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1375         if(!self.invincible_finished)
1376                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1377         if(!self.superweapons_finished)
1378                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1379
1380         precache_sound("misc/itempickup.wav");
1381         precache_sound("misc/megahealth.wav");
1382         precache_sound("misc/armor25.wav");
1383         precache_sound("misc/powerup.wav");
1384         precache_sound("misc/poweroff.wav");
1385         precache_sound("weapons/weaponpickup.wav");
1386
1387         n = tokenize_console(self.netname);
1388         if(argv(0) == "give")
1389         {
1390                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1391         }
1392         else
1393         {
1394                 for(i = 0; i < n; ++i)
1395                 {
1396                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1397                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1398                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1399                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1400                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1401                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1402                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1403                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1404                         else
1405                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1406                         {
1407                                 e = get_weaponinfo(j);
1408                                 if(argv(i) == e.netname)
1409                                 {
1410                                         self.weapons |= e.weapons;
1411                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1412                                                 weapon_action(e.weapon, WR_PRECACHE);
1413                                         break;
1414                                 }
1415                         }
1416                         if(j > WEP_LAST)
1417                                 print("target_items: invalid item ", argv(i), "\n");
1418                 }
1419
1420                 string itemprefix, valueprefix;
1421                 if(self.spawnflags == 0)
1422                 {
1423                         itemprefix = "";
1424                         valueprefix = "";
1425                 }
1426                 else if(self.spawnflags == 1)
1427                 {
1428                         itemprefix = "max ";
1429                         valueprefix = "max ";
1430                 }
1431                 else if(self.spawnflags == 2)
1432                 {
1433                         itemprefix = "min ";
1434                         valueprefix = "min ";
1435                 }
1436                 else if(self.spawnflags == 4)
1437                 {
1438                         itemprefix = "minus ";
1439                         valueprefix = "max ";
1440                 }
1441                 else
1442                         error("invalid spawnflags");
1443
1444                 self.netname = "";
1445                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1446                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1447                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1448                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1449                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1450                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1451                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1452                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1453                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1454                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1455                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1456                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1457                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1458                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1459                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1460                 {
1461                         e = get_weaponinfo(j);
1462                         if(e.weapons)
1463                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1464                 }
1465         }
1466         self.netname = strzone(self.netname);
1467         //print(self.netname, "\n");
1468
1469         n = tokenize_console(self.netname);
1470         for(i = 0; i < n; ++i)
1471         {
1472                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1473                 {
1474                         e = get_weaponinfo(j);
1475                         if(argv(i) == e.netname)
1476                         {
1477                                 weapon_action(e.weapon, WR_PRECACHE);
1478                                 break;
1479                         }
1480                 }
1481         }
1482 }
1483
1484 void spawnfunc_item_fuel(void)
1485 {
1486         if(!self.ammo_fuel)
1487                 self.ammo_fuel = g_pickup_fuel;
1488         if(!self.pickup_anyway)
1489                 self.pickup_anyway = g_pickup_ammo_anyway;
1490         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1491 }
1492
1493 void spawnfunc_item_fuel_regen(void)
1494 {
1495         if(start_items & IT_FUEL_REGEN)
1496         {
1497                 spawnfunc_item_fuel();
1498                 return;
1499         }
1500         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1501 }
1502
1503 void spawnfunc_item_jetpack(void)
1504 {
1505         if(g_grappling_hook)
1506                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1507         if(!self.ammo_fuel)
1508                 self.ammo_fuel = g_pickup_fuel_jetpack;
1509         if(start_items & IT_JETPACK)
1510         {
1511                 spawnfunc_item_fuel();
1512                 return;
1513         }
1514         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1515 }
1516
1517
1518 #define OP_SET 0
1519 #define OP_MIN 1
1520 #define OP_MAX 2
1521 #define OP_PLUS 3
1522 #define OP_MINUS 4
1523
1524 float GiveBit(entity e, .float fld, float bit, float op, float val)
1525 {
1526         float v0, v1;
1527         v0 = (e.fld & bit);
1528         switch(op)
1529         {
1530                 case OP_SET:
1531                         if(val > 0)
1532                                 e.fld |= bit;
1533                         else
1534                                 e.fld &~= bit;
1535                         break;
1536                 case OP_MIN:
1537                 case OP_PLUS:
1538                         if(val > 0)
1539                                 e.fld |= bit;
1540                         break;
1541                 case OP_MAX:
1542                         if(val <= 0)
1543                                 e.fld &~= bit;
1544                         break;
1545                 case OP_MINUS:
1546                         if(val > 0)
1547                                 e.fld &~= bit;
1548                         break;
1549         }
1550         v1 = (e.fld & bit);
1551         return (v0 != v1);
1552 }
1553
1554 float GiveValue(entity e, .float fld, float op, float val)
1555 {
1556         float v0, v1;
1557         v0 = e.fld;
1558         switch(op)
1559         {
1560                 case OP_SET:
1561                         e.fld = val;
1562                         break;
1563                 case OP_MIN:
1564                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1565                         break;
1566                 case OP_MAX:
1567                         e.fld = min(e.fld, val);
1568                         break;
1569                 case OP_PLUS:
1570                         e.fld += val;
1571                         break;
1572                 case OP_MINUS:
1573                         e.fld -= val;
1574                         break;
1575         }
1576         v1 = e.fld;
1577         return (v0 != v1);
1578 }
1579
1580 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1581 {
1582         if(v1 == v0)
1583                 return;
1584         if(v1 <= v0 - t)
1585         {
1586                 if(snd_decr != "")
1587                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1588         }
1589         else if(v0 >= v0 + t)
1590         {
1591                 if(snd_incr != "")
1592                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1593         }
1594 }
1595
1596 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1597 {
1598         if(v0 < v1)
1599                 e.rotfield = max(e.rotfield, time + rottime);
1600         else if(v0 > v1)
1601                 e.regenfield = max(e.regenfield, time + regentime);
1602 }
1603
1604 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1605 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1606 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1607 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1608
1609 float GiveItems(entity e, float beginarg, float endarg)
1610 {
1611         float got, i, j, val, op;
1612         float _switchweapon;
1613         entity wi;
1614         string cmd;
1615
1616         val = 999;
1617         op = OP_SET;
1618
1619         got = 0;
1620
1621         _switchweapon = FALSE;
1622         if (e.autoswitch)
1623                 if (e.switchweapon == w_getbestweapon(e))
1624                         _switchweapon = TRUE;
1625
1626         e.strength_finished = max(0, e.strength_finished - time);
1627         e.invincible_finished = max(0, e.invincible_finished - time);
1628         e.superweapons_finished = max(0, e.superweapons_finished - time);
1629
1630         PREGIVE(e, items);
1631         PREGIVE(e, weapons);
1632         PREGIVE(e, strength_finished);
1633         PREGIVE(e, invincible_finished);
1634         PREGIVE(e, superweapons_finished);
1635         PREGIVE(e, ammo_nails);
1636         PREGIVE(e, ammo_cells);
1637         PREGIVE(e, ammo_shells);
1638         PREGIVE(e, ammo_rockets);
1639         PREGIVE(e, ammo_fuel);
1640         PREGIVE(e, armorvalue);
1641         PREGIVE(e, health);
1642
1643         for(i = beginarg; i < endarg; ++i)
1644         {
1645                 cmd = argv(i);
1646
1647                 if(cmd == "0" || stof(cmd))
1648                 {
1649                         val = stof(cmd);
1650                         continue;
1651                 }
1652                 switch(cmd)
1653                 {
1654                         case "no":
1655                                 op = OP_MAX;
1656                                 val = 0;
1657                                 continue;
1658                         case "max":
1659                                 op = OP_MAX;
1660                                 continue;
1661                         case "min":
1662                                 op = OP_MIN;
1663                                 continue;
1664                         case "plus":
1665                                 op = OP_PLUS;
1666                                 continue;
1667                         case "minus":
1668                                 op = OP_MINUS;
1669                                 continue;
1670                         case "ALL":
1671                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1672                                 got += GiveValue(e, strength_finished, op, val);
1673                                 got += GiveValue(e, invincible_finished, op, val);
1674                                 got += GiveValue(e, superweapons_finished, op, val);
1675                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1676                         case "all":
1677                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1678                                 got += GiveValue(e, health, op, val);
1679                                 got += GiveValue(e, armorvalue, op, val);
1680                         case "allweapons":
1681                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1682                                 {
1683                                         wi = get_weaponinfo(j);
1684                                         if(wi.weapons)
1685                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1686                                 }
1687                         case "allammo":
1688                                 got += GiveValue(e, ammo_cells, op, val);
1689                                 got += GiveValue(e, ammo_shells, op, val);
1690                                 got += GiveValue(e, ammo_nails, op, val);
1691                                 got += GiveValue(e, ammo_rockets, op, val);
1692                                 got += GiveValue(e, ammo_fuel, op, val);
1693                                 break;
1694                         case "unlimited_ammo":
1695                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1696                                 break;
1697                         case "unlimited_weapon_ammo":
1698                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1699                                 break;
1700                         case "unlimited_superweapons":
1701                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1702                                 break;
1703                         case "jetpack":
1704                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1705                                 break;
1706                         case "fuel_regen":
1707                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1708                                 break;
1709                         case "strength":
1710                                 got += GiveValue(e, strength_finished, op, val);
1711                                 break;
1712                         case "invincible":
1713                                 got += GiveValue(e, invincible_finished, op, val);
1714                                 break;
1715                         case "superweapons":
1716                                 got += GiveValue(e, superweapons_finished, op, val);
1717                                 break;
1718                         case "cells":
1719                                 got += GiveValue(e, ammo_cells, op, val);
1720                                 break;
1721                         case "shells":
1722                                 got += GiveValue(e, ammo_shells, op, val);
1723                                 break;
1724                         case "nails":
1725                         case "bullets":
1726                                 got += GiveValue(e, ammo_nails, op, val);
1727                                 break;
1728                         case "rockets":
1729                                 got += GiveValue(e, ammo_rockets, op, val);
1730                                 break;
1731                         case "health":
1732                                 got += GiveValue(e, health, op, val);
1733                                 break;
1734                         case "armor":
1735                                 got += GiveValue(e, armorvalue, op, val);
1736                                 break;
1737                         case "fuel":
1738                                 got += GiveValue(e, ammo_fuel, op, val);
1739                                 break;
1740                         default:
1741                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1742                                 {
1743                                         wi = get_weaponinfo(j);
1744                                         if(cmd == wi.netname)
1745                                         {
1746                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1747                                                 break;
1748                                         }
1749                                 }
1750                                 if(j > WEP_LAST)
1751                                         print("give: invalid item ", cmd, "\n");
1752                                 break;
1753                 }
1754                 val = 999;
1755                 op = OP_SET;
1756         }
1757
1758         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1759         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1760         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1761         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1762         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1763         {
1764                 wi = get_weaponinfo(j);
1765                 if(wi.weapons)
1766                 {
1767                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1768                         if not(save_weapons & wi.weapons)
1769                                 if(e.weapons & wi.weapons)
1770                                         weapon_action(wi.weapon, WR_PRECACHE);
1771                 }
1772         }
1773         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1774         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1775         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1776         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1777         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1778         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1779         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1780         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1781         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1782
1783         if(e.superweapons_finished <= 0)
1784                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1785                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1786
1787         if (g_minstagib)
1788         {
1789                 e.health = bound(0, e.health, 100);
1790                 e.armorvalue = bound(0, e.armorvalue, 999);
1791         }
1792
1793         if(e.strength_finished <= 0)
1794                 e.strength_finished = 0;
1795         else
1796                 e.strength_finished += time;
1797         if(e.invincible_finished <= 0)
1798                 e.invincible_finished = 0;
1799         else
1800                 e.invincible_finished += time;
1801         if(e.superweapons_finished <= 0)
1802                 e.superweapons_finished = 0;
1803         else
1804                 e.superweapons_finished += time;
1805
1806         if not(e.weapons & W_WeaponBit(e.switchweapon))
1807                 _switchweapon = TRUE;
1808         if(_switchweapon)
1809                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1810
1811         return got;
1812 }