Merge remote branch 'refs/remotes/origin/fruitiex/racefixes'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / t_items.qc
1 #define ITEM_RESPAWN_TICKS 10
2
3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
6         // range: 10 .. respawntime + respawntimejitter
7
8 floatfield Item_CounterField(float it)
9 {
10         switch(it)
11         {
12                 case IT_SHELLS:      return ammo_shells;
13                 case IT_NAILS:       return ammo_nails;
14                 case IT_ROCKETS:     return ammo_rockets;
15                 case IT_CELLS:       return ammo_cells;
16                 case IT_FUEL:        return ammo_fuel;
17                 case IT_5HP:         return health;
18                 case IT_25HP:        return health;
19                 case IT_HEALTH:      return health;
20                 case IT_ARMOR_SHARD: return armorvalue;
21                 case IT_ARMOR:       return armorvalue;
22                 // add more things here (health, armor)
23                 default:             error("requested item has no counter field");
24         }
25 }
26
27 string Item_CounterFieldName(float it)
28 {
29         switch(it)
30         {
31                 case IT_SHELLS:      return "shells";
32                 case IT_NAILS:       return "nails";
33                 case IT_ROCKETS:     return "rockets";
34                 case IT_CELLS:       return "cells";
35                 case IT_FUEL:        return "fuel";
36
37                 // add more things here (health, armor)
38                 default:             error("requested item has no counter field name");
39         }
40 }
41
42 .float max_armorvalue;
43 .float pickup_anyway;
44
45 float Item_Customize()
46 {
47         if(self.spawnshieldtime)
48                 return TRUE;
49         if(self.weapons != (self.weapons & other.weapons))
50         {
51                 self.colormod = '0 0 0';
52                 self.glowmod = self.colormod;
53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
54                 return TRUE;
55         }
56         else
57         {
58                 if(g_ghost_items)
59                 {
60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
61                         self.glowmod = self.colormod;
62                         self.alpha = g_ghost_items;
63                         return TRUE;
64                 }
65                 else
66                         return FALSE;
67         }
68 }
69
70 void Item_Show (entity e, float mode)
71 {
72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
73         if (mode > 0)
74         {
75                 // make the item look normal, and be touchable
76                 e.model = e.mdl;
77                 e.solid = SOLID_TRIGGER;
78                 e.colormod = '0 0 0';
79                 self.glowmod = self.colormod;
80                 e.alpha = 0;
81                 e.customizeentityforclient = func_null;
82
83                 e.spawnshieldtime = 1;
84         }
85         else if (mode < 0)
86         {
87                 // hide the item completely
88                 e.model = string_null;
89                 e.solid = SOLID_NOT;
90                 e.colormod = '0 0 0';
91                 self.glowmod = self.colormod;
92                 e.alpha = 0;
93                 e.customizeentityforclient = func_null;
94
95                 e.spawnshieldtime = 1;
96         }
97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
98         {
99                 // make the item translucent green and not touchable
100                 e.model = e.mdl;
101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
102                 e.colormod = '0 0 0';
103                 self.glowmod = self.colormod;
104                 e.effects |= EF_STARDUST;
105                 e.customizeentityforclient = Item_Customize;
106
107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
108         }
109         else if(g_ghost_items)
110         {
111                 // make the item translucent green and not touchable
112                 e.model = e.mdl;
113                 e.solid = SOLID_NOT;
114                 e.colormod = stov(cvar_string("g_ghost_items_color"));
115                 e.glowmod = e.colormod;
116                 e.alpha = g_ghost_items;
117                 e.customizeentityforclient = func_null;
118
119                 e.spawnshieldtime = 1;
120         }
121         else
122         {
123                 // hide the item completely
124                 e.model = string_null;
125                 e.solid = SOLID_NOT;
126                 e.colormod = stov(cvar_string("g_ghost_items_color"));
127                 e.glowmod = e.colormod;
128                 e.alpha = 0;
129                 e.customizeentityforclient = func_null;
130
131                 e.spawnshieldtime = 1;
132         }
133
134         if (e.strength_finished || e.invincible_finished)
135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
136         if (cvar("g_nodepthtestitems"))
137                 e.effects |= EF_NODEPTHTEST;
138         if (cvar("g_fullbrightitems"))
139                 e.effects |= EF_FULLBRIGHT;
140
141         // relink entity (because solid may have changed)
142         setorigin(e, e.origin);
143 }
144
145 void Item_Respawn (void)
146 {
147         Item_Show(self, 1);
148         if(!g_minstagib && self.items == IT_STRENGTH)
149                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
151                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
152         else
153                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
154         setorigin (self, self.origin);
155
156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
158 }
159
160 void Item_RespawnCountdown (void)
161 {
162         if(self.count >= ITEM_RESPAWN_TICKS)
163         {
164                 if(self.waypointsprite_attached)
165                         WaypointSprite_Kill(self.waypointsprite_attached);
166                 Item_Respawn();
167         }
168         else
169         {
170                 self.nextthink = time + 1;
171                 self.count += 1;
172                 if(self.count == 1)
173                 {
174                         string name;
175                         vector rgb;
176                         name = string_null;
177                         if(g_minstagib)
178                         {
179                                 switch(self.items)
180                                 {
181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
184                                 }
185                         }
186                         else
187                         {
188                                 switch(self.items)
189                                 {
190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
192                                 }
193                         }
194                         switch(self.items)
195                         {
196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
198                         }
199                         if(name)
200                         {
201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
202                                 if(self.waypointsprite_attached)
203                                 {
204                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
205                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
206                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
207                                 }
208                         }
209                 }
210                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
211                 if(self.waypointsprite_attached)
212                 {
213                         WaypointSprite_Ping(self.waypointsprite_attached);
214                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
215                 }
216         }
217 }
218
219 void Item_ScheduleRespawnIn(entity e, float t)
220 {
221         if(e.flags & FL_POWERUP)
222         {
223                 e.think = Item_RespawnCountdown;
224                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
225                 e.count = 0;
226         }
227         else
228         {
229                 e.think = Item_Respawn;
230                 e.nextthink = time + t;
231         }
232 }
233
234 void Item_ScheduleRespawn(entity e)
235 {
236         if(e.respawntime > 0)
237         {
238                 Item_Show(e, 0);
239                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
240         }
241         else // if respawntime is -1, this item does not respawn
242                 Item_Show(e, -1);
243 }
244
245 void Item_ScheduleInitialRespawn(entity e)
246 {
247         Item_Show(e, 0);
248         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
249 }
250
251 float Item_GiveTo(entity item, entity player)
252 {
253         float _switchweapon;
254         float pickedup;
255         float it;
256         float i;
257         entity e;
258
259         // if nothing happens to player, just return without taking the item
260         pickedup = FALSE;
261         _switchweapon = FALSE;
262
263         if (g_minstagib)
264         {
265                 if(item.spawnshieldtime)
266                 {
267                         if (item.ammo_fuel)
268                         if (player.ammo_fuel < g_pickup_fuel_max)
269                         {
270                                 pickedup = TRUE;
271                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
272                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
273                         }
274                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
275                         {
276                                 pickedup = TRUE;
277                                 player.items |= it;
278                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
279                         }
280
281                         _switchweapon = TRUE;
282                         if (item.ammo_cells)
283                         {
284                                 pickedup = TRUE;
285                                 // play some cool sounds ;)
286                                 centerprint(player, "\n");
287                                 if (clienttype(player) == CLIENTTYPE_REAL)
288                                 {
289                                         if(player.health <= 5)
290                                                 AnnounceTo(player, "lastsecond");
291                                         else if(player.health < 50)
292                                                 AnnounceTo(player, "narrowly");
293                                 }
294                                 // sound not available
295                                 // else if(item.items == IT_CELLS)
296                                 //      AnnounceTo(player, "ammo");
297
298                                 if (item.weapons & WEPBIT_MINSTANEX)
299                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
300                                 if (item.ammo_cells)
301                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
302                                 player.health = 100;
303                         }
304
305                         // extralife powerup
306                         if (item.max_health)
307                         {
308                                 pickedup = TRUE;
309                                 // sound not available
310                                 // AnnounceTo(player, "_lives");
311                                 player.armorvalue = min(player.armorvalue + cvar("g_minstagib_extralives"), 999);
312                                 sprint(player, "^3You picked up some extra lives\n");
313                         }
314
315                         // invis powerup
316                         if (item.strength_finished)
317                         {
318                                 pickedup = TRUE;
319                                 // sound not available
320                                 // AnnounceTo(player, "invisible");
321                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
322                         }
323
324                         // speed powerup
325                         if (item.invincible_finished)
326                         {
327                                 pickedup = TRUE;
328                                 // sound not available
329                                 // AnnounceTo(player, "speed");
330                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
331                         }
332
333                         if (item.ammo_fuel)
334                         if (player.ammo_fuel < g_pickup_fuel_max) 
335                         {
336                                 pickedup = TRUE;
337                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
338                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
339                         }
340                 }
341         }
342         else
343         {
344                 if (g_weapon_stay == 1)
345                 if not(item.flags & FL_NO_WEAPON_STAY)
346                 if (item.flags & FL_WEAPON)
347                 {
348                         if(item.classname == "droppedweapon")
349                         {
350                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
351                                         goto skip;
352                         }
353                         else
354                         {
355                                 if (player.weapons & item.weapons)
356                                         goto skip;
357                         }
358                 }
359
360                 // in case the player has autoswitch enabled do the following:
361                 // if the player is using their best weapon before items are given, they
362                 // probably want to switch to an even better weapon after items are given
363                 if (player.autoswitch)
364                 if (player.switchweapon == w_getbestweapon(player))
365                         _switchweapon = TRUE;
366
367                 if not(player.weapons & W_WeaponBit(player.switchweapon))
368                         _switchweapon = TRUE;
369
370                 if(item.spawnshieldtime)
371                 {
372                         if (item.ammo_shells)
373                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
374                         {
375                                 pickedup = TRUE;
376                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
377                         }
378                         if (item.ammo_nails)
379                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
380                         {
381                                 pickedup = TRUE;
382                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
383                         }
384                         if (item.ammo_rockets)
385                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
386                         {
387                                 pickedup = TRUE;
388                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
389                         }
390                         if (item.ammo_cells)
391                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
392                         {
393                                 pickedup = TRUE;
394                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
395                         }
396                         if (item.ammo_fuel)
397                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
398                         {
399                                 pickedup = TRUE;
400                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
401                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
402                         }
403                 }
404
405                 if (item.flags & FL_WEAPON)
406                 if ((it = item.weapons - (item.weapons & player.weapons)) || g_pickup_weapons_anyway)
407                 {
408                         pickedup = TRUE;
409                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
410                         {
411                                 e = get_weaponinfo(i);
412                                 if(it & e.weapons)
413                                         W_GiveWeapon (player, e.weapon, item.netname);
414                         }
415                 }
416
417                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
418                 {
419                         pickedup = TRUE;
420                         player.items |= it;
421                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
422                 }
423
424                 if(item.spawnshieldtime)
425                 {
426                         if (item.strength_finished)
427                         {
428                                 pickedup = TRUE;
429                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
430                         }
431                         if (item.invincible_finished)
432                         {
433                                 pickedup = TRUE;
434                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
435                         }
436
437                         if (item.health)
438                         if ((player.health < item.max_health) || item.pickup_anyway)
439                         {
440                                 pickedup = TRUE;
441                                 player.health = min(player.health + item.health, item.max_health);
442                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
443                         }
444                         if (item.armorvalue)
445                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
446                         {
447                                 pickedup = TRUE;
448                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
449                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
450                         }
451                 }
452         }
453
454 :skip
455         // always eat teamed entities
456         if(item.team)
457                 pickedup = TRUE;
458
459         if (!pickedup)
460                 return 0;
461
462         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
463         if (_switchweapon)
464                 if (player.switchweapon != w_getbestweapon(player))
465                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
466
467         return 1;
468 }
469
470 void Item_Touch (void)
471 {
472         entity e, head;
473
474         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
475         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
476         {
477                 remove(self);
478                 return;
479         }
480         if (other.classname != "player")
481                 return;
482         if (other.deadflag)
483                 return;
484         if (self.solid != SOLID_TRIGGER)
485                 return;
486         if (self.owner == other)
487                 return;
488
489         if(!Item_GiveTo(self, other))
490                 return;
491
492         other.last_pickup = time;
493
494         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
495
496         if (self.classname == "droppedweapon")
497                 remove (self);
498         else if not(self.spawnshieldtime)
499                 return;
500         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
501                 return;
502         else
503         {
504                 if(self.team)
505                 {
506                         RandomSelection_Init();
507                         for(head = world; (head = findfloat(head, team, self.team)); )
508                         {
509                                 if(head.flags & FL_ITEM)
510                                 {
511                                         Item_Show(head, -1);
512                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
513                                 }
514                         }
515                         e = RandomSelection_chosen_ent;
516                 }
517                 else
518                         e = self;
519                 Item_ScheduleRespawn(e);
520         }
521 }
522
523 void Item_FindTeam()
524 {
525         entity head, e;
526
527         if(self.effects & EF_NODRAW)
528         {
529                 // marker for item team search
530                 dprint("Initializing item team ", ftos(self.team), "\n");
531                 RandomSelection_Init();
532                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
533                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
534                 e = RandomSelection_chosen_ent;
535                 e.state = 0;
536                 Item_Show(e, 1);
537
538                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
539                 {
540                         if(head != e)
541                         {
542                                 // make it a non-spawned item
543                                 Item_Show(head, -1);
544                                 head.state = 1; // state 1 = initially hidden item
545                         }
546                         head.effects &~= EF_NODRAW;
547                 }
548
549                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
550                         Item_ScheduleInitialRespawn(e);
551         }
552 }
553
554 void Item_Reset()
555 {
556         Item_Show(self, !self.state);
557         setorigin (self, self.origin);
558         self.think = SUB_Null;
559         self.nextthink = 0;
560
561         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
562                 Item_ScheduleInitialRespawn(self);
563 }
564
565 // Savage: used for item garbage-collection
566 // TODO: perhaps nice special effect?
567 void RemoveItem(void)
568 {
569         remove(self);
570 }
571
572 // pickup evaluation functions
573 // these functions decide how desirable an item is to the bots
574
575 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
576
577 float weapon_pickupevalfunc(entity player, entity item)
578 {
579         float c, i, j, position;
580
581         // See if I have it already
582         if(player.weapons & item.weapons == item.weapons)
583         {
584                 // If I can pick it up
585                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
586                         c = 0;
587                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
588                 {
589                         // Skilled bots will grab more
590                         c = bound(0, skill / 10, 1) * 0.5;
591                 }
592                 else
593                         c = 0;
594         }
595         else
596                 c = 1;
597
598         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
599         if( bot_custom_weapon && c )
600         {
601                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
602                 {
603                         // Find weapon
604                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
605                                 continue;
606
607                         // Find the highest position on any range
608                         position = -1;
609                         for(j = 0; j < WEP_LAST ; ++j){
610                                 if(
611                                                 bot_weapons_far[j] == i ||
612                                                 bot_weapons_mid[j] == i ||
613                                                 bot_weapons_close[j] == i
614                                   )
615                                 {
616                                         position = j;
617                                         break;
618                                 }
619                         }
620
621                         // Rate it
622                         if (position >= 0 )
623                         {
624                                 position = WEP_LAST - position;
625                                 // item.bot_pickupbasevalue is overwritten here
626                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
627                         }
628                 }
629         }
630
631         return item.bot_pickupbasevalue * c;
632 };
633
634 float commodity_pickupevalfunc(entity player, entity item)
635 {
636         float c, i, need_shells, need_nails, need_rockets, need_cells;
637         entity wi;
638         c = 0;
639
640         // Detect needed ammo
641         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
642         {
643                 wi = get_weaponinfo(i);
644
645                 if not(wi.weapons & player.weapons)
646                         continue;
647
648                 if(wi.items & IT_SHELLS)
649                         need_shells = TRUE;
650                 else if(wi.items & IT_NAILS)
651                         need_nails = TRUE;
652                 else if(wi.items & IT_ROCKETS)
653                         need_rockets = TRUE;
654                 else if(wi.items & IT_CELLS)
655                         need_cells = TRUE;
656         }
657
658         // TODO: figure out if the player even has the weapon this ammo is for?
659         // may not affect strategy much though...
660         // find out how much more ammo/armor/health the player can hold
661         if (need_shells)
662         if (item.ammo_shells)
663         if (player.ammo_shells < g_pickup_shells_max)
664                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
665         if (need_nails)
666         if (item.ammo_nails)
667         if (player.ammo_nails < g_pickup_nails_max)
668                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
669         if (need_rockets)
670         if (item.ammo_rockets)
671         if (player.ammo_rockets < g_pickup_rockets_max)
672                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
673         if (need_cells)
674         if (item.ammo_cells)
675         if (player.ammo_cells < g_pickup_cells_max)
676                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
677         if (item.armorvalue)
678         if (player.armorvalue < item.max_armorvalue)
679                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
680         if (item.health)
681         if (player.health < item.max_health)
682                 c = c + max(0, 1 - player.health / item.max_health);
683
684         return item.bot_pickupbasevalue * c;
685 };
686
687
688 .float is_item;
689 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
690 {
691         startitem_failed = FALSE;
692
693         self.items = itemid;
694         self.weapons = weaponid;
695
696         // is it a dropped weapon?
697         if (self.classname == "droppedweapon")
698         {
699                 self.reset = SUB_Remove;
700                 // it's a dropped weapon
701                 self.movetype = MOVETYPE_TOSS;
702                 // Savage: remove thrown items after a certain period of time ("garbage collection")
703                 self.think = RemoveItem;
704                 self.nextthink = time + 60;
705                 // don't drop if in a NODROP zone (such as lava)
706                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
707                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
708                 {
709                         startitem_failed = TRUE;
710                         remove(self);
711                         return;
712                 }
713         }
714         else
715         {
716                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
717                 {
718                         startitem_failed = TRUE;
719                         remove(self);
720                         return;
721                 }
722
723                 self.reset = Item_Reset;
724                 // it's a level item
725                 if(self.spawnflags & 1)
726                         self.noalign = 1;
727                 if (self.noalign)
728                         self.movetype = MOVETYPE_NONE;
729                 else
730                         self.movetype = MOVETYPE_TOSS;
731                 // do item filtering according to game mode and other things
732                 if (!self.noalign)
733                 {
734                         // first nudge it off the floor a little bit to avoid math errors
735                         setorigin(self, self.origin + '0 0 1');
736                         // set item size before we spawn a spawnfunc_waypoint
737                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
738                                 setsize (self, '-16 -16 0', '16 16 48');
739                         else
740                                 setsize (self, '-16 -16 0', '16 16 32');
741                         // note droptofloor returns FALSE if stuck/or would fall too far
742                         droptofloor();
743                         waypoint_spawnforitem(self);
744                 }
745
746                 if(teams_matter)
747                 {
748                         if(self.notteam)
749                         {
750                                 print("removed non-teamplay ", self.classname, "\n");
751                                 startitem_failed = TRUE;
752                                 remove (self);
753                                 return;
754                         }
755                 }
756                 else
757                 {
758                         if(self.notfree)
759                         {
760                                 print("removed non-FFA ", self.classname, "\n");
761                                 startitem_failed = TRUE;
762                                 remove (self);
763                                 return;
764                         }
765                 }
766
767                 if(self.notq3a)
768                 {
769                         // We aren't TA or something like that, so we keep the Q3A entities
770                         print("removed non-Q3A ", self.classname, "\n");
771                         startitem_failed = TRUE;
772                         remove (self);
773                         return;
774                 }
775
776                 /*
777                  * can't do it that way, as it would break maps
778                  * TODO make a target_give like entity another way, that perhaps has
779                  * the weapon name in a key
780                 if(self.targetname)
781                 {
782                         // target_give not yet supported; maybe later
783                         print("removed targeted ", self.classname, "\n");
784                         startitem_failed = TRUE;
785                         remove (self);
786                         return;
787                 }
788                 */
789
790                 if(cvar("spawn_debug") >= 2)
791                 {
792                         entity otheritem;
793                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
794                         {
795                                 if(otheritem.is_item)
796                                 {
797                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
798                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
799                                         error("Mapper sucks.");
800                                 }
801                         }
802                         self.is_item = TRUE;
803                 }
804
805                 if(g_lms || g_ca)
806                 {
807                         startitem_failed = TRUE;
808                         remove(self);
809                         return;
810                 }
811                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
812                 {
813                         startitem_failed = TRUE;
814                         remove(self);
815                         return;
816                 }
817                 else if (g_minstagib)
818                 {
819                         // don't remove dropped items and powerups
820                         if (self.classname != "minstagib")
821                         {
822                                 startitem_failed = TRUE;
823                                 remove (self);
824                                 return;
825                         }
826                 }
827                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
828                 {
829                         startitem_failed = TRUE;
830                         remove (self);
831                         return;
832                 }
833
834                 weaponsInMap |= weaponid;
835
836                 precache_model (itemmodel);
837                 precache_sound (pickupsound);
838
839                 precache_sound ("misc/itemrespawncountdown.wav");
840                 if(!g_minstagib && itemid == IT_STRENGTH)
841                         precache_sound ("misc/strength_respawn.wav");
842                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
843                         precache_sound ("misc/shield_respawn.wav");
844                 else
845                         precache_sound ("misc/itemrespawn.wav");
846
847                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
848                         self.target = "###item###"; // for finding the nearest item using find()
849         }
850
851         self.bot_pickup = TRUE;
852         self.bot_pickupevalfunc = pickupevalfunc;
853         self.bot_pickupbasevalue = pickupbasevalue;
854         self.mdl = itemmodel;
855         self.item_pickupsound = pickupsound;
856         // let mappers override respawntime
857         if(!self.respawntime) // both set
858         {
859                 self.respawntime = defaultrespawntime;
860                 self.respawntimejitter = defaultrespawntimejitter;
861         }
862         self.netname = itemname;
863         self.flags = FL_ITEM | itemflags;
864         self.touch = Item_Touch;
865         setmodel (self, self.mdl); // precision set below
866         self.effects |= EF_LOWPRECISION;
867         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
868                 setsize (self, '-16 -16 0', '16 16 48');
869         else
870                 setsize (self, '-16 -16 0', '16 16 32');
871         if(itemflags & FL_WEAPON)
872                 self.modelflags |= MF_ROTATE;
873
874         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
875         if (itemflags & FL_WEAPON)
876         {
877                 // neutral team color for pickup weapons
878                 self.colormap = 1024; // color shirt=0 pants=0 grey
879         }
880
881         Item_Show(self, 1);
882         self.state = 0;
883         if(self.team)
884         {
885                 if(!self.cnt)
886                         self.cnt = 1; // item probability weight
887                 self.effects = self.effects | EF_NODRAW; // marker for item team search
888                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
889         }
890         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
891                 Item_ScheduleInitialRespawn(self);
892 }
893
894 /* replace items in minstagib
895  * IT_STRENGTH   = invisibility
896  * IT_NAILS      = extra lives
897  * IT_INVINCIBLE = speed
898  */
899 void minstagib_items (float itemid)
900 {
901         local float rnd;
902         self.classname = "minstagib";
903
904         // replace rocket launchers and nex guns with ammo cells
905         if (itemid == IT_CELLS)
906         {
907                 self.ammo_cells = 1;
908                 StartItem ("models/items/a_cells.md3",
909                         "misc/itempickup.wav", 45, 0,
910                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
911                 return;
912         }
913
914         // randomize
915         rnd = random() * 3;
916         if (rnd <= 1)
917                 itemid = IT_STRENGTH;
918         else if (rnd <= 2)
919                 itemid = IT_NAILS;
920         else
921                 itemid = IT_INVINCIBLE;
922
923         // replace with invis
924         if (itemid == IT_STRENGTH)
925         {
926                 self.strength_finished = 30;
927                 StartItem ("models/items/g_strength.md3",
928                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
929                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
930         }
931         // replace with extra lives
932         if (itemid == IT_NAILS)
933         {
934                 self.max_health = 1;
935                 StartItem ("models/items/g_h100.md3",
936                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
937                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
938         }
939         // replace with speed
940         if (itemid == IT_INVINCIBLE)
941         {
942                 self.invincible_finished = 30;
943                 StartItem ("models/items/g_invincible.md3",
944                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
945                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
946         }
947 }
948
949 float minst_no_auto_cells;
950 void minst_remove_item (void) {
951         if(minst_no_auto_cells)
952                 remove(self);
953 }
954
955 float weaponswapping;
956 float internalteam;
957
958 void weapon_defaultspawnfunc(float wpn)
959 {
960         entity e;
961         float t;
962         var .float ammofield;
963         string s;
964         entity oldself;
965         float i, j;
966
967         // set the respawntime in advance (so replaced weapons can copy it)
968
969         if(!self.respawntime)
970         {
971                 e = get_weaponinfo(wpn);
972                 if(e.items == IT_SUPERWEAPON)
973                 {
974                         self.respawntime = g_pickup_respawntime_powerup;
975                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
976                 }
977                 else
978                 {
979                         self.respawntime = g_pickup_respawntime_weapon;
980                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
981                 }
982         }
983
984         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
985         {
986                 e = get_weaponinfo(wpn);
987                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
988                 if(s == "0")
989                 {
990                         remove(self);
991                         startitem_failed = TRUE;
992                         return;
993                 }
994                 t = tokenize_console(s);
995                 if(t >= 2)
996                 {
997                         self.team = --internalteam;
998                         oldself = self;
999                         for(i = 1; i < t; ++i)
1000                         {
1001                                 s = argv(i);
1002                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1003                                 {
1004                                         e = get_weaponinfo(j);
1005                                         if(e.netname == s)
1006                                         {
1007                                                 self = spawn();
1008                                                 copyentity(oldself, self);
1009                                                 self.classname = "replacedweapon";
1010                                                 weapon_defaultspawnfunc(j);
1011                                                 break;
1012                                         }
1013                                 }
1014                                 if(j > WEP_LAST)
1015                                 {
1016                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1017                                 }
1018                         }
1019                         self = oldself;
1020                 }
1021                 if(t >= 1)
1022                 {
1023                         s = argv(0);
1024                         wpn = 0;
1025                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1026                         {
1027                                 e = get_weaponinfo(j);
1028                                 if(e.netname == s)
1029                                 {
1030                                         wpn = j;
1031                                         break;
1032                                 }
1033                         }
1034                         if(j > WEP_LAST)
1035                         {
1036                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1037                         }
1038                 }
1039                 if(wpn == 0)
1040                 {
1041                         remove(self);
1042                         startitem_failed = TRUE;
1043                         return;
1044                 }
1045         }
1046
1047         e = get_weaponinfo(wpn);
1048
1049         if(e.items && e.items != IT_SUPERWEAPON)
1050         {
1051                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1052                 {
1053                         if(e.items & j)
1054                         {
1055                                 ammofield = Item_CounterField(j);
1056                                 if(!self.ammofield)
1057                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1058                         }
1059                 }
1060         }
1061         else
1062         {
1063                 self.flags |= FL_NO_WEAPON_STAY;
1064         }
1065
1066         // weapon stay isn't supported for teamed weapons
1067         if(self.team)
1068                 self.flags |= FL_NO_WEAPON_STAY;
1069
1070         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1071         {
1072                 self.ammo_shells = 0;
1073                 self.ammo_nails = 0;
1074                 self.ammo_cells = 0;
1075                 self.ammo_rockets = 0;
1076                 // weapon stay 2: don't use ammo on weapon pickups; instead
1077                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1078         }
1079
1080         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1081         if (self.modelindex) // don't precache if self was removed
1082                 weapon_action(e.weapon, WR_PRECACHE);
1083 }
1084
1085 void spawnfunc_weapon_shotgun (void);
1086 void spawnfunc_weapon_uzi (void) {
1087         if(q3acompat_machineshotgunswap)
1088         if(self.classname != "droppedweapon")
1089         {
1090                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1091                 return;
1092         }
1093         weapon_defaultspawnfunc(WEP_UZI);
1094 }
1095
1096 void spawnfunc_weapon_shotgun (void) {
1097         if(q3acompat_machineshotgunswap)
1098         if(self.classname != "droppedweapon")
1099         {
1100                 weapon_defaultspawnfunc(WEP_UZI);
1101                 return;
1102         }
1103         weapon_defaultspawnfunc(WEP_SHOTGUN);
1104 }
1105
1106 void spawnfunc_weapon_nex (void)
1107 {
1108         if (g_minstagib)
1109         {
1110                 minstagib_items(IT_CELLS);
1111                 self.think = minst_remove_item;
1112                 self.nextthink = time;
1113                 return;
1114         }
1115         weapon_defaultspawnfunc(WEP_NEX);
1116 }
1117
1118 void spawnfunc_weapon_minstanex (void)
1119 {
1120         if (g_minstagib)
1121         {
1122                 minstagib_items(IT_CELLS);
1123                 self.think = minst_remove_item;
1124                 self.nextthink = time;
1125                 return;
1126         }
1127         weapon_defaultspawnfunc(WEP_MINSTANEX);
1128 }
1129
1130 void spawnfunc_weapon_rocketlauncher (void)
1131 {
1132         if (g_minstagib)
1133         {
1134                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1135                 self.think = minst_remove_item;
1136                 self.nextthink = time;
1137                 return;
1138         }
1139         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1140 }
1141
1142 void spawnfunc_item_rockets (void) {
1143         if(!self.ammo_rockets)
1144                 self.ammo_rockets = g_pickup_rockets;
1145         if(!self.pickup_anyway)
1146                 self.pickup_anyway = g_pickup_ammo_anyway;
1147         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1148 }
1149
1150 void spawnfunc_item_shells (void);
1151 void spawnfunc_item_bullets (void) {
1152         if(!weaponswapping)
1153         if(q3acompat_machineshotgunswap)
1154         if(self.classname != "droppedweapon")
1155         {
1156                 weaponswapping = TRUE;
1157                 spawnfunc_item_shells();
1158                 weaponswapping = FALSE;
1159                 return;
1160         }
1161
1162         if(!self.ammo_nails)
1163                 self.ammo_nails = g_pickup_nails;
1164         if(!self.pickup_anyway)
1165                 self.pickup_anyway = g_pickup_ammo_anyway;
1166         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1167 }
1168
1169 void spawnfunc_item_cells (void) {
1170         if(!self.ammo_cells)
1171                 self.ammo_cells = g_pickup_cells;
1172         if(!self.pickup_anyway)
1173                 self.pickup_anyway = g_pickup_ammo_anyway;
1174         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1175 }
1176
1177 void spawnfunc_item_shells (void) {
1178         if(!weaponswapping)
1179         if(q3acompat_machineshotgunswap)
1180         if(self.classname != "droppedweapon")
1181         {
1182                 weaponswapping = TRUE;
1183                 spawnfunc_item_bullets();
1184                 weaponswapping = FALSE;
1185                 return;
1186         }
1187
1188         if(!self.ammo_shells)
1189                 self.ammo_shells = g_pickup_shells;
1190         if(!self.pickup_anyway)
1191                 self.pickup_anyway = g_pickup_ammo_anyway;
1192         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1193 }
1194
1195 void spawnfunc_item_armor_small (void) {
1196         if(!self.armorvalue)
1197                 self.armorvalue = g_pickup_armorsmall;
1198         if(!self.max_armorvalue)
1199                 self.max_armorvalue = g_pickup_armorsmall_max;
1200         if(!self.pickup_anyway)
1201                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1202         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1203 }
1204
1205 void spawnfunc_item_armor_medium (void) {
1206         if(!self.armorvalue)
1207                 self.armorvalue = g_pickup_armormedium;
1208         if(!self.max_armorvalue)
1209                 self.max_armorvalue = g_pickup_armormedium_max;
1210         if(!self.pickup_anyway)
1211                 self.pickup_anyway = g_pickup_armormedium_anyway;
1212         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1213 }
1214
1215 void spawnfunc_item_armor_big (void) {
1216         if(!self.armorvalue)
1217                 self.armorvalue = g_pickup_armorbig;
1218         if(!self.max_armorvalue)
1219                 self.max_armorvalue = g_pickup_armorbig_max;
1220         if(!self.pickup_anyway)
1221                 self.pickup_anyway = g_pickup_armorbig_anyway;
1222         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1223 }
1224
1225 void spawnfunc_item_armor_large (void) {
1226         if(!self.armorvalue)
1227                 self.armorvalue = g_pickup_armorlarge;
1228         if(!self.max_armorvalue)
1229                 self.max_armorvalue = g_pickup_armorlarge_max;
1230         if(!self.pickup_anyway)
1231                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1232         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1233 }
1234
1235 void spawnfunc_item_health_small (void) {
1236         if(!self.max_health)
1237                 self.max_health = g_pickup_healthsmall_max;
1238         if(!self.health)
1239                 self.health = g_pickup_healthsmall;
1240         if(!self.pickup_anyway)
1241                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1242         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1243 }
1244
1245 void spawnfunc_item_health_medium (void) {
1246         if(!self.max_health)
1247                 self.max_health = g_pickup_healthmedium_max;
1248         if(!self.health)
1249                 self.health = g_pickup_healthmedium;
1250         if(!self.pickup_anyway)
1251                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1252         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1253 }
1254
1255 void spawnfunc_item_health_large (void) {
1256         if(!self.max_health)
1257                 self.max_health = g_pickup_healthlarge_max;
1258         if(!self.health)
1259                 self.health = g_pickup_healthlarge;
1260         if(!self.pickup_anyway)
1261                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1262         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1263 }
1264
1265 void spawnfunc_item_health_mega (void) {
1266         if(!cvar("g_powerup_superhealth"))
1267                 return;
1268
1269         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1270                 return;
1271
1272         if(g_minstagib) {
1273                 minstagib_items(IT_NAILS);
1274         } else {
1275                 if(!self.max_health)
1276                         self.max_health = g_pickup_healthmega_max;
1277                 if(!self.health)
1278                         self.health = g_pickup_healthmega;
1279                 if(!self.pickup_anyway)
1280                         self.pickup_anyway = g_pickup_healthmega_anyway;
1281                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1282         }
1283 }
1284
1285 // support old misnamed entities
1286 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1287 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1288 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1289 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1290 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1291
1292 void spawnfunc_item_strength (void) {
1293         if(!cvar("g_powerup_strength"))
1294                 return;
1295
1296         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1297                 return;
1298
1299         if(g_minstagib) {
1300                 minstagib_items(IT_STRENGTH);
1301         } else {
1302                 precache_sound("weapons/strength_fire.wav");
1303                 self.strength_finished = 30;
1304                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1305         }
1306 }
1307
1308 void spawnfunc_item_invincible (void) {
1309         if(!cvar("g_powerup_shield"))
1310                 return;
1311
1312         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1313                 return;
1314
1315         if(g_minstagib) {
1316                 minstagib_items(IT_INVINCIBLE);
1317         } else {
1318                 self.invincible_finished = 30;
1319                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1320         }
1321 }
1322
1323 void spawnfunc_item_minst_cells (void) {
1324         if (g_minstagib)
1325         {
1326                 minst_no_auto_cells = 1;
1327                 minstagib_items(IT_CELLS);
1328         }
1329         else
1330                 remove(self);
1331 }
1332
1333 // compatibility:
1334 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1335
1336 float GiveItems(entity e, float beginarg, float endarg);
1337 void target_items_use (void)
1338 {
1339         if(activator.classname == "droppedweapon")
1340         {
1341                 EXACTTRIGGER_TOUCH;
1342                 remove(activator);
1343                 return;
1344         }
1345
1346         if(activator.classname != "player")
1347                 return;
1348         if(activator.deadflag != DEAD_NO)
1349                 return;
1350         EXACTTRIGGER_TOUCH;
1351
1352         entity e;
1353         for(e = world; (e = find(e, classname, "droppedweapon")); )
1354                 if(e.enemy == activator)
1355                         remove(e);
1356
1357         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1358                 centerprint(activator, self.message);
1359 }
1360
1361 void spawnfunc_target_items (void)
1362 {
1363         float n, i, j;
1364         entity e;
1365
1366         self.use = target_items_use;
1367         if(!self.strength_finished)
1368                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1369         if(!self.invincible_finished)
1370                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1371
1372         precache_sound("misc/itempickup.wav");
1373         precache_sound("misc/megahealth.wav");
1374         precache_sound("misc/armor25.wav");
1375         precache_sound("misc/powerup.wav");
1376         precache_sound("misc/poweroff.wav");
1377         precache_sound("weapons/weaponpickup.wav");
1378
1379         n = tokenize_console(self.netname);
1380         if(argv(0) == "give")
1381         {
1382                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1383         }
1384         else
1385         {
1386                 for(i = 0; i < n; ++i)
1387                 {
1388                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1389                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1390                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1391                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1392                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1393                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1394                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1395                         else
1396                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1397                         {
1398                                 e = get_weaponinfo(j);
1399                                 if(argv(i) == e.netname)
1400                                 {
1401                                         self.weapons |= e.weapons;
1402                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1403                                                 weapon_action(e.weapon, WR_PRECACHE);
1404                                         break;
1405                                 }
1406                         }
1407                         if(j > WEP_LAST)
1408                                 print("target_items: invalid item ", argv(i), "\n");
1409                 }
1410
1411                 string itemprefix, valueprefix;
1412                 if(self.spawnflags == 0)
1413                 {
1414                         itemprefix = "";
1415                         valueprefix = "";
1416                 }
1417                 else if(self.spawnflags == 1)
1418                 {
1419                         itemprefix = "max ";
1420                         valueprefix = "max ";
1421                 }
1422                 else if(self.spawnflags == 2)
1423                 {
1424                         itemprefix = "min ";
1425                         valueprefix = "min ";
1426                 }
1427                 else if(self.spawnflags == 4)
1428                 {
1429                         itemprefix = "minus ";
1430                         valueprefix = "max ";
1431                 }
1432                 else
1433                         error("invalid spawnflags");
1434
1435                 self.netname = "";
1436                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1437                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1438                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1439                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1440                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1441                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1442                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1443                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1444                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1445                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1446                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1447                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1448                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1449                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1450                 {
1451                         e = get_weaponinfo(j);
1452                         if(e.weapons)
1453                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1454                 }
1455         }
1456         self.netname = strzone(self.netname);
1457         //print(self.netname, "\n");
1458
1459         n = tokenize_console(self.netname);
1460         for(i = 0; i < n; ++i)
1461         {
1462                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1463                 {
1464                         e = get_weaponinfo(j);
1465                         if(argv(i) == e.netname)
1466                         {
1467                                 weapon_action(e.weapon, WR_PRECACHE);
1468                                 break;
1469                         }
1470                 }
1471         }
1472 }
1473
1474 void spawnfunc_item_fuel(void)
1475 {
1476         if(!self.ammo_fuel)
1477                 self.ammo_fuel = g_pickup_fuel;
1478         if(!self.pickup_anyway)
1479                 self.pickup_anyway = g_pickup_ammo_anyway;
1480         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1481 }
1482
1483 void spawnfunc_item_fuel_regen(void)
1484 {
1485         if(start_items & IT_FUEL_REGEN)
1486         {
1487                 spawnfunc_item_fuel();
1488                 return;
1489         }
1490         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1491 }
1492
1493 void spawnfunc_item_jetpack(void)
1494 {
1495         if(g_grappling_hook)
1496                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1497         if(!self.ammo_fuel)
1498                 self.ammo_fuel = g_pickup_fuel_jetpack;
1499         if(start_items & IT_JETPACK)
1500         {
1501                 spawnfunc_item_fuel();
1502                 return;
1503         }
1504         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1505 }
1506
1507
1508 #define OP_SET 0
1509 #define OP_MIN 1
1510 #define OP_MAX 2
1511 #define OP_PLUS 3
1512 #define OP_MINUS 4
1513
1514 float GiveBit(entity e, .float fld, float bit, float op, float val)
1515 {
1516         float v0, v1;
1517         v0 = (e.fld & bit);
1518         switch(op)
1519         {
1520                 case OP_SET:
1521                         if(val > 0)
1522                                 e.fld |= bit;
1523                         else
1524                                 e.fld &~= bit;
1525                         break;
1526                 case OP_MIN:
1527                 case OP_PLUS:
1528                         if(val > 0)
1529                                 e.fld |= bit;
1530                         break;
1531                 case OP_MAX:
1532                         if(val <= 0)
1533                                 e.fld &~= bit;
1534                         break;
1535                 case OP_MINUS:
1536                         if(val > 0)
1537                                 e.fld &~= bit;
1538                         break;
1539         }
1540         v1 = (e.fld & bit);
1541         return (v0 != v1);
1542 }
1543
1544 float GiveValue(entity e, .float fld, float op, float val)
1545 {
1546         float v0, v1;
1547         v0 = e.fld;
1548         switch(op)
1549         {
1550                 case OP_SET:
1551                         e.fld = val;
1552                         break;
1553                 case OP_MIN:
1554                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1555                         break;
1556                 case OP_MAX:
1557                         e.fld = min(e.fld, val);
1558                         break;
1559                 case OP_PLUS:
1560                         e.fld += val;
1561                         break;
1562                 case OP_MINUS:
1563                         e.fld -= val;
1564                         break;
1565         }
1566         v1 = e.fld;
1567         return (v0 != v1);
1568 }
1569
1570 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1571 {
1572         if(v1 == v0)
1573                 return;
1574         if(v1 <= v0 - t)
1575         {
1576                 if(snd_decr != "")
1577                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1578         }
1579         else if(v0 >= v0 + t)
1580         {
1581                 if(snd_incr != "")
1582                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1583         }
1584 }
1585
1586 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1587 {
1588         if(v0 < v1)
1589                 e.rotfield = max(e.rotfield, time + rottime);
1590         else if(v0 > v1)
1591                 e.regenfield = max(e.regenfield, time + regentime);
1592 }
1593
1594 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1595 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1596 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1597 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1598
1599 float GiveItems(entity e, float beginarg, float endarg)
1600 {
1601         float got, i, j, val, op;
1602         float _switchweapon;
1603         entity wi;
1604         string cmd;
1605
1606         val = 999;
1607         op = OP_SET;
1608
1609         got = 0;
1610
1611         _switchweapon = FALSE;
1612         if (e.autoswitch)
1613                 if (e.switchweapon == w_getbestweapon(e))
1614                         _switchweapon = TRUE;
1615
1616         e.strength_finished = max(0, e.strength_finished - time);
1617         e.invincible_finished = max(0, e.invincible_finished - time);
1618         
1619         PREGIVE(e, items);
1620         PREGIVE(e, weapons);
1621         PREGIVE(e, strength_finished);
1622         PREGIVE(e, invincible_finished);
1623         PREGIVE(e, ammo_nails);
1624         PREGIVE(e, ammo_cells);
1625         PREGIVE(e, ammo_shells);
1626         PREGIVE(e, ammo_rockets);
1627         PREGIVE(e, ammo_fuel);
1628         PREGIVE(e, armorvalue);
1629         PREGIVE(e, health);
1630
1631         for(i = beginarg; i < endarg; ++i)
1632         {
1633                 cmd = argv(i);
1634
1635                 if(cmd == "0" || stof(cmd))
1636                 {
1637                         val = stof(cmd);
1638                         continue;
1639                 }
1640                 switch(cmd)
1641                 {
1642                         case "no":
1643                                 op = OP_MAX;
1644                                 val = 0;
1645                                 continue;
1646                         case "max":
1647                                 op = OP_MAX;
1648                                 continue;
1649                         case "min":
1650                                 op = OP_MIN;
1651                                 continue;
1652                         case "plus":
1653                                 op = OP_PLUS;
1654                                 continue;
1655                         case "minus":
1656                                 op = OP_MINUS;
1657                                 continue;
1658                         case "ALL":
1659                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1660                                 got += GiveValue(e, strength_finished, op, time);
1661                                 got += GiveValue(e, invincible_finished, op, time);
1662                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1663                         case "all":
1664                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1665                                 got += GiveValue(e, health, op, val);
1666                                 got += GiveValue(e, armorvalue, op, val);
1667                         case "allweapons":
1668                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1669                                 {
1670                                         wi = get_weaponinfo(j);
1671                                         if(wi.weapons)
1672                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1673                                 }
1674                         case "allammo":
1675                                 got += GiveValue(e, ammo_cells, op, val);
1676                                 got += GiveValue(e, ammo_shells, op, val);
1677                                 got += GiveValue(e, ammo_nails, op, val);
1678                                 got += GiveValue(e, ammo_rockets, op, val);
1679                                 got += GiveValue(e, ammo_fuel, op, val);
1680                                 break;
1681                         case "unlimited_ammo":
1682                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1683                                 break;
1684                         case "unlimited_weapon_ammo":
1685                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1686                                 break;
1687                         case "unlimited_superweapons":
1688                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1689                                 break;
1690                         case "jetpack":
1691                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1692                                 break;
1693                         case "fuel_regen":
1694                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1695                                 break;
1696                         case "strength":
1697                                 got += GiveValue(e, strength_finished, op, val);
1698                                 break;
1699                         case "invincible":
1700                                 got += GiveValue(e, invincible_finished, op, val);
1701                                 break;
1702                         case "cells":
1703                                 got += GiveValue(e, ammo_cells, op, val);
1704                                 break;
1705                         case "shells":
1706                                 got += GiveValue(e, ammo_shells, op, val);
1707                                 break;
1708                         case "nails":
1709                         case "bullets":
1710                                 got += GiveValue(e, ammo_nails, op, val);
1711                                 break;
1712                         case "rockets":
1713                                 got += GiveValue(e, ammo_rockets, op, val);
1714                                 break;
1715                         case "health":
1716                                 got += GiveValue(e, health, op, val);
1717                                 break;
1718                         case "armor":
1719                                 got += GiveValue(e, armorvalue, op, val);
1720                                 break;
1721                         case "fuel":
1722                                 got += GiveValue(e, ammo_fuel, op, val);
1723                                 break;
1724                         default:
1725                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1726                                 {
1727                                         wi = get_weaponinfo(j);
1728                                         if(cmd == wi.netname)
1729                                         {
1730                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1731                                                 break;
1732                                         }
1733                                 }
1734                                 if(j > WEP_LAST)
1735                                         print("give: invalid item ", cmd, "\n");
1736                                 break;
1737                 }
1738                 val = 999;
1739                 op = OP_SET;
1740         }
1741
1742         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1743         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1744         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1745         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1746         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1747         {
1748                 wi = get_weaponinfo(j);
1749                 if(wi.weapons)
1750                 {
1751                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1752                         if not(save_weapons & wi.weapons)
1753                                 if(e.weapons & wi.weapons)
1754                                         weapon_action(wi.weapon, WR_PRECACHE);
1755                 }
1756         }
1757         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1758         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1759         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1760         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1761         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1762         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1763         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1764         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1765         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1766
1767         if (g_minstagib)
1768         {
1769                 e.health = bound(0, e.health, 100);
1770                 e.armorvalue = bound(0, e.armorvalue, 999);
1771         }
1772
1773         if(e.strength_finished <= 0)
1774                 e.strength_finished = 0;
1775         else
1776                 e.strength_finished += time;
1777         if(e.invincible_finished <= 0)
1778                 e.invincible_finished = 0;
1779         else
1780                 e.invincible_finished += time;
1781
1782         if not(e.weapons & W_WeaponBit(e.switchweapon))
1783                 _switchweapon = TRUE;
1784         if(_switchweapon)
1785                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1786
1787         return got;
1788 }