qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(!name)
 237                         {
 238                                 print("Unknown powerup-marked item is wanting to respawn\n");
 239                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 240                         }
 241                         if(name)
 242                         {
 243                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 244                                 if(self.waypointsprite_attached)
 245                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 246                         }
 247                 }
 248                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 249                 if(self.waypointsprite_attached)
 250                 {
 251                         WaypointSprite_Ping(self.waypointsprite_attached);
 252                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 253                 }
 254         }
 255 }
 256
 257 void Item_ScheduleRespawnIn(entity e, float t)
 258 {
 259         if(e.flags & FL_POWERUP)
 260         {
 261                 e.think = Item_RespawnCountdown;
 262                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 263                 e.count = 0;
 264         }
 265         else
 266         {
 267                 e.think = Item_Respawn;
 268                 e.nextthink = time + t;
 269         }
 270 }
 271
 272 void Item_ScheduleRespawn(entity e)
 273 {
 274         if(e.respawntime > 0)
 275         {
 276                 Item_Show(e, 0);
 277                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 278         }
 279         else // if respawntime is -1, this item does not respawn
 280                 Item_Show(e, -1);
 281 }
 282
 283 void Item_ScheduleInitialRespawn(entity e)
 284 {
 285         Item_Show(e, 0);
 286         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 287 }
 288
 289 float ITEM_MODE_NONE = 0;
 290 float ITEM_MODE_HEALTH = 1;
 291 float ITEM_MODE_ARMOR = 2;
 292 float ITEM_MODE_FUEL = 3;
 293 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 294 {
 295         if (!item.ammofield)
 296                 return FALSE;
 297
 298         if (item.spawnshieldtime)
 299         {
 300                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 301                 {
 302                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 303                         goto YEAH;
 304                 }
 305         }
 306         else if(g_weapon_stay == 2)
 307         {
 308                 float mi = min(item.ammofield, ammomax);
 309                 if (player.ammofield < mi)
 310                 {
 311                         player.ammofield = mi;
 312                         goto YEAH;
 313                 }
 314         }
 315
 316         return FALSE;
 317
 318 :YEAH
 319         switch(mode)
 320         {
 321                 case ITEM_MODE_FUEL:
 322                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 323                         break;
 324                 case ITEM_MODE_HEALTH:
 325                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 326                         break;
 327                 case ITEM_MODE_ARMOR:
 328                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 329                         break;
 330                 default:
 331                         break;
 332         }
 333         return TRUE;
 334 }
 335
 336 float Item_GiveTo(entity item, entity player)
 337 {
 338         float _switchweapon;
 339         float pickedup;
 340         float it;
 341         float i;
 342         entity e;
 343
 344         // if nothing happens to player, just return without taking the item
 345         pickedup = FALSE;
 346         _switchweapon = FALSE;
 347
 348         if (g_minstagib)
 349         {
 350                 float prevcells = player.ammo_cells;
 351
 352                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 353                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 354
 355                 if(player.ammo_cells > prevcells)
 356                 {
 357                         _switchweapon = TRUE;
 358
 359                         // play some cool sounds ;)
 360                         if (clienttype(player) == CLIENTTYPE_REAL)
 361                         {
 362                                 if(player.health <= 5)
 363                                         AnnounceTo(player, "lastsecond");
 364                                 else if(player.health < 50)
 365                                         AnnounceTo(player, "narrowly");
 366                         }
 367                         // sound not available
 368                         // else if(item.items == IT_CELLS)
 369                         //      AnnounceTo(player, "ammo");
 370
 371                         if (item.weapons & WEPBIT_MINSTANEX)
 372                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 373                         if (item.ammo_cells)
 374                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 375                         player.health = 100;
 376                 }
 377
 378                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 379                 {
 380                         pickedup = TRUE;
 381                         player.items |= it;
 382                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 383                 }
 384
 385                 // extralife powerup
 386                 if (item.max_health)
 387                 {
 388                         pickedup = TRUE;
 389                         // sound not available
 390                         // AnnounceTo(player, "_lives");
 391                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 392                         sprint(player, "^3You picked up some extra lives\n");
 393                 }
 394
 395                 // invis powerup
 396                 if (item.strength_finished)
 397                 {
 398                         pickedup = TRUE;
 399                         // sound not available
 400                         // AnnounceTo(player, "invisible");
 401                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 402                 }
 403
 404                 // speed powerup
 405                 if (item.invincible_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "speed");
 410                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412         }
 413         else
 414         {
 415                 // in case the player has autoswitch enabled do the following:
 416                 // if the player is using their best weapon before items are given, they
 417                 // probably want to switch to an even better weapon after items are given
 418                 if (player.autoswitch)
 419                 if (player.switchweapon == w_getbestweapon(player))
 420                         _switchweapon = TRUE;
 421
 422                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 423                         _switchweapon = TRUE;
 424
 425                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 426                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 427                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 428                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 429                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 430                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 431                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 432
 433                 if (item.flags & FL_WEAPON)
 434                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && g_pickup_weapons_anyway))
 435                 {
 436                         pickedup = TRUE;
 437                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 438                         {
 439                                 e = get_weaponinfo(i);
 440                                 if(it & e.weapons)
 441                                         W_GiveWeapon (player, e.weapon, item.netname);
 442                         }
 443                 }
 444
 445                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 446                 {
 447                         pickedup = TRUE;
 448                         player.items |= it;
 449                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 450                 }
 451
 452                 if (item.strength_finished)
 453                 {
 454                         pickedup = TRUE;
 455                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 456                 }
 457                 if (item.invincible_finished)
 458                 {
 459                         pickedup = TRUE;
 460                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 461                 }
 462         }
 463
 464 :skip
 465         // always eat teamed entities
 466         if(item.team)
 467                 pickedup = TRUE;
 468
 469         if (!pickedup)
 470                 return 0;
 471
 472         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 473         if (_switchweapon)
 474                 if (player.switchweapon != w_getbestweapon(player))
 475                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 476
 477         return 1;
 478 }
 479
 480 void Item_Touch (void)
 481 {
 482         entity e, head;
 483
 484         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 485         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 486         {
 487                 remove(self);
 488                 return;
 489         }
 490         if (other.classname != "player")
 491                 return;
 492         if (other.deadflag)
 493                 return;
 494         if (self.solid != SOLID_TRIGGER)
 495                 return;
 496         if (self.owner == other)
 497                 return;
 498
 499         if(!Item_GiveTo(self, other))
 500                 return;
 501
 502         other.last_pickup = time;
 503
 504         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 505
 506         if (self.classname == "droppedweapon")
 507                 remove (self);
 508         else if not(self.spawnshieldtime)
 509                 return;
 510         else
 511         {
 512                 if(self.team)
 513                 {
 514                         RandomSelection_Init();
 515                         for(head = world; (head = findfloat(head, team, self.team)); )
 516                         {
 517                                 if(head.flags & FL_ITEM)
 518                                 {
 519                                         Item_Show(head, -1);
 520                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 521                                 }
 522                         }
 523                         e = RandomSelection_chosen_ent;
 524                 }
 525                 else
 526                         e = self;
 527                 Item_ScheduleRespawn(e);
 528         }
 529 }
 530
 531 void Item_FindTeam()
 532 {
 533         entity head, e;
 534
 535         if(self.effects & EF_NODRAW)
 536         {
 537                 // marker for item team search
 538                 dprint("Initializing item team ", ftos(self.team), "\n");
 539                 RandomSelection_Init();
 540                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 541                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 542                 e = RandomSelection_chosen_ent;
 543                 e.state = 0;
 544                 Item_Show(e, 1);
 545
 546                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 547                 {
 548                         if(head != e)
 549                         {
 550                                 // make it a non-spawned item
 551                                 Item_Show(head, -1);
 552                                 head.state = 1; // state 1 = initially hidden item
 553                         }
 554                         head.effects &~= EF_NODRAW;
 555                 }
 556
 557                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 558                         Item_ScheduleInitialRespawn(e);
 559         }
 560 }
 561
 562 void Item_Reset()
 563 {
 564         Item_Show(self, !self.state);
 565         setorigin (self, self.origin);
 566         self.think = SUB_Null;
 567         self.nextthink = 0;
 568
 569         if(self.waypointsprite_attached)
 570                 WaypointSprite_Kill(self.waypointsprite_attached);
 571
 572         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 573                 Item_ScheduleInitialRespawn(self);
 574 }
 575
 576 // Savage: used for item garbage-collection
 577 // TODO: perhaps nice special effect?
 578 void RemoveItem(void)
 579 {
 580         remove(self);
 581 }
 582
 583 // pickup evaluation functions
 584 // these functions decide how desirable an item is to the bots
 585
 586 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 587
 588 float weapon_pickupevalfunc(entity player, entity item)
 589 {
 590         float c, i, j, position;
 591
 592         // See if I have it already
 593         if(player.weapons & item.weapons == item.weapons)
 594         {
 595                 // If I can pick it up
 596                 if(!item.spawnshieldtime)
 597                         c = 0;
 598                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 599                 {
 600                         // Skilled bots will grab more
 601                         c = bound(0, skill / 10, 1) * 0.5;
 602                 }
 603                 else
 604                         c = 0;
 605         }
 606         else
 607                 c = 1;
 608
 609         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 610         if( bot_custom_weapon && c )
 611         {
 612                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 613                 {
 614                         // Find weapon
 615                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 616                                 continue;
 617
 618                         // Find the highest position on any range
 619                         position = -1;
 620                         for(j = 0; j < WEP_LAST ; ++j){
 621                                 if(
 622                                                 bot_weapons_far[j] == i ||
 623                                                 bot_weapons_mid[j] == i ||
 624                                                 bot_weapons_close[j] == i
 625                                   )
 626                                 {
 627                                         position = j;
 628                                         break;
 629                                 }
 630                         }
 631
 632                         // Rate it
 633                         if (position >= 0 )
 634                         {
 635                                 position = WEP_LAST - position;
 636                                 // item.bot_pickupbasevalue is overwritten here
 637                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 638                         }
 639                 }
 640         }
 641
 642         return item.bot_pickupbasevalue * c;
 643 }
 644
 645 float commodity_pickupevalfunc(entity player, entity item)
 646 {
 647         float c, i, need_shells, need_nails, need_rockets, need_cells;
 648         entity wi;
 649         c = 0;
 650
 651         // Detect needed ammo
 652         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 653         {
 654                 wi = get_weaponinfo(i);
 655
 656                 if not(wi.weapons & player.weapons)
 657                         continue;
 658
 659                 if(wi.items & IT_SHELLS)
 660                         need_shells = TRUE;
 661                 else if(wi.items & IT_NAILS)
 662                         need_nails = TRUE;
 663                 else if(wi.items & IT_ROCKETS)
 664                         need_rockets = TRUE;
 665                 else if(wi.items & IT_CELLS)
 666                         need_cells = TRUE;
 667         }
 668
 669         // TODO: figure out if the player even has the weapon this ammo is for?
 670         // may not affect strategy much though...
 671         // find out how much more ammo/armor/health the player can hold
 672         if (need_shells)
 673         if (item.ammo_shells)
 674         if (player.ammo_shells < g_pickup_shells_max)
 675                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 676         if (need_nails)
 677         if (item.ammo_nails)
 678         if (player.ammo_nails < g_pickup_nails_max)
 679                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 680         if (need_rockets)
 681         if (item.ammo_rockets)
 682         if (player.ammo_rockets < g_pickup_rockets_max)
 683                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 684         if (need_cells)
 685         if (item.ammo_cells)
 686         if (player.ammo_cells < g_pickup_cells_max)
 687                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 688         if (item.armorvalue)
 689         if (player.armorvalue < item.max_armorvalue)
 690                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 691         if (item.health)
 692         if (player.health < item.max_health)
 693                 c = c + max(0, 1 - player.health / item.max_health);
 694
 695         return item.bot_pickupbasevalue * c;
 696 }
 697
 698
 699 .float is_item;
 700 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 701 {
 702         startitem_failed = FALSE;
 703
 704         self.items = itemid;
 705         self.weapons = weaponid;
 706         self.flags = FL_ITEM | itemflags;
 707
 708         // is it a dropped weapon?
 709         if (self.classname == "droppedweapon")
 710         {
 711                 self.reset = SUB_Remove;
 712                 // it's a dropped weapon
 713                 self.movetype = MOVETYPE_TOSS;
 714                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 715                 self.think = RemoveItem;
 716                 self.nextthink = time + 60;
 717                 // don't drop if in a NODROP zone (such as lava)
 718                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 719                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 720                 {
 721                         startitem_failed = TRUE;
 722                         remove(self);
 723                         return;
 724                 }
 725         }
 726         else
 727         {
 728                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 729                 {
 730                         startitem_failed = TRUE;
 731                         remove(self);
 732                         return;
 733                 }
 734
 735                 if(!have_pickup_item())
 736                 {
 737                         startitem_failed = TRUE;
 738                         remove (self);
 739                         return;
 740                 }
 741
 742                 self.reset = Item_Reset;
 743                 // it's a level item
 744                 if(self.spawnflags & 1)
 745                         self.noalign = 1;
 746                 if (self.noalign)
 747                         self.movetype = MOVETYPE_NONE;
 748                 else
 749                         self.movetype = MOVETYPE_TOSS;
 750                 // do item filtering according to game mode and other things
 751                 if (!self.noalign)
 752                 {
 753                         // first nudge it off the floor a little bit to avoid math errors
 754                         setorigin(self, self.origin + '0 0 1');
 755                         // set item size before we spawn a spawnfunc_waypoint
 756                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 757                                 setsize (self, '-16 -16 0', '16 16 48');
 758                         else
 759                                 setsize (self, '-16 -16 0', '16 16 32');
 760                         // note droptofloor returns FALSE if stuck/or would fall too far
 761                         droptofloor();
 762                         waypoint_spawnforitem(self);
 763                 }
 764
 765                 /*
 766                  * can't do it that way, as it would break maps
 767                  * TODO make a target_give like entity another way, that perhaps has
 768                  * the weapon name in a key
 769                 if(self.targetname)
 770                 {
 771                         // target_give not yet supported; maybe later
 772                         print("removed targeted ", self.classname, "\n");
 773                         startitem_failed = TRUE;
 774                         remove (self);
 775                         return;
 776                 }
 777                 */
 778
 779                 if(autocvar_spawn_debug >= 2)
 780                 {
 781                         entity otheritem;
 782                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 783                         {
 784                                 if(otheritem.is_item)
 785                                 {
 786                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 787                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 788                                         error("Mapper sucks.");
 789                                 }
 790                         }
 791                         self.is_item = TRUE;
 792                 }
 793
 794                 weaponsInMap |= weaponid;
 795
 796                 precache_model (itemmodel);
 797                 precache_sound (pickupsound);
 798
 799                 precache_sound ("misc/itemrespawncountdown.wav");
 800                 if(!g_minstagib && itemid == IT_STRENGTH)
 801                         precache_sound ("misc/strength_respawn.wav");
 802                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 803                         precache_sound ("misc/shield_respawn.wav");
 804                 else
 805                         precache_sound ("misc/itemrespawn.wav");
 806
 807                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 808                         self.target = "###item###"; // for finding the nearest item using find()
 809         }
 810
 811         self.bot_pickup = TRUE;
 812         self.bot_pickupevalfunc = pickupevalfunc;
 813         self.bot_pickupbasevalue = pickupbasevalue;
 814         self.mdl = itemmodel;
 815         self.item_pickupsound = pickupsound;
 816         // let mappers override respawntime
 817         if(!self.respawntime) // both set
 818         {
 819                 self.respawntime = defaultrespawntime;
 820                 self.respawntimejitter = defaultrespawntimejitter;
 821         }
 822         self.netname = itemname;
 823         self.touch = Item_Touch;
 824         setmodel (self, self.mdl); // precision set below
 825         self.effects |= EF_LOWPRECISION;
 826         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 827                 setsize (self, '-16 -16 0', '16 16 48');
 828         else
 829                 setsize (self, '-16 -16 0', '16 16 32');
 830         if(itemflags & FL_WEAPON)
 831                 self.modelflags |= MF_ROTATE;
 832
 833         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 834         if (itemflags & FL_WEAPON)
 835         {
 836                 // neutral team color for pickup weapons
 837                 self.colormap = 1024; // color shirt=0 pants=0 grey
 838         }
 839
 840         Item_Show(self, 1);
 841         self.state = 0;
 842         if(self.team)
 843         {
 844                 if(!self.cnt)
 845                         self.cnt = 1; // item probability weight
 846                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 847                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 848         }
 849         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 850                 Item_ScheduleInitialRespawn(self);
 851 }
 852
 853 /* replace items in minstagib
 854  * IT_STRENGTH   = invisibility
 855  * IT_NAILS      = extra lives
 856  * IT_INVINCIBLE = speed
 857  */
 858 void minstagib_items (float itemid)
 859 {
 860         float rnd;
 861         self.classname = "minstagib";
 862
 863         // replace rocket launchers and nex guns with ammo cells
 864         if (itemid == IT_CELLS)
 865         {
 866                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 867                 StartItem ("models/items/a_cells.md3",
 868                         "misc/itempickup.wav", 45, 0,
 869                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 870                 return;
 871         }
 872
 873         // randomize
 874         rnd = random() * 3;
 875         if (rnd <= 1)
 876                 itemid = IT_STRENGTH;
 877         else if (rnd <= 2)
 878                 itemid = IT_NAILS;
 879         else
 880                 itemid = IT_INVINCIBLE;
 881
 882         // replace with invis
 883         if (itemid == IT_STRENGTH)
 884         {
 885                 self.strength_finished = 30;
 886                 StartItem ("models/items/g_strength.md3",
 887                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 888                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 889         }
 890         // replace with extra lives
 891         if (itemid == IT_NAILS)
 892         {
 893                 self.max_health = 1;
 894                 StartItem ("models/items/g_h100.md3",
 895                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 896                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 897         }
 898         // replace with speed
 899         if (itemid == IT_INVINCIBLE)
 900         {
 901                 self.invincible_finished = 30;
 902                 StartItem ("models/items/g_invincible.md3",
 903                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 904                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 905         }
 906 }
 907
 908 float minst_no_auto_cells;
 909 void minst_remove_item (void) {
 910         if(minst_no_auto_cells)
 911                 remove(self);
 912 }
 913
 914 float weaponswapping;
 915 float internalteam;
 916
 917 void weapon_defaultspawnfunc(float wpn)
 918 {
 919         entity e;
 920         float t;
 921         var .float ammofield;
 922         string s;
 923         entity oldself;
 924         float i, j;
 925
 926         // set the respawntime in advance (so replaced weapons can copy it)
 927
 928         if(!self.respawntime)
 929         {
 930                 e = get_weaponinfo(wpn);
 931                 if(e.items == IT_SUPERWEAPON)
 932                 {
 933                         self.respawntime = g_pickup_respawntime_powerup;
 934                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 935                 }
 936                 else
 937                 {
 938                         self.respawntime = g_pickup_respawntime_weapon;
 939                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 940                 }
 941         }
 942
 943         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 944         {
 945                 e = get_weaponinfo(wpn);
 946                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 947                 if(s == "0")
 948                 {
 949                         remove(self);
 950                         startitem_failed = TRUE;
 951                         return;
 952                 }
 953                 t = tokenize_console(s);
 954                 if(t >= 2)
 955                 {
 956                         self.team = --internalteam;
 957                         oldself = self;
 958                         for(i = 1; i < t; ++i)
 959                         {
 960                                 s = argv(i);
 961                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 962                                 {
 963                                         e = get_weaponinfo(j);
 964                                         if(e.netname == s)
 965                                         {
 966                                                 self = spawn();
 967                                                 copyentity(oldself, self);
 968                                                 self.classname = "replacedweapon";
 969                                                 weapon_defaultspawnfunc(j);
 970                                                 break;
 971                                         }
 972                                 }
 973                                 if(j > WEP_LAST)
 974                                 {
 975                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 976                                 }
 977                         }
 978                         self = oldself;
 979                 }
 980                 if(t >= 1)
 981                 {
 982                         s = argv(0);
 983                         wpn = 0;
 984                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 985                         {
 986                                 e = get_weaponinfo(j);
 987                                 if(e.netname == s)
 988                                 {
 989                                         wpn = j;
 990                                         break;
 991                                 }
 992                         }
 993                         if(j > WEP_LAST)
 994                         {
 995                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 996                         }
 997                 }
 998                 if(wpn == 0)
 999                 {
1000                         remove(self);
1001                         startitem_failed = TRUE;
1002                         return;
1003                 }
1004         }
1005
1006         e = get_weaponinfo(wpn);
1007
1008         if(e.items && e.items != IT_SUPERWEAPON)
1009         {
1010                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1011                 {
1012                         if(e.items & j)
1013                         {
1014                                 ammofield = Item_CounterField(j);
1015                                 if(!self.ammofield)
1016                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1017                         }
1018                 }
1019         }
1020         else
1021         {
1022                 self.flags |= FL_NO_WEAPON_STAY;
1023         }
1024
1025         // weapon stay isn't supported for teamed weapons
1026         if(self.team)
1027                 self.flags |= FL_NO_WEAPON_STAY;
1028
1029         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1030         if (self.modelindex) // don't precache if self was removed
1031                 weapon_action(e.weapon, WR_PRECACHE);
1032 }
1033
1034 void spawnfunc_weapon_shotgun (void);
1035 void spawnfunc_weapon_uzi (void) {
1036         if(autocvar_sv_q3acompat_machineshotgunswap)
1037         if(self.classname != "droppedweapon")
1038         {
1039                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1040                 return;
1041         }
1042         weapon_defaultspawnfunc(WEP_UZI);
1043 }
1044
1045 void spawnfunc_weapon_shotgun (void) {
1046         if(autocvar_sv_q3acompat_machineshotgunswap)
1047         if(self.classname != "droppedweapon")
1048         {
1049                 weapon_defaultspawnfunc(WEP_UZI);
1050                 return;
1051         }
1052         weapon_defaultspawnfunc(WEP_SHOTGUN);
1053 }
1054
1055 void spawnfunc_weapon_nex (void)
1056 {
1057         if (g_minstagib)
1058         {
1059                 minstagib_items(IT_CELLS);
1060                 self.think = minst_remove_item;
1061                 self.nextthink = time;
1062                 return;
1063         }
1064         weapon_defaultspawnfunc(WEP_NEX);
1065 }
1066
1067 void spawnfunc_weapon_minstanex (void)
1068 {
1069         if (g_minstagib)
1070         {
1071                 minstagib_items(IT_CELLS);
1072                 self.think = minst_remove_item;
1073                 self.nextthink = time;
1074                 return;
1075         }
1076         weapon_defaultspawnfunc(WEP_MINSTANEX);
1077 }
1078
1079 void spawnfunc_weapon_rocketlauncher (void)
1080 {
1081         if (g_minstagib)
1082         {
1083                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1084                 self.think = minst_remove_item;
1085                 self.nextthink = time;
1086                 return;
1087         }
1088         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1089 }
1090
1091 void spawnfunc_item_rockets (void) {
1092         if(!self.ammo_rockets)
1093                 self.ammo_rockets = g_pickup_rockets;
1094         if(!self.pickup_anyway)
1095                 self.pickup_anyway = g_pickup_ammo_anyway;
1096         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1097 }
1098
1099 void spawnfunc_item_shells (void);
1100 void spawnfunc_item_bullets (void) {
1101         if(!weaponswapping)
1102         if(autocvar_sv_q3acompat_machineshotgunswap)
1103         if(self.classname != "droppedweapon")
1104         {
1105                 weaponswapping = TRUE;
1106                 spawnfunc_item_shells();
1107                 weaponswapping = FALSE;
1108                 return;
1109         }
1110
1111         if(!self.ammo_nails)
1112                 self.ammo_nails = g_pickup_nails;
1113         if(!self.pickup_anyway)
1114                 self.pickup_anyway = g_pickup_ammo_anyway;
1115         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1116 }
1117
1118 void spawnfunc_item_cells (void) {
1119         if(!self.ammo_cells)
1120                 self.ammo_cells = g_pickup_cells;
1121         if(!self.pickup_anyway)
1122                 self.pickup_anyway = g_pickup_ammo_anyway;
1123         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1124 }
1125
1126 void spawnfunc_item_shells (void) {
1127         if(!weaponswapping)
1128         if(autocvar_sv_q3acompat_machineshotgunswap)
1129         if(self.classname != "droppedweapon")
1130         {
1131                 weaponswapping = TRUE;
1132                 spawnfunc_item_bullets();
1133                 weaponswapping = FALSE;
1134                 return;
1135         }
1136
1137         if(!self.ammo_shells)
1138                 self.ammo_shells = g_pickup_shells;
1139         if(!self.pickup_anyway)
1140                 self.pickup_anyway = g_pickup_ammo_anyway;
1141         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1142 }
1143
1144 void spawnfunc_item_armor_small (void) {
1145         if(!self.armorvalue)
1146                 self.armorvalue = g_pickup_armorsmall;
1147         if(!self.max_armorvalue)
1148                 self.max_armorvalue = g_pickup_armorsmall_max;
1149         if(!self.pickup_anyway)
1150                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1151         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1152 }
1153
1154 void spawnfunc_item_armor_medium (void) {
1155         if(!self.armorvalue)
1156                 self.armorvalue = g_pickup_armormedium;
1157         if(!self.max_armorvalue)
1158                 self.max_armorvalue = g_pickup_armormedium_max;
1159         if(!self.pickup_anyway)
1160                 self.pickup_anyway = g_pickup_armormedium_anyway;
1161         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1162 }
1163
1164 void spawnfunc_item_armor_big (void) {
1165         if(!self.armorvalue)
1166                 self.armorvalue = g_pickup_armorbig;
1167         if(!self.max_armorvalue)
1168                 self.max_armorvalue = g_pickup_armorbig_max;
1169         if(!self.pickup_anyway)
1170                 self.pickup_anyway = g_pickup_armorbig_anyway;
1171         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1172 }
1173
1174 void spawnfunc_item_armor_large (void) {
1175         if(!self.armorvalue)
1176                 self.armorvalue = g_pickup_armorlarge;
1177         if(!self.max_armorvalue)
1178                 self.max_armorvalue = g_pickup_armorlarge_max;
1179         if(!self.pickup_anyway)
1180                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1181         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1182 }
1183
1184 void spawnfunc_item_health_small (void) {
1185         if(!self.max_health)
1186                 self.max_health = g_pickup_healthsmall_max;
1187         if(!self.health)
1188                 self.health = g_pickup_healthsmall;
1189         if(!self.pickup_anyway)
1190                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1191         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1192 }
1193
1194 void spawnfunc_item_health_medium (void) {
1195         if(!self.max_health)
1196                 self.max_health = g_pickup_healthmedium_max;
1197         if(!self.health)
1198                 self.health = g_pickup_healthmedium;
1199         if(!self.pickup_anyway)
1200                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1201         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1202 }
1203
1204 void spawnfunc_item_health_large (void) {
1205         if(!self.max_health)
1206                 self.max_health = g_pickup_healthlarge_max;
1207         if(!self.health)
1208                 self.health = g_pickup_healthlarge;
1209         if(!self.pickup_anyway)
1210                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1211         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1212 }
1213
1214 void spawnfunc_item_health_mega (void) {
1215         if(g_minstagib) {
1216                 minstagib_items(IT_NAILS);
1217         } else {
1218                 if(!self.max_health)
1219                         self.max_health = g_pickup_healthmega_max;
1220                 if(!self.health)
1221                         self.health = g_pickup_healthmega;
1222                 if(!self.pickup_anyway)
1223                         self.pickup_anyway = g_pickup_healthmega_anyway;
1224                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1225         }
1226 }
1227
1228 // support old misnamed entities
1229 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1230 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1231 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1232 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1233 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1234
1235 void spawnfunc_item_strength (void) {
1236         if(g_minstagib) {
1237                 minstagib_items(IT_STRENGTH);
1238         } else {
1239                 precache_sound("weapons/strength_fire.wav");
1240                 self.strength_finished = 30;
1241                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1242         }
1243 }
1244
1245 void spawnfunc_item_invincible (void) {
1246         if(g_minstagib) {
1247                 minstagib_items(IT_INVINCIBLE);
1248         } else {
1249                 self.invincible_finished = 30;
1250                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1251         }
1252 }
1253
1254 void spawnfunc_item_minst_cells (void) {
1255         if (g_minstagib)
1256         {
1257                 minst_no_auto_cells = 1;
1258                 minstagib_items(IT_CELLS);
1259         }
1260         else
1261                 remove(self);
1262 }
1263
1264 // compatibility:
1265 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1266
1267 float GiveItems(entity e, float beginarg, float endarg);
1268 void target_items_use (void)
1269 {
1270         if(activator.classname == "droppedweapon")
1271         {
1272                 EXACTTRIGGER_TOUCH;
1273                 remove(activator);
1274                 return;
1275         }
1276
1277         if(activator.classname != "player")
1278                 return;
1279         if(activator.deadflag != DEAD_NO)
1280                 return;
1281         EXACTTRIGGER_TOUCH;
1282
1283         entity e;
1284         for(e = world; (e = find(e, classname, "droppedweapon")); )
1285                 if(e.enemy == activator)
1286                         remove(e);
1287
1288         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1289                 centerprint(activator, self.message);
1290 }
1291
1292 void spawnfunc_target_items (void)
1293 {
1294         float n, i, j;
1295         entity e;
1296
1297         self.use = target_items_use;
1298         if(!self.strength_finished)
1299                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1300         if(!self.invincible_finished)
1301                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1302
1303         precache_sound("misc/itempickup.wav");
1304         precache_sound("misc/megahealth.wav");
1305         precache_sound("misc/armor25.wav");
1306         precache_sound("misc/powerup.wav");
1307         precache_sound("misc/poweroff.wav");
1308         precache_sound("weapons/weaponpickup.wav");
1309
1310         n = tokenize_console(self.netname);
1311         if(argv(0) == "give")
1312         {
1313                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1314         }
1315         else
1316         {
1317                 for(i = 0; i < n; ++i)
1318                 {
1319                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1320                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1321                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1322                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1323                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1324                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1325                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1326                         else
1327                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1328                         {
1329                                 e = get_weaponinfo(j);
1330                                 if(argv(i) == e.netname)
1331                                 {
1332                                         self.weapons |= e.weapons;
1333                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1334                                                 weapon_action(e.weapon, WR_PRECACHE);
1335                                         break;
1336                                 }
1337                         }
1338                         if(j > WEP_LAST)
1339                                 print("target_items: invalid item ", argv(i), "\n");
1340                 }
1341
1342                 string itemprefix, valueprefix;
1343                 if(self.spawnflags == 0)
1344                 {
1345                         itemprefix = "";
1346                         valueprefix = "";
1347                 }
1348                 else if(self.spawnflags == 1)
1349                 {
1350                         itemprefix = "max ";
1351                         valueprefix = "max ";
1352                 }
1353                 else if(self.spawnflags == 2)
1354                 {
1355                         itemprefix = "min ";
1356                         valueprefix = "min ";
1357                 }
1358                 else if(self.spawnflags == 4)
1359                 {
1360                         itemprefix = "minus ";
1361                         valueprefix = "max ";
1362                 }
1363                 else
1364                         error("invalid spawnflags");
1365
1366                 self.netname = "";
1367                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1368                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1369                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1370                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1371                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1372                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1373                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1374                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1375                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1376                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1377                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1378                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1379                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1380                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1381                 {
1382                         e = get_weaponinfo(j);
1383                         if(e.weapons)
1384                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1385                 }
1386         }
1387         self.netname = strzone(self.netname);
1388         //print(self.netname, "\n");
1389
1390         n = tokenize_console(self.netname);
1391         for(i = 0; i < n; ++i)
1392         {
1393                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1394                 {
1395                         e = get_weaponinfo(j);
1396                         if(argv(i) == e.netname)
1397                         {
1398                                 weapon_action(e.weapon, WR_PRECACHE);
1399                                 break;
1400                         }
1401                 }
1402         }
1403 }
1404
1405 void spawnfunc_item_fuel(void)
1406 {
1407         if(!self.ammo_fuel)
1408                 self.ammo_fuel = g_pickup_fuel;
1409         if(!self.pickup_anyway)
1410                 self.pickup_anyway = g_pickup_ammo_anyway;
1411         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1412 }
1413
1414 void spawnfunc_item_fuel_regen(void)
1415 {
1416         if(start_items & IT_FUEL_REGEN)
1417         {
1418                 spawnfunc_item_fuel();
1419                 return;
1420         }
1421         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1422 }
1423
1424 void spawnfunc_item_jetpack(void)
1425 {
1426         if(g_grappling_hook)
1427                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1428         if(!self.ammo_fuel)
1429                 self.ammo_fuel = g_pickup_fuel_jetpack;
1430         if(start_items & IT_JETPACK)
1431         {
1432                 spawnfunc_item_fuel();
1433                 return;
1434         }
1435         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1436 }
1437
1438
1439 #define OP_SET 0
1440 #define OP_MIN 1
1441 #define OP_MAX 2
1442 #define OP_PLUS 3
1443 #define OP_MINUS 4
1444
1445 float GiveBit(entity e, .float fld, float bit, float op, float val)
1446 {
1447         float v0, v1;
1448         v0 = (e.fld & bit);
1449         switch(op)
1450         {
1451                 case OP_SET:
1452                         if(val > 0)
1453                                 e.fld |= bit;
1454                         else
1455                                 e.fld &~= bit;
1456                         break;
1457                 case OP_MIN:
1458                 case OP_PLUS:
1459                         if(val > 0)
1460                                 e.fld |= bit;
1461                         break;
1462                 case OP_MAX:
1463                         if(val <= 0)
1464                                 e.fld &~= bit;
1465                         break;
1466                 case OP_MINUS:
1467                         if(val > 0)
1468                                 e.fld &~= bit;
1469                         break;
1470         }
1471         v1 = (e.fld & bit);
1472         return (v0 != v1);
1473 }
1474
1475 float GiveValue(entity e, .float fld, float op, float val)
1476 {
1477         float v0, v1;
1478         v0 = e.fld;
1479         switch(op)
1480         {
1481                 case OP_SET:
1482                         e.fld = val;
1483                         break;
1484                 case OP_MIN:
1485                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1486                         break;
1487                 case OP_MAX:
1488                         e.fld = min(e.fld, val);
1489                         break;
1490                 case OP_PLUS:
1491                         e.fld += val;
1492                         break;
1493                 case OP_MINUS:
1494                         e.fld -= val;
1495                         break;
1496         }
1497         v1 = e.fld;
1498         return (v0 != v1);
1499 }
1500
1501 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1502 {
1503         if(v1 == v0)
1504                 return;
1505         if(v1 <= v0 - t)
1506         {
1507                 if(snd_decr != "")
1508                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1509         }
1510         else if(v0 >= v0 + t)
1511         {
1512                 if(snd_incr != "")
1513                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1514         }
1515 }
1516
1517 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1518 {
1519         if(v0 < v1)
1520                 e.rotfield = max(e.rotfield, time + rottime);
1521         else if(v0 > v1)
1522                 e.regenfield = max(e.regenfield, time + regentime);
1523 }
1524
1525 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1526 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1527 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1528 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1529
1530 float GiveItems(entity e, float beginarg, float endarg)
1531 {
1532         float got, i, j, val, op;
1533         float _switchweapon;
1534         entity wi;
1535         string cmd;
1536
1537         val = 999;
1538         op = OP_SET;
1539
1540         got = 0;
1541
1542         _switchweapon = FALSE;
1543         if (e.autoswitch)
1544                 if (e.switchweapon == w_getbestweapon(e))
1545                         _switchweapon = TRUE;
1546
1547         e.strength_finished = max(0, e.strength_finished - time);
1548         e.invincible_finished = max(0, e.invincible_finished - time);
1549
1550         PREGIVE(e, items);
1551         PREGIVE(e, weapons);
1552         PREGIVE(e, strength_finished);
1553         PREGIVE(e, invincible_finished);
1554         PREGIVE(e, ammo_nails);
1555         PREGIVE(e, ammo_cells);
1556         PREGIVE(e, ammo_shells);
1557         PREGIVE(e, ammo_rockets);
1558         PREGIVE(e, ammo_fuel);
1559         PREGIVE(e, armorvalue);
1560         PREGIVE(e, health);
1561
1562         for(i = beginarg; i < endarg; ++i)
1563         {
1564                 cmd = argv(i);
1565
1566                 if(cmd == "0" || stof(cmd))
1567                 {
1568                         val = stof(cmd);
1569                         continue;
1570                 }
1571                 switch(cmd)
1572                 {
1573                         case "no":
1574                                 op = OP_MAX;
1575                                 val = 0;
1576                                 continue;
1577                         case "max":
1578                                 op = OP_MAX;
1579                                 continue;
1580                         case "min":
1581                                 op = OP_MIN;
1582                                 continue;
1583                         case "plus":
1584                                 op = OP_PLUS;
1585                                 continue;
1586                         case "minus":
1587                                 op = OP_MINUS;
1588                                 continue;
1589                         case "ALL":
1590                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1591                                 got += GiveValue(e, strength_finished, op, time);
1592                                 got += GiveValue(e, invincible_finished, op, time);
1593                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1594                         case "all":
1595                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1596                                 got += GiveValue(e, health, op, val);
1597                                 got += GiveValue(e, armorvalue, op, val);
1598                         case "allweapons":
1599                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1600                                 {
1601                                         wi = get_weaponinfo(j);
1602                                         if(wi.weapons)
1603                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1604                                 }
1605                         case "allammo":
1606                                 got += GiveValue(e, ammo_cells, op, val);
1607                                 got += GiveValue(e, ammo_shells, op, val);
1608                                 got += GiveValue(e, ammo_nails, op, val);
1609                                 got += GiveValue(e, ammo_rockets, op, val);
1610                                 got += GiveValue(e, ammo_fuel, op, val);
1611                                 break;
1612                         case "unlimited_ammo":
1613                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1614                                 break;
1615                         case "unlimited_weapon_ammo":
1616                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1617                                 break;
1618                         case "unlimited_superweapons":
1619                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1620                                 break;
1621                         case "jetpack":
1622                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1623                                 break;
1624                         case "fuel_regen":
1625                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1626                                 break;
1627                         case "strength":
1628                                 got += GiveValue(e, strength_finished, op, val);
1629                                 break;
1630                         case "invincible":
1631                                 got += GiveValue(e, invincible_finished, op, val);
1632                                 break;
1633                         case "cells":
1634                                 got += GiveValue(e, ammo_cells, op, val);
1635                                 break;
1636                         case "shells":
1637                                 got += GiveValue(e, ammo_shells, op, val);
1638                                 break;
1639                         case "nails":
1640                         case "bullets":
1641                                 got += GiveValue(e, ammo_nails, op, val);
1642                                 break;
1643                         case "rockets":
1644                                 got += GiveValue(e, ammo_rockets, op, val);
1645                                 break;
1646                         case "health":
1647                                 got += GiveValue(e, health, op, val);
1648                                 break;
1649                         case "armor":
1650                                 got += GiveValue(e, armorvalue, op, val);
1651                                 break;
1652                         case "fuel":
1653                                 got += GiveValue(e, ammo_fuel, op, val);
1654                                 break;
1655                         default:
1656                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1657                                 {
1658                                         wi = get_weaponinfo(j);
1659                                         if(cmd == wi.netname)
1660                                         {
1661                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1662                                                 break;
1663                                         }
1664                                 }
1665                                 if(j > WEP_LAST)
1666                                         print("give: invalid item ", cmd, "\n");
1667                                 break;
1668                 }
1669                 val = 999;
1670                 op = OP_SET;
1671         }
1672
1673         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1674         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1675         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1676         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1677         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1678         {
1679                 wi = get_weaponinfo(j);
1680                 if(wi.weapons)
1681                 {
1682                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1683                         if not(save_weapons & wi.weapons)
1684                                 if(e.weapons & wi.weapons)
1685                                         weapon_action(wi.weapon, WR_PRECACHE);
1686                 }
1687         }
1688         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1689         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1690         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1691         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1692         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1693         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1694         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1695         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1696         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1697
1698         if (g_minstagib)
1699         {
1700                 e.health = bound(0, e.health, 100);
1701                 e.armorvalue = bound(0, e.armorvalue, 999);
1702         }
1703
1704         if(e.strength_finished <= 0)
1705                 e.strength_finished = 0;
1706         else
1707                 e.strength_finished += time;
1708         if(e.invincible_finished <= 0)
1709                 e.invincible_finished = 0;
1710         else
1711                 e.invincible_finished += time;
1712
1713         if not(e.weapons & W_WeaponBit(e.switchweapon))
1714                 _switchweapon = TRUE;
1715         if(_switchweapon)
1716                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1717
1718         return got;
1719 }