qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "bot/bot.qh"
   8     #include "bot/waypoints.qh"
   9
  10     #include "mutators/mutators_include.qh"
  11
  12     #include "weapons/common.qh"
  13     #include "weapons/selection.qh"
  14     #include "weapons/weaponsystem.qh"
  15
  16     #include "../common/constants.qh"
  17     #include "../common/deathtypes/all.qh"
  18     #include "../common/notifications.qh"
  19         #include "../common/triggers/subs.qh"
  20     #include "../common/util.qh"
  21
  22     #include "../common/monsters/all.qh"
  23
  24     #include "../common/weapons/all.qh"
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #endif
  28
  29 #ifdef CSQC
  30 void ItemDraw(entity self)
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple(entity this)
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void Item_PreDraw()
  78 {SELFPARAM();
  79         vector org;
  80         float alph;
  81         org = getpropertyvec(VF_ORIGIN);
  82         if(!checkpvs(org, self)) // this makes sense as long as we don't support recursive warpzones
  83                 alph = 0;
  84         else if(self.fade_start)
  85                 alph = bound(0, (self.fade_end - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.fade_end - self.fade_start), 1);
  86         else
  87                 alph = 1;
  88         //printf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs));
  89         if(self.ItemStatus & ITS_AVAILABLE)
  90                 self.alpha = alph;
  91         if(alph <= 0)
  92                 self.drawmask = 0;
  93         else
  94                 self.drawmask = MASK_NORMAL;
  95 }
  96
  97 void ItemRead(float _IsNew)
  98 {SELFPARAM();
  99     int sf = ReadByte();
 100
 101     if(sf & ISF_LOCATION)
 102     {
 103         self.origin_x = ReadCoord();
 104         self.origin_y = ReadCoord();
 105         self.origin_z = ReadCoord();
 106         setorigin(self, self.origin);
 107         self.oldorigin = self.origin;
 108     }
 109
 110     if(sf & ISF_ANGLES)
 111     {
 112         self.angles_x = ReadAngle();
 113         self.angles_y = ReadAngle();
 114         self.angles_z = ReadAngle();
 115         self.move_angles = self.angles;
 116     }
 117
 118     if(sf & ISF_SIZE)
 119     {
 120         float use_bigsize = ReadByte();
 121         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 122     }
 123
 124     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 125     {
 126         self.ItemStatus = ReadByte();
 127
 128         if(self.ItemStatus & ITS_AVAILABLE)
 129         {
 130             self.alpha = 1;
 131             self.colormod = self.glowmod = '1 1 1';
 132         }
 133         else
 134         {
 135             if (autocvar_cl_ghost_items_color)
 136             {
 137                 self.alpha = autocvar_cl_ghost_items;
 138                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 139             }
 140             else
 141                 self.alpha = -1;
 142         }
 143
 144         if(autocvar_cl_fullbright_items)
 145             if(self.ItemStatus & ITS_ALLOWFB)
 146                 self.effects |= EF_FULLBRIGHT;
 147
 148         if(self.ItemStatus & ITS_STAYWEP)
 149         {
 150             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 151             self.alpha = autocvar_cl_weapon_stay_alpha;
 152
 153         }
 154
 155         if(self.ItemStatus & ITS_POWERUP)
 156         {
 157             if(self.ItemStatus & ITS_AVAILABLE)
 158                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 159             else
 160                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 161         }
 162     }
 163
 164     if(sf & ISF_MODEL)
 165     {
 166         self.drawmask  = MASK_NORMAL;
 167                 self.move_movetype = self.movetype = MOVETYPE_TOSS;
 168         self.draw       = ItemDraw;
 169
 170         self.fade_end = ReadShort();
 171         self.fade_start = ReadShort();
 172         if(self.fade_start && !autocvar_cl_items_nofade)
 173                 self.predraw = Item_PreDraw;
 174
 175         if(self.mdl)
 176             strunzone(self.mdl);
 177
 178         self.mdl = "";
 179         string _fn = ReadString();
 180
 181         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 182         {
 183             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 184             self.draw = ItemDrawSimple;
 185
 186             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 187                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 188             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 189                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 190             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 191                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 192             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 193                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 194             else
 195             {
 196                 self.draw = ItemDraw;
 197                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 198             }
 199         }
 200
 201         if(self.draw != ItemDrawSimple)
 202             self.mdl = strzone(_fn);
 203
 204
 205         if(self.mdl == "")
 206             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 207
 208         precache_model(self.mdl);
 209         _setmodel(self, self.mdl);
 210     }
 211
 212     if(sf & ISF_COLORMAP)
 213         self.colormap = ReadShort();
 214
 215     if(sf & ISF_DROP)
 216     {
 217         self.gravity = 1;
 218         //self.move_angles = '0 0 0';
 219         self.move_movetype = MOVETYPE_TOSS;
 220         self.move_velocity_x = ReadCoord();
 221         self.move_velocity_y = ReadCoord();
 222         self.move_velocity_z = ReadCoord();
 223         self.velocity = self.move_velocity;
 224         self.move_origin = self.oldorigin;
 225
 226         if(!self.move_time)
 227         {
 228             self.move_time = time;
 229             self.spawntime = time;
 230         }
 231         else
 232             self.move_time = max(self.move_time, time);
 233     }
 234
 235     if(autocvar_cl_animate_items)
 236     {
 237         if(self.ItemStatus & ITS_ANIMATE1)
 238             self.move_avelocity = '0 180 0';
 239
 240         if(self.ItemStatus & ITS_ANIMATE2)
 241             self.move_avelocity = '0 -90 0';
 242     }
 243 }
 244
 245 #endif
 246
 247 #ifdef SVQC
 248 bool ItemSend(entity this, entity to, int sf)
 249 {
 250         if(self.gravity)
 251                 sf |= ISF_DROP;
 252         else
 253                 sf &= ~ISF_DROP;
 254
 255         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 256         WriteByte(MSG_ENTITY, sf);
 257
 258         //WriteByte(MSG_ENTITY, self.cnt);
 259         if(sf & ISF_LOCATION)
 260         {
 261                 WriteCoord(MSG_ENTITY, self.origin.x);
 262                 WriteCoord(MSG_ENTITY, self.origin.y);
 263                 WriteCoord(MSG_ENTITY, self.origin.z);
 264         }
 265
 266         if(sf & ISF_ANGLES)
 267         {
 268                 WriteAngle(MSG_ENTITY, self.angles_x);
 269                 WriteAngle(MSG_ENTITY, self.angles_y);
 270                 WriteAngle(MSG_ENTITY, self.angles_z);
 271         }
 272
 273         if(sf & ISF_SIZE)
 274         {
 275                 WriteByte(MSG_ENTITY, ((self.flags & FL_POWERUP) || self.health || self.armorvalue));
 276         }
 277
 278         if(sf & ISF_STATUS)
 279                 WriteByte(MSG_ENTITY, self.ItemStatus);
 280
 281         if(sf & ISF_MODEL)
 282         {
 283                 WriteShort(MSG_ENTITY, self.fade_end);
 284                 WriteShort(MSG_ENTITY, self.fade_start);
 285
 286                 if(self.mdl == "")
 287                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 288
 289                 WriteString(MSG_ENTITY, self.mdl);
 290         }
 291
 292
 293         if(sf & ISF_COLORMAP)
 294                 WriteShort(MSG_ENTITY, self.colormap);
 295
 296         if(sf & ISF_DROP)
 297         {
 298                 WriteCoord(MSG_ENTITY, self.velocity.x);
 299                 WriteCoord(MSG_ENTITY, self.velocity.y);
 300                 WriteCoord(MSG_ENTITY, self.velocity.z);
 301         }
 302
 303         return true;
 304 }
 305
 306 void ItemUpdate(entity item)
 307 {
 308         item.SendFlags |= ISF_LOCATION;
 309 }
 310
 311 float have_pickup_item(void)
 312 {SELFPARAM();
 313         if(self.flags & FL_POWERUP)
 314         {
 315                 if(autocvar_g_powerups > 0)
 316                         return true;
 317                 if(autocvar_g_powerups == 0)
 318                         return false;
 319         }
 320         else
 321         {
 322                 if(autocvar_g_pickup_items > 0)
 323                         return true;
 324                 if(autocvar_g_pickup_items == 0)
 325                         return false;
 326                 if(g_weaponarena)
 327                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 328                                 return false;
 329         }
 330         return true;
 331 }
 332
 333 /*
 334 float Item_Customize()
 335 {
 336         if(self.spawnshieldtime)
 337                 return true;
 338         if(self.weapons & ~other.weapons)
 339         {
 340                 self.colormod = '0 0 0';
 341                 self.glowmod = self.colormod;
 342                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 343                 return true;
 344         }
 345         else
 346         {
 347                 if(g_ghost_items)
 348                 {
 349                         self.colormod = stov(autocvar_g_ghost_items_color);
 350                         self.glowmod = self.colormod;
 351                         self.alpha = g_ghost_items;
 352                         return true;
 353                 }
 354                 else
 355                         return false;
 356         }
 357 }
 358 */
 359
 360 void Item_Show (entity e, float mode)
 361 {
 362         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 363         e.ItemStatus &= ~ITS_STAYWEP;
 364         if (mode > 0)
 365         {
 366                 // make the item look normal, and be touchable
 367                 e.model = e.mdl;
 368                 e.solid = SOLID_TRIGGER;
 369                 e.spawnshieldtime = 1;
 370                 e.ItemStatus |= ITS_AVAILABLE;
 371         }
 372         else if (mode < 0)
 373         {
 374                 // hide the item completely
 375                 e.model = string_null;
 376                 e.solid = SOLID_NOT;
 377                 e.spawnshieldtime = 1;
 378                 e.ItemStatus &= ~ITS_AVAILABLE;
 379         }
 380         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 381         {
 382                 // make the item translucent and not touchable
 383                 e.model = e.mdl;
 384                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 385                 e.effects |= EF_STARDUST;
 386                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 387                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 388         }
 389         else
 390         {
 391                 //setmodel(e, "null");
 392                 e.solid = SOLID_NOT;
 393                 e.colormod = '0 0 0';
 394                 e.glowmod = e.colormod;
 395                 e.spawnshieldtime = 1;
 396                 e.ItemStatus &= ~ITS_AVAILABLE;
 397         }
 398
 399         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 400                 e.ItemStatus |= ITS_POWERUP;
 401
 402         if (autocvar_g_nodepthtestitems)
 403                 e.effects |= EF_NODEPTHTEST;
 404
 405
 406         if (autocvar_g_fullbrightitems)
 407                 e.ItemStatus |= ITS_ALLOWFB;
 408
 409         if (autocvar_sv_simple_items)
 410                 e.ItemStatus |= ITS_ALLOWSI;
 411
 412         // relink entity (because solid may have changed)
 413         setorigin(e, e.origin);
 414         e.SendFlags |= ISF_STATUS;
 415 }
 416
 417 void Item_Think()
 418 {SELFPARAM();
 419         self.nextthink = time;
 420         if(self.origin != self.oldorigin)
 421         {
 422                 self.oldorigin = self.origin;
 423                 ItemUpdate(self);
 424         }
 425 }
 426
 427 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 428 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 429 float Item_ItemsTime_UpdateTime(entity e, float t);
 430 void Item_ItemsTime_SetTime(entity e, float t);
 431 void Item_ItemsTime_SetTimesForAllPlayers();
 432
 433 void Item_Respawn (void)
 434 {SELFPARAM();
 435         Item_Show(self, 1);
 436         // this is ugly...
 437         if(self.items == ITEM_Strength.m_itemid)
 438                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 439         else if(self.items == ITEM_Shield.m_itemid)
 440                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 441         else
 442                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 443         setorigin (self, self.origin);
 444
 445     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 446         {
 447                 float t = Item_ItemsTime_UpdateTime(self, 0);
 448                 Item_ItemsTime_SetTime(self, t);
 449                 Item_ItemsTime_SetTimesForAllPlayers();
 450         }
 451
 452         self.think = Item_Think;
 453         self.nextthink = time;
 454
 455         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 456         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 457 }
 458
 459 void Item_RespawnCountdown (void)
 460 {SELFPARAM();
 461         if(self.count >= ITEM_RESPAWN_TICKS)
 462         {
 463                 if(self.waypointsprite_attached)
 464                         WaypointSprite_Kill(self.waypointsprite_attached);
 465                 Item_Respawn();
 466         }
 467         else
 468         {
 469                 self.nextthink = time + 1;
 470                 self.count += 1;
 471                 if(self.count == 1)
 472                 {
 473                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 474                         do {
 475                                 {
 476                                         entity wi = get_weaponinfo(self.weapon);
 477                                         if (wi.m_id) {
 478                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
 479                                                 wp.wp_extra = wi.m_id;
 480                                                 break;
 481                                         }
 482                                 }
 483                                 {
 484                                         entity ii = self.itemdef;
 485                                         if (ii.m_id) {
 486                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
 487                                                 wp.wp_extra = ii.m_id;
 488                                                 break;
 489                                         }
 490                                 }
 491                         } while (0);
 492             if(self.waypointsprite_attached)
 493             {
 494                 GameItem def = self.itemdef;
 495                 if (Item_ItemsTime_SpectatorOnly(def))
 496                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 497                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 498             }
 499                 }
 500
 501                 if(self.waypointsprite_attached)
 502                 {
 503                         setself(self.waypointsprite_attached);
 504                         entity e;
 505                         FOR_EACH_REALCLIENT(e)
 506                                 if(self.waypointsprite_visible_for_player(e))
 507                                 {
 508                                         msg_entity = e;
 509                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 510                                 }
 511                         setself(this);
 512
 513                         WaypointSprite_Ping(self.waypointsprite_attached);
 514                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 515                 }
 516                 else
 517                         sound(self, CH_TRIGGER, SND_ITEMRESPAWNCOUNTDOWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 518         }
 519 }
 520
 521 void Item_RespawnThink()
 522 {SELFPARAM();
 523         self.nextthink = time;
 524         if(self.origin != self.oldorigin)
 525         {
 526                 self.oldorigin = self.origin;
 527                 ItemUpdate(self);
 528         }
 529
 530         if(time >= self.wait)
 531                 Item_Respawn();
 532 }
 533
 534 void Item_ScheduleRespawnIn(entity e, float t)
 535 {
 536         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 537         {
 538                 e.think = Item_RespawnCountdown;
 539                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 540                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 541                 e.count = 0;
 542                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 543                 Item_ItemsTime_SetTime(e, t);
 544                 Item_ItemsTime_SetTimesForAllPlayers();
 545         }
 546         else
 547         {
 548                 e.think = Item_RespawnThink;
 549                 e.nextthink = time;
 550                 e.scheduledrespawntime = time + t;
 551                 e.wait = time + t;
 552         }
 553 }
 554
 555 void Item_ScheduleRespawn(entity e)
 556 {
 557         if(e.respawntime > 0)
 558         {
 559                 Item_Show(e, 0);
 560                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 561         }
 562         else // if respawntime is -1, this item does not respawn
 563                 Item_Show(e, -1);
 564 }
 565
 566 void Item_ScheduleInitialRespawn(entity e)
 567 {
 568         Item_Show(e, 0);
 569         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 570 }
 571
 572 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 573 {
 574         if (!item.(ammotype))
 575                 return false;
 576
 577         if (item.spawnshieldtime)
 578         {
 579                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 580                 {
 581                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 582                         goto YEAH;
 583                 }
 584         }
 585         else if(g_weapon_stay == 2)
 586         {
 587                 float mi = min(item.(ammotype), ammomax);
 588                 if (player.(ammotype) < mi)
 589                 {
 590                         player.(ammotype) = mi;
 591                         goto YEAH;
 592                 }
 593         }
 594
 595         return false;
 596
 597 :YEAH
 598         switch(mode)
 599         {
 600                 case ITEM_MODE_FUEL:
 601                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 602                         break;
 603                 case ITEM_MODE_HEALTH:
 604                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 605                         break;
 606                 case ITEM_MODE_ARMOR:
 607                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 608                         break;
 609                 default:
 610                         break;
 611         }
 612         return true;
 613 }
 614
 615 float Item_GiveTo(entity item, entity player)
 616 {
 617         float _switchweapon;
 618         float pickedup;
 619         float it;
 620         float i;
 621
 622         // if nothing happens to player, just return without taking the item
 623         pickedup = false;
 624         _switchweapon = false;
 625         // in case the player has autoswitch enabled do the following:
 626         // if the player is using their best weapon before items are given, they
 627         // probably want to switch to an even better weapon after items are given
 628         if (player.autoswitch)
 629         if (player.switchweapon == w_getbestweapon(player))
 630                 _switchweapon = true;
 631
 632         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 633                 _switchweapon = true;
 634
 635         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 636         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 637         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 638         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 639         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 640         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 641         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 642         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 643
 644         if (item.flags & FL_WEAPON)
 645         {
 646                 WepSet it;
 647                 it = item.weapons;
 648                 it &= ~player.weapons;
 649
 650                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 651                 {
 652                         pickedup = true;
 653                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 654                         if(it & WepSet_FromWeapon(i))
 655                         {
 656                                 W_DropEvent(wr_pickup, player, i, item);
 657                                 W_GiveWeapon(player, i);
 658                         }
 659                 }
 660         }
 661
 662         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 663         {
 664                 pickedup = true;
 665                 player.items |= it;
 666                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 667         }
 668
 669         if (item.strength_finished)
 670         {
 671                 pickedup = true;
 672                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 673         }
 674         if (item.invincible_finished)
 675         {
 676                 pickedup = true;
 677                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 678         }
 679         if (item.superweapons_finished)
 680         {
 681                 pickedup = true;
 682                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 683         }
 684
 685 :skip
 686
 687         // always eat teamed entities
 688         if(item.team)
 689                 pickedup = true;
 690
 691         if (!pickedup)
 692                 return 0;
 693
 694         // crude hack to enforce switching weapons
 695         if(g_cts && (item.flags & FL_WEAPON))
 696         {
 697                 W_SwitchWeapon_Force(player, item.weapon);
 698                 return 1;
 699         }
 700
 701         if (_switchweapon)
 702                 if (player.switchweapon != w_getbestweapon(player))
 703                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 704
 705         return 1;
 706 }
 707
 708 void Item_Touch (void)
 709 {SELFPARAM();
 710         entity e, head;
 711
 712         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 713         if(self.classname == "droppedweapon")
 714         {
 715                 if (ITEM_TOUCH_NEEDKILL())
 716                 {
 717                         remove(self);
 718                         return;
 719                 }
 720         }
 721
 722         if(!(other.flags & FL_PICKUPITEMS)
 723         || other.frozen
 724         || other.deadflag
 725         || (self.solid != SOLID_TRIGGER)
 726         || (self.owner == other)
 727         || (time < self.item_spawnshieldtime)
 728         ) { return;}
 729
 730         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 731         {
 732                 case MUT_ITEMTOUCH_RETURN: { return; }
 733                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 734         }
 735
 736         if (self.classname == "droppedweapon")
 737         {
 738                 self.strength_finished = max(0, self.strength_finished - time);
 739                 self.invincible_finished = max(0, self.invincible_finished - time);
 740                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 741         }
 742         entity it = self.itemdef;
 743         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 744         if (!gave)
 745         {
 746                 if (self.classname == "droppedweapon")
 747                 {
 748                         // undo what we did above
 749                         self.strength_finished += time;
 750                         self.invincible_finished += time;
 751                         self.superweapons_finished += time;
 752                 }
 753                 return;
 754         }
 755
 756         :pickup
 757
 758         other.last_pickup = time;
 759
 760         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 761         _sound (other, CH_TRIGGER, (self.item_pickupsound ? self.item_pickupsound : self.item_pickupsound_ent.sound_str()), VOL_BASE, ATTEN_NORM);
 762
 763         if (self.classname == "droppedweapon")
 764                 remove (self);
 765         else if (self.spawnshieldtime)
 766         {
 767                 if(self.team)
 768                 {
 769                         RandomSelection_Init();
 770                         for(head = world; (head = findfloat(head, team, self.team)); )
 771                         {
 772                                 if(head.flags & FL_ITEM)
 773                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 774                                 {
 775                                         Item_Show(head, -1);
 776                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 777                                 }
 778                         }
 779                         e = RandomSelection_chosen_ent;
 780
 781                 }
 782                 else
 783                         e = self;
 784                 Item_ScheduleRespawn(e);
 785         }
 786 }
 787
 788 void Item_Reset()
 789 {SELFPARAM();
 790         Item_Show(self, !self.state);
 791         setorigin (self, self.origin);
 792
 793         if(self.classname != "droppedweapon")
 794         {
 795                 self.think = Item_Think;
 796                 self.nextthink = time;
 797
 798                 if(self.waypointsprite_attached)
 799                         WaypointSprite_Kill(self.waypointsprite_attached);
 800
 801                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 802                         Item_ScheduleInitialRespawn(self);
 803         }
 804 }
 805
 806 void Item_FindTeam()
 807 {SELFPARAM();
 808         entity head, e;
 809
 810         if(self.effects & EF_NODRAW)
 811         {
 812                 // marker for item team search
 813                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 814                 RandomSelection_Init();
 815                 for(head = world; (head = findfloat(head, team, self.team)); )
 816                 if(head.flags & FL_ITEM)
 817                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 818                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 819                 e = RandomSelection_chosen_ent;
 820                 e.state = 0;
 821                 Item_Show(e, 1);
 822
 823                 for(head = world; (head = findfloat(head, team, self.team)); )
 824                 if(head.flags & FL_ITEM)
 825                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 826                 {
 827                         if(head != e)
 828                         {
 829                                 // make it a non-spawned item
 830                                 Item_Show(head, -1);
 831                                 head.state = 1; // state 1 = initially hidden item
 832                         }
 833                         head.effects &= ~EF_NODRAW;
 834                 }
 835
 836                 Item_Reset();
 837         }
 838 }
 839
 840 // Savage: used for item garbage-collection
 841 // TODO: perhaps nice special effect?
 842 void RemoveItem(void)
 843 {SELFPARAM();
 844         if(wasfreed(self) || !self) { return; }
 845         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 846         remove(self);
 847 }
 848
 849 // pickup evaluation functions
 850 // these functions decide how desirable an item is to the bots
 851
 852 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 853
 854 float weapon_pickupevalfunc(entity player, entity item)
 855 {
 856         float c;
 857
 858         // See if I have it already
 859         if(item.weapons & ~player.weapons)
 860         {
 861                 // If I can pick it up
 862                 if(!item.spawnshieldtime)
 863                         c = 0;
 864                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 865                 {
 866                         // Skilled bots will grab more
 867                         c = bound(0, skill / 10, 1) * 0.5;
 868                 }
 869                 else
 870                         c = 0;
 871         }
 872         else
 873                 c = 1;
 874
 875         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 876         if( bot_custom_weapon && c )
 877         {
 878                 // Find the highest position on any range
 879                 int position = -1;
 880                 for (int j = 0; j < WEP_LAST ; ++j){
 881                         if(
 882                                         bot_weapons_far[j] == item.weapon ||
 883                                         bot_weapons_mid[j] == item.weapon ||
 884                                         bot_weapons_close[j] == item.weapon
 885                           )
 886                         {
 887                                 position = j;
 888                                 break;
 889                         }
 890                 }
 891
 892                 // Rate it
 893                 if (position >= 0 )
 894                 {
 895                         position = WEP_LAST - position;
 896                         // item.bot_pickupbasevalue is overwritten here
 897                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 898                 }
 899         }
 900
 901         return item.bot_pickupbasevalue * c;
 902 }
 903
 904 float commodity_pickupevalfunc(entity player, entity item)
 905 {
 906         float c, i;
 907         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 908         entity wi;
 909         c = 0;
 910
 911         // Detect needed ammo
 912         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 913         {
 914                 wi = get_weaponinfo(i);
 915
 916                 if (!(player.weapons & WepSet_FromWeapon(i)))
 917                         continue;
 918
 919                 if(wi.items & ITEM_Shells.m_itemid)
 920                         need_shells = true;
 921                 else if(wi.items & ITEM_Bullets.m_itemid)
 922                         need_nails = true;
 923                 else if(wi.items & ITEM_Rockets.m_itemid)
 924                         need_rockets = true;
 925                 else if(wi.items & ITEM_Cells.m_itemid)
 926                         need_cells = true;
 927                 else if(wi.items & ITEM_Plasma.m_itemid)
 928                         need_plasma = true;
 929                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 930                         need_fuel = true;
 931         }
 932
 933         // TODO: figure out if the player even has the weapon this ammo is for?
 934         // may not affect strategy much though...
 935         // find out how much more ammo/armor/health the player can hold
 936         if (need_shells)
 937         if (item.ammo_shells)
 938         if (player.ammo_shells < g_pickup_shells_max)
 939                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 940         if (need_nails)
 941         if (item.ammo_nails)
 942         if (player.ammo_nails < g_pickup_nails_max)
 943                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 944         if (need_rockets)
 945         if (item.ammo_rockets)
 946         if (player.ammo_rockets < g_pickup_rockets_max)
 947                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 948         if (need_cells)
 949         if (item.ammo_cells)
 950         if (player.ammo_cells < g_pickup_cells_max)
 951                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 952         if (need_plasma)
 953         if (item.ammo_plasma)
 954         if (player.ammo_plasma < g_pickup_plasma_max)
 955                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 956         if (need_fuel)
 957         if (item.ammo_fuel)
 958         if (player.ammo_fuel < g_pickup_fuel_max)
 959                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 960         if (item.armorvalue)
 961         if (player.armorvalue < item.max_armorvalue)
 962                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 963         if (item.health)
 964         if (player.health < item.max_health)
 965                 c = c + max(0, 1 - player.health / item.max_health);
 966
 967         return item.bot_pickupbasevalue * c;
 968 }
 969
 970 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 971 {
 972         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 973                 RemoveItem();
 974 }
 975
 976 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 977 {SELFPARAM();
 978         startitem_failed = false;
 979
 980         if(self.model == "")
 981                 self.model = itemmodel;
 982
 983         if(self.model == "")
 984     {
 985         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 986         return;
 987     }
 988
 989         if(self.item_pickupsound == "")
 990                 self.item_pickupsound = pickupsound;
 991
 992         if(!self.respawntime) // both need to be set
 993         {
 994                 self.respawntime = defaultrespawntime;
 995                 self.respawntimejitter = defaultrespawntimejitter;
 996         }
 997
 998         self.items = itemid;
 999         self.weapon = weaponid;
1000
1001         if(!self.fade_end)
1002         {
1003                 self.fade_start = autocvar_g_items_mindist;
1004                 self.fade_end = autocvar_g_items_maxdist;
1005         }
1006
1007         if(weaponid)
1008                 self.weapons = WepSet_FromWeapon(weaponid);
1009
1010         self.flags = FL_ITEM | itemflags;
1011
1012         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1013         {
1014                 startitem_failed = true;
1015                 remove(self);
1016                 return;
1017         }
1018
1019         // is it a dropped weapon?
1020         if (self.classname == "droppedweapon")
1021         {
1022                 self.reset = SUB_Remove;
1023                 // it's a dropped weapon
1024                 self.movetype = MOVETYPE_TOSS;
1025
1026                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1027                 self.think = RemoveItem;
1028                 self.nextthink = time + 20;
1029
1030                 self.takedamage = DAMAGE_YES;
1031                 self.event_damage = Item_Damage;
1032
1033                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1034                 /*
1035                 if(self.items == 0)
1036                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1037                 if(self.ammo_nails == 0)
1038                 if(self.ammo_cells == 0)
1039                 if(self.ammo_rockets == 0)
1040                 if(self.ammo_shells == 0)
1041                 if(self.ammo_fuel == 0)
1042                 if(self.health == 0)
1043                 if(self.armorvalue == 0)
1044                 */
1045                 {
1046                         // if item is worthless after a timer, have it expire then
1047                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1048                 }
1049
1050                 // don't drop if in a NODROP zone (such as lava)
1051                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1052                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1053                 {
1054                         startitem_failed = true;
1055                         remove(self);
1056                         return;
1057                 }
1058         }
1059         else
1060         {
1061                 if(!have_pickup_item())
1062                 {
1063                         startitem_failed = true;
1064                         remove (self);
1065                         return;
1066                 }
1067
1068                 if(self.angles != '0 0 0')
1069                         self.SendFlags |= ISF_ANGLES;
1070
1071                 self.reset = Item_Reset;
1072                 // it's a level item
1073                 if(self.spawnflags & 1)
1074                         self.noalign = 1;
1075                 if (self.noalign)
1076                         self.movetype = MOVETYPE_NONE;
1077                 else
1078                         self.movetype = MOVETYPE_TOSS;
1079                 // do item filtering according to game mode and other things
1080                 if (!self.noalign)
1081                 {
1082                         // first nudge it off the floor a little bit to avoid math errors
1083                         setorigin(self, self.origin + '0 0 1');
1084                         // set item size before we spawn a spawnfunc_waypoint
1085                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1086                                 setsize (self, '-16 -16 0', '16 16 48');
1087                         else
1088                                 setsize (self, '-16 -16 0', '16 16 32');
1089                         self.SendFlags |= ISF_SIZE;
1090                         // note droptofloor returns false if stuck/or would fall too far
1091                         droptofloor();
1092                         waypoint_spawnforitem(self);
1093                 }
1094
1095                 /*
1096                  * can't do it that way, as it would break maps
1097                  * TODO make a target_give like entity another way, that perhaps has
1098                  * the weapon name in a key
1099                 if(self.targetname)
1100                 {
1101                         // target_give not yet supported; maybe later
1102                         print("removed targeted ", self.classname, "\n");
1103                         startitem_failed = true;
1104                         remove (self);
1105                         return;
1106                 }
1107                 */
1108
1109                 if(autocvar_spawn_debug >= 2)
1110                 {
1111                         entity otheritem;
1112                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1113                         {
1114                             // why not flags & fl_item?
1115                                 if(otheritem.is_item)
1116                                 {
1117                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(self.origin));
1118                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1119                                         error("Mapper sucks.");
1120                                 }
1121                         }
1122                         self.is_item = true;
1123                 }
1124
1125                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1126
1127                 precache_model (self.model);
1128                 precache_sound (self.item_pickupsound);
1129
1130                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1131                         self.target = "###item###"; // for finding the nearest item using find()
1132
1133                 Item_ItemsTime_SetTime(self, 0);
1134         }
1135
1136         self.bot_pickup = true;
1137         self.bot_pickupevalfunc = pickupevalfunc;
1138         self.bot_pickupbasevalue = pickupbasevalue;
1139         self.mdl = self.model;
1140         self.netname = itemname;
1141         self.touch = Item_Touch;
1142         setmodel(self, MDL_Null); // precision set below
1143         //self.effects |= EF_LOWPRECISION;
1144
1145         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1146         {
1147                 self.pos1 = '-16 -16 0';
1148                 self.pos2 = '16 16 48';
1149         }
1150         else
1151         {
1152                 self.pos1 = '-16 -16 0';
1153                 self.pos2 = '16 16 32';
1154         }
1155         setsize (self, self.pos1, self.pos2);
1156
1157         self.SendFlags |= ISF_SIZE;
1158
1159         if(itemflags & FL_POWERUP)
1160                 self.ItemStatus |= ITS_ANIMATE1;
1161
1162         if(self.armorvalue || self.health)
1163                 self.ItemStatus |= ITS_ANIMATE2;
1164
1165         if(itemflags & FL_WEAPON)
1166         {
1167                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1168                         self.colormap = 1024; // color shirt=0 pants=0 grey
1169                 else
1170                         self.gravity = 1;
1171
1172                 self.ItemStatus |= ITS_ANIMATE1;
1173                 self.ItemStatus |= ISF_COLORMAP;
1174         }
1175
1176         self.state = 0;
1177         if(self.team) // broken, no idea why.
1178         {
1179                 if(!self.cnt)
1180                         self.cnt = 1; // item probability weight
1181
1182                 self.effects |= EF_NODRAW; // marker for item team search
1183                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1184         }
1185         else
1186                 Item_Reset();
1187
1188         Net_LinkEntity(self, !((itemflags & FL_POWERUP) || self.health || self.armorvalue), 0, ItemSend);
1189
1190         // call this hook after everything else has been done
1191         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1192         {
1193                 startitem_failed = true;
1194                 remove(self);
1195                 return;
1196         }
1197 }
1198
1199 void StartItemA (entity a)
1200 {SELFPARAM();
1201     self.itemdef = a;
1202     StartItem(strzone(a.m_model.model_str()), a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1203 }
1204
1205 spawnfunc(item_rockets)
1206 {
1207         if(!self.ammo_rockets)
1208                 self.ammo_rockets = g_pickup_rockets;
1209         if(!self.pickup_anyway)
1210                 self.pickup_anyway = g_pickup_ammo_anyway;
1211     StartItemA (ITEM_Rockets);
1212 }
1213
1214 spawnfunc(item_bullets)
1215 {
1216         if(!weaponswapping)
1217         if(autocvar_sv_q3acompat_machineshotgunswap)
1218         if(self.classname != "droppedweapon")
1219         {
1220                 weaponswapping = true;
1221                 spawnfunc_item_shells(this);
1222                 weaponswapping = false;
1223                 return;
1224         }
1225
1226         if(!self.ammo_nails)
1227                 self.ammo_nails = g_pickup_nails;
1228         if(!self.pickup_anyway)
1229                 self.pickup_anyway = g_pickup_ammo_anyway;
1230     StartItemA (ITEM_Bullets);
1231 }
1232
1233 spawnfunc(item_cells)
1234 {
1235         if(!self.ammo_cells)
1236                 self.ammo_cells = g_pickup_cells;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_ammo_anyway;
1239         StartItemA (ITEM_Cells);
1240 }
1241
1242 spawnfunc(item_plasma)
1243 {
1244         if(!self.ammo_plasma)
1245                 self.ammo_plasma = g_pickup_plasma;
1246         if(!self.pickup_anyway)
1247                 self.pickup_anyway = g_pickup_ammo_anyway;
1248         StartItemA (ITEM_Plasma);
1249 }
1250
1251 spawnfunc(item_shells)
1252 {
1253         if(!weaponswapping)
1254         if(autocvar_sv_q3acompat_machineshotgunswap)
1255         if(self.classname != "droppedweapon")
1256         {
1257                 weaponswapping = true;
1258                 spawnfunc_item_bullets(this);
1259                 weaponswapping = false;
1260                 return;
1261         }
1262
1263         if(!self.ammo_shells)
1264                 self.ammo_shells = g_pickup_shells;
1265         if(!self.pickup_anyway)
1266                 self.pickup_anyway = g_pickup_ammo_anyway;
1267         StartItemA (ITEM_Shells);
1268 }
1269
1270 spawnfunc(item_armor_small)
1271 {
1272         if(!self.armorvalue)
1273                 self.armorvalue = g_pickup_armorsmall;
1274         if(!self.max_armorvalue)
1275                 self.max_armorvalue = g_pickup_armorsmall_max;
1276         if(!self.pickup_anyway)
1277                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1278         StartItemA (ITEM_ArmorSmall);
1279 }
1280
1281 spawnfunc(item_armor_medium)
1282 {
1283         if(!self.armorvalue)
1284                 self.armorvalue = g_pickup_armormedium;
1285         if(!self.max_armorvalue)
1286                 self.max_armorvalue = g_pickup_armormedium_max;
1287         if(!self.pickup_anyway)
1288                 self.pickup_anyway = g_pickup_armormedium_anyway;
1289         StartItemA (ITEM_ArmorMedium);
1290 }
1291
1292 spawnfunc(item_armor_big)
1293 {
1294         if(!self.armorvalue)
1295                 self.armorvalue = g_pickup_armorbig;
1296         if(!self.max_armorvalue)
1297                 self.max_armorvalue = g_pickup_armorbig_max;
1298         if(!self.pickup_anyway)
1299                 self.pickup_anyway = g_pickup_armorbig_anyway;
1300         StartItemA (ITEM_ArmorLarge);
1301 }
1302
1303 spawnfunc(item_armor_large)
1304 {
1305         if(!self.armorvalue)
1306                 self.armorvalue = g_pickup_armorlarge;
1307         if(!self.max_armorvalue)
1308                 self.max_armorvalue = g_pickup_armorlarge_max;
1309         if(!self.pickup_anyway)
1310                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1311         StartItemA (ITEM_ArmorMega);
1312 }
1313
1314 spawnfunc(item_health_small)
1315 {
1316         if(!self.max_health)
1317                 self.max_health = g_pickup_healthsmall_max;
1318         if(!self.health)
1319                 self.health = g_pickup_healthsmall;
1320         if(!self.pickup_anyway)
1321                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1322         StartItemA (ITEM_HealthSmall);
1323 }
1324
1325 spawnfunc(item_health_medium)
1326 {
1327         if(!self.max_health)
1328                 self.max_health = g_pickup_healthmedium_max;
1329         if(!self.health)
1330                 self.health = g_pickup_healthmedium;
1331         if(!self.pickup_anyway)
1332                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1333     StartItemA (ITEM_HealthMedium);
1334 }
1335
1336 spawnfunc(item_health_large)
1337 {
1338         if(!self.max_health)
1339                 self.max_health = g_pickup_healthlarge_max;
1340         if(!self.health)
1341                 self.health = g_pickup_healthlarge;
1342         if(!self.pickup_anyway)
1343                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1344         StartItemA (ITEM_HealthLarge);
1345 }
1346
1347 spawnfunc(item_health_mega)
1348 {
1349     if(!self.max_health)
1350         self.max_health = g_pickup_healthmega_max;
1351     if(!self.health)
1352         self.health = g_pickup_healthmega;
1353     if(!self.pickup_anyway)
1354         self.pickup_anyway = g_pickup_healthmega_anyway;
1355     StartItemA (ITEM_HealthMega);
1356 }
1357
1358 // support old misnamed entities
1359 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1360 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1361 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1362 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1363 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1364
1365 spawnfunc(item_strength)
1366 {
1367                 if(!self.strength_finished)
1368                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1369                 StartItemA (ITEM_Strength);
1370 }
1371
1372 spawnfunc(item_invincible)
1373 {
1374                 if(!self.invincible_finished)
1375                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1376                 StartItemA (ITEM_Shield);
1377 }
1378
1379 // compatibility:
1380 spawnfunc(item_quad) { self.classname = "item_strength";spawnfunc_item_strength(this);}
1381
1382 void target_items_use()
1383 {SELFPARAM();
1384         if(activator.classname == "droppedweapon")
1385         {
1386                 EXACTTRIGGER_TOUCH;
1387                 remove(activator);
1388                 return;
1389         }
1390
1391         if (!IS_PLAYER(activator))
1392                 return;
1393         if(activator.deadflag != DEAD_NO)
1394                 return;
1395         EXACTTRIGGER_TOUCH;
1396
1397         entity e;
1398         for(e = world; (e = find(e, classname, "droppedweapon")); )
1399                 if(e.enemy == activator)
1400                         remove(e);
1401
1402         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1403                 centerprint(activator, self.message);
1404 }
1405
1406 spawnfunc(target_items)
1407 {
1408         float n, i, j;
1409         entity e;
1410         string s;
1411
1412         self.use = target_items_use;
1413         if(!self.strength_finished)
1414                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1415         if(!self.invincible_finished)
1416                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1417         if(!self.superweapons_finished)
1418                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1419
1420         n = tokenize_console(self.netname);
1421         if(argv(0) == "give")
1422         {
1423                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1424         }
1425         else
1426         {
1427                 for(i = 0; i < n; ++i)
1428                 {
1429                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1430                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1431                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1432                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1433                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1434                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1435                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1436                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1437                         else
1438                         {
1439                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1440                                 {
1441                                         e = get_weaponinfo(j);
1442                                         s = W_UndeprecateName(argv(i));
1443                                         if(s == e.netname)
1444                                         {
1445                                                 self.weapons |= WepSet_FromWeapon(j);
1446                                                 if(self.spawnflags == 0 || self.spawnflags == 2) {
1447                                                         Weapon w = get_weaponinfo(e.weapon);
1448                                                         w.wr_init(w);
1449                                                 }
1450                                                 break;
1451                                         }
1452                                 }
1453                                 if(j > WEP_LAST)
1454                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1455                         }
1456                 }
1457
1458                 string itemprefix, valueprefix;
1459                 if(self.spawnflags == 0)
1460                 {
1461                         itemprefix = "";
1462                         valueprefix = "";
1463                 }
1464                 else if(self.spawnflags == 1)
1465                 {
1466                         itemprefix = "max ";
1467                         valueprefix = "max ";
1468                 }
1469                 else if(self.spawnflags == 2)
1470                 {
1471                         itemprefix = "min ";
1472                         valueprefix = "min ";
1473                 }
1474                 else if(self.spawnflags == 4)
1475                 {
1476                         itemprefix = "minus ";
1477                         valueprefix = "max ";
1478                 }
1479                 else
1480                 {
1481                         error("invalid spawnflags");
1482                         itemprefix = valueprefix = string_null;
1483                 }
1484
1485                 self.netname = "";
1486                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1487                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1488                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1489                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1490                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1491                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1492                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1493                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1494                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1495                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1496                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1497                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1498                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1499                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1500                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1501                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1502                 {
1503                         e = get_weaponinfo(j);
1504                         if(e.weapon)
1505                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1506                 }
1507         }
1508         self.netname = strzone(self.netname);
1509         //print(self.netname, "\n");
1510
1511         n = tokenize_console(self.netname);
1512         for(i = 0; i < n; ++i)
1513         {
1514                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1515                 {
1516                         e = get_weaponinfo(j);
1517                         if(argv(i) == e.netname)
1518                         {
1519                                 Weapon w = get_weaponinfo(e.weapon);
1520                                 w.wr_init(w);
1521                                 break;
1522                         }
1523                 }
1524         }
1525 }
1526
1527 spawnfunc(item_fuel)
1528 {
1529         if(!self.ammo_fuel)
1530                 self.ammo_fuel = g_pickup_fuel;
1531         if(!self.pickup_anyway)
1532                 self.pickup_anyway = g_pickup_ammo_anyway;
1533         StartItemA (ITEM_JetpackFuel);
1534 }
1535
1536 spawnfunc(item_fuel_regen)
1537 {
1538         if(start_items & ITEM_JetpackRegen.m_itemid)
1539         {
1540                 spawnfunc_item_fuel(this);
1541                 return;
1542         }
1543         StartItemA (ITEM_JetpackRegen);
1544 }
1545
1546 spawnfunc(item_jetpack)
1547 {
1548         if(!self.ammo_fuel)
1549                 self.ammo_fuel = g_pickup_fuel_jetpack;
1550         if(start_items & ITEM_Jetpack.m_itemid)
1551         {
1552                 spawnfunc_item_fuel(this);
1553                 return;
1554         }
1555         StartItemA (ITEM_Jetpack);
1556 }
1557
1558 float GiveWeapon(entity e, float wpn, float op, float val)
1559 {
1560         WepSet v0, v1;
1561         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1562         switch(op)
1563         {
1564                 case OP_SET:
1565                         if(val > 0)
1566                                 e.weapons |= WepSet_FromWeapon(wpn);
1567                         else
1568                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1569                         break;
1570                 case OP_MIN:
1571                 case OP_PLUS:
1572                         if(val > 0)
1573                                 e.weapons |= WepSet_FromWeapon(wpn);
1574                         break;
1575                 case OP_MAX:
1576                         if(val <= 0)
1577                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1578                         break;
1579                 case OP_MINUS:
1580                         if(val > 0)
1581                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1582                         break;
1583         }
1584         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1585         return (v0 != v1);
1586 }
1587
1588 float GiveBit(entity e, .float fld, float bit, float op, float val)
1589 {
1590         float v0, v1;
1591         v0 = (e.(fld) & bit);
1592         switch(op)
1593         {
1594                 case OP_SET:
1595                         if(val > 0)
1596                                 e.(fld) |= bit;
1597                         else
1598                                 e.(fld) &= ~bit;
1599                         break;
1600                 case OP_MIN:
1601                 case OP_PLUS:
1602                         if(val > 0)
1603                                 e.(fld) |= bit;
1604                         break;
1605                 case OP_MAX:
1606                         if(val <= 0)
1607                                 e.(fld) &= ~bit;
1608                         break;
1609                 case OP_MINUS:
1610                         if(val > 0)
1611                                 e.(fld) &= ~bit;
1612                         break;
1613         }
1614         v1 = (e.(fld) & bit);
1615         return (v0 != v1);
1616 }
1617
1618 float GiveValue(entity e, .float fld, float op, float val)
1619 {
1620         float v0, v1;
1621         v0 = e.(fld);
1622         switch(op)
1623         {
1624                 case OP_SET:
1625                         e.(fld) = val;
1626                         break;
1627                 case OP_MIN:
1628                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1629                         break;
1630                 case OP_MAX:
1631                         e.(fld) = min(e.(fld), val);
1632                         break;
1633                 case OP_PLUS:
1634                         e.(fld) += val;
1635                         break;
1636                 case OP_MINUS:
1637                         e.(fld) -= val;
1638                         break;
1639         }
1640         v1 = e.(fld);
1641         return (v0 != v1);
1642 }
1643
1644 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1645 {
1646         if(v1 == v0)
1647                 return;
1648         if(v1 <= v0 - t)
1649         {
1650                 if(snd_decr != "")
1651                         _sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1652         }
1653         else if(v0 >= v0 + t)
1654         {
1655                 if(snd_incr != "")
1656                         _sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1657         }
1658 }
1659
1660 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1661 {
1662         if(v0 < v1)
1663                 e.(rotfield) = max(e.(rotfield), time + rottime);
1664         else if(v0 > v1)
1665                 e.(regenfield) = max(e.(regenfield), time + regentime);
1666 }
1667 float GiveItems(entity e, float beginarg, float endarg)
1668 {SELFPARAM();
1669         float got, i, j, val, op;
1670         float _switchweapon;
1671         entity wi;
1672         string cmd;
1673
1674         val = 999;
1675         op = OP_SET;
1676
1677         got = 0;
1678
1679         _switchweapon = false;
1680         if (e.autoswitch)
1681                 if (e.switchweapon == w_getbestweapon(e))
1682                         _switchweapon = true;
1683
1684         e.strength_finished = max(0, e.strength_finished - time);
1685         e.invincible_finished = max(0, e.invincible_finished - time);
1686         e.superweapons_finished = max(0, e.superweapons_finished - time);
1687
1688         PREGIVE(e, items);
1689         PREGIVE_WEAPONS(e);
1690         PREGIVE(e, strength_finished);
1691         PREGIVE(e, invincible_finished);
1692         PREGIVE(e, superweapons_finished);
1693         PREGIVE(e, ammo_nails);
1694         PREGIVE(e, ammo_cells);
1695         PREGIVE(e, ammo_plasma);
1696         PREGIVE(e, ammo_shells);
1697         PREGIVE(e, ammo_rockets);
1698         PREGIVE(e, ammo_fuel);
1699         PREGIVE(e, armorvalue);
1700         PREGIVE(e, health);
1701
1702         for(i = beginarg; i < endarg; ++i)
1703         {
1704                 cmd = argv(i);
1705
1706                 if(cmd == "0" || stof(cmd))
1707                 {
1708                         val = stof(cmd);
1709                         continue;
1710                 }
1711                 switch(cmd)
1712                 {
1713                         case "no":
1714                                 op = OP_MAX;
1715                                 val = 0;
1716                                 continue;
1717                         case "max":
1718                                 op = OP_MAX;
1719                                 continue;
1720                         case "min":
1721                                 op = OP_MIN;
1722                                 continue;
1723                         case "plus":
1724                                 op = OP_PLUS;
1725                                 continue;
1726                         case "minus":
1727                                 op = OP_MINUS;
1728                                 continue;
1729                         case "ALL":
1730                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1731                                 got += GiveValue(e, strength_finished, op, val);
1732                                 got += GiveValue(e, invincible_finished, op, val);
1733                                 got += GiveValue(e, superweapons_finished, op, val);
1734                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1735                         case "all":
1736                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1737                                 got += GiveValue(e, health, op, val);
1738                                 got += GiveValue(e, armorvalue, op, val);
1739                         case "allweapons":
1740                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1741                                 {
1742                                         wi = get_weaponinfo(j);
1743                                         if(wi.weapon)
1744                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1745                                                         got += GiveWeapon(e, j, op, val);
1746                                 }
1747                         case "allammo":
1748                                 got += GiveValue(e, ammo_cells, op, val);
1749                                 got += GiveValue(e, ammo_plasma, op, val);
1750                                 got += GiveValue(e, ammo_shells, op, val);
1751                                 got += GiveValue(e, ammo_nails, op, val);
1752                                 got += GiveValue(e, ammo_rockets, op, val);
1753                                 got += GiveValue(e, ammo_fuel, op, val);
1754                                 break;
1755                         case "unlimited_ammo":
1756                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1757                                 break;
1758                         case "unlimited_weapon_ammo":
1759                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1760                                 break;
1761                         case "unlimited_superweapons":
1762                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1763                                 break;
1764                         case "jetpack":
1765                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1766                                 break;
1767                         case "fuel_regen":
1768                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1769                                 break;
1770                         case "strength":
1771                                 got += GiveValue(e, strength_finished, op, val);
1772                                 break;
1773                         case "invincible":
1774                                 got += GiveValue(e, invincible_finished, op, val);
1775                                 break;
1776                         case "superweapons":
1777                                 got += GiveValue(e, superweapons_finished, op, val);
1778                                 break;
1779                         case "cells":
1780                                 got += GiveValue(e, ammo_cells, op, val);
1781                                 break;
1782                         case "plasma":
1783                                 got += GiveValue(e, ammo_plasma, op, val);
1784                                 break;
1785                         case "shells":
1786                                 got += GiveValue(e, ammo_shells, op, val);
1787                                 break;
1788                         case "nails":
1789                         case "bullets":
1790                                 got += GiveValue(e, ammo_nails, op, val);
1791                                 break;
1792                         case "rockets":
1793                                 got += GiveValue(e, ammo_rockets, op, val);
1794                                 break;
1795                         case "health":
1796                                 got += GiveValue(e, health, op, val);
1797                                 break;
1798                         case "armor":
1799                                 got += GiveValue(e, armorvalue, op, val);
1800                                 break;
1801                         case "fuel":
1802                                 got += GiveValue(e, ammo_fuel, op, val);
1803                                 break;
1804                         default:
1805                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1806                                 {
1807                                         wi = get_weaponinfo(j);
1808                                         if(cmd == wi.netname)
1809                                         {
1810                                                 got += GiveWeapon(e, j, op, val);
1811                                                 break;
1812                                         }
1813                                 }
1814                                 if(j > WEP_LAST)
1815                                         LOG_INFO("give: invalid item ", cmd, "\n");
1816                                 break;
1817                 }
1818                 val = 999;
1819                 op = OP_SET;
1820         }
1821
1822         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND(ITEMPICKUP), string_null);
1823         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND(POWERUP), SND(POWEROFF));
1824         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND(POWERUP), SND(POWEROFF));
1825         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND(ITEMPICKUP), string_null);
1826         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1827         {
1828                 wi = get_weaponinfo(j);
1829                 if(wi.weapon)
1830                 {
1831                         POSTGIVE_WEAPON(e, j, SND(WEAPONPICKUP), string_null);
1832                         if (!(save_weapons & WepSet_FromWeapon(j)))
1833                                 if(e.weapons & WepSet_FromWeapon(j)) {
1834                                         Weapon w = get_weaponinfo(wi.weapon);
1835                                         w.wr_init(w);
1836                                 }
1837                 }
1838         }
1839         POSTGIVE_VALUE(e, strength_finished, 1, SND(POWERUP), SND(POWEROFF));
1840         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", SND(POWEROFF));
1841         POSTGIVE_VALUE(e, ammo_nails, 0, SND(ITEMPICKUP), string_null);
1842         POSTGIVE_VALUE(e, ammo_cells, 0, SND(ITEMPICKUP), string_null);
1843         POSTGIVE_VALUE(e, ammo_plasma, 0, SND(ITEMPICKUP), string_null);
1844         POSTGIVE_VALUE(e, ammo_shells, 0, SND(ITEMPICKUP), string_null);
1845         POSTGIVE_VALUE(e, ammo_rockets, 0, SND(ITEMPICKUP), string_null);
1846         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND(ITEMPICKUP), string_null);
1847         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(ARMOR25), string_null);
1848         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND(MEGAHEALTH), string_null);
1849
1850         if(e.superweapons_finished <= 0)
1851                 if(self.weapons & WEPSET_SUPERWEAPONS)
1852                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1853
1854         if(e.strength_finished <= 0)
1855                 e.strength_finished = 0;
1856         else
1857                 e.strength_finished += time;
1858         if(e.invincible_finished <= 0)
1859                 e.invincible_finished = 0;
1860         else
1861                 e.invincible_finished += time;
1862         if(e.superweapons_finished <= 0)
1863                 e.superweapons_finished = 0;
1864         else
1865                 e.superweapons_finished += time;
1866
1867         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1868                 _switchweapon = true;
1869         if(_switchweapon)
1870                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1871
1872         return got;
1873 }
1874 #endif