qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.items == IT_STRENGTH || self.items == IT_INVINCIBLE)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(name)
 237                         {
 238                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 239                                 if(self.waypointsprite_attached)
 240                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 241                         }
 242                 }
 243                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 244                 if(self.waypointsprite_attached)
 245                 {
 246                         WaypointSprite_Ping(self.waypointsprite_attached);
 247                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 248                 }
 249         }
 250 }
 251
 252 void Item_ScheduleRespawnIn(entity e, float t)
 253 {
 254         if(e.flags & FL_POWERUP)
 255         {
 256                 e.think = Item_RespawnCountdown;
 257                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 258                 e.count = 0;
 259         }
 260         else
 261         {
 262                 e.think = Item_Respawn;
 263                 e.nextthink = time + t;
 264         }
 265 }
 266
 267 void Item_ScheduleRespawn(entity e)
 268 {
 269         if(e.respawntime > 0)
 270         {
 271                 Item_Show(e, 0);
 272                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 273         }
 274         else // if respawntime is -1, this item does not respawn
 275                 Item_Show(e, -1);
 276 }
 277
 278 void Item_ScheduleInitialRespawn(entity e)
 279 {
 280         Item_Show(e, 0);
 281         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 282 }
 283
 284 float Item_GiveTo(entity item, entity player)
 285 {
 286         float _switchweapon;
 287         float pickedup;
 288         float it;
 289         float i;
 290         entity e;
 291
 292         // if nothing happens to player, just return without taking the item
 293         pickedup = FALSE;
 294         _switchweapon = FALSE;
 295
 296         if (g_minstagib)
 297         {
 298                 if(item.spawnshieldtime)
 299                 {
 300                         if (item.ammo_fuel)
 301                         if (player.ammo_fuel < g_pickup_fuel_max)
 302                         {
 303                                 pickedup = TRUE;
 304                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 305                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 306                         }
 307
 308                         _switchweapon = TRUE;
 309                         if (item.ammo_cells)
 310                         {
 311                                 pickedup = TRUE;
 312                                 // play some cool sounds ;)
 313                                 if (clienttype(player) == CLIENTTYPE_REAL)
 314                                 {
 315                                         if(player.health <= 5)
 316                                                 AnnounceTo(player, "lastsecond");
 317                                         else if(player.health < 50)
 318                                                 AnnounceTo(player, "narrowly");
 319                                 }
 320                                 // sound not available
 321                                 // else if(item.items == IT_CELLS)
 322                                 //      AnnounceTo(player, "ammo");
 323
 324                                 if (item.weapons & WEPBIT_MINSTANEX)
 325                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 326                                 if (item.ammo_cells)
 327                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 328                                 player.health = 100;
 329                         }
 330                 }
 331
 332                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 333                 {
 334                         pickedup = TRUE;
 335                         player.items |= it;
 336                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 337                 }
 338
 339                 // extralife powerup
 340                 if (item.max_health)
 341                 {
 342                         pickedup = TRUE;
 343                         // sound not available
 344                         // AnnounceTo(player, "_lives");
 345                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 346                         sprint(player, "^3You picked up some extra lives\n");
 347                 }
 348
 349                 // invis powerup
 350                 if (item.strength_finished)
 351                 {
 352                         pickedup = TRUE;
 353                         // sound not available
 354                         // AnnounceTo(player, "invisible");
 355                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 356                 }
 357
 358                 // speed powerup
 359                 if (item.invincible_finished)
 360                 {
 361                         pickedup = TRUE;
 362                         // sound not available
 363                         // AnnounceTo(player, "speed");
 364                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 365                 }
 366         }
 367         else
 368         {
 369                 // in case the player has autoswitch enabled do the following:
 370                 // if the player is using their best weapon before items are given, they
 371                 // probably want to switch to an even better weapon after items are given
 372                 if (player.autoswitch)
 373                 if (player.switchweapon == w_getbestweapon(player))
 374                         _switchweapon = TRUE;
 375
 376                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 377                         _switchweapon = TRUE;
 378
 379                 if(item.spawnshieldtime)
 380                 {
 381                         if (item.ammo_shells)
 382                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 383                         {
 384                                 pickedup = TRUE;
 385                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 386                         }
 387                         if (item.ammo_nails)
 388                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 389                         {
 390                                 pickedup = TRUE;
 391                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 392                         }
 393                         if (item.ammo_rockets)
 394                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 395                         {
 396                                 pickedup = TRUE;
 397                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 398                         }
 399                         if (item.ammo_cells)
 400                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 401                         {
 402                                 pickedup = TRUE;
 403                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 404                         }
 405                         if (item.ammo_fuel)
 406                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 407                         {
 408                                 pickedup = TRUE;
 409                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 410                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 411                         }
 412                 }
 413
 414                 if (item.flags & FL_WEAPON)
 415                 if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway))
 416                 {
 417                         pickedup = TRUE;
 418                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 419                         {
 420                                 e = get_weaponinfo(i);
 421                                 if(it & e.weapons)
 422                                         W_GiveWeapon (player, e.weapon, item.netname);
 423                         }
 424                 }
 425
 426                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 427                 {
 428                         pickedup = TRUE;
 429                         player.items |= it;
 430                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 431                 }
 432
 433                         if (item.strength_finished)
 434                 {
 435                         pickedup = TRUE;
 436                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 437                 }
 438                 if (item.invincible_finished)
 439                 {
 440                         pickedup = TRUE;
 441                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 442                 }
 443
 444                 if (item.health)
 445                 if ((player.health < item.max_health) || item.pickup_anyway)
 446                 {
 447                         pickedup = TRUE;
 448                         player.health = bound(player.health, item.max_health, player.health + item.health);
 449                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 450                 }
 451                 if (item.armorvalue)
 452                 if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 453                 {
 454                         pickedup = TRUE;
 455                         player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 456                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 457                 }
 458         }
 459
 460 :skip
 461         // always eat teamed entities
 462         if(item.team)
 463                 pickedup = TRUE;
 464
 465         if (!pickedup)
 466                 return 0;
 467
 468         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 469         if (_switchweapon)
 470                 if (player.switchweapon != w_getbestweapon(player))
 471                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 472
 473         return 1;
 474 }
 475
 476 void Item_Touch (void)
 477 {
 478         entity e, head;
 479
 480         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 481         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 482         {
 483                 remove(self);
 484                 return;
 485         }
 486         if (other.classname != "player")
 487                 return;
 488         if (other.deadflag)
 489                 return;
 490         if (self.solid != SOLID_TRIGGER)
 491                 return;
 492         if (self.owner == other)
 493                 return;
 494
 495         if(!Item_GiveTo(self, other))
 496                 return;
 497
 498         other.last_pickup = time;
 499
 500         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 501
 502         if (self.classname == "droppedweapon")
 503                 remove (self);
 504         else if not(self.spawnshieldtime)
 505                 return;
 506         else
 507         {
 508                 if(self.team)
 509                 {
 510                         RandomSelection_Init();
 511                         for(head = world; (head = findfloat(head, team, self.team)); )
 512                         {
 513                                 if(head.flags & FL_ITEM)
 514                                 {
 515                                         Item_Show(head, -1);
 516                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 517                                 }
 518                         }
 519                         e = RandomSelection_chosen_ent;
 520                 }
 521                 else
 522                         e = self;
 523                 Item_ScheduleRespawn(e);
 524         }
 525 }
 526
 527 void Item_FindTeam()
 528 {
 529         entity head, e;
 530
 531         if(self.effects & EF_NODRAW)
 532         {
 533                 // marker for item team search
 534                 dprint("Initializing item team ", ftos(self.team), "\n");
 535                 RandomSelection_Init();
 536                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 537                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 538                 e = RandomSelection_chosen_ent;
 539                 e.state = 0;
 540                 Item_Show(e, 1);
 541
 542                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 543                 {
 544                         if(head != e)
 545                         {
 546                                 // make it a non-spawned item
 547                                 Item_Show(head, -1);
 548                                 head.state = 1; // state 1 = initially hidden item
 549                         }
 550                         head.effects &~= EF_NODRAW;
 551                 }
 552
 553                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 554                         Item_ScheduleInitialRespawn(e);
 555         }
 556 }
 557
 558 void Item_Reset()
 559 {
 560         Item_Show(self, !self.state);
 561         setorigin (self, self.origin);
 562         self.think = SUB_Null;
 563         self.nextthink = 0;
 564
 565         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 566                 Item_ScheduleInitialRespawn(self);
 567 }
 568
 569 // Savage: used for item garbage-collection
 570 // TODO: perhaps nice special effect?
 571 void RemoveItem(void)
 572 {
 573         remove(self);
 574 }
 575
 576 // pickup evaluation functions
 577 // these functions decide how desirable an item is to the bots
 578
 579 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 580
 581 float weapon_pickupevalfunc(entity player, entity item)
 582 {
 583         float c, i, j, position;
 584
 585         // See if I have it already
 586         if(player.weapons & item.weapons == item.weapons)
 587         {
 588                 // If I can pick it up
 589                 if(!item.spawnshieldtime)
 590                         c = 0;
 591                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 592                 {
 593                         // Skilled bots will grab more
 594                         c = bound(0, skill / 10, 1) * 0.5;
 595                 }
 596                 else
 597                         c = 0;
 598         }
 599         else
 600                 c = 1;
 601
 602         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 603         if( bot_custom_weapon && c )
 604         {
 605                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 606                 {
 607                         // Find weapon
 608                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 609                                 continue;
 610
 611                         // Find the highest position on any range
 612                         position = -1;
 613                         for(j = 0; j < WEP_LAST ; ++j){
 614                                 if(
 615                                                 bot_weapons_far[j] == i ||
 616                                                 bot_weapons_mid[j] == i ||
 617                                                 bot_weapons_close[j] == i
 618                                   )
 619                                 {
 620                                         position = j;
 621                                         break;
 622                                 }
 623                         }
 624
 625                         // Rate it
 626                         if (position >= 0 )
 627                         {
 628                                 position = WEP_LAST - position;
 629                                 // item.bot_pickupbasevalue is overwritten here
 630                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 631                         }
 632                 }
 633         }
 634
 635         return item.bot_pickupbasevalue * c;
 636 }
 637
 638 float commodity_pickupevalfunc(entity player, entity item)
 639 {
 640         float c, i, need_shells, need_nails, need_rockets, need_cells;
 641         entity wi;
 642         c = 0;
 643
 644         // Detect needed ammo
 645         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 646         {
 647                 wi = get_weaponinfo(i);
 648
 649                 if not(wi.weapons & player.weapons)
 650                         continue;
 651
 652                 if(wi.items & IT_SHELLS)
 653                         need_shells = TRUE;
 654                 else if(wi.items & IT_NAILS)
 655                         need_nails = TRUE;
 656                 else if(wi.items & IT_ROCKETS)
 657                         need_rockets = TRUE;
 658                 else if(wi.items & IT_CELLS)
 659                         need_cells = TRUE;
 660         }
 661
 662         // TODO: figure out if the player even has the weapon this ammo is for?
 663         // may not affect strategy much though...
 664         // find out how much more ammo/armor/health the player can hold
 665         if (need_shells)
 666         if (item.ammo_shells)
 667         if (player.ammo_shells < g_pickup_shells_max)
 668                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 669         if (need_nails)
 670         if (item.ammo_nails)
 671         if (player.ammo_nails < g_pickup_nails_max)
 672                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 673         if (need_rockets)
 674         if (item.ammo_rockets)
 675         if (player.ammo_rockets < g_pickup_rockets_max)
 676                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 677         if (need_cells)
 678         if (item.ammo_cells)
 679         if (player.ammo_cells < g_pickup_cells_max)
 680                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 681         if (item.armorvalue)
 682         if (player.armorvalue < item.max_armorvalue)
 683                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 684         if (item.health)
 685         if (player.health < item.max_health)
 686                 c = c + max(0, 1 - player.health / item.max_health);
 687
 688         return item.bot_pickupbasevalue * c;
 689 }
 690
 691
 692 .float is_item;
 693 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 694 {
 695         startitem_failed = FALSE;
 696
 697         self.items = itemid;
 698         self.weapons = weaponid;
 699
 700         // is it a dropped weapon?
 701         if (self.classname == "droppedweapon")
 702         {
 703                 self.reset = SUB_Remove;
 704                 // it's a dropped weapon
 705                 self.movetype = MOVETYPE_TOSS;
 706                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 707                 self.think = RemoveItem;
 708                 self.nextthink = time + 60;
 709                 // don't drop if in a NODROP zone (such as lava)
 710                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 711                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 712                 {
 713                         startitem_failed = TRUE;
 714                         remove(self);
 715                         return;
 716                 }
 717         }
 718         else
 719         {
 720                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 721                 {
 722                         startitem_failed = TRUE;
 723                         remove(self);
 724                         return;
 725                 }
 726
 727                 if(!have_pickup_item())
 728                 {
 729                         startitem_failed = TRUE;
 730                         remove (self);
 731                         return;
 732                 }
 733
 734                 self.reset = Item_Reset;
 735                 // it's a level item
 736                 if(self.spawnflags & 1)
 737                         self.noalign = 1;
 738                 if (self.noalign)
 739                         self.movetype = MOVETYPE_NONE;
 740                 else
 741                         self.movetype = MOVETYPE_TOSS;
 742                 // do item filtering according to game mode and other things
 743                 if (!self.noalign)
 744                 {
 745                         // first nudge it off the floor a little bit to avoid math errors
 746                         setorigin(self, self.origin + '0 0 1');
 747                         // set item size before we spawn a spawnfunc_waypoint
 748                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 749                                 setsize (self, '-16 -16 0', '16 16 48');
 750                         else
 751                                 setsize (self, '-16 -16 0', '16 16 32');
 752                         // note droptofloor returns FALSE if stuck/or would fall too far
 753                         droptofloor();
 754                         waypoint_spawnforitem(self);
 755                 }
 756
 757                 /*
 758                  * can't do it that way, as it would break maps
 759                  * TODO make a target_give like entity another way, that perhaps has
 760                  * the weapon name in a key
 761                 if(self.targetname)
 762                 {
 763                         // target_give not yet supported; maybe later
 764                         print("removed targeted ", self.classname, "\n");
 765                         startitem_failed = TRUE;
 766                         remove (self);
 767                         return;
 768                 }
 769                 */
 770
 771                 if(autocvar_spawn_debug >= 2)
 772                 {
 773                         entity otheritem;
 774                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 775                         {
 776                                 if(otheritem.is_item)
 777                                 {
 778                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 779                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 780                                         error("Mapper sucks.");
 781                                 }
 782                         }
 783                         self.is_item = TRUE;
 784                 }
 785
 786                 weaponsInMap |= weaponid;
 787
 788                 precache_model (itemmodel);
 789                 precache_sound (pickupsound);
 790
 791                 precache_sound ("misc/itemrespawncountdown.wav");
 792                 if(!g_minstagib && itemid == IT_STRENGTH)
 793                         precache_sound ("misc/strength_respawn.wav");
 794                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 795                         precache_sound ("misc/shield_respawn.wav");
 796                 else
 797                         precache_sound ("misc/itemrespawn.wav");
 798
 799                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 800                         self.target = "###item###"; // for finding the nearest item using find()
 801         }
 802
 803         self.bot_pickup = TRUE;
 804         self.bot_pickupevalfunc = pickupevalfunc;
 805         self.bot_pickupbasevalue = pickupbasevalue;
 806         self.mdl = itemmodel;
 807         self.item_pickupsound = pickupsound;
 808         // let mappers override respawntime
 809         if(!self.respawntime) // both set
 810         {
 811                 self.respawntime = defaultrespawntime;
 812                 self.respawntimejitter = defaultrespawntimejitter;
 813         }
 814         self.netname = itemname;
 815         self.flags = FL_ITEM | itemflags;
 816         self.touch = Item_Touch;
 817         setmodel (self, self.mdl); // precision set below
 818         self.effects |= EF_LOWPRECISION;
 819         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 820                 setsize (self, '-16 -16 0', '16 16 48');
 821         else
 822                 setsize (self, '-16 -16 0', '16 16 32');
 823         if(itemflags & FL_WEAPON)
 824                 self.modelflags |= MF_ROTATE;
 825
 826         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 827         if (itemflags & FL_WEAPON)
 828         {
 829                 // neutral team color for pickup weapons
 830                 self.colormap = 1024; // color shirt=0 pants=0 grey
 831         }
 832
 833         Item_Show(self, 1);
 834         self.state = 0;
 835         if(self.team)
 836         {
 837                 if(!self.cnt)
 838                         self.cnt = 1; // item probability weight
 839                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 840                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 841         }
 842         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 843                 Item_ScheduleInitialRespawn(self);
 844 }
 845
 846 /* replace items in minstagib
 847  * IT_STRENGTH   = invisibility
 848  * IT_NAILS      = extra lives
 849  * IT_INVINCIBLE = speed
 850  */
 851 void minstagib_items (float itemid)
 852 {
 853         float rnd;
 854         self.classname = "minstagib";
 855
 856         // replace rocket launchers and nex guns with ammo cells
 857         if (itemid == IT_CELLS)
 858         {
 859                 self.ammo_cells = 1;
 860                 StartItem ("models/items/a_cells.md3",
 861                         "misc/itempickup.wav", 45, 0,
 862                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 863                 return;
 864         }
 865
 866         // randomize
 867         rnd = random() * 3;
 868         if (rnd <= 1)
 869                 itemid = IT_STRENGTH;
 870         else if (rnd <= 2)
 871                 itemid = IT_NAILS;
 872         else
 873                 itemid = IT_INVINCIBLE;
 874
 875         // replace with invis
 876         if (itemid == IT_STRENGTH)
 877         {
 878                 self.strength_finished = 30;
 879                 StartItem ("models/items/g_strength.md3",
 880                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 881                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 882         }
 883         // replace with extra lives
 884         if (itemid == IT_NAILS)
 885         {
 886                 self.max_health = 1;
 887                 StartItem ("models/items/g_h100.md3",
 888                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 889                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 890         }
 891         // replace with speed
 892         if (itemid == IT_INVINCIBLE)
 893         {
 894                 self.invincible_finished = 30;
 895                 StartItem ("models/items/g_invincible.md3",
 896                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 897                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 898         }
 899 }
 900
 901 float minst_no_auto_cells;
 902 void minst_remove_item (void) {
 903         if(minst_no_auto_cells)
 904                 remove(self);
 905 }
 906
 907 float weaponswapping;
 908 float internalteam;
 909
 910 void weapon_defaultspawnfunc(float wpn)
 911 {
 912         entity e;
 913         float t;
 914         var .float ammofield;
 915         string s;
 916         entity oldself;
 917         float i, j;
 918
 919         // set the respawntime in advance (so replaced weapons can copy it)
 920
 921         if(!self.respawntime)
 922         {
 923                 e = get_weaponinfo(wpn);
 924                 if(e.items == IT_SUPERWEAPON)
 925                 {
 926                         self.respawntime = g_pickup_respawntime_powerup;
 927                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 928                 }
 929                 else
 930                 {
 931                         self.respawntime = g_pickup_respawntime_weapon;
 932                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 933                 }
 934         }
 935
 936         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 937         {
 938                 e = get_weaponinfo(wpn);
 939                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 940                 if(s == "0")
 941                 {
 942                         remove(self);
 943                         startitem_failed = TRUE;
 944                         return;
 945                 }
 946                 t = tokenize_console(s);
 947                 if(t >= 2)
 948                 {
 949                         self.team = --internalteam;
 950                         oldself = self;
 951                         for(i = 1; i < t; ++i)
 952                         {
 953                                 s = argv(i);
 954                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 955                                 {
 956                                         e = get_weaponinfo(j);
 957                                         if(e.netname == s)
 958                                         {
 959                                                 self = spawn();
 960                                                 copyentity(oldself, self);
 961                                                 self.classname = "replacedweapon";
 962                                                 weapon_defaultspawnfunc(j);
 963                                                 break;
 964                                         }
 965                                 }
 966                                 if(j > WEP_LAST)
 967                                 {
 968                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 969                                 }
 970                         }
 971                         self = oldself;
 972                 }
 973                 if(t >= 1)
 974                 {
 975                         s = argv(0);
 976                         wpn = 0;
 977                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 978                         {
 979                                 e = get_weaponinfo(j);
 980                                 if(e.netname == s)
 981                                 {
 982                                         wpn = j;
 983                                         break;
 984                                 }
 985                         }
 986                         if(j > WEP_LAST)
 987                         {
 988                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 989                         }
 990                 }
 991                 if(wpn == 0)
 992                 {
 993                         remove(self);
 994                         startitem_failed = TRUE;
 995                         return;
 996                 }
 997         }
 998
 999         e = get_weaponinfo(wpn);
1000
1001         if(e.items && e.items != IT_SUPERWEAPON)
1002         {
1003                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1004                 {
1005                         if(e.items & j)
1006                         {
1007                                 ammofield = Item_CounterField(j);
1008                                 if(!self.ammofield)
1009                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1010                         }
1011                 }
1012         }
1013         else
1014         {
1015                 self.flags |= FL_NO_WEAPON_STAY;
1016         }
1017
1018         // weapon stay isn't supported for teamed weapons
1019         if(self.team)
1020                 self.flags |= FL_NO_WEAPON_STAY;
1021
1022         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1023         if (self.modelindex) // don't precache if self was removed
1024                 weapon_action(e.weapon, WR_PRECACHE);
1025 }
1026
1027 void spawnfunc_weapon_shotgun (void);
1028 void spawnfunc_weapon_uzi (void) {
1029         if(autocvar_sv_q3acompat_machineshotgunswap)
1030         if(self.classname != "droppedweapon")
1031         {
1032                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1033                 return;
1034         }
1035         weapon_defaultspawnfunc(WEP_UZI);
1036 }
1037
1038 void spawnfunc_weapon_shotgun (void) {
1039         if(autocvar_sv_q3acompat_machineshotgunswap)
1040         if(self.classname != "droppedweapon")
1041         {
1042                 weapon_defaultspawnfunc(WEP_UZI);
1043                 return;
1044         }
1045         weapon_defaultspawnfunc(WEP_SHOTGUN);
1046 }
1047
1048 void spawnfunc_weapon_nex (void)
1049 {
1050         if (g_minstagib)
1051         {
1052                 minstagib_items(IT_CELLS);
1053                 self.think = minst_remove_item;
1054                 self.nextthink = time;
1055                 return;
1056         }
1057         weapon_defaultspawnfunc(WEP_NEX);
1058 }
1059
1060 void spawnfunc_weapon_minstanex (void)
1061 {
1062         if (g_minstagib)
1063         {
1064                 minstagib_items(IT_CELLS);
1065                 self.think = minst_remove_item;
1066                 self.nextthink = time;
1067                 return;
1068         }
1069         weapon_defaultspawnfunc(WEP_MINSTANEX);
1070 }
1071
1072 void spawnfunc_weapon_rocketlauncher (void)
1073 {
1074         if (g_minstagib)
1075         {
1076                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1077                 self.think = minst_remove_item;
1078                 self.nextthink = time;
1079                 return;
1080         }
1081         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1082 }
1083
1084 void spawnfunc_item_rockets (void) {
1085         if(!self.ammo_rockets)
1086                 self.ammo_rockets = g_pickup_rockets;
1087         if(!self.pickup_anyway)
1088                 self.pickup_anyway = g_pickup_ammo_anyway;
1089         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1090 }
1091
1092 void spawnfunc_item_shells (void);
1093 void spawnfunc_item_bullets (void) {
1094         if(!weaponswapping)
1095         if(autocvar_sv_q3acompat_machineshotgunswap)
1096         if(self.classname != "droppedweapon")
1097         {
1098                 weaponswapping = TRUE;
1099                 spawnfunc_item_shells();
1100                 weaponswapping = FALSE;
1101                 return;
1102         }
1103
1104         if(!self.ammo_nails)
1105                 self.ammo_nails = g_pickup_nails;
1106         if(!self.pickup_anyway)
1107                 self.pickup_anyway = g_pickup_ammo_anyway;
1108         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1109 }
1110
1111 void spawnfunc_item_cells (void) {
1112         if(!self.ammo_cells)
1113                 self.ammo_cells = g_pickup_cells;
1114         if(!self.pickup_anyway)
1115                 self.pickup_anyway = g_pickup_ammo_anyway;
1116         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1117 }
1118
1119 void spawnfunc_item_shells (void) {
1120         if(!weaponswapping)
1121         if(autocvar_sv_q3acompat_machineshotgunswap)
1122         if(self.classname != "droppedweapon")
1123         {
1124                 weaponswapping = TRUE;
1125                 spawnfunc_item_bullets();
1126                 weaponswapping = FALSE;
1127                 return;
1128         }
1129
1130         if(!self.ammo_shells)
1131                 self.ammo_shells = g_pickup_shells;
1132         if(!self.pickup_anyway)
1133                 self.pickup_anyway = g_pickup_ammo_anyway;
1134         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1135 }
1136
1137 void spawnfunc_item_armor_small (void) {
1138         if(!self.armorvalue)
1139                 self.armorvalue = g_pickup_armorsmall;
1140         if(!self.max_armorvalue)
1141                 self.max_armorvalue = g_pickup_armorsmall_max;
1142         if(!self.pickup_anyway)
1143                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1144         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1145 }
1146
1147 void spawnfunc_item_armor_medium (void) {
1148         if(!self.armorvalue)
1149                 self.armorvalue = g_pickup_armormedium;
1150         if(!self.max_armorvalue)
1151                 self.max_armorvalue = g_pickup_armormedium_max;
1152         if(!self.pickup_anyway)
1153                 self.pickup_anyway = g_pickup_armormedium_anyway;
1154         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1155 }
1156
1157 void spawnfunc_item_armor_big (void) {
1158         if(!self.armorvalue)
1159                 self.armorvalue = g_pickup_armorbig;
1160         if(!self.max_armorvalue)
1161                 self.max_armorvalue = g_pickup_armorbig_max;
1162         if(!self.pickup_anyway)
1163                 self.pickup_anyway = g_pickup_armorbig_anyway;
1164         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1165 }
1166
1167 void spawnfunc_item_armor_large (void) {
1168         if(!self.armorvalue)
1169                 self.armorvalue = g_pickup_armorlarge;
1170         if(!self.max_armorvalue)
1171                 self.max_armorvalue = g_pickup_armorlarge_max;
1172         if(!self.pickup_anyway)
1173                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1174         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1175 }
1176
1177 void spawnfunc_item_health_small (void) {
1178         if(!self.max_health)
1179                 self.max_health = g_pickup_healthsmall_max;
1180         if(!self.health)
1181                 self.health = g_pickup_healthsmall;
1182         if(!self.pickup_anyway)
1183                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1184         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1185 }
1186
1187 void spawnfunc_item_health_medium (void) {
1188         if(!self.max_health)
1189                 self.max_health = g_pickup_healthmedium_max;
1190         if(!self.health)
1191                 self.health = g_pickup_healthmedium;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1194         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1195 }
1196
1197 void spawnfunc_item_health_large (void) {
1198         if(!self.max_health)
1199                 self.max_health = g_pickup_healthlarge_max;
1200         if(!self.health)
1201                 self.health = g_pickup_healthlarge;
1202         if(!self.pickup_anyway)
1203                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1204         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1205 }
1206
1207 void spawnfunc_item_health_mega (void) {
1208         if(g_minstagib) {
1209                 minstagib_items(IT_NAILS);
1210         } else {
1211                 if(!self.max_health)
1212                         self.max_health = g_pickup_healthmega_max;
1213                 if(!self.health)
1214                         self.health = g_pickup_healthmega;
1215                 if(!self.pickup_anyway)
1216                         self.pickup_anyway = g_pickup_healthmega_anyway;
1217                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1218         }
1219 }
1220
1221 // support old misnamed entities
1222 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1223 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1224 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1225 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1226 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1227
1228 void spawnfunc_item_strength (void) {
1229         if(g_minstagib) {
1230                 minstagib_items(IT_STRENGTH);
1231         } else {
1232                 precache_sound("weapons/strength_fire.wav");
1233                 self.strength_finished = 30;
1234                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1235         }
1236 }
1237
1238 void spawnfunc_item_invincible (void) {
1239         if(g_minstagib) {
1240                 minstagib_items(IT_INVINCIBLE);
1241         } else {
1242                 self.invincible_finished = 30;
1243                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1244         }
1245 }
1246
1247 void spawnfunc_item_minst_cells (void) {
1248         if (g_minstagib)
1249         {
1250                 minst_no_auto_cells = 1;
1251                 minstagib_items(IT_CELLS);
1252         }
1253         else
1254                 remove(self);
1255 }
1256
1257 // compatibility:
1258 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1259
1260 float GiveItems(entity e, float beginarg, float endarg);
1261 void target_items_use (void)
1262 {
1263         if(activator.classname == "droppedweapon")
1264         {
1265                 EXACTTRIGGER_TOUCH;
1266                 remove(activator);
1267                 return;
1268         }
1269
1270         if(activator.classname != "player")
1271                 return;
1272         if(activator.deadflag != DEAD_NO)
1273                 return;
1274         EXACTTRIGGER_TOUCH;
1275
1276         entity e;
1277         for(e = world; (e = find(e, classname, "droppedweapon")); )
1278                 if(e.enemy == activator)
1279                         remove(e);
1280
1281         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1282                 centerprint(activator, self.message);
1283 }
1284
1285 void spawnfunc_target_items (void)
1286 {
1287         float n, i, j;
1288         entity e;
1289
1290         self.use = target_items_use;
1291         if(!self.strength_finished)
1292                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1293         if(!self.invincible_finished)
1294                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1295
1296         precache_sound("misc/itempickup.wav");
1297         precache_sound("misc/megahealth.wav");
1298         precache_sound("misc/armor25.wav");
1299         precache_sound("misc/powerup.wav");
1300         precache_sound("misc/poweroff.wav");
1301         precache_sound("weapons/weaponpickup.wav");
1302
1303         n = tokenize_console(self.netname);
1304         if(argv(0) == "give")
1305         {
1306                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1307         }
1308         else
1309         {
1310                 for(i = 0; i < n; ++i)
1311                 {
1312                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1313                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1314                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1315                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1316                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1317                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1318                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1319                         else
1320                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1321                         {
1322                                 e = get_weaponinfo(j);
1323                                 if(argv(i) == e.netname)
1324                                 {
1325                                         self.weapons |= e.weapons;
1326                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1327                                                 weapon_action(e.weapon, WR_PRECACHE);
1328                                         break;
1329                                 }
1330                         }
1331                         if(j > WEP_LAST)
1332                                 print("target_items: invalid item ", argv(i), "\n");
1333                 }
1334
1335                 string itemprefix, valueprefix;
1336                 if(self.spawnflags == 0)
1337                 {
1338                         itemprefix = "";
1339                         valueprefix = "";
1340                 }
1341                 else if(self.spawnflags == 1)
1342                 {
1343                         itemprefix = "max ";
1344                         valueprefix = "max ";
1345                 }
1346                 else if(self.spawnflags == 2)
1347                 {
1348                         itemprefix = "min ";
1349                         valueprefix = "min ";
1350                 }
1351                 else if(self.spawnflags == 4)
1352                 {
1353                         itemprefix = "minus ";
1354                         valueprefix = "max ";
1355                 }
1356                 else
1357                         error("invalid spawnflags");
1358
1359                 self.netname = "";
1360                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1361                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1362                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1363                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1364                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1365                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1366                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1367                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1368                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1369                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1370                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1371                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1372                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1373                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1374                 {
1375                         e = get_weaponinfo(j);
1376                         if(e.weapons)
1377                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1378                 }
1379         }
1380         self.netname = strzone(self.netname);
1381         //print(self.netname, "\n");
1382
1383         n = tokenize_console(self.netname);
1384         for(i = 0; i < n; ++i)
1385         {
1386                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1387                 {
1388                         e = get_weaponinfo(j);
1389                         if(argv(i) == e.netname)
1390                         {
1391                                 weapon_action(e.weapon, WR_PRECACHE);
1392                                 break;
1393                         }
1394                 }
1395         }
1396 }
1397
1398 void spawnfunc_item_fuel(void)
1399 {
1400         if(!self.ammo_fuel)
1401                 self.ammo_fuel = g_pickup_fuel;
1402         if(!self.pickup_anyway)
1403                 self.pickup_anyway = g_pickup_ammo_anyway;
1404         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1405 }
1406
1407 void spawnfunc_item_fuel_regen(void)
1408 {
1409         if(start_items & IT_FUEL_REGEN)
1410         {
1411                 spawnfunc_item_fuel();
1412                 return;
1413         }
1414         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1415 }
1416
1417 void spawnfunc_item_jetpack(void)
1418 {
1419         if(g_grappling_hook)
1420                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1421         if(!self.ammo_fuel)
1422                 self.ammo_fuel = g_pickup_fuel_jetpack;
1423         if(start_items & IT_JETPACK)
1424         {
1425                 spawnfunc_item_fuel();
1426                 return;
1427         }
1428         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1429 }
1430
1431
1432 #define OP_SET 0
1433 #define OP_MIN 1
1434 #define OP_MAX 2
1435 #define OP_PLUS 3
1436 #define OP_MINUS 4
1437
1438 float GiveBit(entity e, .float fld, float bit, float op, float val)
1439 {
1440         float v0, v1;
1441         v0 = (e.fld & bit);
1442         switch(op)
1443         {
1444                 case OP_SET:
1445                         if(val > 0)
1446                                 e.fld |= bit;
1447                         else
1448                                 e.fld &~= bit;
1449                         break;
1450                 case OP_MIN:
1451                 case OP_PLUS:
1452                         if(val > 0)
1453                                 e.fld |= bit;
1454                         break;
1455                 case OP_MAX:
1456                         if(val <= 0)
1457                                 e.fld &~= bit;
1458                         break;
1459                 case OP_MINUS:
1460                         if(val > 0)
1461                                 e.fld &~= bit;
1462                         break;
1463         }
1464         v1 = (e.fld & bit);
1465         return (v0 != v1);
1466 }
1467
1468 float GiveValue(entity e, .float fld, float op, float val)
1469 {
1470         float v0, v1;
1471         v0 = e.fld;
1472         switch(op)
1473         {
1474                 case OP_SET:
1475                         e.fld = val;
1476                         break;
1477                 case OP_MIN:
1478                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1479                         break;
1480                 case OP_MAX:
1481                         e.fld = min(e.fld, val);
1482                         break;
1483                 case OP_PLUS:
1484                         e.fld += val;
1485                         break;
1486                 case OP_MINUS:
1487                         e.fld -= val;
1488                         break;
1489         }
1490         v1 = e.fld;
1491         return (v0 != v1);
1492 }
1493
1494 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1495 {
1496         if(v1 == v0)
1497                 return;
1498         if(v1 <= v0 - t)
1499         {
1500                 if(snd_decr != "")
1501                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1502         }
1503         else if(v0 >= v0 + t)
1504         {
1505                 if(snd_incr != "")
1506                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1507         }
1508 }
1509
1510 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1511 {
1512         if(v0 < v1)
1513                 e.rotfield = max(e.rotfield, time + rottime);
1514         else if(v0 > v1)
1515                 e.regenfield = max(e.regenfield, time + regentime);
1516 }
1517
1518 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1519 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1520 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1521 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1522
1523 float GiveItems(entity e, float beginarg, float endarg)
1524 {
1525         float got, i, j, val, op;
1526         float _switchweapon;
1527         entity wi;
1528         string cmd;
1529
1530         val = 999;
1531         op = OP_SET;
1532
1533         got = 0;
1534
1535         _switchweapon = FALSE;
1536         if (e.autoswitch)
1537                 if (e.switchweapon == w_getbestweapon(e))
1538                         _switchweapon = TRUE;
1539
1540         e.strength_finished = max(0, e.strength_finished - time);
1541         e.invincible_finished = max(0, e.invincible_finished - time);
1542
1543         PREGIVE(e, items);
1544         PREGIVE(e, weapons);
1545         PREGIVE(e, strength_finished);
1546         PREGIVE(e, invincible_finished);
1547         PREGIVE(e, ammo_nails);
1548         PREGIVE(e, ammo_cells);
1549         PREGIVE(e, ammo_shells);
1550         PREGIVE(e, ammo_rockets);
1551         PREGIVE(e, ammo_fuel);
1552         PREGIVE(e, armorvalue);
1553         PREGIVE(e, health);
1554
1555         for(i = beginarg; i < endarg; ++i)
1556         {
1557                 cmd = argv(i);
1558
1559                 if(cmd == "0" || stof(cmd))
1560                 {
1561                         val = stof(cmd);
1562                         continue;
1563                 }
1564                 switch(cmd)
1565                 {
1566                         case "no":
1567                                 op = OP_MAX;
1568                                 val = 0;
1569                                 continue;
1570                         case "max":
1571                                 op = OP_MAX;
1572                                 continue;
1573                         case "min":
1574                                 op = OP_MIN;
1575                                 continue;
1576                         case "plus":
1577                                 op = OP_PLUS;
1578                                 continue;
1579                         case "minus":
1580                                 op = OP_MINUS;
1581                                 continue;
1582                         case "ALL":
1583                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1584                                 got += GiveValue(e, strength_finished, op, time);
1585                                 got += GiveValue(e, invincible_finished, op, time);
1586                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1587                         case "all":
1588                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1589                                 got += GiveValue(e, health, op, val);
1590                                 got += GiveValue(e, armorvalue, op, val);
1591                         case "allweapons":
1592                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1593                                 {
1594                                         wi = get_weaponinfo(j);
1595                                         if(wi.weapons)
1596                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1597                                 }
1598                         case "allammo":
1599                                 got += GiveValue(e, ammo_cells, op, val);
1600                                 got += GiveValue(e, ammo_shells, op, val);
1601                                 got += GiveValue(e, ammo_nails, op, val);
1602                                 got += GiveValue(e, ammo_rockets, op, val);
1603                                 got += GiveValue(e, ammo_fuel, op, val);
1604                                 break;
1605                         case "unlimited_ammo":
1606                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1607                                 break;
1608                         case "unlimited_weapon_ammo":
1609                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1610                                 break;
1611                         case "unlimited_superweapons":
1612                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1613                                 break;
1614                         case "jetpack":
1615                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1616                                 break;
1617                         case "fuel_regen":
1618                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1619                                 break;
1620                         case "strength":
1621                                 got += GiveValue(e, strength_finished, op, val);
1622                                 break;
1623                         case "invincible":
1624                                 got += GiveValue(e, invincible_finished, op, val);
1625                                 break;
1626                         case "cells":
1627                                 got += GiveValue(e, ammo_cells, op, val);
1628                                 break;
1629                         case "shells":
1630                                 got += GiveValue(e, ammo_shells, op, val);
1631                                 break;
1632                         case "nails":
1633                         case "bullets":
1634                                 got += GiveValue(e, ammo_nails, op, val);
1635                                 break;
1636                         case "rockets":
1637                                 got += GiveValue(e, ammo_rockets, op, val);
1638                                 break;
1639                         case "health":
1640                                 got += GiveValue(e, health, op, val);
1641                                 break;
1642                         case "armor":
1643                                 got += GiveValue(e, armorvalue, op, val);
1644                                 break;
1645                         case "fuel":
1646                                 got += GiveValue(e, ammo_fuel, op, val);
1647                                 break;
1648                         default:
1649                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1650                                 {
1651                                         wi = get_weaponinfo(j);
1652                                         if(cmd == wi.netname)
1653                                         {
1654                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1655                                                 break;
1656                                         }
1657                                 }
1658                                 if(j > WEP_LAST)
1659                                         print("give: invalid item ", cmd, "\n");
1660                                 break;
1661                 }
1662                 val = 999;
1663                 op = OP_SET;
1664         }
1665
1666         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1667         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1668         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1669         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1670         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1671         {
1672                 wi = get_weaponinfo(j);
1673                 if(wi.weapons)
1674                 {
1675                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1676                         if not(save_weapons & wi.weapons)
1677                                 if(e.weapons & wi.weapons)
1678                                         weapon_action(wi.weapon, WR_PRECACHE);
1679                 }
1680         }
1681         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1682         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1683         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1684         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1685         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1686         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1687         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1688         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1689         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1690
1691         if (g_minstagib)
1692         {
1693                 e.health = bound(0, e.health, 100);
1694                 e.armorvalue = bound(0, e.armorvalue, 999);
1695         }
1696
1697         if(e.strength_finished <= 0)
1698                 e.strength_finished = 0;
1699         else
1700                 e.strength_finished += time;
1701         if(e.invincible_finished <= 0)
1702                 e.invincible_finished = 0;
1703         else
1704                 e.invincible_finished += time;
1705
1706         if not(e.weapons & W_WeaponBit(e.switchweapon))
1707                 _switchweapon = TRUE;
1708         if(_switchweapon)
1709                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1710
1711         return got;
1712 }