qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '0 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         if (item.ammo_cells)
 383                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 384                         player.health = 100;
 385                 }
 386
 387                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 388                 {
 389                         pickedup = TRUE;
 390                         player.items |= it;
 391                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 392                 }
 393
 394                 // extralife powerup
 395                 if (item.max_health)
 396                 {
 397                         pickedup = TRUE;
 398                         // sound not available
 399                         // AnnounceTo(player, "_lives");
 400                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 401                         sprint(player, "^3You picked up some extra lives\n");
 402                 }
 403
 404                 // invis powerup
 405                 if (item.strength_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "invisible");
 410                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412
 413                 // speed powerup
 414                 if (item.invincible_finished)
 415                 {
 416                         pickedup = TRUE;
 417                         // sound not available
 418                         // AnnounceTo(player, "speed");
 419                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 420                 }
 421         }
 422         else
 423         {
 424                 // in case the player has autoswitch enabled do the following:
 425                 // if the player is using their best weapon before items are given, they
 426                 // probably want to switch to an even better weapon after items are given
 427                 if (player.autoswitch)
 428                 if (player.switchweapon == w_getbestweapon(player))
 429                         _switchweapon = TRUE;
 430
 431                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 432                         _switchweapon = TRUE;
 433
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 439                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 440                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 441
 442                 if (item.flags & FL_WEAPON)
 443                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && g_pickup_weapons_anyway))
 444                 {
 445                         pickedup = TRUE;
 446                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 447                         {
 448                                 e = get_weaponinfo(i);
 449                                 if(it & e.weapons)
 450                                         W_GiveWeapon (player, e.weapon, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 487         if (_switchweapon)
 488                 if (player.switchweapon != w_getbestweapon(player))
 489                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 490
 491         return 1;
 492 }
 493
 494 void Item_Touch (void)
 495 {
 496         entity e, head;
 497
 498         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 499         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 500         {
 501                 remove(self);
 502                 return;
 503         }
 504         if (other.classname != "player")
 505                 return;
 506         if (other.deadflag)
 507                 return;
 508         if (self.solid != SOLID_TRIGGER)
 509                 return;
 510         if (self.owner == other)
 511                 return;
 512
 513         if(!Item_GiveTo(self, other))
 514                 return;
 515
 516         other.last_pickup = time;
 517
 518         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 519
 520         if (self.classname == "droppedweapon")
 521                 remove (self);
 522         else if not(self.spawnshieldtime)
 523                 return;
 524         else
 525         {
 526                 if(self.team)
 527                 {
 528                         RandomSelection_Init();
 529                         for(head = world; (head = findfloat(head, team, self.team)); )
 530                         {
 531                                 if(head.flags & FL_ITEM)
 532                                 {
 533                                         Item_Show(head, -1);
 534                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 535                                 }
 536                         }
 537                         e = RandomSelection_chosen_ent;
 538                 }
 539                 else
 540                         e = self;
 541                 Item_ScheduleRespawn(e);
 542         }
 543 }
 544
 545 void Item_Reset()
 546 {
 547         Item_Show(self, !self.state);
 548         setorigin (self, self.origin);
 549         self.think = SUB_Null;
 550         self.nextthink = 0;
 551
 552         if((self.flags & FL_POWERUP) | (self.weapons & WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 553                 Item_ScheduleInitialRespawn(self);
 554 }
 555
 556 void Item_FindTeam()
 557 {
 558         entity head, e;
 559
 560         if(self.effects & EF_NODRAW)
 561         {
 562                 // marker for item team search
 563                 dprint("Initializing item team ", ftos(self.team), "\n");
 564                 RandomSelection_Init();
 565                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 566                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 567                 e = RandomSelection_chosen_ent;
 568                 e.state = 0;
 569                 Item_Show(e, 1);
 570
 571                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 572                 {
 573                         if(head != e)
 574                         {
 575                                 // make it a non-spawned item
 576                                 Item_Show(head, -1);
 577                                 head.state = 1; // state 1 = initially hidden item
 578                         }
 579                         head.effects &~= EF_NODRAW;
 580                 }
 581
 582                 Item_Reset();
 583         }
 584 }
 585
 586 // Savage: used for item garbage-collection
 587 // TODO: perhaps nice special effect?
 588 void RemoveItem(void)
 589 {
 590         remove(self);
 591 }
 592
 593 // pickup evaluation functions
 594 // these functions decide how desirable an item is to the bots
 595
 596 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 597
 598 float weapon_pickupevalfunc(entity player, entity item)
 599 {
 600         float c, i, j, position;
 601
 602         // See if I have it already
 603         if(player.weapons & item.weapons == item.weapons)
 604         {
 605                 // If I can pick it up
 606                 if(!item.spawnshieldtime)
 607                         c = 0;
 608                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 609                 {
 610                         // Skilled bots will grab more
 611                         c = bound(0, skill / 10, 1) * 0.5;
 612                 }
 613                 else
 614                         c = 0;
 615         }
 616         else
 617                 c = 1;
 618
 619         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 620         if( bot_custom_weapon && c )
 621         {
 622                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 623                 {
 624                         // Find weapon
 625                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 626                                 continue;
 627
 628                         // Find the highest position on any range
 629                         position = -1;
 630                         for(j = 0; j < WEP_LAST ; ++j){
 631                                 if(
 632                                                 bot_weapons_far[j] == i ||
 633                                                 bot_weapons_mid[j] == i ||
 634                                                 bot_weapons_close[j] == i
 635                                   )
 636                                 {
 637                                         position = j;
 638                                         break;
 639                                 }
 640                         }
 641
 642                         // Rate it
 643                         if (position >= 0 )
 644                         {
 645                                 position = WEP_LAST - position;
 646                                 // item.bot_pickupbasevalue is overwritten here
 647                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 648                         }
 649                 }
 650         }
 651
 652         return item.bot_pickupbasevalue * c;
 653 }
 654
 655 float commodity_pickupevalfunc(entity player, entity item)
 656 {
 657         float c, i, need_shells, need_nails, need_rockets, need_cells;
 658         entity wi;
 659         c = 0;
 660
 661         // Detect needed ammo
 662         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 663         {
 664                 wi = get_weaponinfo(i);
 665
 666                 if not(wi.weapons & player.weapons)
 667                         continue;
 668
 669                 if(wi.items & IT_SHELLS)
 670                         need_shells = TRUE;
 671                 else if(wi.items & IT_NAILS)
 672                         need_nails = TRUE;
 673                 else if(wi.items & IT_ROCKETS)
 674                         need_rockets = TRUE;
 675                 else if(wi.items & IT_CELLS)
 676                         need_cells = TRUE;
 677         }
 678
 679         // TODO: figure out if the player even has the weapon this ammo is for?
 680         // may not affect strategy much though...
 681         // find out how much more ammo/armor/health the player can hold
 682         if (need_shells)
 683         if (item.ammo_shells)
 684         if (player.ammo_shells < g_pickup_shells_max)
 685                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 686         if (need_nails)
 687         if (item.ammo_nails)
 688         if (player.ammo_nails < g_pickup_nails_max)
 689                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 690         if (need_rockets)
 691         if (item.ammo_rockets)
 692         if (player.ammo_rockets < g_pickup_rockets_max)
 693                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 694         if (need_cells)
 695         if (item.ammo_cells)
 696         if (player.ammo_cells < g_pickup_cells_max)
 697                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 698         if (item.armorvalue)
 699         if (player.armorvalue < item.max_armorvalue)
 700                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 701         if (item.health)
 702         if (player.health < item.max_health)
 703                 c = c + max(0, 1 - player.health / item.max_health);
 704
 705         return item.bot_pickupbasevalue * c;
 706 }
 707
 708
 709 .float is_item;
 710 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 711 {
 712         startitem_failed = FALSE;
 713
 714         self.items = itemid;
 715         self.weapons = weaponid;
 716         self.flags = FL_ITEM | itemflags;
 717
 718         // is it a dropped weapon?
 719         if (self.classname == "droppedweapon")
 720         {
 721                 self.reset = SUB_Remove;
 722                 // it's a dropped weapon
 723                 self.movetype = MOVETYPE_TOSS;
 724                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 725                 self.think = RemoveItem;
 726                 self.nextthink = time + 60;
 727                 // don't drop if in a NODROP zone (such as lava)
 728                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 729                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 730                 {
 731                         startitem_failed = TRUE;
 732                         remove(self);
 733                         return;
 734                 }
 735         }
 736         else
 737         {
 738                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 739                 {
 740                         startitem_failed = TRUE;
 741                         remove(self);
 742                         return;
 743                 }
 744
 745                 if(!have_pickup_item())
 746                 {
 747                         startitem_failed = TRUE;
 748                         remove (self);
 749                         return;
 750                 }
 751
 752                 if(self.model != "")
 753                         itemmodel = self.model;
 754                 if(self.item_pickupsound != "")
 755                         pickupsound = self.item_pickupsound;
 756
 757                 self.reset = Item_Reset;
 758                 // it's a level item
 759                 if(self.spawnflags & 1)
 760                         self.noalign = 1;
 761                 if (self.noalign)
 762                         self.movetype = MOVETYPE_NONE;
 763                 else
 764                         self.movetype = MOVETYPE_TOSS;
 765                 // do item filtering according to game mode and other things
 766                 if (!self.noalign)
 767                 {
 768                         // first nudge it off the floor a little bit to avoid math errors
 769                         setorigin(self, self.origin + '0 0 1');
 770                         // set item size before we spawn a spawnfunc_waypoint
 771                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 772                                 setsize (self, '-16 -16 0', '16 16 48');
 773                         else
 774                                 setsize (self, '-16 -16 0', '16 16 32');
 775                         // note droptofloor returns FALSE if stuck/or would fall too far
 776                         droptofloor();
 777                         waypoint_spawnforitem(self);
 778                 }
 779
 780                 /*
 781                  * can't do it that way, as it would break maps
 782                  * TODO make a target_give like entity another way, that perhaps has
 783                  * the weapon name in a key
 784                 if(self.targetname)
 785                 {
 786                         // target_give not yet supported; maybe later
 787                         print("removed targeted ", self.classname, "\n");
 788                         startitem_failed = TRUE;
 789                         remove (self);
 790                         return;
 791                 }
 792                 */
 793
 794                 if(autocvar_spawn_debug >= 2)
 795                 {
 796                         entity otheritem;
 797                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 798                         {
 799                                 if(otheritem.is_item)
 800                                 {
 801                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 802                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 803                                         error("Mapper sucks.");
 804                                 }
 805                         }
 806                         self.is_item = TRUE;
 807                 }
 808
 809                 weaponsInMap |= weaponid;
 810
 811                 precache_model (itemmodel);
 812                 precache_sound (pickupsound);
 813
 814                 precache_sound ("misc/itemrespawncountdown.wav");
 815                 if(!g_minstagib && itemid == IT_STRENGTH)
 816                         precache_sound ("misc/strength_respawn.wav");
 817                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 818                         precache_sound ("misc/shield_respawn.wav");
 819                 else
 820                         precache_sound ("misc/itemrespawn.wav");
 821
 822                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 823                         self.target = "###item###"; // for finding the nearest item using find()
 824         }
 825
 826         self.bot_pickup = TRUE;
 827         self.bot_pickupevalfunc = pickupevalfunc;
 828         self.bot_pickupbasevalue = pickupbasevalue;
 829         self.mdl = itemmodel;
 830         self.item_pickupsound = pickupsound;
 831         if(self.weapons)
 832                 self.weapon = WEP_FIRST + log2of(lowestbit(self.weapons));
 833         else
 834                 self.weapon = 0;
 835         // let mappers override respawntime
 836         if(!self.respawntime) // both set
 837         {
 838                 self.respawntime = defaultrespawntime;
 839                 self.respawntimejitter = defaultrespawntimejitter;
 840         }
 841         self.netname = itemname;
 842         self.touch = Item_Touch;
 843         setmodel (self, self.mdl); // precision set below
 844         self.effects |= EF_LOWPRECISION;
 845         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 846                 setsize (self, '-16 -16 0', '16 16 48');
 847         else
 848                 setsize (self, '-16 -16 0', '16 16 32');
 849         if(itemflags & FL_WEAPON)
 850                 self.modelflags |= MF_ROTATE;
 851
 852         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 853         if (itemflags & FL_WEAPON)
 854         {
 855                 // neutral team color for pickup weapons
 856                 self.colormap = 1024; // color shirt=0 pants=0 grey
 857         }
 858
 859         Item_Show(self, 1);
 860         self.state = 0;
 861         if(self.team)
 862         {
 863                 if(!self.cnt)
 864                         self.cnt = 1; // item probability weight
 865                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 866                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 867         }
 868         else
 869                 Item_Reset();
 870 }
 871
 872 /* replace items in minstagib
 873  * IT_STRENGTH   = invisibility
 874  * IT_NAILS      = extra lives
 875  * IT_INVINCIBLE = speed
 876  */
 877 void minstagib_items (float itemid)
 878 {
 879         float rnd;
 880         self.classname = "minstagib";
 881
 882         // replace rocket launchers and nex guns with ammo cells
 883         if (itemid == IT_CELLS)
 884         {
 885                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 886                 StartItem ("models/items/a_cells.md3",
 887                         "misc/itempickup.wav", 45, 0,
 888                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 889                 return;
 890         }
 891
 892         // randomize
 893         rnd = random() * 3;
 894         if (rnd <= 1)
 895                 itemid = IT_STRENGTH;
 896         else if (rnd <= 2)
 897                 itemid = IT_NAILS;
 898         else
 899                 itemid = IT_INVINCIBLE;
 900
 901         // replace with invis
 902         if (itemid == IT_STRENGTH)
 903         {
 904                 if(!self.strength_finished)
 905                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 906                 StartItem ("models/items/g_strength.md3",
 907                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 908                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 909         }
 910         // replace with extra lives
 911         if (itemid == IT_NAILS)
 912         {
 913                 self.max_health = 1;
 914                 StartItem ("models/items/g_h100.md3",
 915                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 916                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 917         }
 918         // replace with speed
 919         if (itemid == IT_INVINCIBLE)
 920         {
 921                 if(!self.invincible_finished)
 922                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 923                 StartItem ("models/items/g_invincible.md3",
 924                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 925                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 926         }
 927 }
 928
 929 float minst_no_auto_cells;
 930 void minst_remove_item (void) {
 931         if(minst_no_auto_cells)
 932                 remove(self);
 933 }
 934
 935 float weaponswapping;
 936 float internalteam;
 937
 938 void weapon_defaultspawnfunc(float wpn)
 939 {
 940         entity e;
 941         float t;
 942         var .float ammofield;
 943         string s;
 944         entity oldself;
 945         float i, j;
 946
 947         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 948         {
 949                 e = get_weaponinfo(wpn);
 950                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 951                 if(s == "0")
 952                 {
 953                         remove(self);
 954                         startitem_failed = TRUE;
 955                         return;
 956                 }
 957                 t = tokenize_console(s);
 958                 if(t >= 2)
 959                 {
 960                         self.team = --internalteam;
 961                         oldself = self;
 962                         for(i = 1; i < t; ++i)
 963                         {
 964                                 s = argv(i);
 965                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 966                                 {
 967                                         e = get_weaponinfo(j);
 968                                         if(e.netname == s)
 969                                         {
 970                                                 self = spawn();
 971                                                 copyentity(oldself, self);
 972                                                 self.classname = "replacedweapon";
 973                                                 weapon_defaultspawnfunc(j);
 974                                                 break;
 975                                         }
 976                                 }
 977                                 if(j > WEP_LAST)
 978                                 {
 979                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 980                                 }
 981                         }
 982                         self = oldself;
 983                 }
 984                 if(t >= 1)
 985                 {
 986                         s = argv(0);
 987                         wpn = 0;
 988                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 989                         {
 990                                 e = get_weaponinfo(j);
 991                                 if(e.netname == s)
 992                                 {
 993                                         wpn = j;
 994                                         break;
 995                                 }
 996                         }
 997                         if(j > WEP_LAST)
 998                         {
 999                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1000                         }
1001                 }
1002                 if(wpn == 0)
1003                 {
1004                         remove(self);
1005                         startitem_failed = TRUE;
1006                         return;
1007                 }
1008         }
1009
1010         e = get_weaponinfo(wpn);
1011
1012         if(!self.respawntime)
1013         {
1014                 if(e.weapons & WEPBIT_SUPERWEAPONS)
1015                 {
1016                         self.respawntime = g_pickup_respawntime_superweapon;
1017                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1018                 }
1019                 else
1020                 {
1021                         self.respawntime = g_pickup_respawntime_weapon;
1022                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1023                 }
1024         }
1025
1026         if(e.weapons & WEPBIT_SUPERWEAPONS)
1027                 if(!self.superweapons_finished)
1028                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1029
1030         if(e.items)
1031         {
1032                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1033                 {
1034                         if(e.items & j)
1035                         {
1036                                 ammofield = Item_CounterField(j);
1037                                 if(!self.ammofield)
1038                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1039                         }
1040                 }
1041         }
1042
1043         // no weapon-stay on superweapons
1044         if(self.weapons & WEPBIT_SUPERWEAPONS)
1045                 self.flags |= FL_NO_WEAPON_STAY;
1046
1047         // weapon stay isn't supported for teamed weapons
1048         if(self.team)
1049                 self.flags |= FL_NO_WEAPON_STAY;
1050
1051         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1052         if (self.modelindex) // don't precache if self was removed
1053                 weapon_action(e.weapon, WR_PRECACHE);
1054 }
1055
1056 void spawnfunc_weapon_shotgun (void);
1057 void spawnfunc_weapon_uzi (void) {
1058         if(autocvar_sv_q3acompat_machineshotgunswap)
1059         if(self.classname != "droppedweapon")
1060         {
1061                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1062                 return;
1063         }
1064         weapon_defaultspawnfunc(WEP_UZI);
1065 }
1066
1067 void spawnfunc_weapon_shotgun (void) {
1068         if(autocvar_sv_q3acompat_machineshotgunswap)
1069         if(self.classname != "droppedweapon")
1070         {
1071                 weapon_defaultspawnfunc(WEP_UZI);
1072                 return;
1073         }
1074         weapon_defaultspawnfunc(WEP_SHOTGUN);
1075 }
1076
1077 void spawnfunc_weapon_nex (void)
1078 {
1079         if (g_minstagib)
1080         {
1081                 minstagib_items(IT_CELLS);
1082                 self.think = minst_remove_item;
1083                 self.nextthink = time;
1084                 return;
1085         }
1086         weapon_defaultspawnfunc(WEP_NEX);
1087 }
1088
1089 void spawnfunc_weapon_minstanex (void)
1090 {
1091         if (g_minstagib)
1092         {
1093                 minstagib_items(IT_CELLS);
1094                 self.think = minst_remove_item;
1095                 self.nextthink = time;
1096                 return;
1097         }
1098         weapon_defaultspawnfunc(WEP_MINSTANEX);
1099 }
1100
1101 void spawnfunc_weapon_rocketlauncher (void)
1102 {
1103         if (g_minstagib)
1104         {
1105                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1106                 self.think = minst_remove_item;
1107                 self.nextthink = time;
1108                 return;
1109         }
1110         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1111 }
1112
1113 void spawnfunc_item_rockets (void) {
1114         if(!self.ammo_rockets)
1115                 self.ammo_rockets = g_pickup_rockets;
1116         if(!self.pickup_anyway)
1117                 self.pickup_anyway = g_pickup_ammo_anyway;
1118         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1119 }
1120
1121 void spawnfunc_item_shells (void);
1122 void spawnfunc_item_bullets (void) {
1123         if(!weaponswapping)
1124         if(autocvar_sv_q3acompat_machineshotgunswap)
1125         if(self.classname != "droppedweapon")
1126         {
1127                 weaponswapping = TRUE;
1128                 spawnfunc_item_shells();
1129                 weaponswapping = FALSE;
1130                 return;
1131         }
1132
1133         if(!self.ammo_nails)
1134                 self.ammo_nails = g_pickup_nails;
1135         if(!self.pickup_anyway)
1136                 self.pickup_anyway = g_pickup_ammo_anyway;
1137         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1138 }
1139
1140 void spawnfunc_item_cells (void) {
1141         if(!self.ammo_cells)
1142                 self.ammo_cells = g_pickup_cells;
1143         if(!self.pickup_anyway)
1144                 self.pickup_anyway = g_pickup_ammo_anyway;
1145         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1146 }
1147
1148 void spawnfunc_item_shells (void) {
1149         if(!weaponswapping)
1150         if(autocvar_sv_q3acompat_machineshotgunswap)
1151         if(self.classname != "droppedweapon")
1152         {
1153                 weaponswapping = TRUE;
1154                 spawnfunc_item_bullets();
1155                 weaponswapping = FALSE;
1156                 return;
1157         }
1158
1159         if(!self.ammo_shells)
1160                 self.ammo_shells = g_pickup_shells;
1161         if(!self.pickup_anyway)
1162                 self.pickup_anyway = g_pickup_ammo_anyway;
1163         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1164 }
1165
1166 void spawnfunc_item_armor_small (void) {
1167         if(!self.armorvalue)
1168                 self.armorvalue = g_pickup_armorsmall;
1169         if(!self.max_armorvalue)
1170                 self.max_armorvalue = g_pickup_armorsmall_max;
1171         if(!self.pickup_anyway)
1172                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1173         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1174 }
1175
1176 void spawnfunc_item_armor_medium (void) {
1177         if(!self.armorvalue)
1178                 self.armorvalue = g_pickup_armormedium;
1179         if(!self.max_armorvalue)
1180                 self.max_armorvalue = g_pickup_armormedium_max;
1181         if(!self.pickup_anyway)
1182                 self.pickup_anyway = g_pickup_armormedium_anyway;
1183         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1184 }
1185
1186 void spawnfunc_item_armor_big (void) {
1187         if(!self.armorvalue)
1188                 self.armorvalue = g_pickup_armorbig;
1189         if(!self.max_armorvalue)
1190                 self.max_armorvalue = g_pickup_armorbig_max;
1191         if(!self.pickup_anyway)
1192                 self.pickup_anyway = g_pickup_armorbig_anyway;
1193         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1194 }
1195
1196 void spawnfunc_item_armor_large (void) {
1197         if(!self.armorvalue)
1198                 self.armorvalue = g_pickup_armorlarge;
1199         if(!self.max_armorvalue)
1200                 self.max_armorvalue = g_pickup_armorlarge_max;
1201         if(!self.pickup_anyway)
1202                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1203         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1204 }
1205
1206 void spawnfunc_item_health_small (void) {
1207         if(!self.max_health)
1208                 self.max_health = g_pickup_healthsmall_max;
1209         if(!self.health)
1210                 self.health = g_pickup_healthsmall;
1211         if(!self.pickup_anyway)
1212                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1213         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1214 }
1215
1216 void spawnfunc_item_health_medium (void) {
1217         if(!self.max_health)
1218                 self.max_health = g_pickup_healthmedium_max;
1219         if(!self.health)
1220                 self.health = g_pickup_healthmedium;
1221         if(!self.pickup_anyway)
1222                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1223         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1224 }
1225
1226 void spawnfunc_item_health_large (void) {
1227         if(!self.max_health)
1228                 self.max_health = g_pickup_healthlarge_max;
1229         if(!self.health)
1230                 self.health = g_pickup_healthlarge;
1231         if(!self.pickup_anyway)
1232                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1233         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1234 }
1235
1236 void spawnfunc_item_health_mega (void) {
1237         if(g_minstagib) {
1238                 minstagib_items(IT_NAILS);
1239         } else {
1240                 if(!self.max_health)
1241                         self.max_health = g_pickup_healthmega_max;
1242                 if(!self.health)
1243                         self.health = g_pickup_healthmega;
1244                 if(!self.pickup_anyway)
1245                         self.pickup_anyway = g_pickup_healthmega_anyway;
1246                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1247         }
1248 }
1249
1250 // support old misnamed entities
1251 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1252 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1253 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1254 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1255 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1256
1257 void spawnfunc_item_strength (void) {
1258         if(g_minstagib) {
1259                 minstagib_items(IT_STRENGTH);
1260         } else {
1261                 precache_sound("weapons/strength_fire.wav");
1262                 if(!self.strength_finished)
1263                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1264                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1265         }
1266 }
1267
1268 void spawnfunc_item_invincible (void) {
1269         if(g_minstagib) {
1270                 minstagib_items(IT_INVINCIBLE);
1271         } else {
1272                 if(!self.invincible_finished)
1273                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1274                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1275         }
1276 }
1277
1278 void spawnfunc_item_minst_cells (void) {
1279         if (g_minstagib)
1280         {
1281                 minst_no_auto_cells = 1;
1282                 minstagib_items(IT_CELLS);
1283         }
1284         else
1285                 remove(self);
1286 }
1287
1288 // compatibility:
1289 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1290
1291 float GiveItems(entity e, float beginarg, float endarg);
1292 void target_items_use (void)
1293 {
1294         if(activator.classname == "droppedweapon")
1295         {
1296                 EXACTTRIGGER_TOUCH;
1297                 remove(activator);
1298                 return;
1299         }
1300
1301         if(activator.classname != "player")
1302                 return;
1303         if(activator.deadflag != DEAD_NO)
1304                 return;
1305         EXACTTRIGGER_TOUCH;
1306
1307         entity e;
1308         for(e = world; (e = find(e, classname, "droppedweapon")); )
1309                 if(e.enemy == activator)
1310                         remove(e);
1311
1312         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1313                 centerprint(activator, self.message);
1314 }
1315
1316 void spawnfunc_target_items (void)
1317 {
1318         float n, i, j;
1319         entity e;
1320
1321         self.use = target_items_use;
1322         if(!self.strength_finished)
1323                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1324         if(!self.invincible_finished)
1325                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1326         if(!self.superweapons_finished)
1327                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1328
1329         precache_sound("misc/itempickup.wav");
1330         precache_sound("misc/megahealth.wav");
1331         precache_sound("misc/armor25.wav");
1332         precache_sound("misc/powerup.wav");
1333         precache_sound("misc/poweroff.wav");
1334         precache_sound("weapons/weaponpickup.wav");
1335
1336         n = tokenize_console(self.netname);
1337         if(argv(0) == "give")
1338         {
1339                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1340         }
1341         else
1342         {
1343                 for(i = 0; i < n; ++i)
1344                 {
1345                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1346                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1347                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1348                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1349                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1350                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1351                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1352                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1353                         else
1354                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1355                         {
1356                                 e = get_weaponinfo(j);
1357                                 if(argv(i) == e.netname)
1358                                 {
1359                                         self.weapons |= e.weapons;
1360                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1361                                                 weapon_action(e.weapon, WR_PRECACHE);
1362                                         break;
1363                                 }
1364                         }
1365                         if(j > WEP_LAST)
1366                                 print("target_items: invalid item ", argv(i), "\n");
1367                 }
1368
1369                 string itemprefix, valueprefix;
1370                 if(self.spawnflags == 0)
1371                 {
1372                         itemprefix = "";
1373                         valueprefix = "";
1374                 }
1375                 else if(self.spawnflags == 1)
1376                 {
1377                         itemprefix = "max ";
1378                         valueprefix = "max ";
1379                 }
1380                 else if(self.spawnflags == 2)
1381                 {
1382                         itemprefix = "min ";
1383                         valueprefix = "min ";
1384                 }
1385                 else if(self.spawnflags == 4)
1386                 {
1387                         itemprefix = "minus ";
1388                         valueprefix = "max ";
1389                 }
1390                 else
1391                         error("invalid spawnflags");
1392
1393                 self.netname = "";
1394                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1395                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1396                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1397                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1398                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1399                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1400                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1401                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1402                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1403                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1404                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1405                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1406                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1407                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1408                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1409                 {
1410                         e = get_weaponinfo(j);
1411                         if(e.weapons)
1412                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1413                 }
1414         }
1415         self.netname = strzone(self.netname);
1416         //print(self.netname, "\n");
1417
1418         n = tokenize_console(self.netname);
1419         for(i = 0; i < n; ++i)
1420         {
1421                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1422                 {
1423                         e = get_weaponinfo(j);
1424                         if(argv(i) == e.netname)
1425                         {
1426                                 weapon_action(e.weapon, WR_PRECACHE);
1427                                 break;
1428                         }
1429                 }
1430         }
1431 }
1432
1433 void spawnfunc_item_fuel(void)
1434 {
1435         if(!self.ammo_fuel)
1436                 self.ammo_fuel = g_pickup_fuel;
1437         if(!self.pickup_anyway)
1438                 self.pickup_anyway = g_pickup_ammo_anyway;
1439         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1440 }
1441
1442 void spawnfunc_item_fuel_regen(void)
1443 {
1444         if(start_items & IT_FUEL_REGEN)
1445         {
1446                 spawnfunc_item_fuel();
1447                 return;
1448         }
1449         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1450 }
1451
1452 void spawnfunc_item_jetpack(void)
1453 {
1454         if(g_grappling_hook)
1455                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1456         if(!self.ammo_fuel)
1457                 self.ammo_fuel = g_pickup_fuel_jetpack;
1458         if(start_items & IT_JETPACK)
1459         {
1460                 spawnfunc_item_fuel();
1461                 return;
1462         }
1463         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1464 }
1465
1466
1467 #define OP_SET 0
1468 #define OP_MIN 1
1469 #define OP_MAX 2
1470 #define OP_PLUS 3
1471 #define OP_MINUS 4
1472
1473 float GiveBit(entity e, .float fld, float bit, float op, float val)
1474 {
1475         float v0, v1;
1476         v0 = (e.fld & bit);
1477         switch(op)
1478         {
1479                 case OP_SET:
1480                         if(val > 0)
1481                                 e.fld |= bit;
1482                         else
1483                                 e.fld &~= bit;
1484                         break;
1485                 case OP_MIN:
1486                 case OP_PLUS:
1487                         if(val > 0)
1488                                 e.fld |= bit;
1489                         break;
1490                 case OP_MAX:
1491                         if(val <= 0)
1492                                 e.fld &~= bit;
1493                         break;
1494                 case OP_MINUS:
1495                         if(val > 0)
1496                                 e.fld &~= bit;
1497                         break;
1498         }
1499         v1 = (e.fld & bit);
1500         return (v0 != v1);
1501 }
1502
1503 float GiveValue(entity e, .float fld, float op, float val)
1504 {
1505         float v0, v1;
1506         v0 = e.fld;
1507         switch(op)
1508         {
1509                 case OP_SET:
1510                         e.fld = val;
1511                         break;
1512                 case OP_MIN:
1513                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1514                         break;
1515                 case OP_MAX:
1516                         e.fld = min(e.fld, val);
1517                         break;
1518                 case OP_PLUS:
1519                         e.fld += val;
1520                         break;
1521                 case OP_MINUS:
1522                         e.fld -= val;
1523                         break;
1524         }
1525         v1 = e.fld;
1526         return (v0 != v1);
1527 }
1528
1529 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1530 {
1531         if(v1 == v0)
1532                 return;
1533         if(v1 <= v0 - t)
1534         {
1535                 if(snd_decr != "")
1536                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1537         }
1538         else if(v0 >= v0 + t)
1539         {
1540                 if(snd_incr != "")
1541                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1542         }
1543 }
1544
1545 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1546 {
1547         if(v0 < v1)
1548                 e.rotfield = max(e.rotfield, time + rottime);
1549         else if(v0 > v1)
1550                 e.regenfield = max(e.regenfield, time + regentime);
1551 }
1552
1553 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1554 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1555 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1556 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1557
1558 float GiveItems(entity e, float beginarg, float endarg)
1559 {
1560         float got, i, j, val, op;
1561         float _switchweapon;
1562         entity wi;
1563         string cmd;
1564
1565         val = 999;
1566         op = OP_SET;
1567
1568         got = 0;
1569
1570         _switchweapon = FALSE;
1571         if (e.autoswitch)
1572                 if (e.switchweapon == w_getbestweapon(e))
1573                         _switchweapon = TRUE;
1574
1575         e.strength_finished = max(0, e.strength_finished - time);
1576         e.invincible_finished = max(0, e.invincible_finished - time);
1577         e.superweapons_finished = max(0, e.superweapons_finished - time);
1578
1579         PREGIVE(e, items);
1580         PREGIVE(e, weapons);
1581         PREGIVE(e, strength_finished);
1582         PREGIVE(e, invincible_finished);
1583         PREGIVE(e, superweapons_finished);
1584         PREGIVE(e, ammo_nails);
1585         PREGIVE(e, ammo_cells);
1586         PREGIVE(e, ammo_shells);
1587         PREGIVE(e, ammo_rockets);
1588         PREGIVE(e, ammo_fuel);
1589         PREGIVE(e, armorvalue);
1590         PREGIVE(e, health);
1591
1592         for(i = beginarg; i < endarg; ++i)
1593         {
1594                 cmd = argv(i);
1595
1596                 if(cmd == "0" || stof(cmd))
1597                 {
1598                         val = stof(cmd);
1599                         continue;
1600                 }
1601                 switch(cmd)
1602                 {
1603                         case "no":
1604                                 op = OP_MAX;
1605                                 val = 0;
1606                                 continue;
1607                         case "max":
1608                                 op = OP_MAX;
1609                                 continue;
1610                         case "min":
1611                                 op = OP_MIN;
1612                                 continue;
1613                         case "plus":
1614                                 op = OP_PLUS;
1615                                 continue;
1616                         case "minus":
1617                                 op = OP_MINUS;
1618                                 continue;
1619                         case "ALL":
1620                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1621                                 got += GiveValue(e, strength_finished, op, val);
1622                                 got += GiveValue(e, invincible_finished, op, val);
1623                                 got += GiveValue(e, superweapons_finished, op, val);
1624                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1625                         case "all":
1626                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1627                                 got += GiveValue(e, health, op, val);
1628                                 got += GiveValue(e, armorvalue, op, val);
1629                         case "allweapons":
1630                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1631                                 {
1632                                         wi = get_weaponinfo(j);
1633                                         if(wi.weapons)
1634                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1635                                 }
1636                         case "allammo":
1637                                 got += GiveValue(e, ammo_cells, op, val);
1638                                 got += GiveValue(e, ammo_shells, op, val);
1639                                 got += GiveValue(e, ammo_nails, op, val);
1640                                 got += GiveValue(e, ammo_rockets, op, val);
1641                                 got += GiveValue(e, ammo_fuel, op, val);
1642                                 break;
1643                         case "unlimited_ammo":
1644                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1645                                 break;
1646                         case "unlimited_weapon_ammo":
1647                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1648                                 break;
1649                         case "unlimited_superweapons":
1650                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1651                                 break;
1652                         case "jetpack":
1653                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1654                                 break;
1655                         case "fuel_regen":
1656                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1657                                 break;
1658                         case "strength":
1659                                 got += GiveValue(e, strength_finished, op, val);
1660                                 break;
1661                         case "invincible":
1662                                 got += GiveValue(e, invincible_finished, op, val);
1663                                 break;
1664                         case "superweapons":
1665                                 got += GiveValue(e, superweapons_finished, op, val);
1666                                 break;
1667                         case "cells":
1668                                 got += GiveValue(e, ammo_cells, op, val);
1669                                 break;
1670                         case "shells":
1671                                 got += GiveValue(e, ammo_shells, op, val);
1672                                 break;
1673                         case "nails":
1674                         case "bullets":
1675                                 got += GiveValue(e, ammo_nails, op, val);
1676                                 break;
1677                         case "rockets":
1678                                 got += GiveValue(e, ammo_rockets, op, val);
1679                                 break;
1680                         case "health":
1681                                 got += GiveValue(e, health, op, val);
1682                                 break;
1683                         case "armor":
1684                                 got += GiveValue(e, armorvalue, op, val);
1685                                 break;
1686                         case "fuel":
1687                                 got += GiveValue(e, ammo_fuel, op, val);
1688                                 break;
1689                         default:
1690                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1691                                 {
1692                                         wi = get_weaponinfo(j);
1693                                         if(cmd == wi.netname)
1694                                         {
1695                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1696                                                 break;
1697                                         }
1698                                 }
1699                                 if(j > WEP_LAST)
1700                                         print("give: invalid item ", cmd, "\n");
1701                                 break;
1702                 }
1703                 val = 999;
1704                 op = OP_SET;
1705         }
1706
1707         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1708         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1709         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1710         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1711         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1712         {
1713                 wi = get_weaponinfo(j);
1714                 if(wi.weapons)
1715                 {
1716                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1717                         if not(save_weapons & wi.weapons)
1718                                 if(e.weapons & wi.weapons)
1719                                         weapon_action(wi.weapon, WR_PRECACHE);
1720                 }
1721         }
1722         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1723         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1724         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1725         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1726         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1727         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1728         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1729         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1730         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1731
1732         if(e.superweapons_finished <= 0)
1733                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1734                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1735
1736         if (g_minstagib)
1737         {
1738                 e.health = bound(0, e.health, 100);
1739                 e.armorvalue = bound(0, e.armorvalue, 999);
1740         }
1741
1742         if(e.strength_finished <= 0)
1743                 e.strength_finished = 0;
1744         else
1745                 e.strength_finished += time;
1746         if(e.invincible_finished <= 0)
1747                 e.invincible_finished = 0;
1748         else
1749                 e.invincible_finished += time;
1750         if(e.superweapons_finished <= 0)
1751                 e.superweapons_finished = 0;
1752         else
1753                 e.superweapons_finished += time;
1754
1755         if not(e.weapons & W_WeaponBit(e.switchweapon))
1756                 _switchweapon = TRUE;
1757         if(_switchweapon)
1758                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1759
1760         return got;
1761 }