qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(autocvar_g_ghost_items_color);
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(autocvar_g_ghost_items_color);
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = '0 0 0';
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (autocvar_g_nodepthtestitems)
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (autocvar_g_fullbrightitems)
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 void Item_Respawn (void)
 146 {
 147         Item_Show(self, 1);
 148         if(!g_minstagib && self.items == IT_STRENGTH)
 149                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 150         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 151                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 152         else
 153                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 154         setorigin (self, self.origin);
 155
 156         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 157         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 158 }
 159
 160 void Item_RespawnCountdown (void)
 161 {
 162         if(self.count >= ITEM_RESPAWN_TICKS)
 163         {
 164                 if(self.waypointsprite_attached)
 165                         WaypointSprite_Kill(self.waypointsprite_attached);
 166                 Item_Respawn();
 167         }
 168         else
 169         {
 170                 self.nextthink = time + 1;
 171                 self.count += 1;
 172                 if(self.count == 1)
 173                 {
 174                         string name;
 175                         vector rgb;
 176                         name = string_null;
 177                         if(g_minstagib)
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 182                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 183                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 184                                 }
 185                         }
 186                         else
 187                         {
 188                                 switch(self.items)
 189                                 {
 190                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 191                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 192                                 }
 193                         }
 194                         switch(self.items)
 195                         {
 196                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 197                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 198                         }
 199                         if(name)
 200                         {
 201                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 202                                 if(self.waypointsprite_attached)
 203                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 204                         }
 205                 }
 206                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 207                 if(self.waypointsprite_attached)
 208                 {
 209                         WaypointSprite_Ping(self.waypointsprite_attached);
 210                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 211                 }
 212         }
 213 }
 214
 215 void Item_ScheduleRespawnIn(entity e, float t)
 216 {
 217         if(e.flags & FL_POWERUP)
 218         {
 219                 e.think = Item_RespawnCountdown;
 220                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 221                 e.count = 0;
 222         }
 223         else
 224         {
 225                 e.think = Item_Respawn;
 226                 e.nextthink = time + t;
 227         }
 228 }
 229
 230 void Item_ScheduleRespawn(entity e)
 231 {
 232         if(e.respawntime > 0)
 233         {
 234                 Item_Show(e, 0);
 235                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 236         }
 237         else // if respawntime is -1, this item does not respawn
 238                 Item_Show(e, -1);
 239 }
 240
 241 void Item_ScheduleInitialRespawn(entity e)
 242 {
 243         Item_Show(e, 0);
 244         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 245 }
 246
 247 float Item_GiveTo(entity item, entity player)
 248 {
 249         float _switchweapon;
 250         float pickedup;
 251         float it;
 252         float i;
 253         entity e;
 254
 255         // if nothing happens to player, just return without taking the item
 256         pickedup = FALSE;
 257         _switchweapon = FALSE;
 258
 259         if (g_minstagib)
 260         {
 261                 if(item.spawnshieldtime)
 262                 {
 263                         if (item.ammo_fuel)
 264                         if (player.ammo_fuel < g_pickup_fuel_max)
 265                         {
 266                                 pickedup = TRUE;
 267                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 268                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 269                         }
 270                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 271                         {
 272                                 pickedup = TRUE;
 273                                 player.items |= it;
 274                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 275                         }
 276
 277                         _switchweapon = TRUE;
 278                         if (item.ammo_cells)
 279                         {
 280                                 pickedup = TRUE;
 281                                 // play some cool sounds ;)
 282                                 centerprint(player, "\n");
 283                                 if (clienttype(player) == CLIENTTYPE_REAL)
 284                                 {
 285                                         if(player.health <= 5)
 286                                                 AnnounceTo(player, "lastsecond");
 287                                         else if(player.health < 50)
 288                                                 AnnounceTo(player, "narrowly");
 289                                 }
 290                                 // sound not available
 291                                 // else if(item.items == IT_CELLS)
 292                                 //      AnnounceTo(player, "ammo");
 293
 294                                 if (item.weapons & WEPBIT_MINSTANEX)
 295                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 296                                 if (item.ammo_cells)
 297                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 298                                 player.health = 100;
 299                         }
 300
 301                         // extralife powerup
 302                         if (item.max_health)
 303                         {
 304                                 pickedup = TRUE;
 305                                 // sound not available
 306                                 // AnnounceTo(player, "_lives");
 307                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 308                                 sprint(player, "^3You picked up some extra lives\n");
 309                         }
 310
 311                         // invis powerup
 312                         if (item.strength_finished)
 313                         {
 314                                 pickedup = TRUE;
 315                                 // sound not available
 316                                 // AnnounceTo(player, "invisible");
 317                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 318                         }
 319
 320                         // speed powerup
 321                         if (item.invincible_finished)
 322                         {
 323                                 pickedup = TRUE;
 324                                 // sound not available
 325                                 // AnnounceTo(player, "speed");
 326                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 327                         }
 328                 }
 329         }
 330         else
 331         {
 332                 if (g_weapon_stay == 1)
 333                 if not(item.flags & FL_NO_WEAPON_STAY)
 334                 if (item.flags & FL_WEAPON)
 335                 {
 336                         if(item.classname == "droppedweapon")
 337                         {
 338                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 339                                         goto skip;
 340                         }
 341                         else
 342                         {
 343                                 if (player.weapons & item.weapons)
 344                                         goto skip;
 345                         }
 346                 }
 347
 348                 // in case the player has autoswitch enabled do the following:
 349                 // if the player is using their best weapon before items are given, they
 350                 // probably want to switch to an even better weapon after items are given
 351                 if (player.autoswitch)
 352                 if (player.switchweapon == w_getbestweapon(player))
 353                         _switchweapon = TRUE;
 354
 355                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 356                         _switchweapon = TRUE;
 357
 358                 if(item.spawnshieldtime)
 359                 {
 360                         if (item.ammo_shells)
 361                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 362                         {
 363                                 pickedup = TRUE;
 364                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 365                         }
 366                         if (item.ammo_nails)
 367                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 368                         {
 369                                 pickedup = TRUE;
 370                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 371                         }
 372                         if (item.ammo_rockets)
 373                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 374                         {
 375                                 pickedup = TRUE;
 376                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 377                         }
 378                         if (item.ammo_cells)
 379                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 380                         {
 381                                 pickedup = TRUE;
 382                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 383                         }
 384                         if (item.ammo_fuel)
 385                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 386                         {
 387                                 pickedup = TRUE;
 388                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 389                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 390                         }
 391                 }
 392
 393                 if (item.flags & FL_WEAPON)
 394                 if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway && !(g_weapon_stay == 3 && !e.spawnshieldtime)))
 395                 {
 396                         pickedup = TRUE;
 397                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 398                         {
 399                                 e = get_weaponinfo(i);
 400                                 if(it & e.weapons)
 401                                         W_GiveWeapon (player, e.weapon, item.netname);
 402                         }
 403                 }
 404
 405                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 406                 {
 407                         pickedup = TRUE;
 408                         player.items |= it;
 409                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 410                 }
 411
 412                 if(item.spawnshieldtime)
 413                 {
 414                         if (item.strength_finished)
 415                         {
 416                                 pickedup = TRUE;
 417                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 418                         }
 419                         if (item.invincible_finished)
 420                         {
 421                                 pickedup = TRUE;
 422                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 423                         }
 424
 425                         if (item.health)
 426                         if ((player.health < item.max_health) || item.pickup_anyway)
 427                         {
 428                                 pickedup = TRUE;
 429                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 430                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 431                         }
 432                         if (item.armorvalue)
 433                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 434                         {
 435                                 pickedup = TRUE;
 436                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 437                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 438                         }
 439                 }
 440         }
 441
 442 :skip
 443         // always eat teamed entities
 444         if(item.team)
 445                 pickedup = TRUE;
 446
 447         if (!pickedup)
 448                 return 0;
 449
 450         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 451         if (_switchweapon)
 452                 if (player.switchweapon != w_getbestweapon(player))
 453                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 454
 455         return 1;
 456 }
 457
 458 void Item_Touch (void)
 459 {
 460         entity e, head;
 461
 462         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 463         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 464         {
 465                 remove(self);
 466                 return;
 467         }
 468         if (other.classname != "player")
 469                 return;
 470         if (other.deadflag)
 471                 return;
 472         if (self.solid != SOLID_TRIGGER)
 473                 return;
 474         if (self.owner == other)
 475                 return;
 476
 477         if(!Item_GiveTo(self, other))
 478                 return;
 479
 480         other.last_pickup = time;
 481
 482         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 483
 484         if (self.classname == "droppedweapon")
 485                 remove (self);
 486         else if not(self.spawnshieldtime)
 487                 return;
 488         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 489                 return;
 490         else
 491         {
 492                 if(self.team)
 493                 {
 494                         RandomSelection_Init();
 495                         for(head = world; (head = findfloat(head, team, self.team)); )
 496                         {
 497                                 if(head.flags & FL_ITEM)
 498                                 {
 499                                         Item_Show(head, -1);
 500                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 501                                 }
 502                         }
 503                         e = RandomSelection_chosen_ent;
 504                 }
 505                 else
 506                         e = self;
 507                 Item_ScheduleRespawn(e);
 508         }
 509 }
 510
 511 void Item_FindTeam()
 512 {
 513         entity head, e;
 514
 515         if(self.effects & EF_NODRAW)
 516         {
 517                 // marker for item team search
 518                 dprint("Initializing item team ", ftos(self.team), "\n");
 519                 RandomSelection_Init();
 520                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 521                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 522                 e = RandomSelection_chosen_ent;
 523                 e.state = 0;
 524                 Item_Show(e, 1);
 525
 526                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 527                 {
 528                         if(head != e)
 529                         {
 530                                 // make it a non-spawned item
 531                                 Item_Show(head, -1);
 532                                 head.state = 1; // state 1 = initially hidden item
 533                         }
 534                         head.effects &~= EF_NODRAW;
 535                 }
 536
 537                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 538                         Item_ScheduleInitialRespawn(e);
 539         }
 540 }
 541
 542 void Item_Reset()
 543 {
 544         Item_Show(self, !self.state);
 545         setorigin (self, self.origin);
 546         self.think = SUB_Null;
 547         self.nextthink = 0;
 548
 549         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 550                 Item_ScheduleInitialRespawn(self);
 551 }
 552
 553 // Savage: used for item garbage-collection
 554 // TODO: perhaps nice special effect?
 555 void RemoveItem(void)
 556 {
 557         remove(self);
 558 }
 559
 560 // pickup evaluation functions
 561 // these functions decide how desirable an item is to the bots
 562
 563 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 564
 565 float weapon_pickupevalfunc(entity player, entity item)
 566 {
 567         float c, i, j, position;
 568
 569         // See if I have it already
 570         if(player.weapons & item.weapons == item.weapons)
 571         {
 572                 // If I can pick it up
 573                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 574                         c = 0;
 575                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 576                 {
 577                         // Skilled bots will grab more
 578                         c = bound(0, skill / 10, 1) * 0.5;
 579                 }
 580                 else
 581                         c = 0;
 582         }
 583         else
 584                 c = 1;
 585
 586         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 587         if( bot_custom_weapon && c )
 588         {
 589                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 590                 {
 591                         // Find weapon
 592                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 593                                 continue;
 594
 595                         // Find the highest position on any range
 596                         position = -1;
 597                         for(j = 0; j < WEP_LAST ; ++j){
 598                                 if(
 599                                                 bot_weapons_far[j] == i ||
 600                                                 bot_weapons_mid[j] == i ||
 601                                                 bot_weapons_close[j] == i
 602                                   )
 603                                 {
 604                                         position = j;
 605                                         break;
 606                                 }
 607                         }
 608
 609                         // Rate it
 610                         if (position >= 0 )
 611                         {
 612                                 position = WEP_LAST - position;
 613                                 // item.bot_pickupbasevalue is overwritten here
 614                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 615                         }
 616                 }
 617         }
 618
 619         return item.bot_pickupbasevalue * c;
 620 };
 621
 622 float commodity_pickupevalfunc(entity player, entity item)
 623 {
 624         float c, i, need_shells, need_nails, need_rockets, need_cells;
 625         entity wi;
 626         c = 0;
 627
 628         // Detect needed ammo
 629         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 630         {
 631                 wi = get_weaponinfo(i);
 632
 633                 if not(wi.weapons & player.weapons)
 634                         continue;
 635
 636                 if(wi.items & IT_SHELLS)
 637                         need_shells = TRUE;
 638                 else if(wi.items & IT_NAILS)
 639                         need_nails = TRUE;
 640                 else if(wi.items & IT_ROCKETS)
 641                         need_rockets = TRUE;
 642                 else if(wi.items & IT_CELLS)
 643                         need_cells = TRUE;
 644         }
 645
 646         // TODO: figure out if the player even has the weapon this ammo is for?
 647         // may not affect strategy much though...
 648         // find out how much more ammo/armor/health the player can hold
 649         if (need_shells)
 650         if (item.ammo_shells)
 651         if (player.ammo_shells < g_pickup_shells_max)
 652                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 653         if (need_nails)
 654         if (item.ammo_nails)
 655         if (player.ammo_nails < g_pickup_nails_max)
 656                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 657         if (need_rockets)
 658         if (item.ammo_rockets)
 659         if (player.ammo_rockets < g_pickup_rockets_max)
 660                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 661         if (need_cells)
 662         if (item.ammo_cells)
 663         if (player.ammo_cells < g_pickup_cells_max)
 664                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 665         if (item.armorvalue)
 666         if (player.armorvalue < item.max_armorvalue)
 667                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 668         if (item.health)
 669         if (player.health < item.max_health)
 670                 c = c + max(0, 1 - player.health / item.max_health);
 671
 672         return item.bot_pickupbasevalue * c;
 673 };
 674
 675
 676 .float is_item;
 677 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 678 {
 679         startitem_failed = FALSE;
 680
 681         self.items = itemid;
 682         self.weapons = weaponid;
 683
 684         // is it a dropped weapon?
 685         if (self.classname == "droppedweapon")
 686         {
 687                 self.reset = SUB_Remove;
 688                 // it's a dropped weapon
 689                 self.movetype = MOVETYPE_TOSS;
 690                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 691                 self.think = RemoveItem;
 692                 self.nextthink = time + 60;
 693                 // don't drop if in a NODROP zone (such as lava)
 694                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 695                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 696                 {
 697                         startitem_failed = TRUE;
 698                         remove(self);
 699                         return;
 700                 }
 701         }
 702         else
 703         {
 704                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 705                 {
 706                         startitem_failed = TRUE;
 707                         remove(self);
 708                         return;
 709                 }
 710
 711                 self.reset = Item_Reset;
 712                 // it's a level item
 713                 if(self.spawnflags & 1)
 714                         self.noalign = 1;
 715                 if (self.noalign)
 716                         self.movetype = MOVETYPE_NONE;
 717                 else
 718                         self.movetype = MOVETYPE_TOSS;
 719                 // do item filtering according to game mode and other things
 720                 if (!self.noalign)
 721                 {
 722                         // first nudge it off the floor a little bit to avoid math errors
 723                         setorigin(self, self.origin + '0 0 1');
 724                         // set item size before we spawn a spawnfunc_waypoint
 725                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 726                                 setsize (self, '-16 -16 0', '16 16 48');
 727                         else
 728                                 setsize (self, '-16 -16 0', '16 16 32');
 729                         // note droptofloor returns FALSE if stuck/or would fall too far
 730                         droptofloor();
 731                         waypoint_spawnforitem(self);
 732                 }
 733
 734                 /*
 735                  * can't do it that way, as it would break maps
 736                  * TODO make a target_give like entity another way, that perhaps has
 737                  * the weapon name in a key
 738                 if(self.targetname)
 739                 {
 740                         // target_give not yet supported; maybe later
 741                         print("removed targeted ", self.classname, "\n");
 742                         startitem_failed = TRUE;
 743                         remove (self);
 744                         return;
 745                 }
 746                 */
 747
 748                 if(autocvar_spawn_debug >= 2)
 749                 {
 750                         entity otheritem;
 751                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 752                         {
 753                                 if(otheritem.is_item)
 754                                 {
 755                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 756                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 757                                         error("Mapper sucks.");
 758                                 }
 759                         }
 760                         self.is_item = TRUE;
 761                 }
 762
 763                 if(g_lms || g_ca)
 764                 {
 765                         startitem_failed = TRUE;
 766                         remove(self);
 767                         return;
 768                 }
 769                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 770                 {
 771                         startitem_failed = TRUE;
 772                         remove(self);
 773                         return;
 774                 }
 775                 else if (g_minstagib)
 776                 {
 777                         // don't remove dropped items and powerups
 778                         if (self.classname != "minstagib")
 779                         {
 780                                 startitem_failed = TRUE;
 781                                 remove (self);
 782                                 return;
 783                         }
 784                 }
 785                 else if (!autocvar_g_pickup_items && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 786                 {
 787                         startitem_failed = TRUE;
 788                         remove (self);
 789                         return;
 790                 }
 791
 792                 weaponsInMap |= weaponid;
 793
 794                 precache_model (itemmodel);
 795                 precache_sound (pickupsound);
 796
 797                 precache_sound ("misc/itemrespawncountdown.wav");
 798                 if(!g_minstagib && itemid == IT_STRENGTH)
 799                         precache_sound ("misc/strength_respawn.wav");
 800                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 801                         precache_sound ("misc/shield_respawn.wav");
 802                 else
 803                         precache_sound ("misc/itemrespawn.wav");
 804
 805                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 806                         self.target = "###item###"; // for finding the nearest item using find()
 807         }
 808
 809         self.bot_pickup = TRUE;
 810         self.bot_pickupevalfunc = pickupevalfunc;
 811         self.bot_pickupbasevalue = pickupbasevalue;
 812         self.mdl = itemmodel;
 813         self.item_pickupsound = pickupsound;
 814         // let mappers override respawntime
 815         if(!self.respawntime) // both set
 816         {
 817                 self.respawntime = defaultrespawntime;
 818                 self.respawntimejitter = defaultrespawntimejitter;
 819         }
 820         self.netname = itemname;
 821         self.flags = FL_ITEM | itemflags;
 822         self.touch = Item_Touch;
 823         setmodel (self, self.mdl); // precision set below
 824         self.effects |= EF_LOWPRECISION;
 825         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 826                 setsize (self, '-16 -16 0', '16 16 48');
 827         else
 828                 setsize (self, '-16 -16 0', '16 16 32');
 829         if(itemflags & FL_WEAPON)
 830                 self.modelflags |= MF_ROTATE;
 831
 832         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 833         if (itemflags & FL_WEAPON)
 834         {
 835                 // neutral team color for pickup weapons
 836                 self.colormap = 1024; // color shirt=0 pants=0 grey
 837         }
 838
 839         Item_Show(self, 1);
 840         self.state = 0;
 841         if(self.team)
 842         {
 843                 if(!self.cnt)
 844                         self.cnt = 1; // item probability weight
 845                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 846                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 847         }
 848         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 849                 Item_ScheduleInitialRespawn(self);
 850 }
 851
 852 /* replace items in minstagib
 853  * IT_STRENGTH   = invisibility
 854  * IT_NAILS      = extra lives
 855  * IT_INVINCIBLE = speed
 856  */
 857 void minstagib_items (float itemid)
 858 {
 859         local float rnd;
 860         self.classname = "minstagib";
 861
 862         // replace rocket launchers and nex guns with ammo cells
 863         if (itemid == IT_CELLS)
 864         {
 865                 self.ammo_cells = 1;
 866                 StartItem ("models/items/a_cells.md3",
 867                         "misc/itempickup.wav", 45, 0,
 868                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 869                 return;
 870         }
 871
 872         // randomize
 873         rnd = random() * 3;
 874         if (rnd <= 1)
 875                 itemid = IT_STRENGTH;
 876         else if (rnd <= 2)
 877                 itemid = IT_NAILS;
 878         else
 879                 itemid = IT_INVINCIBLE;
 880
 881         // replace with invis
 882         if (itemid == IT_STRENGTH)
 883         {
 884                 self.strength_finished = 30;
 885                 StartItem ("models/items/g_strength.md3",
 886                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 887                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 888         }
 889         // replace with extra lives
 890         if (itemid == IT_NAILS)
 891         {
 892                 self.max_health = 1;
 893                 StartItem ("models/items/g_h100.md3",
 894                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 895                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 896         }
 897         // replace with speed
 898         if (itemid == IT_INVINCIBLE)
 899         {
 900                 self.invincible_finished = 30;
 901                 StartItem ("models/items/g_invincible.md3",
 902                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 903                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 904         }
 905 }
 906
 907 float minst_no_auto_cells;
 908 void minst_remove_item (void) {
 909         if(minst_no_auto_cells)
 910                 remove(self);
 911 }
 912
 913 float weaponswapping;
 914 float internalteam;
 915
 916 void weapon_defaultspawnfunc(float wpn)
 917 {
 918         entity e;
 919         float t;
 920         var .float ammofield;
 921         string s;
 922         entity oldself;
 923         float i, j;
 924
 925         // set the respawntime in advance (so replaced weapons can copy it)
 926
 927         if(!self.respawntime)
 928         {
 929                 e = get_weaponinfo(wpn);
 930                 if(e.items == IT_SUPERWEAPON)
 931                 {
 932                         self.respawntime = g_pickup_respawntime_powerup;
 933                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 934                 }
 935                 else
 936                 {
 937                         self.respawntime = g_pickup_respawntime_weapon;
 938                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 939                 }
 940         }
 941
 942         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 943         {
 944                 e = get_weaponinfo(wpn);
 945                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 946                 if(s == "0")
 947                 {
 948                         remove(self);
 949                         startitem_failed = TRUE;
 950                         return;
 951                 }
 952                 t = tokenize_console(s);
 953                 if(t >= 2)
 954                 {
 955                         self.team = --internalteam;
 956                         oldself = self;
 957                         for(i = 1; i < t; ++i)
 958                         {
 959                                 s = argv(i);
 960                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 961                                 {
 962                                         e = get_weaponinfo(j);
 963                                         if(e.netname == s)
 964                                         {
 965                                                 self = spawn();
 966                                                 copyentity(oldself, self);
 967                                                 self.classname = "replacedweapon";
 968                                                 weapon_defaultspawnfunc(j);
 969                                                 break;
 970                                         }
 971                                 }
 972                                 if(j > WEP_LAST)
 973                                 {
 974                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 975                                 }
 976                         }
 977                         self = oldself;
 978                 }
 979                 if(t >= 1)
 980                 {
 981                         s = argv(0);
 982                         wpn = 0;
 983                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 984                         {
 985                                 e = get_weaponinfo(j);
 986                                 if(e.netname == s)
 987                                 {
 988                                         wpn = j;
 989                                         break;
 990                                 }
 991                         }
 992                         if(j > WEP_LAST)
 993                         {
 994                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 995                         }
 996                 }
 997                 if(wpn == 0)
 998                 {
 999                         remove(self);
1000                         startitem_failed = TRUE;
1001                         return;
1002                 }
1003         }
1004
1005         e = get_weaponinfo(wpn);
1006
1007         if(e.items && e.items != IT_SUPERWEAPON)
1008         {
1009                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1010                 {
1011                         if(e.items & j)
1012                         {
1013                                 ammofield = Item_CounterField(j);
1014                                 if(!self.ammofield)
1015                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1016                         }
1017                 }
1018         }
1019         else
1020         {
1021                 self.flags |= FL_NO_WEAPON_STAY;
1022         }
1023
1024         // weapon stay isn't supported for teamed weapons
1025         if(self.team)
1026                 self.flags |= FL_NO_WEAPON_STAY;
1027
1028         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1029         {
1030                 self.ammo_shells = 0;
1031                 self.ammo_nails = 0;
1032                 self.ammo_cells = 0;
1033                 self.ammo_rockets = 0;
1034                 // weapon stay 2: don't use ammo on weapon pickups; instead
1035                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1036         }
1037
1038         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1039         if (self.modelindex) // don't precache if self was removed
1040                 weapon_action(e.weapon, WR_PRECACHE);
1041 }
1042
1043 void spawnfunc_weapon_shotgun (void);
1044 void spawnfunc_weapon_uzi (void) {
1045         if(q3acompat_machineshotgunswap)
1046         if(self.classname != "droppedweapon")
1047         {
1048                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1049                 return;
1050         }
1051         weapon_defaultspawnfunc(WEP_UZI);
1052 }
1053
1054 void spawnfunc_weapon_shotgun (void) {
1055         if(q3acompat_machineshotgunswap)
1056         if(self.classname != "droppedweapon")
1057         {
1058                 weapon_defaultspawnfunc(WEP_UZI);
1059                 return;
1060         }
1061         weapon_defaultspawnfunc(WEP_SHOTGUN);
1062 }
1063
1064 void spawnfunc_weapon_nex (void)
1065 {
1066         if (g_minstagib)
1067         {
1068                 minstagib_items(IT_CELLS);
1069                 self.think = minst_remove_item;
1070                 self.nextthink = time;
1071                 return;
1072         }
1073         weapon_defaultspawnfunc(WEP_NEX);
1074 }
1075
1076 void spawnfunc_weapon_minstanex (void)
1077 {
1078         if (g_minstagib)
1079         {
1080                 minstagib_items(IT_CELLS);
1081                 self.think = minst_remove_item;
1082                 self.nextthink = time;
1083                 return;
1084         }
1085         weapon_defaultspawnfunc(WEP_MINSTANEX);
1086 }
1087
1088 void spawnfunc_weapon_rocketlauncher (void)
1089 {
1090         if (g_minstagib)
1091         {
1092                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1093                 self.think = minst_remove_item;
1094                 self.nextthink = time;
1095                 return;
1096         }
1097         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1098 }
1099
1100 void spawnfunc_item_rockets (void) {
1101         if(!self.ammo_rockets)
1102                 self.ammo_rockets = g_pickup_rockets;
1103         if(!self.pickup_anyway)
1104                 self.pickup_anyway = g_pickup_ammo_anyway;
1105         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1106 }
1107
1108 void spawnfunc_item_shells (void);
1109 void spawnfunc_item_bullets (void) {
1110         if(!weaponswapping)
1111         if(q3acompat_machineshotgunswap)
1112         if(self.classname != "droppedweapon")
1113         {
1114                 weaponswapping = TRUE;
1115                 spawnfunc_item_shells();
1116                 weaponswapping = FALSE;
1117                 return;
1118         }
1119
1120         if(!self.ammo_nails)
1121                 self.ammo_nails = g_pickup_nails;
1122         if(!self.pickup_anyway)
1123                 self.pickup_anyway = g_pickup_ammo_anyway;
1124         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1125 }
1126
1127 void spawnfunc_item_cells (void) {
1128         if(!self.ammo_cells)
1129                 self.ammo_cells = g_pickup_cells;
1130         if(!self.pickup_anyway)
1131                 self.pickup_anyway = g_pickup_ammo_anyway;
1132         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1133 }
1134
1135 void spawnfunc_item_shells (void) {
1136         if(!weaponswapping)
1137         if(q3acompat_machineshotgunswap)
1138         if(self.classname != "droppedweapon")
1139         {
1140                 weaponswapping = TRUE;
1141                 spawnfunc_item_bullets();
1142                 weaponswapping = FALSE;
1143                 return;
1144         }
1145
1146         if(!self.ammo_shells)
1147                 self.ammo_shells = g_pickup_shells;
1148         if(!self.pickup_anyway)
1149                 self.pickup_anyway = g_pickup_ammo_anyway;
1150         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1151 }
1152
1153 void spawnfunc_item_armor_small (void) {
1154         if(!self.armorvalue)
1155                 self.armorvalue = g_pickup_armorsmall;
1156         if(!self.max_armorvalue)
1157                 self.max_armorvalue = g_pickup_armorsmall_max;
1158         if(!self.pickup_anyway)
1159                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1160         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1161 }
1162
1163 void spawnfunc_item_armor_medium (void) {
1164         if(!self.armorvalue)
1165                 self.armorvalue = g_pickup_armormedium;
1166         if(!self.max_armorvalue)
1167                 self.max_armorvalue = g_pickup_armormedium_max;
1168         if(!self.pickup_anyway)
1169                 self.pickup_anyway = g_pickup_armormedium_anyway;
1170         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1171 }
1172
1173 void spawnfunc_item_armor_big (void) {
1174         if(!self.armorvalue)
1175                 self.armorvalue = g_pickup_armorbig;
1176         if(!self.max_armorvalue)
1177                 self.max_armorvalue = g_pickup_armorbig_max;
1178         if(!self.pickup_anyway)
1179                 self.pickup_anyway = g_pickup_armorbig_anyway;
1180         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1181 }
1182
1183 void spawnfunc_item_armor_large (void) {
1184         if(!self.armorvalue)
1185                 self.armorvalue = g_pickup_armorlarge;
1186         if(!self.max_armorvalue)
1187                 self.max_armorvalue = g_pickup_armorlarge_max;
1188         if(!self.pickup_anyway)
1189                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1190         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1191 }
1192
1193 void spawnfunc_item_health_small (void) {
1194         if(!self.max_health)
1195                 self.max_health = g_pickup_healthsmall_max;
1196         if(!self.health)
1197                 self.health = g_pickup_healthsmall;
1198         if(!self.pickup_anyway)
1199                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1200         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1201 }
1202
1203 void spawnfunc_item_health_medium (void) {
1204         if(!self.max_health)
1205                 self.max_health = g_pickup_healthmedium_max;
1206         if(!self.health)
1207                 self.health = g_pickup_healthmedium;
1208         if(!self.pickup_anyway)
1209                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1210         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1211 }
1212
1213 void spawnfunc_item_health_large (void) {
1214         if(!self.max_health)
1215                 self.max_health = g_pickup_healthlarge_max;
1216         if(!self.health)
1217                 self.health = g_pickup_healthlarge;
1218         if(!self.pickup_anyway)
1219                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1220         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1221 }
1222
1223 void spawnfunc_item_health_mega (void) {
1224         if(!autocvar_g_powerup_superhealth)
1225                 return;
1226
1227         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1228                 return;
1229
1230         if(g_minstagib) {
1231                 minstagib_items(IT_NAILS);
1232         } else {
1233                 if(!self.max_health)
1234                         self.max_health = g_pickup_healthmega_max;
1235                 if(!self.health)
1236                         self.health = g_pickup_healthmega;
1237                 if(!self.pickup_anyway)
1238                         self.pickup_anyway = g_pickup_healthmega_anyway;
1239                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1240         }
1241 }
1242
1243 // support old misnamed entities
1244 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1245 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1246 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1247 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1248 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1249
1250 void spawnfunc_item_strength (void) {
1251         if(!autocvar_g_powerup_strength)
1252                 return;
1253
1254         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1255                 return;
1256
1257         if(g_minstagib) {
1258                 minstagib_items(IT_STRENGTH);
1259         } else {
1260                 precache_sound("weapons/strength_fire.wav");
1261                 self.strength_finished = 30;
1262                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1263         }
1264 }
1265
1266 void spawnfunc_item_invincible (void) {
1267         if(!autocvar_g_powerup_shield)
1268                 return;
1269
1270         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1271                 return;
1272
1273         if(g_minstagib) {
1274                 minstagib_items(IT_INVINCIBLE);
1275         } else {
1276                 self.invincible_finished = 30;
1277                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1278         }
1279 }
1280
1281 void spawnfunc_item_minst_cells (void) {
1282         if (g_minstagib)
1283         {
1284                 minst_no_auto_cells = 1;
1285                 minstagib_items(IT_CELLS);
1286         }
1287         else
1288                 remove(self);
1289 }
1290
1291 // compatibility:
1292 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1293
1294 float GiveItems(entity e, float beginarg, float endarg);
1295 void target_items_use (void)
1296 {
1297         if(activator.classname == "droppedweapon")
1298         {
1299                 EXACTTRIGGER_TOUCH;
1300                 remove(activator);
1301                 return;
1302         }
1303
1304         if(activator.classname != "player")
1305                 return;
1306         if(activator.deadflag != DEAD_NO)
1307                 return;
1308         EXACTTRIGGER_TOUCH;
1309
1310         entity e;
1311         for(e = world; (e = find(e, classname, "droppedweapon")); )
1312                 if(e.enemy == activator)
1313                         remove(e);
1314
1315         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1316                 centerprint(activator, self.message);
1317 }
1318
1319 void spawnfunc_target_items (void)
1320 {
1321         float n, i, j;
1322         entity e;
1323
1324         self.use = target_items_use;
1325         if(!self.strength_finished)
1326                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1327         if(!self.invincible_finished)
1328                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1329
1330         precache_sound("misc/itempickup.wav");
1331         precache_sound("misc/megahealth.wav");
1332         precache_sound("misc/armor25.wav");
1333         precache_sound("misc/powerup.wav");
1334         precache_sound("misc/poweroff.wav");
1335         precache_sound("weapons/weaponpickup.wav");
1336
1337         n = tokenize_console(self.netname);
1338         if(argv(0) == "give")
1339         {
1340                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1341         }
1342         else
1343         {
1344                 for(i = 0; i < n; ++i)
1345                 {
1346                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1347                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1348                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1349                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1350                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1351                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1352                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1353                         else
1354                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1355                         {
1356                                 e = get_weaponinfo(j);
1357                                 if(argv(i) == e.netname)
1358                                 {
1359                                         self.weapons |= e.weapons;
1360                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1361                                                 weapon_action(e.weapon, WR_PRECACHE);
1362                                         break;
1363                                 }
1364                         }
1365                         if(j > WEP_LAST)
1366                                 print("target_items: invalid item ", argv(i), "\n");
1367                 }
1368
1369                 string itemprefix, valueprefix;
1370                 if(self.spawnflags == 0)
1371                 {
1372                         itemprefix = "";
1373                         valueprefix = "";
1374                 }
1375                 else if(self.spawnflags == 1)
1376                 {
1377                         itemprefix = "max ";
1378                         valueprefix = "max ";
1379                 }
1380                 else if(self.spawnflags == 2)
1381                 {
1382                         itemprefix = "min ";
1383                         valueprefix = "min ";
1384                 }
1385                 else if(self.spawnflags == 4)
1386                 {
1387                         itemprefix = "minus ";
1388                         valueprefix = "max ";
1389                 }
1390                 else
1391                         error("invalid spawnflags");
1392
1393                 self.netname = "";
1394                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1395                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1396                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1397                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1398                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1399                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1400                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1401                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1402                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1403                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1404                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1405                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1406                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1407                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1408                 {
1409                         e = get_weaponinfo(j);
1410                         if(e.weapons)
1411                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1412                 }
1413         }
1414         self.netname = strzone(self.netname);
1415         //print(self.netname, "\n");
1416
1417         n = tokenize_console(self.netname);
1418         for(i = 0; i < n; ++i)
1419         {
1420                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1421                 {
1422                         e = get_weaponinfo(j);
1423                         if(argv(i) == e.netname)
1424                         {
1425                                 weapon_action(e.weapon, WR_PRECACHE);
1426                                 break;
1427                         }
1428                 }
1429         }
1430 }
1431
1432 void spawnfunc_item_fuel(void)
1433 {
1434         if(!self.ammo_fuel)
1435                 self.ammo_fuel = g_pickup_fuel;
1436         if(!self.pickup_anyway)
1437                 self.pickup_anyway = g_pickup_ammo_anyway;
1438         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1439 }
1440
1441 void spawnfunc_item_fuel_regen(void)
1442 {
1443         if(start_items & IT_FUEL_REGEN)
1444         {
1445                 spawnfunc_item_fuel();
1446                 return;
1447         }
1448         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1449 }
1450
1451 void spawnfunc_item_jetpack(void)
1452 {
1453         if(g_grappling_hook)
1454                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1455         if(!self.ammo_fuel)
1456                 self.ammo_fuel = g_pickup_fuel_jetpack;
1457         if(start_items & IT_JETPACK)
1458         {
1459                 spawnfunc_item_fuel();
1460                 return;
1461         }
1462         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1463 }
1464
1465
1466 #define OP_SET 0
1467 #define OP_MIN 1
1468 #define OP_MAX 2
1469 #define OP_PLUS 3
1470 #define OP_MINUS 4
1471
1472 float GiveBit(entity e, .float fld, float bit, float op, float val)
1473 {
1474         float v0, v1;
1475         v0 = (e.fld & bit);
1476         switch(op)
1477         {
1478                 case OP_SET:
1479                         if(val > 0)
1480                                 e.fld |= bit;
1481                         else
1482                                 e.fld &~= bit;
1483                         break;
1484                 case OP_MIN:
1485                 case OP_PLUS:
1486                         if(val > 0)
1487                                 e.fld |= bit;
1488                         break;
1489                 case OP_MAX:
1490                         if(val <= 0)
1491                                 e.fld &~= bit;
1492                         break;
1493                 case OP_MINUS:
1494                         if(val > 0)
1495                                 e.fld &~= bit;
1496                         break;
1497         }
1498         v1 = (e.fld & bit);
1499         return (v0 != v1);
1500 }
1501
1502 float GiveValue(entity e, .float fld, float op, float val)
1503 {
1504         float v0, v1;
1505         v0 = e.fld;
1506         switch(op)
1507         {
1508                 case OP_SET:
1509                         e.fld = val;
1510                         break;
1511                 case OP_MIN:
1512                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1513                         break;
1514                 case OP_MAX:
1515                         e.fld = min(e.fld, val);
1516                         break;
1517                 case OP_PLUS:
1518                         e.fld += val;
1519                         break;
1520                 case OP_MINUS:
1521                         e.fld -= val;
1522                         break;
1523         }
1524         v1 = e.fld;
1525         return (v0 != v1);
1526 }
1527
1528 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1529 {
1530         if(v1 == v0)
1531                 return;
1532         if(v1 <= v0 - t)
1533         {
1534                 if(snd_decr != "")
1535                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1536         }
1537         else if(v0 >= v0 + t)
1538         {
1539                 if(snd_incr != "")
1540                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1541         }
1542 }
1543
1544 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1545 {
1546         if(v0 < v1)
1547                 e.rotfield = max(e.rotfield, time + rottime);
1548         else if(v0 > v1)
1549                 e.regenfield = max(e.regenfield, time + regentime);
1550 }
1551
1552 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1553 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1554 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1555 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1556
1557 float GiveItems(entity e, float beginarg, float endarg)
1558 {
1559         float got, i, j, val, op;
1560         float _switchweapon;
1561         entity wi;
1562         string cmd;
1563
1564         val = 999;
1565         op = OP_SET;
1566
1567         got = 0;
1568
1569         _switchweapon = FALSE;
1570         if (e.autoswitch)
1571                 if (e.switchweapon == w_getbestweapon(e))
1572                         _switchweapon = TRUE;
1573
1574         e.strength_finished = max(0, e.strength_finished - time);
1575         e.invincible_finished = max(0, e.invincible_finished - time);
1576
1577         PREGIVE(e, items);
1578         PREGIVE(e, weapons);
1579         PREGIVE(e, strength_finished);
1580         PREGIVE(e, invincible_finished);
1581         PREGIVE(e, ammo_nails);
1582         PREGIVE(e, ammo_cells);
1583         PREGIVE(e, ammo_shells);
1584         PREGIVE(e, ammo_rockets);
1585         PREGIVE(e, ammo_fuel);
1586         PREGIVE(e, armorvalue);
1587         PREGIVE(e, health);
1588
1589         for(i = beginarg; i < endarg; ++i)
1590         {
1591                 cmd = argv(i);
1592
1593                 if(cmd == "0" || stof(cmd))
1594                 {
1595                         val = stof(cmd);
1596                         continue;
1597                 }
1598                 switch(cmd)
1599                 {
1600                         case "no":
1601                                 op = OP_MAX;
1602                                 val = 0;
1603                                 continue;
1604                         case "max":
1605                                 op = OP_MAX;
1606                                 continue;
1607                         case "min":
1608                                 op = OP_MIN;
1609                                 continue;
1610                         case "plus":
1611                                 op = OP_PLUS;
1612                                 continue;
1613                         case "minus":
1614                                 op = OP_MINUS;
1615                                 continue;
1616                         case "ALL":
1617                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1618                                 got += GiveValue(e, strength_finished, op, time);
1619                                 got += GiveValue(e, invincible_finished, op, time);
1620                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1621                         case "all":
1622                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1623                                 got += GiveValue(e, health, op, val);
1624                                 got += GiveValue(e, armorvalue, op, val);
1625                         case "allweapons":
1626                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1627                                 {
1628                                         wi = get_weaponinfo(j);
1629                                         if(wi.weapons)
1630                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1631                                 }
1632                         case "allammo":
1633                                 got += GiveValue(e, ammo_cells, op, val);
1634                                 got += GiveValue(e, ammo_shells, op, val);
1635                                 got += GiveValue(e, ammo_nails, op, val);
1636                                 got += GiveValue(e, ammo_rockets, op, val);
1637                                 got += GiveValue(e, ammo_fuel, op, val);
1638                                 break;
1639                         case "unlimited_ammo":
1640                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1641                                 break;
1642                         case "unlimited_weapon_ammo":
1643                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1644                                 break;
1645                         case "unlimited_superweapons":
1646                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1647                                 break;
1648                         case "jetpack":
1649                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1650                                 break;
1651                         case "fuel_regen":
1652                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1653                                 break;
1654                         case "strength":
1655                                 got += GiveValue(e, strength_finished, op, val);
1656                                 break;
1657                         case "invincible":
1658                                 got += GiveValue(e, invincible_finished, op, val);
1659                                 break;
1660                         case "cells":
1661                                 got += GiveValue(e, ammo_cells, op, val);
1662                                 break;
1663                         case "shells":
1664                                 got += GiveValue(e, ammo_shells, op, val);
1665                                 break;
1666                         case "nails":
1667                         case "bullets":
1668                                 got += GiveValue(e, ammo_nails, op, val);
1669                                 break;
1670                         case "rockets":
1671                                 got += GiveValue(e, ammo_rockets, op, val);
1672                                 break;
1673                         case "health":
1674                                 got += GiveValue(e, health, op, val);
1675                                 break;
1676                         case "armor":
1677                                 got += GiveValue(e, armorvalue, op, val);
1678                                 break;
1679                         case "fuel":
1680                                 got += GiveValue(e, ammo_fuel, op, val);
1681                                 break;
1682                         default:
1683                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1684                                 {
1685                                         wi = get_weaponinfo(j);
1686                                         if(cmd == wi.netname)
1687                                         {
1688                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1689                                                 break;
1690                                         }
1691                                 }
1692                                 if(j > WEP_LAST)
1693                                         print("give: invalid item ", cmd, "\n");
1694                                 break;
1695                 }
1696                 val = 999;
1697                 op = OP_SET;
1698         }
1699
1700         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1701         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1702         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1703         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1704         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1705         {
1706                 wi = get_weaponinfo(j);
1707                 if(wi.weapons)
1708                 {
1709                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1710                         if not(save_weapons & wi.weapons)
1711                                 if(e.weapons & wi.weapons)
1712                                         weapon_action(wi.weapon, WR_PRECACHE);
1713                 }
1714         }
1715         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1716         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1717         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1718         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1719         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1720         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1721         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1722         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1723         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1724
1725         if (g_minstagib)
1726         {
1727                 e.health = bound(0, e.health, 100);
1728                 e.armorvalue = bound(0, e.armorvalue, 999);
1729         }
1730
1731         if(e.strength_finished <= 0)
1732                 e.strength_finished = 0;
1733         else
1734                 e.strength_finished += time;
1735         if(e.invincible_finished <= 0)
1736                 e.invincible_finished = 0;
1737         else
1738                 e.invincible_finished += time;
1739
1740         if not(e.weapons & W_WeaponBit(e.switchweapon))
1741                 _switchweapon = TRUE;
1742         if(_switchweapon)
1743                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1744
1745         return got;
1746 }