qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(get_weaponinfo(e.weapon).items & IT_SUPERWEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '0 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || ((e.flags & FL_WEAPON) && (get_weaponinfo(e.weapon).items & IT_SUPERWEAPON)))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         if (item.ammo_cells)
 383                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 384                         player.health = 100;
 385                 }
 386
 387                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 388                 {
 389                         pickedup = TRUE;
 390                         player.items |= it;
 391                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 392                 }
 393
 394                 // extralife powerup
 395                 if (item.max_health)
 396                 {
 397                         pickedup = TRUE;
 398                         // sound not available
 399                         // AnnounceTo(player, "_lives");
 400                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 401                         sprint(player, "^3You picked up some extra lives\n");
 402                 }
 403
 404                 // invis powerup
 405                 if (item.strength_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "invisible");
 410                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412
 413                 // speed powerup
 414                 if (item.invincible_finished)
 415                 {
 416                         pickedup = TRUE;
 417                         // sound not available
 418                         // AnnounceTo(player, "speed");
 419                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 420                 }
 421         }
 422         else
 423         {
 424                 // in case the player has autoswitch enabled do the following:
 425                 // if the player is using their best weapon before items are given, they
 426                 // probably want to switch to an even better weapon after items are given
 427                 if (player.autoswitch)
 428                 if (player.switchweapon == w_getbestweapon(player))
 429                         _switchweapon = TRUE;
 430
 431                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 432                         _switchweapon = TRUE;
 433
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 439                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 440                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 441
 442                 if (item.flags & FL_WEAPON)
 443                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && g_pickup_weapons_anyway))
 444                 {
 445                         pickedup = TRUE;
 446                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 447                         {
 448                                 e = get_weaponinfo(i);
 449                                 if(it & e.weapons)
 450                                         W_GiveWeapon (player, e.weapon, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 470                 }
 471         }
 472
 473 :skip
 474         // always eat teamed entities
 475         if(item.team)
 476                 pickedup = TRUE;
 477
 478         if (!pickedup)
 479                 return 0;
 480
 481         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 482         if (_switchweapon)
 483                 if (player.switchweapon != w_getbestweapon(player))
 484                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 485
 486         return 1;
 487 }
 488
 489 void Item_Touch (void)
 490 {
 491         entity e, head;
 492
 493         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 494         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 495         {
 496                 remove(self);
 497                 return;
 498         }
 499         if (other.classname != "player")
 500                 return;
 501         if (other.deadflag)
 502                 return;
 503         if (self.solid != SOLID_TRIGGER)
 504                 return;
 505         if (self.owner == other)
 506                 return;
 507
 508         if(!Item_GiveTo(self, other))
 509                 return;
 510
 511         other.last_pickup = time;
 512
 513         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 514
 515         if (self.classname == "droppedweapon")
 516                 remove (self);
 517         else if not(self.spawnshieldtime)
 518                 return;
 519         else
 520         {
 521                 if(self.team)
 522                 {
 523                         RandomSelection_Init();
 524                         for(head = world; (head = findfloat(head, team, self.team)); )
 525                         {
 526                                 if(head.flags & FL_ITEM)
 527                                 {
 528                                         Item_Show(head, -1);
 529                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 530                                 }
 531                         }
 532                         e = RandomSelection_chosen_ent;
 533                 }
 534                 else
 535                         e = self;
 536                 Item_ScheduleRespawn(e);
 537         }
 538 }
 539
 540 void Item_FindTeam()
 541 {
 542         entity head, e;
 543
 544         if(self.effects & EF_NODRAW)
 545         {
 546                 // marker for item team search
 547                 dprint("Initializing item team ", ftos(self.team), "\n");
 548                 RandomSelection_Init();
 549                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 550                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 551                 e = RandomSelection_chosen_ent;
 552                 e.state = 0;
 553                 Item_Show(e, 1);
 554
 555                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 556                 {
 557                         if(head != e)
 558                         {
 559                                 // make it a non-spawned item
 560                                 Item_Show(head, -1);
 561                                 head.state = 1; // state 1 = initially hidden item
 562                         }
 563                         head.effects &~= EF_NODRAW;
 564                 }
 565
 566                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 567                         Item_ScheduleInitialRespawn(e);
 568         }
 569 }
 570
 571 void Item_Reset()
 572 {
 573         Item_Show(self, !self.state);
 574         setorigin (self, self.origin);
 575         self.think = SUB_Null;
 576         self.nextthink = 0;
 577
 578         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 579                 Item_ScheduleInitialRespawn(self);
 580 }
 581
 582 // Savage: used for item garbage-collection
 583 // TODO: perhaps nice special effect?
 584 void RemoveItem(void)
 585 {
 586         remove(self);
 587 }
 588
 589 // pickup evaluation functions
 590 // these functions decide how desirable an item is to the bots
 591
 592 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 593
 594 float weapon_pickupevalfunc(entity player, entity item)
 595 {
 596         float c, i, j, position;
 597
 598         // See if I have it already
 599         if(player.weapons & item.weapons == item.weapons)
 600         {
 601                 // If I can pick it up
 602                 if(!item.spawnshieldtime)
 603                         c = 0;
 604                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 605                 {
 606                         // Skilled bots will grab more
 607                         c = bound(0, skill / 10, 1) * 0.5;
 608                 }
 609                 else
 610                         c = 0;
 611         }
 612         else
 613                 c = 1;
 614
 615         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 616         if( bot_custom_weapon && c )
 617         {
 618                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 619                 {
 620                         // Find weapon
 621                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 622                                 continue;
 623
 624                         // Find the highest position on any range
 625                         position = -1;
 626                         for(j = 0; j < WEP_LAST ; ++j){
 627                                 if(
 628                                                 bot_weapons_far[j] == i ||
 629                                                 bot_weapons_mid[j] == i ||
 630                                                 bot_weapons_close[j] == i
 631                                   )
 632                                 {
 633                                         position = j;
 634                                         break;
 635                                 }
 636                         }
 637
 638                         // Rate it
 639                         if (position >= 0 )
 640                         {
 641                                 position = WEP_LAST - position;
 642                                 // item.bot_pickupbasevalue is overwritten here
 643                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 644                         }
 645                 }
 646         }
 647
 648         return item.bot_pickupbasevalue * c;
 649 }
 650
 651 float commodity_pickupevalfunc(entity player, entity item)
 652 {
 653         float c, i, need_shells, need_nails, need_rockets, need_cells;
 654         entity wi;
 655         c = 0;
 656
 657         // Detect needed ammo
 658         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 659         {
 660                 wi = get_weaponinfo(i);
 661
 662                 if not(wi.weapons & player.weapons)
 663                         continue;
 664
 665                 if(wi.items & IT_SHELLS)
 666                         need_shells = TRUE;
 667                 else if(wi.items & IT_NAILS)
 668                         need_nails = TRUE;
 669                 else if(wi.items & IT_ROCKETS)
 670                         need_rockets = TRUE;
 671                 else if(wi.items & IT_CELLS)
 672                         need_cells = TRUE;
 673         }
 674
 675         // TODO: figure out if the player even has the weapon this ammo is for?
 676         // may not affect strategy much though...
 677         // find out how much more ammo/armor/health the player can hold
 678         if (need_shells)
 679         if (item.ammo_shells)
 680         if (player.ammo_shells < g_pickup_shells_max)
 681                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 682         if (need_nails)
 683         if (item.ammo_nails)
 684         if (player.ammo_nails < g_pickup_nails_max)
 685                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 686         if (need_rockets)
 687         if (item.ammo_rockets)
 688         if (player.ammo_rockets < g_pickup_rockets_max)
 689                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 690         if (need_cells)
 691         if (item.ammo_cells)
 692         if (player.ammo_cells < g_pickup_cells_max)
 693                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 694         if (item.armorvalue)
 695         if (player.armorvalue < item.max_armorvalue)
 696                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 697         if (item.health)
 698         if (player.health < item.max_health)
 699                 c = c + max(0, 1 - player.health / item.max_health);
 700
 701         return item.bot_pickupbasevalue * c;
 702 }
 703
 704
 705 .float is_item;
 706 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 707 {
 708         startitem_failed = FALSE;
 709
 710         self.items = itemid;
 711         self.weapons = weaponid;
 712         self.flags = FL_ITEM | itemflags;
 713
 714         // is it a dropped weapon?
 715         if (self.classname == "droppedweapon")
 716         {
 717                 self.reset = SUB_Remove;
 718                 // it's a dropped weapon
 719                 self.movetype = MOVETYPE_TOSS;
 720                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 721                 self.think = RemoveItem;
 722                 self.nextthink = time + 60;
 723                 // don't drop if in a NODROP zone (such as lava)
 724                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 725                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 726                 {
 727                         startitem_failed = TRUE;
 728                         remove(self);
 729                         return;
 730                 }
 731         }
 732         else
 733         {
 734                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 735                 {
 736                         startitem_failed = TRUE;
 737                         remove(self);
 738                         return;
 739                 }
 740
 741                 if(!have_pickup_item())
 742                 {
 743                         startitem_failed = TRUE;
 744                         remove (self);
 745                         return;
 746                 }
 747
 748                 if(self.model != "")
 749                         itemmodel = self.model;
 750                 if(self.item_pickupsound != "")
 751                         pickupsound = self.item_pickupsound;
 752
 753                 self.reset = Item_Reset;
 754                 // it's a level item
 755                 if(self.spawnflags & 1)
 756                         self.noalign = 1;
 757                 if (self.noalign)
 758                         self.movetype = MOVETYPE_NONE;
 759                 else
 760                         self.movetype = MOVETYPE_TOSS;
 761                 // do item filtering according to game mode and other things
 762                 if (!self.noalign)
 763                 {
 764                         // first nudge it off the floor a little bit to avoid math errors
 765                         setorigin(self, self.origin + '0 0 1');
 766                         // set item size before we spawn a spawnfunc_waypoint
 767                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 768                                 setsize (self, '-16 -16 0', '16 16 48');
 769                         else
 770                                 setsize (self, '-16 -16 0', '16 16 32');
 771                         // note droptofloor returns FALSE if stuck/or would fall too far
 772                         droptofloor();
 773                         waypoint_spawnforitem(self);
 774                 }
 775
 776                 /*
 777                  * can't do it that way, as it would break maps
 778                  * TODO make a target_give like entity another way, that perhaps has
 779                  * the weapon name in a key
 780                 if(self.targetname)
 781                 {
 782                         // target_give not yet supported; maybe later
 783                         print("removed targeted ", self.classname, "\n");
 784                         startitem_failed = TRUE;
 785                         remove (self);
 786                         return;
 787                 }
 788                 */
 789
 790                 if(autocvar_spawn_debug >= 2)
 791                 {
 792                         entity otheritem;
 793                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 794                         {
 795                                 if(otheritem.is_item)
 796                                 {
 797                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 798                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 799                                         error("Mapper sucks.");
 800                                 }
 801                         }
 802                         self.is_item = TRUE;
 803                 }
 804
 805                 weaponsInMap |= weaponid;
 806
 807                 precache_model (itemmodel);
 808                 precache_sound (pickupsound);
 809
 810                 precache_sound ("misc/itemrespawncountdown.wav");
 811                 if(!g_minstagib && itemid == IT_STRENGTH)
 812                         precache_sound ("misc/strength_respawn.wav");
 813                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 814                         precache_sound ("misc/shield_respawn.wav");
 815                 else
 816                         precache_sound ("misc/itemrespawn.wav");
 817
 818                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 819                         self.target = "###item###"; // for finding the nearest item using find()
 820         }
 821
 822         self.bot_pickup = TRUE;
 823         self.bot_pickupevalfunc = pickupevalfunc;
 824         self.bot_pickupbasevalue = pickupbasevalue;
 825         self.mdl = itemmodel;
 826         self.item_pickupsound = pickupsound;
 827         // let mappers override respawntime
 828         if(!self.respawntime) // both set
 829         {
 830                 self.respawntime = defaultrespawntime;
 831                 self.respawntimejitter = defaultrespawntimejitter;
 832         }
 833         self.netname = itemname;
 834         self.touch = Item_Touch;
 835         setmodel (self, self.mdl); // precision set below
 836         self.effects |= EF_LOWPRECISION;
 837         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 838                 setsize (self, '-16 -16 0', '16 16 48');
 839         else
 840                 setsize (self, '-16 -16 0', '16 16 32');
 841         if(itemflags & FL_WEAPON)
 842                 self.modelflags |= MF_ROTATE;
 843
 844         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 845         if (itemflags & FL_WEAPON)
 846         {
 847                 // neutral team color for pickup weapons
 848                 self.colormap = 1024; // color shirt=0 pants=0 grey
 849         }
 850
 851         Item_Show(self, 1);
 852         self.state = 0;
 853         if(self.team)
 854         {
 855                 if(!self.cnt)
 856                         self.cnt = 1; // item probability weight
 857                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 858                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 859         }
 860         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 861                 Item_ScheduleInitialRespawn(self);
 862 }
 863
 864 /* replace items in minstagib
 865  * IT_STRENGTH   = invisibility
 866  * IT_NAILS      = extra lives
 867  * IT_INVINCIBLE = speed
 868  */
 869 void minstagib_items (float itemid)
 870 {
 871         float rnd;
 872         self.classname = "minstagib";
 873
 874         // replace rocket launchers and nex guns with ammo cells
 875         if (itemid == IT_CELLS)
 876         {
 877                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 878                 StartItem ("models/items/a_cells.md3",
 879                         "misc/itempickup.wav", 45, 0,
 880                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 881                 return;
 882         }
 883
 884         // randomize
 885         rnd = random() * 3;
 886         if (rnd <= 1)
 887                 itemid = IT_STRENGTH;
 888         else if (rnd <= 2)
 889                 itemid = IT_NAILS;
 890         else
 891                 itemid = IT_INVINCIBLE;
 892
 893         // replace with invis
 894         if (itemid == IT_STRENGTH)
 895         {
 896                 self.strength_finished = 30;
 897                 StartItem ("models/items/g_strength.md3",
 898                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 899                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 900         }
 901         // replace with extra lives
 902         if (itemid == IT_NAILS)
 903         {
 904                 self.max_health = 1;
 905                 StartItem ("models/items/g_h100.md3",
 906                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 907                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 908         }
 909         // replace with speed
 910         if (itemid == IT_INVINCIBLE)
 911         {
 912                 self.invincible_finished = 30;
 913                 StartItem ("models/items/g_invincible.md3",
 914                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 915                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 916         }
 917 }
 918
 919 float minst_no_auto_cells;
 920 void minst_remove_item (void) {
 921         if(minst_no_auto_cells)
 922                 remove(self);
 923 }
 924
 925 float weaponswapping;
 926 float internalteam;
 927
 928 void weapon_defaultspawnfunc(float wpn)
 929 {
 930         entity e;
 931         float t;
 932         var .float ammofield;
 933         string s;
 934         entity oldself;
 935         float i, j;
 936
 937         // set the respawntime in advance (so replaced weapons can copy it)
 938
 939         if(!self.respawntime)
 940         {
 941                 e = get_weaponinfo(wpn);
 942                 if(e.items == IT_SUPERWEAPON)
 943                 {
 944                         self.respawntime = g_pickup_respawntime_superweapon;
 945                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
 946                 }
 947                 else
 948                 {
 949                         self.respawntime = g_pickup_respawntime_weapon;
 950                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 951                 }
 952         }
 953
 954         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 955         {
 956                 e = get_weaponinfo(wpn);
 957                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 958                 if(s == "0")
 959                 {
 960                         remove(self);
 961                         startitem_failed = TRUE;
 962                         return;
 963                 }
 964                 t = tokenize_console(s);
 965                 if(t >= 2)
 966                 {
 967                         self.team = --internalteam;
 968                         oldself = self;
 969                         for(i = 1; i < t; ++i)
 970                         {
 971                                 s = argv(i);
 972                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 973                                 {
 974                                         e = get_weaponinfo(j);
 975                                         if(e.netname == s)
 976                                         {
 977                                                 self = spawn();
 978                                                 copyentity(oldself, self);
 979                                                 self.classname = "replacedweapon";
 980                                                 weapon_defaultspawnfunc(j);
 981                                                 break;
 982                                         }
 983                                 }
 984                                 if(j > WEP_LAST)
 985                                 {
 986                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 987                                 }
 988                         }
 989                         self = oldself;
 990                 }
 991                 if(t >= 1)
 992                 {
 993                         s = argv(0);
 994                         wpn = 0;
 995                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 996                         {
 997                                 e = get_weaponinfo(j);
 998                                 if(e.netname == s)
 999                                 {
1000                                         wpn = j;
1001                                         break;
1002                                 }
1003                         }
1004                         if(j > WEP_LAST)
1005                         {
1006                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1007                         }
1008                 }
1009                 if(wpn == 0)
1010                 {
1011                         remove(self);
1012                         startitem_failed = TRUE;
1013                         return;
1014                 }
1015         }
1016
1017         e = get_weaponinfo(wpn);
1018
1019         if(e.items && e.items != IT_SUPERWEAPON)
1020         {
1021                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1022                 {
1023                         if(e.items & j)
1024                         {
1025                                 ammofield = Item_CounterField(j);
1026                                 if(!self.ammofield)
1027                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1028                         }
1029                 }
1030         }
1031         else
1032         {
1033                 self.flags |= FL_NO_WEAPON_STAY;
1034         }
1035
1036         // weapon stay isn't supported for teamed weapons
1037         if(self.team)
1038                 self.flags |= FL_NO_WEAPON_STAY;
1039
1040         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1041         if (self.modelindex) // don't precache if self was removed
1042                 weapon_action(e.weapon, WR_PRECACHE);
1043 }
1044
1045 void spawnfunc_weapon_shotgun (void);
1046 void spawnfunc_weapon_uzi (void) {
1047         if(autocvar_sv_q3acompat_machineshotgunswap)
1048         if(self.classname != "droppedweapon")
1049         {
1050                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1051                 return;
1052         }
1053         weapon_defaultspawnfunc(WEP_UZI);
1054 }
1055
1056 void spawnfunc_weapon_shotgun (void) {
1057         if(autocvar_sv_q3acompat_machineshotgunswap)
1058         if(self.classname != "droppedweapon")
1059         {
1060                 weapon_defaultspawnfunc(WEP_UZI);
1061                 return;
1062         }
1063         weapon_defaultspawnfunc(WEP_SHOTGUN);
1064 }
1065
1066 void spawnfunc_weapon_nex (void)
1067 {
1068         if (g_minstagib)
1069         {
1070                 minstagib_items(IT_CELLS);
1071                 self.think = minst_remove_item;
1072                 self.nextthink = time;
1073                 return;
1074         }
1075         weapon_defaultspawnfunc(WEP_NEX);
1076 }
1077
1078 void spawnfunc_weapon_minstanex (void)
1079 {
1080         if (g_minstagib)
1081         {
1082                 minstagib_items(IT_CELLS);
1083                 self.think = minst_remove_item;
1084                 self.nextthink = time;
1085                 return;
1086         }
1087         weapon_defaultspawnfunc(WEP_MINSTANEX);
1088 }
1089
1090 void spawnfunc_weapon_rocketlauncher (void)
1091 {
1092         if (g_minstagib)
1093         {
1094                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1095                 self.think = minst_remove_item;
1096                 self.nextthink = time;
1097                 return;
1098         }
1099         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1100 }
1101
1102 void spawnfunc_item_rockets (void) {
1103         if(!self.ammo_rockets)
1104                 self.ammo_rockets = g_pickup_rockets;
1105         if(!self.pickup_anyway)
1106                 self.pickup_anyway = g_pickup_ammo_anyway;
1107         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1108 }
1109
1110 void spawnfunc_item_shells (void);
1111 void spawnfunc_item_bullets (void) {
1112         if(!weaponswapping)
1113         if(autocvar_sv_q3acompat_machineshotgunswap)
1114         if(self.classname != "droppedweapon")
1115         {
1116                 weaponswapping = TRUE;
1117                 spawnfunc_item_shells();
1118                 weaponswapping = FALSE;
1119                 return;
1120         }
1121
1122         if(!self.ammo_nails)
1123                 self.ammo_nails = g_pickup_nails;
1124         if(!self.pickup_anyway)
1125                 self.pickup_anyway = g_pickup_ammo_anyway;
1126         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1127 }
1128
1129 void spawnfunc_item_cells (void) {
1130         if(!self.ammo_cells)
1131                 self.ammo_cells = g_pickup_cells;
1132         if(!self.pickup_anyway)
1133                 self.pickup_anyway = g_pickup_ammo_anyway;
1134         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1135 }
1136
1137 void spawnfunc_item_shells (void) {
1138         if(!weaponswapping)
1139         if(autocvar_sv_q3acompat_machineshotgunswap)
1140         if(self.classname != "droppedweapon")
1141         {
1142                 weaponswapping = TRUE;
1143                 spawnfunc_item_bullets();
1144                 weaponswapping = FALSE;
1145                 return;
1146         }
1147
1148         if(!self.ammo_shells)
1149                 self.ammo_shells = g_pickup_shells;
1150         if(!self.pickup_anyway)
1151                 self.pickup_anyway = g_pickup_ammo_anyway;
1152         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1153 }
1154
1155 void spawnfunc_item_armor_small (void) {
1156         if(!self.armorvalue)
1157                 self.armorvalue = g_pickup_armorsmall;
1158         if(!self.max_armorvalue)
1159                 self.max_armorvalue = g_pickup_armorsmall_max;
1160         if(!self.pickup_anyway)
1161                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1162         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1163 }
1164
1165 void spawnfunc_item_armor_medium (void) {
1166         if(!self.armorvalue)
1167                 self.armorvalue = g_pickup_armormedium;
1168         if(!self.max_armorvalue)
1169                 self.max_armorvalue = g_pickup_armormedium_max;
1170         if(!self.pickup_anyway)
1171                 self.pickup_anyway = g_pickup_armormedium_anyway;
1172         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1173 }
1174
1175 void spawnfunc_item_armor_big (void) {
1176         if(!self.armorvalue)
1177                 self.armorvalue = g_pickup_armorbig;
1178         if(!self.max_armorvalue)
1179                 self.max_armorvalue = g_pickup_armorbig_max;
1180         if(!self.pickup_anyway)
1181                 self.pickup_anyway = g_pickup_armorbig_anyway;
1182         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1183 }
1184
1185 void spawnfunc_item_armor_large (void) {
1186         if(!self.armorvalue)
1187                 self.armorvalue = g_pickup_armorlarge;
1188         if(!self.max_armorvalue)
1189                 self.max_armorvalue = g_pickup_armorlarge_max;
1190         if(!self.pickup_anyway)
1191                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1192         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1193 }
1194
1195 void spawnfunc_item_health_small (void) {
1196         if(!self.max_health)
1197                 self.max_health = g_pickup_healthsmall_max;
1198         if(!self.health)
1199                 self.health = g_pickup_healthsmall;
1200         if(!self.pickup_anyway)
1201                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1202         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1203 }
1204
1205 void spawnfunc_item_health_medium (void) {
1206         if(!self.max_health)
1207                 self.max_health = g_pickup_healthmedium_max;
1208         if(!self.health)
1209                 self.health = g_pickup_healthmedium;
1210         if(!self.pickup_anyway)
1211                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1212         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1213 }
1214
1215 void spawnfunc_item_health_large (void) {
1216         if(!self.max_health)
1217                 self.max_health = g_pickup_healthlarge_max;
1218         if(!self.health)
1219                 self.health = g_pickup_healthlarge;
1220         if(!self.pickup_anyway)
1221                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1222         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1223 }
1224
1225 void spawnfunc_item_health_mega (void) {
1226         if(g_minstagib) {
1227                 minstagib_items(IT_NAILS);
1228         } else {
1229                 if(!self.max_health)
1230                         self.max_health = g_pickup_healthmega_max;
1231                 if(!self.health)
1232                         self.health = g_pickup_healthmega;
1233                 if(!self.pickup_anyway)
1234                         self.pickup_anyway = g_pickup_healthmega_anyway;
1235                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1236         }
1237 }
1238
1239 // support old misnamed entities
1240 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1241 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1242 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1243 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1244 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1245
1246 void spawnfunc_item_strength (void) {
1247         if(g_minstagib) {
1248                 minstagib_items(IT_STRENGTH);
1249         } else {
1250                 precache_sound("weapons/strength_fire.wav");
1251                 self.strength_finished = 30;
1252                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1253         }
1254 }
1255
1256 void spawnfunc_item_invincible (void) {
1257         if(g_minstagib) {
1258                 minstagib_items(IT_INVINCIBLE);
1259         } else {
1260                 self.invincible_finished = 30;
1261                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1262         }
1263 }
1264
1265 void spawnfunc_item_minst_cells (void) {
1266         if (g_minstagib)
1267         {
1268                 minst_no_auto_cells = 1;
1269                 minstagib_items(IT_CELLS);
1270         }
1271         else
1272                 remove(self);
1273 }
1274
1275 // compatibility:
1276 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1277
1278 float GiveItems(entity e, float beginarg, float endarg);
1279 void target_items_use (void)
1280 {
1281         if(activator.classname == "droppedweapon")
1282         {
1283                 EXACTTRIGGER_TOUCH;
1284                 remove(activator);
1285                 return;
1286         }
1287
1288         if(activator.classname != "player")
1289                 return;
1290         if(activator.deadflag != DEAD_NO)
1291                 return;
1292         EXACTTRIGGER_TOUCH;
1293
1294         entity e;
1295         for(e = world; (e = find(e, classname, "droppedweapon")); )
1296                 if(e.enemy == activator)
1297                         remove(e);
1298
1299         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1300                 centerprint(activator, self.message);
1301 }
1302
1303 void spawnfunc_target_items (void)
1304 {
1305         float n, i, j;
1306         entity e;
1307
1308         self.use = target_items_use;
1309         if(!self.strength_finished)
1310                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1311         if(!self.invincible_finished)
1312                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1313
1314         precache_sound("misc/itempickup.wav");
1315         precache_sound("misc/megahealth.wav");
1316         precache_sound("misc/armor25.wav");
1317         precache_sound("misc/powerup.wav");
1318         precache_sound("misc/poweroff.wav");
1319         precache_sound("weapons/weaponpickup.wav");
1320
1321         n = tokenize_console(self.netname);
1322         if(argv(0) == "give")
1323         {
1324                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1325         }
1326         else
1327         {
1328                 for(i = 0; i < n; ++i)
1329                 {
1330                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1331                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1332                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1333                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1334                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1335                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1336                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1337                         else
1338                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1339                         {
1340                                 e = get_weaponinfo(j);
1341                                 if(argv(i) == e.netname)
1342                                 {
1343                                         self.weapons |= e.weapons;
1344                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1345                                                 weapon_action(e.weapon, WR_PRECACHE);
1346                                         break;
1347                                 }
1348                         }
1349                         if(j > WEP_LAST)
1350                                 print("target_items: invalid item ", argv(i), "\n");
1351                 }
1352
1353                 string itemprefix, valueprefix;
1354                 if(self.spawnflags == 0)
1355                 {
1356                         itemprefix = "";
1357                         valueprefix = "";
1358                 }
1359                 else if(self.spawnflags == 1)
1360                 {
1361                         itemprefix = "max ";
1362                         valueprefix = "max ";
1363                 }
1364                 else if(self.spawnflags == 2)
1365                 {
1366                         itemprefix = "min ";
1367                         valueprefix = "min ";
1368                 }
1369                 else if(self.spawnflags == 4)
1370                 {
1371                         itemprefix = "minus ";
1372                         valueprefix = "max ";
1373                 }
1374                 else
1375                         error("invalid spawnflags");
1376
1377                 self.netname = "";
1378                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1379                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1380                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1381                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1382                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1383                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1384                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1385                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1386                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1387                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1388                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1389                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1390                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1391                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1392                 {
1393                         e = get_weaponinfo(j);
1394                         if(e.weapons)
1395                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1396                 }
1397         }
1398         self.netname = strzone(self.netname);
1399         //print(self.netname, "\n");
1400
1401         n = tokenize_console(self.netname);
1402         for(i = 0; i < n; ++i)
1403         {
1404                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1405                 {
1406                         e = get_weaponinfo(j);
1407                         if(argv(i) == e.netname)
1408                         {
1409                                 weapon_action(e.weapon, WR_PRECACHE);
1410                                 break;
1411                         }
1412                 }
1413         }
1414 }
1415
1416 void spawnfunc_item_fuel(void)
1417 {
1418         if(!self.ammo_fuel)
1419                 self.ammo_fuel = g_pickup_fuel;
1420         if(!self.pickup_anyway)
1421                 self.pickup_anyway = g_pickup_ammo_anyway;
1422         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1423 }
1424
1425 void spawnfunc_item_fuel_regen(void)
1426 {
1427         if(start_items & IT_FUEL_REGEN)
1428         {
1429                 spawnfunc_item_fuel();
1430                 return;
1431         }
1432         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1433 }
1434
1435 void spawnfunc_item_jetpack(void)
1436 {
1437         if(g_grappling_hook)
1438                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1439         if(!self.ammo_fuel)
1440                 self.ammo_fuel = g_pickup_fuel_jetpack;
1441         if(start_items & IT_JETPACK)
1442         {
1443                 spawnfunc_item_fuel();
1444                 return;
1445         }
1446         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1447 }
1448
1449
1450 #define OP_SET 0
1451 #define OP_MIN 1
1452 #define OP_MAX 2
1453 #define OP_PLUS 3
1454 #define OP_MINUS 4
1455
1456 float GiveBit(entity e, .float fld, float bit, float op, float val)
1457 {
1458         float v0, v1;
1459         v0 = (e.fld & bit);
1460         switch(op)
1461         {
1462                 case OP_SET:
1463                         if(val > 0)
1464                                 e.fld |= bit;
1465                         else
1466                                 e.fld &~= bit;
1467                         break;
1468                 case OP_MIN:
1469                 case OP_PLUS:
1470                         if(val > 0)
1471                                 e.fld |= bit;
1472                         break;
1473                 case OP_MAX:
1474                         if(val <= 0)
1475                                 e.fld &~= bit;
1476                         break;
1477                 case OP_MINUS:
1478                         if(val > 0)
1479                                 e.fld &~= bit;
1480                         break;
1481         }
1482         v1 = (e.fld & bit);
1483         return (v0 != v1);
1484 }
1485
1486 float GiveValue(entity e, .float fld, float op, float val)
1487 {
1488         float v0, v1;
1489         v0 = e.fld;
1490         switch(op)
1491         {
1492                 case OP_SET:
1493                         e.fld = val;
1494                         break;
1495                 case OP_MIN:
1496                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1497                         break;
1498                 case OP_MAX:
1499                         e.fld = min(e.fld, val);
1500                         break;
1501                 case OP_PLUS:
1502                         e.fld += val;
1503                         break;
1504                 case OP_MINUS:
1505                         e.fld -= val;
1506                         break;
1507         }
1508         v1 = e.fld;
1509         return (v0 != v1);
1510 }
1511
1512 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1513 {
1514         if(v1 == v0)
1515                 return;
1516         if(v1 <= v0 - t)
1517         {
1518                 if(snd_decr != "")
1519                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1520         }
1521         else if(v0 >= v0 + t)
1522         {
1523                 if(snd_incr != "")
1524                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1525         }
1526 }
1527
1528 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1529 {
1530         if(v0 < v1)
1531                 e.rotfield = max(e.rotfield, time + rottime);
1532         else if(v0 > v1)
1533                 e.regenfield = max(e.regenfield, time + regentime);
1534 }
1535
1536 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1537 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1538 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1539 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1540
1541 float GiveItems(entity e, float beginarg, float endarg)
1542 {
1543         float got, i, j, val, op;
1544         float _switchweapon;
1545         entity wi;
1546         string cmd;
1547
1548         val = 999;
1549         op = OP_SET;
1550
1551         got = 0;
1552
1553         _switchweapon = FALSE;
1554         if (e.autoswitch)
1555                 if (e.switchweapon == w_getbestweapon(e))
1556                         _switchweapon = TRUE;
1557
1558         e.strength_finished = max(0, e.strength_finished - time);
1559         e.invincible_finished = max(0, e.invincible_finished - time);
1560
1561         PREGIVE(e, items);
1562         PREGIVE(e, weapons);
1563         PREGIVE(e, strength_finished);
1564         PREGIVE(e, invincible_finished);
1565         PREGIVE(e, ammo_nails);
1566         PREGIVE(e, ammo_cells);
1567         PREGIVE(e, ammo_shells);
1568         PREGIVE(e, ammo_rockets);
1569         PREGIVE(e, ammo_fuel);
1570         PREGIVE(e, armorvalue);
1571         PREGIVE(e, health);
1572
1573         for(i = beginarg; i < endarg; ++i)
1574         {
1575                 cmd = argv(i);
1576
1577                 if(cmd == "0" || stof(cmd))
1578                 {
1579                         val = stof(cmd);
1580                         continue;
1581                 }
1582                 switch(cmd)
1583                 {
1584                         case "no":
1585                                 op = OP_MAX;
1586                                 val = 0;
1587                                 continue;
1588                         case "max":
1589                                 op = OP_MAX;
1590                                 continue;
1591                         case "min":
1592                                 op = OP_MIN;
1593                                 continue;
1594                         case "plus":
1595                                 op = OP_PLUS;
1596                                 continue;
1597                         case "minus":
1598                                 op = OP_MINUS;
1599                                 continue;
1600                         case "ALL":
1601                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1602                                 got += GiveValue(e, strength_finished, op, time);
1603                                 got += GiveValue(e, invincible_finished, op, time);
1604                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1605                         case "all":
1606                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1607                                 got += GiveValue(e, health, op, val);
1608                                 got += GiveValue(e, armorvalue, op, val);
1609                         case "allweapons":
1610                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1611                                 {
1612                                         wi = get_weaponinfo(j);
1613                                         if(wi.weapons)
1614                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1615                                 }
1616                         case "allammo":
1617                                 got += GiveValue(e, ammo_cells, op, val);
1618                                 got += GiveValue(e, ammo_shells, op, val);
1619                                 got += GiveValue(e, ammo_nails, op, val);
1620                                 got += GiveValue(e, ammo_rockets, op, val);
1621                                 got += GiveValue(e, ammo_fuel, op, val);
1622                                 break;
1623                         case "unlimited_ammo":
1624                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1625                                 break;
1626                         case "unlimited_weapon_ammo":
1627                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1628                                 break;
1629                         case "unlimited_superweapons":
1630                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1631                                 break;
1632                         case "jetpack":
1633                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1634                                 break;
1635                         case "fuel_regen":
1636                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1637                                 break;
1638                         case "strength":
1639                                 got += GiveValue(e, strength_finished, op, val);
1640                                 break;
1641                         case "invincible":
1642                                 got += GiveValue(e, invincible_finished, op, val);
1643                                 break;
1644                         case "cells":
1645                                 got += GiveValue(e, ammo_cells, op, val);
1646                                 break;
1647                         case "shells":
1648                                 got += GiveValue(e, ammo_shells, op, val);
1649                                 break;
1650                         case "nails":
1651                         case "bullets":
1652                                 got += GiveValue(e, ammo_nails, op, val);
1653                                 break;
1654                         case "rockets":
1655                                 got += GiveValue(e, ammo_rockets, op, val);
1656                                 break;
1657                         case "health":
1658                                 got += GiveValue(e, health, op, val);
1659                                 break;
1660                         case "armor":
1661                                 got += GiveValue(e, armorvalue, op, val);
1662                                 break;
1663                         case "fuel":
1664                                 got += GiveValue(e, ammo_fuel, op, val);
1665                                 break;
1666                         default:
1667                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1668                                 {
1669                                         wi = get_weaponinfo(j);
1670                                         if(cmd == wi.netname)
1671                                         {
1672                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1673                                                 break;
1674                                         }
1675                                 }
1676                                 if(j > WEP_LAST)
1677                                         print("give: invalid item ", cmd, "\n");
1678                                 break;
1679                 }
1680                 val = 999;
1681                 op = OP_SET;
1682         }
1683
1684         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1685         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1686         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1687         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1688         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1689         {
1690                 wi = get_weaponinfo(j);
1691                 if(wi.weapons)
1692                 {
1693                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1694                         if not(save_weapons & wi.weapons)
1695                                 if(e.weapons & wi.weapons)
1696                                         weapon_action(wi.weapon, WR_PRECACHE);
1697                 }
1698         }
1699         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1700         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1701         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1702         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1703         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1704         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1705         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1706         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1707         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1708
1709         if (g_minstagib)
1710         {
1711                 e.health = bound(0, e.health, 100);
1712                 e.armorvalue = bound(0, e.armorvalue, 999);
1713         }
1714
1715         if(e.strength_finished <= 0)
1716                 e.strength_finished = 0;
1717         else
1718                 e.strength_finished += time;
1719         if(e.invincible_finished <= 0)
1720                 e.invincible_finished = 0;
1721         else
1722                 e.invincible_finished += time;
1723
1724         if not(e.weapons & W_WeaponBit(e.switchweapon))
1725                 _switchweapon = TRUE;
1726         if(_switchweapon)
1727                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1728
1729         return got;
1730 }