qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.items == IT_STRENGTH || self.items == IT_INVINCIBLE)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.strength_finished || e.invincible_finished)
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(name)
 237                         {
 238                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 239                                 if(self.waypointsprite_attached)
 240                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 241                         }
 242                 }
 243                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 244                 if(self.waypointsprite_attached)
 245                 {
 246                         WaypointSprite_Ping(self.waypointsprite_attached);
 247                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 248                 }
 249         }
 250 }
 251
 252 void Item_ScheduleRespawnIn(entity e, float t)
 253 {
 254         if(e.flags & FL_POWERUP)
 255         {
 256                 e.think = Item_RespawnCountdown;
 257                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 258                 e.count = 0;
 259         }
 260         else
 261         {
 262                 e.think = Item_Respawn;
 263                 e.nextthink = time + t;
 264         }
 265 }
 266
 267 void Item_ScheduleRespawn(entity e)
 268 {
 269         if(e.respawntime > 0)
 270         {
 271                 Item_Show(e, 0);
 272                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 273         }
 274         else // if respawntime is -1, this item does not respawn
 275                 Item_Show(e, -1);
 276 }
 277
 278 void Item_ScheduleInitialRespawn(entity e)
 279 {
 280         Item_Show(e, 0);
 281         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 282 }
 283
 284 float ITEM_MODE_NONE = 0;
 285 float ITEM_MODE_HEALTH = 1;
 286 float ITEM_MODE_ARMOR = 2;
 287 float ITEM_MODE_FUEL = 3;
 288 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 289 {
 290         if (!item.ammofield)
 291                 return FALSE;
 292
 293         if (item.spawnshieldtime)
 294         {
 295                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 296                 {
 297                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammo_cells);
 298                         goto YEAH;
 299                 }
 300         }
 301         else if(g_weapon_stay == 2)
 302         {
 303                 float mi = min(item.ammofield, ammomax);
 304                 if ((player.ammofield < mi) || item.pickup_anyway)
 305                 {
 306                         player.ammofield = max(player.ammofield, mi);
 307                         goto YEAH;
 308                 }
 309         }
 310
 311         return FALSE;
 312
 313 :YEAH
 314         switch(mode)
 315         {
 316                 case ITEM_MODE_FUEL:
 317                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 318                         break;
 319                 case ITEM_MODE_HEALTH:
 320                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 321                         break;
 322                 case ITEM_MODE_ARMOR:
 323                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 324                         break;
 325                 default:
 326                         break;
 327         }
 328         return TRUE;
 329 }
 330
 331 float Item_GiveTo(entity item, entity player)
 332 {
 333         float _switchweapon;
 334         float pickedup;
 335         float it;
 336         float i;
 337         entity e;
 338
 339         // if nothing happens to player, just return without taking the item
 340         pickedup = FALSE;
 341         _switchweapon = FALSE;
 342
 343         if (g_minstagib)
 344         {
 345                 float prevcells = player.ammo_cells;
 346
 347                 Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 348                 Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 349
 350                 if(player.ammo_cells > prevcells)
 351                 {
 352                         _switchweapon = TRUE;
 353
 354                         // play some cool sounds ;)
 355                         if (clienttype(player) == CLIENTTYPE_REAL)
 356                         {
 357                                 if(player.health <= 5)
 358                                         AnnounceTo(player, "lastsecond");
 359                                 else if(player.health < 50)
 360                                         AnnounceTo(player, "narrowly");
 361                         }
 362                         // sound not available
 363                         // else if(item.items == IT_CELLS)
 364                         //      AnnounceTo(player, "ammo");
 365
 366                         if (item.weapons & WEPBIT_MINSTANEX)
 367                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 368                         if (item.ammo_cells)
 369                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 370                         player.health = 100;
 371                 }
 372
 373                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 374                 {
 375                         pickedup = TRUE;
 376                         player.items |= it;
 377                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 378                 }
 379
 380                 // extralife powerup
 381                 if (item.max_health)
 382                 {
 383                         pickedup = TRUE;
 384                         // sound not available
 385                         // AnnounceTo(player, "_lives");
 386                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 387                         sprint(player, "^3You picked up some extra lives\n");
 388                 }
 389
 390                 // invis powerup
 391                 if (item.strength_finished)
 392                 {
 393                         pickedup = TRUE;
 394                         // sound not available
 395                         // AnnounceTo(player, "invisible");
 396                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 397                 }
 398
 399                 // speed powerup
 400                 if (item.invincible_finished)
 401                 {
 402                         pickedup = TRUE;
 403                         // sound not available
 404                         // AnnounceTo(player, "speed");
 405                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 406                 }
 407         }
 408         else
 409         {
 410                 // in case the player has autoswitch enabled do the following:
 411                 // if the player is using their best weapon before items are given, they
 412                 // probably want to switch to an even better weapon after items are given
 413                 if (player.autoswitch)
 414                 if (player.switchweapon == w_getbestweapon(player))
 415                         _switchweapon = TRUE;
 416
 417                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 418                         _switchweapon = TRUE;
 419
 420                 Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 421                 Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 422                 Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 423                 Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 424                 Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 425                 Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 426                 Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 427
 428                 if (item.flags & FL_WEAPON)
 429                 if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway))
 430                 {
 431                         pickedup = TRUE;
 432                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 433                         {
 434                                 e = get_weaponinfo(i);
 435                                 if(it & e.weapons)
 436                                         W_GiveWeapon (player, e.weapon, item.netname);
 437                         }
 438                 }
 439
 440                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 441                 {
 442                         pickedup = TRUE;
 443                         player.items |= it;
 444                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 445                 }
 446
 447                 if (item.strength_finished)
 448                 {
 449                         pickedup = TRUE;
 450                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 451                 }
 452                 if (item.invincible_finished)
 453                 {
 454                         pickedup = TRUE;
 455                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 456                 }
 457         }
 458
 459 :skip
 460         // always eat teamed entities
 461         if(item.team)
 462                 pickedup = TRUE;
 463
 464         if (!pickedup)
 465                 return 0;
 466
 467         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 468         if (_switchweapon)
 469                 if (player.switchweapon != w_getbestweapon(player))
 470                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 471
 472         return 1;
 473 }
 474
 475 void Item_Touch (void)
 476 {
 477         entity e, head;
 478
 479         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 480         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 481         {
 482                 remove(self);
 483                 return;
 484         }
 485         if (other.classname != "player")
 486                 return;
 487         if (other.deadflag)
 488                 return;
 489         if (self.solid != SOLID_TRIGGER)
 490                 return;
 491         if (self.owner == other)
 492                 return;
 493
 494         if(!Item_GiveTo(self, other))
 495                 return;
 496
 497         other.last_pickup = time;
 498
 499         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 500
 501         if (self.classname == "droppedweapon")
 502                 remove (self);
 503         else if not(self.spawnshieldtime)
 504                 return;
 505         else
 506         {
 507                 if(self.team)
 508                 {
 509                         RandomSelection_Init();
 510                         for(head = world; (head = findfloat(head, team, self.team)); )
 511                         {
 512                                 if(head.flags & FL_ITEM)
 513                                 {
 514                                         Item_Show(head, -1);
 515                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 516                                 }
 517                         }
 518                         e = RandomSelection_chosen_ent;
 519                 }
 520                 else
 521                         e = self;
 522                 Item_ScheduleRespawn(e);
 523         }
 524 }
 525
 526 void Item_FindTeam()
 527 {
 528         entity head, e;
 529
 530         if(self.effects & EF_NODRAW)
 531         {
 532                 // marker for item team search
 533                 dprint("Initializing item team ", ftos(self.team), "\n");
 534                 RandomSelection_Init();
 535                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 536                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 537                 e = RandomSelection_chosen_ent;
 538                 e.state = 0;
 539                 Item_Show(e, 1);
 540
 541                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 542                 {
 543                         if(head != e)
 544                         {
 545                                 // make it a non-spawned item
 546                                 Item_Show(head, -1);
 547                                 head.state = 1; // state 1 = initially hidden item
 548                         }
 549                         head.effects &~= EF_NODRAW;
 550                 }
 551
 552                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 553                         Item_ScheduleInitialRespawn(e);
 554         }
 555 }
 556
 557 void Item_Reset()
 558 {
 559         Item_Show(self, !self.state);
 560         setorigin (self, self.origin);
 561         self.think = SUB_Null;
 562         self.nextthink = 0;
 563
 564         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 565                 Item_ScheduleInitialRespawn(self);
 566 }
 567
 568 // Savage: used for item garbage-collection
 569 // TODO: perhaps nice special effect?
 570 void RemoveItem(void)
 571 {
 572         remove(self);
 573 }
 574
 575 // pickup evaluation functions
 576 // these functions decide how desirable an item is to the bots
 577
 578 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 579
 580 float weapon_pickupevalfunc(entity player, entity item)
 581 {
 582         float c, i, j, position;
 583
 584         // See if I have it already
 585         if(player.weapons & item.weapons == item.weapons)
 586         {
 587                 // If I can pick it up
 588                 if(!item.spawnshieldtime)
 589                         c = 0;
 590                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 591                 {
 592                         // Skilled bots will grab more
 593                         c = bound(0, skill / 10, 1) * 0.5;
 594                 }
 595                 else
 596                         c = 0;
 597         }
 598         else
 599                 c = 1;
 600
 601         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 602         if( bot_custom_weapon && c )
 603         {
 604                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 605                 {
 606                         // Find weapon
 607                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 608                                 continue;
 609
 610                         // Find the highest position on any range
 611                         position = -1;
 612                         for(j = 0; j < WEP_LAST ; ++j){
 613                                 if(
 614                                                 bot_weapons_far[j] == i ||
 615                                                 bot_weapons_mid[j] == i ||
 616                                                 bot_weapons_close[j] == i
 617                                   )
 618                                 {
 619                                         position = j;
 620                                         break;
 621                                 }
 622                         }
 623
 624                         // Rate it
 625                         if (position >= 0 )
 626                         {
 627                                 position = WEP_LAST - position;
 628                                 // item.bot_pickupbasevalue is overwritten here
 629                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 630                         }
 631                 }
 632         }
 633
 634         return item.bot_pickupbasevalue * c;
 635 }
 636
 637 float commodity_pickupevalfunc(entity player, entity item)
 638 {
 639         float c, i, need_shells, need_nails, need_rockets, need_cells;
 640         entity wi;
 641         c = 0;
 642
 643         // Detect needed ammo
 644         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 645         {
 646                 wi = get_weaponinfo(i);
 647
 648                 if not(wi.weapons & player.weapons)
 649                         continue;
 650
 651                 if(wi.items & IT_SHELLS)
 652                         need_shells = TRUE;
 653                 else if(wi.items & IT_NAILS)
 654                         need_nails = TRUE;
 655                 else if(wi.items & IT_ROCKETS)
 656                         need_rockets = TRUE;
 657                 else if(wi.items & IT_CELLS)
 658                         need_cells = TRUE;
 659         }
 660
 661         // TODO: figure out if the player even has the weapon this ammo is for?
 662         // may not affect strategy much though...
 663         // find out how much more ammo/armor/health the player can hold
 664         if (need_shells)
 665         if (item.ammo_shells)
 666         if (player.ammo_shells < g_pickup_shells_max)
 667                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 668         if (need_nails)
 669         if (item.ammo_nails)
 670         if (player.ammo_nails < g_pickup_nails_max)
 671                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 672         if (need_rockets)
 673         if (item.ammo_rockets)
 674         if (player.ammo_rockets < g_pickup_rockets_max)
 675                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 676         if (need_cells)
 677         if (item.ammo_cells)
 678         if (player.ammo_cells < g_pickup_cells_max)
 679                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 680         if (item.armorvalue)
 681         if (player.armorvalue < item.max_armorvalue)
 682                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 683         if (item.health)
 684         if (player.health < item.max_health)
 685                 c = c + max(0, 1 - player.health / item.max_health);
 686
 687         return item.bot_pickupbasevalue * c;
 688 }
 689
 690
 691 .float is_item;
 692 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 693 {
 694         startitem_failed = FALSE;
 695
 696         self.items = itemid;
 697         self.weapons = weaponid;
 698
 699         // is it a dropped weapon?
 700         if (self.classname == "droppedweapon")
 701         {
 702                 self.reset = SUB_Remove;
 703                 // it's a dropped weapon
 704                 self.movetype = MOVETYPE_TOSS;
 705                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 706                 self.think = RemoveItem;
 707                 self.nextthink = time + 60;
 708                 // don't drop if in a NODROP zone (such as lava)
 709                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 710                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 711                 {
 712                         startitem_failed = TRUE;
 713                         remove(self);
 714                         return;
 715                 }
 716         }
 717         else
 718         {
 719                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 720                 {
 721                         startitem_failed = TRUE;
 722                         remove(self);
 723                         return;
 724                 }
 725
 726                 if(!have_pickup_item())
 727                 {
 728                         startitem_failed = TRUE;
 729                         remove (self);
 730                         return;
 731                 }
 732
 733                 self.reset = Item_Reset;
 734                 // it's a level item
 735                 if(self.spawnflags & 1)
 736                         self.noalign = 1;
 737                 if (self.noalign)
 738                         self.movetype = MOVETYPE_NONE;
 739                 else
 740                         self.movetype = MOVETYPE_TOSS;
 741                 // do item filtering according to game mode and other things
 742                 if (!self.noalign)
 743                 {
 744                         // first nudge it off the floor a little bit to avoid math errors
 745                         setorigin(self, self.origin + '0 0 1');
 746                         // set item size before we spawn a spawnfunc_waypoint
 747                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 748                                 setsize (self, '-16 -16 0', '16 16 48');
 749                         else
 750                                 setsize (self, '-16 -16 0', '16 16 32');
 751                         // note droptofloor returns FALSE if stuck/or would fall too far
 752                         droptofloor();
 753                         waypoint_spawnforitem(self);
 754                 }
 755
 756                 /*
 757                  * can't do it that way, as it would break maps
 758                  * TODO make a target_give like entity another way, that perhaps has
 759                  * the weapon name in a key
 760                 if(self.targetname)
 761                 {
 762                         // target_give not yet supported; maybe later
 763                         print("removed targeted ", self.classname, "\n");
 764                         startitem_failed = TRUE;
 765                         remove (self);
 766                         return;
 767                 }
 768                 */
 769
 770                 if(autocvar_spawn_debug >= 2)
 771                 {
 772                         entity otheritem;
 773                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 774                         {
 775                                 if(otheritem.is_item)
 776                                 {
 777                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 778                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 779                                         error("Mapper sucks.");
 780                                 }
 781                         }
 782                         self.is_item = TRUE;
 783                 }
 784
 785                 weaponsInMap |= weaponid;
 786
 787                 precache_model (itemmodel);
 788                 precache_sound (pickupsound);
 789
 790                 precache_sound ("misc/itemrespawncountdown.wav");
 791                 if(!g_minstagib && itemid == IT_STRENGTH)
 792                         precache_sound ("misc/strength_respawn.wav");
 793                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 794                         precache_sound ("misc/shield_respawn.wav");
 795                 else
 796                         precache_sound ("misc/itemrespawn.wav");
 797
 798                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 799                         self.target = "###item###"; // for finding the nearest item using find()
 800         }
 801
 802         self.bot_pickup = TRUE;
 803         self.bot_pickupevalfunc = pickupevalfunc;
 804         self.bot_pickupbasevalue = pickupbasevalue;
 805         self.mdl = itemmodel;
 806         self.item_pickupsound = pickupsound;
 807         // let mappers override respawntime
 808         if(!self.respawntime) // both set
 809         {
 810                 self.respawntime = defaultrespawntime;
 811                 self.respawntimejitter = defaultrespawntimejitter;
 812         }
 813         self.netname = itemname;
 814         self.flags = FL_ITEM | itemflags;
 815         self.touch = Item_Touch;
 816         setmodel (self, self.mdl); // precision set below
 817         self.effects |= EF_LOWPRECISION;
 818         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 819                 setsize (self, '-16 -16 0', '16 16 48');
 820         else
 821                 setsize (self, '-16 -16 0', '16 16 32');
 822         if(itemflags & FL_WEAPON)
 823                 self.modelflags |= MF_ROTATE;
 824
 825         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 826         if (itemflags & FL_WEAPON)
 827         {
 828                 // neutral team color for pickup weapons
 829                 self.colormap = 1024; // color shirt=0 pants=0 grey
 830         }
 831
 832         Item_Show(self, 1);
 833         self.state = 0;
 834         if(self.team)
 835         {
 836                 if(!self.cnt)
 837                         self.cnt = 1; // item probability weight
 838                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 839                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 840         }
 841         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 842                 Item_ScheduleInitialRespawn(self);
 843 }
 844
 845 /* replace items in minstagib
 846  * IT_STRENGTH   = invisibility
 847  * IT_NAILS      = extra lives
 848  * IT_INVINCIBLE = speed
 849  */
 850 void minstagib_items (float itemid)
 851 {
 852         float rnd;
 853         self.classname = "minstagib";
 854
 855         // replace rocket launchers and nex guns with ammo cells
 856         if (itemid == IT_CELLS)
 857         {
 858                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 859                 StartItem ("models/items/a_cells.md3",
 860                         "misc/itempickup.wav", 45, 0,
 861                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 862                 return;
 863         }
 864
 865         // randomize
 866         rnd = random() * 3;
 867         if (rnd <= 1)
 868                 itemid = IT_STRENGTH;
 869         else if (rnd <= 2)
 870                 itemid = IT_NAILS;
 871         else
 872                 itemid = IT_INVINCIBLE;
 873
 874         // replace with invis
 875         if (itemid == IT_STRENGTH)
 876         {
 877                 self.strength_finished = 30;
 878                 StartItem ("models/items/g_strength.md3",
 879                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 880                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 881         }
 882         // replace with extra lives
 883         if (itemid == IT_NAILS)
 884         {
 885                 self.max_health = 1;
 886                 StartItem ("models/items/g_h100.md3",
 887                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 888                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 889         }
 890         // replace with speed
 891         if (itemid == IT_INVINCIBLE)
 892         {
 893                 self.invincible_finished = 30;
 894                 StartItem ("models/items/g_invincible.md3",
 895                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 896                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 897         }
 898 }
 899
 900 float minst_no_auto_cells;
 901 void minst_remove_item (void) {
 902         if(minst_no_auto_cells)
 903                 remove(self);
 904 }
 905
 906 float weaponswapping;
 907 float internalteam;
 908
 909 void weapon_defaultspawnfunc(float wpn)
 910 {
 911         entity e;
 912         float t;
 913         var .float ammofield;
 914         string s;
 915         entity oldself;
 916         float i, j;
 917
 918         // set the respawntime in advance (so replaced weapons can copy it)
 919
 920         if(!self.respawntime)
 921         {
 922                 e = get_weaponinfo(wpn);
 923                 if(e.items == IT_SUPERWEAPON)
 924                 {
 925                         self.respawntime = g_pickup_respawntime_powerup;
 926                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 927                 }
 928                 else
 929                 {
 930                         self.respawntime = g_pickup_respawntime_weapon;
 931                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 932                 }
 933         }
 934
 935         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 936         {
 937                 e = get_weaponinfo(wpn);
 938                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 939                 if(s == "0")
 940                 {
 941                         remove(self);
 942                         startitem_failed = TRUE;
 943                         return;
 944                 }
 945                 t = tokenize_console(s);
 946                 if(t >= 2)
 947                 {
 948                         self.team = --internalteam;
 949                         oldself = self;
 950                         for(i = 1; i < t; ++i)
 951                         {
 952                                 s = argv(i);
 953                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 954                                 {
 955                                         e = get_weaponinfo(j);
 956                                         if(e.netname == s)
 957                                         {
 958                                                 self = spawn();
 959                                                 copyentity(oldself, self);
 960                                                 self.classname = "replacedweapon";
 961                                                 weapon_defaultspawnfunc(j);
 962                                                 break;
 963                                         }
 964                                 }
 965                                 if(j > WEP_LAST)
 966                                 {
 967                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 968                                 }
 969                         }
 970                         self = oldself;
 971                 }
 972                 if(t >= 1)
 973                 {
 974                         s = argv(0);
 975                         wpn = 0;
 976                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 977                         {
 978                                 e = get_weaponinfo(j);
 979                                 if(e.netname == s)
 980                                 {
 981                                         wpn = j;
 982                                         break;
 983                                 }
 984                         }
 985                         if(j > WEP_LAST)
 986                         {
 987                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 988                         }
 989                 }
 990                 if(wpn == 0)
 991                 {
 992                         remove(self);
 993                         startitem_failed = TRUE;
 994                         return;
 995                 }
 996         }
 997
 998         e = get_weaponinfo(wpn);
 999
1000         if(e.items && e.items != IT_SUPERWEAPON)
1001         {
1002                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1003                 {
1004                         if(e.items & j)
1005                         {
1006                                 ammofield = Item_CounterField(j);
1007                                 if(!self.ammofield)
1008                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1009                         }
1010                 }
1011         }
1012         else
1013         {
1014                 self.flags |= FL_NO_WEAPON_STAY;
1015         }
1016
1017         // weapon stay isn't supported for teamed weapons
1018         if(self.team)
1019                 self.flags |= FL_NO_WEAPON_STAY;
1020
1021         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1022         if (self.modelindex) // don't precache if self was removed
1023                 weapon_action(e.weapon, WR_PRECACHE);
1024 }
1025
1026 void spawnfunc_weapon_shotgun (void);
1027 void spawnfunc_weapon_uzi (void) {
1028         if(autocvar_sv_q3acompat_machineshotgunswap)
1029         if(self.classname != "droppedweapon")
1030         {
1031                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1032                 return;
1033         }
1034         weapon_defaultspawnfunc(WEP_UZI);
1035 }
1036
1037 void spawnfunc_weapon_shotgun (void) {
1038         if(autocvar_sv_q3acompat_machineshotgunswap)
1039         if(self.classname != "droppedweapon")
1040         {
1041                 weapon_defaultspawnfunc(WEP_UZI);
1042                 return;
1043         }
1044         weapon_defaultspawnfunc(WEP_SHOTGUN);
1045 }
1046
1047 void spawnfunc_weapon_nex (void)
1048 {
1049         if (g_minstagib)
1050         {
1051                 minstagib_items(IT_CELLS);
1052                 self.think = minst_remove_item;
1053                 self.nextthink = time;
1054                 return;
1055         }
1056         weapon_defaultspawnfunc(WEP_NEX);
1057 }
1058
1059 void spawnfunc_weapon_minstanex (void)
1060 {
1061         if (g_minstagib)
1062         {
1063                 minstagib_items(IT_CELLS);
1064                 self.think = minst_remove_item;
1065                 self.nextthink = time;
1066                 return;
1067         }
1068         weapon_defaultspawnfunc(WEP_MINSTANEX);
1069 }
1070
1071 void spawnfunc_weapon_rocketlauncher (void)
1072 {
1073         if (g_minstagib)
1074         {
1075                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1076                 self.think = minst_remove_item;
1077                 self.nextthink = time;
1078                 return;
1079         }
1080         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1081 }
1082
1083 void spawnfunc_item_rockets (void) {
1084         if(!self.ammo_rockets)
1085                 self.ammo_rockets = g_pickup_rockets;
1086         if(!self.pickup_anyway)
1087                 self.pickup_anyway = g_pickup_ammo_anyway;
1088         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1089 }
1090
1091 void spawnfunc_item_shells (void);
1092 void spawnfunc_item_bullets (void) {
1093         if(!weaponswapping)
1094         if(autocvar_sv_q3acompat_machineshotgunswap)
1095         if(self.classname != "droppedweapon")
1096         {
1097                 weaponswapping = TRUE;
1098                 spawnfunc_item_shells();
1099                 weaponswapping = FALSE;
1100                 return;
1101         }
1102
1103         if(!self.ammo_nails)
1104                 self.ammo_nails = g_pickup_nails;
1105         if(!self.pickup_anyway)
1106                 self.pickup_anyway = g_pickup_ammo_anyway;
1107         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1108 }
1109
1110 void spawnfunc_item_cells (void) {
1111         if(!self.ammo_cells)
1112                 self.ammo_cells = g_pickup_cells;
1113         if(!self.pickup_anyway)
1114                 self.pickup_anyway = g_pickup_ammo_anyway;
1115         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1116 }
1117
1118 void spawnfunc_item_shells (void) {
1119         if(!weaponswapping)
1120         if(autocvar_sv_q3acompat_machineshotgunswap)
1121         if(self.classname != "droppedweapon")
1122         {
1123                 weaponswapping = TRUE;
1124                 spawnfunc_item_bullets();
1125                 weaponswapping = FALSE;
1126                 return;
1127         }
1128
1129         if(!self.ammo_shells)
1130                 self.ammo_shells = g_pickup_shells;
1131         if(!self.pickup_anyway)
1132                 self.pickup_anyway = g_pickup_ammo_anyway;
1133         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1134 }
1135
1136 void spawnfunc_item_armor_small (void) {
1137         if(!self.armorvalue)
1138                 self.armorvalue = g_pickup_armorsmall;
1139         if(!self.max_armorvalue)
1140                 self.max_armorvalue = g_pickup_armorsmall_max;
1141         if(!self.pickup_anyway)
1142                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1143         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1144 }
1145
1146 void spawnfunc_item_armor_medium (void) {
1147         if(!self.armorvalue)
1148                 self.armorvalue = g_pickup_armormedium;
1149         if(!self.max_armorvalue)
1150                 self.max_armorvalue = g_pickup_armormedium_max;
1151         if(!self.pickup_anyway)
1152                 self.pickup_anyway = g_pickup_armormedium_anyway;
1153         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1154 }
1155
1156 void spawnfunc_item_armor_big (void) {
1157         if(!self.armorvalue)
1158                 self.armorvalue = g_pickup_armorbig;
1159         if(!self.max_armorvalue)
1160                 self.max_armorvalue = g_pickup_armorbig_max;
1161         if(!self.pickup_anyway)
1162                 self.pickup_anyway = g_pickup_armorbig_anyway;
1163         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1164 }
1165
1166 void spawnfunc_item_armor_large (void) {
1167         if(!self.armorvalue)
1168                 self.armorvalue = g_pickup_armorlarge;
1169         if(!self.max_armorvalue)
1170                 self.max_armorvalue = g_pickup_armorlarge_max;
1171         if(!self.pickup_anyway)
1172                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1173         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1174 }
1175
1176 void spawnfunc_item_health_small (void) {
1177         if(!self.max_health)
1178                 self.max_health = g_pickup_healthsmall_max;
1179         if(!self.health)
1180                 self.health = g_pickup_healthsmall;
1181         if(!self.pickup_anyway)
1182                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1183         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1184 }
1185
1186 void spawnfunc_item_health_medium (void) {
1187         if(!self.max_health)
1188                 self.max_health = g_pickup_healthmedium_max;
1189         if(!self.health)
1190                 self.health = g_pickup_healthmedium;
1191         if(!self.pickup_anyway)
1192                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1193         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1194 }
1195
1196 void spawnfunc_item_health_large (void) {
1197         if(!self.max_health)
1198                 self.max_health = g_pickup_healthlarge_max;
1199         if(!self.health)
1200                 self.health = g_pickup_healthlarge;
1201         if(!self.pickup_anyway)
1202                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1203         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1204 }
1205
1206 void spawnfunc_item_health_mega (void) {
1207         if(g_minstagib) {
1208                 minstagib_items(IT_NAILS);
1209         } else {
1210                 if(!self.max_health)
1211                         self.max_health = g_pickup_healthmega_max;
1212                 if(!self.health)
1213                         self.health = g_pickup_healthmega;
1214                 if(!self.pickup_anyway)
1215                         self.pickup_anyway = g_pickup_healthmega_anyway;
1216                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1217         }
1218 }
1219
1220 // support old misnamed entities
1221 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1222 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1223 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1224 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1225 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1226
1227 void spawnfunc_item_strength (void) {
1228         if(g_minstagib) {
1229                 minstagib_items(IT_STRENGTH);
1230         } else {
1231                 precache_sound("weapons/strength_fire.wav");
1232                 self.strength_finished = 30;
1233                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1234         }
1235 }
1236
1237 void spawnfunc_item_invincible (void) {
1238         if(g_minstagib) {
1239                 minstagib_items(IT_INVINCIBLE);
1240         } else {
1241                 self.invincible_finished = 30;
1242                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1243         }
1244 }
1245
1246 void spawnfunc_item_minst_cells (void) {
1247         if (g_minstagib)
1248         {
1249                 minst_no_auto_cells = 1;
1250                 minstagib_items(IT_CELLS);
1251         }
1252         else
1253                 remove(self);
1254 }
1255
1256 // compatibility:
1257 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1258
1259 float GiveItems(entity e, float beginarg, float endarg);
1260 void target_items_use (void)
1261 {
1262         if(activator.classname == "droppedweapon")
1263         {
1264                 EXACTTRIGGER_TOUCH;
1265                 remove(activator);
1266                 return;
1267         }
1268
1269         if(activator.classname != "player")
1270                 return;
1271         if(activator.deadflag != DEAD_NO)
1272                 return;
1273         EXACTTRIGGER_TOUCH;
1274
1275         entity e;
1276         for(e = world; (e = find(e, classname, "droppedweapon")); )
1277                 if(e.enemy == activator)
1278                         remove(e);
1279
1280         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1281                 centerprint(activator, self.message);
1282 }
1283
1284 void spawnfunc_target_items (void)
1285 {
1286         float n, i, j;
1287         entity e;
1288
1289         self.use = target_items_use;
1290         if(!self.strength_finished)
1291                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1292         if(!self.invincible_finished)
1293                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1294
1295         precache_sound("misc/itempickup.wav");
1296         precache_sound("misc/megahealth.wav");
1297         precache_sound("misc/armor25.wav");
1298         precache_sound("misc/powerup.wav");
1299         precache_sound("misc/poweroff.wav");
1300         precache_sound("weapons/weaponpickup.wav");
1301
1302         n = tokenize_console(self.netname);
1303         if(argv(0) == "give")
1304         {
1305                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1306         }
1307         else
1308         {
1309                 for(i = 0; i < n; ++i)
1310                 {
1311                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1312                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1313                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1314                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1315                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1316                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1317                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1318                         else
1319                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1320                         {
1321                                 e = get_weaponinfo(j);
1322                                 if(argv(i) == e.netname)
1323                                 {
1324                                         self.weapons |= e.weapons;
1325                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1326                                                 weapon_action(e.weapon, WR_PRECACHE);
1327                                         break;
1328                                 }
1329                         }
1330                         if(j > WEP_LAST)
1331                                 print("target_items: invalid item ", argv(i), "\n");
1332                 }
1333
1334                 string itemprefix, valueprefix;
1335                 if(self.spawnflags == 0)
1336                 {
1337                         itemprefix = "";
1338                         valueprefix = "";
1339                 }
1340                 else if(self.spawnflags == 1)
1341                 {
1342                         itemprefix = "max ";
1343                         valueprefix = "max ";
1344                 }
1345                 else if(self.spawnflags == 2)
1346                 {
1347                         itemprefix = "min ";
1348                         valueprefix = "min ";
1349                 }
1350                 else if(self.spawnflags == 4)
1351                 {
1352                         itemprefix = "minus ";
1353                         valueprefix = "max ";
1354                 }
1355                 else
1356                         error("invalid spawnflags");
1357
1358                 self.netname = "";
1359                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1360                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1361                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1362                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1363                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1364                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1365                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1366                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1367                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1368                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1369                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1370                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1371                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1372                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1373                 {
1374                         e = get_weaponinfo(j);
1375                         if(e.weapons)
1376                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1377                 }
1378         }
1379         self.netname = strzone(self.netname);
1380         //print(self.netname, "\n");
1381
1382         n = tokenize_console(self.netname);
1383         for(i = 0; i < n; ++i)
1384         {
1385                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1386                 {
1387                         e = get_weaponinfo(j);
1388                         if(argv(i) == e.netname)
1389                         {
1390                                 weapon_action(e.weapon, WR_PRECACHE);
1391                                 break;
1392                         }
1393                 }
1394         }
1395 }
1396
1397 void spawnfunc_item_fuel(void)
1398 {
1399         if(!self.ammo_fuel)
1400                 self.ammo_fuel = g_pickup_fuel;
1401         if(!self.pickup_anyway)
1402                 self.pickup_anyway = g_pickup_ammo_anyway;
1403         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1404 }
1405
1406 void spawnfunc_item_fuel_regen(void)
1407 {
1408         if(start_items & IT_FUEL_REGEN)
1409         {
1410                 spawnfunc_item_fuel();
1411                 return;
1412         }
1413         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1414 }
1415
1416 void spawnfunc_item_jetpack(void)
1417 {
1418         if(g_grappling_hook)
1419                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1420         if(!self.ammo_fuel)
1421                 self.ammo_fuel = g_pickup_fuel_jetpack;
1422         if(start_items & IT_JETPACK)
1423         {
1424                 spawnfunc_item_fuel();
1425                 return;
1426         }
1427         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1428 }
1429
1430
1431 #define OP_SET 0
1432 #define OP_MIN 1
1433 #define OP_MAX 2
1434 #define OP_PLUS 3
1435 #define OP_MINUS 4
1436
1437 float GiveBit(entity e, .float fld, float bit, float op, float val)
1438 {
1439         float v0, v1;
1440         v0 = (e.fld & bit);
1441         switch(op)
1442         {
1443                 case OP_SET:
1444                         if(val > 0)
1445                                 e.fld |= bit;
1446                         else
1447                                 e.fld &~= bit;
1448                         break;
1449                 case OP_MIN:
1450                 case OP_PLUS:
1451                         if(val > 0)
1452                                 e.fld |= bit;
1453                         break;
1454                 case OP_MAX:
1455                         if(val <= 0)
1456                                 e.fld &~= bit;
1457                         break;
1458                 case OP_MINUS:
1459                         if(val > 0)
1460                                 e.fld &~= bit;
1461                         break;
1462         }
1463         v1 = (e.fld & bit);
1464         return (v0 != v1);
1465 }
1466
1467 float GiveValue(entity e, .float fld, float op, float val)
1468 {
1469         float v0, v1;
1470         v0 = e.fld;
1471         switch(op)
1472         {
1473                 case OP_SET:
1474                         e.fld = val;
1475                         break;
1476                 case OP_MIN:
1477                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1478                         break;
1479                 case OP_MAX:
1480                         e.fld = min(e.fld, val);
1481                         break;
1482                 case OP_PLUS:
1483                         e.fld += val;
1484                         break;
1485                 case OP_MINUS:
1486                         e.fld -= val;
1487                         break;
1488         }
1489         v1 = e.fld;
1490         return (v0 != v1);
1491 }
1492
1493 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1494 {
1495         if(v1 == v0)
1496                 return;
1497         if(v1 <= v0 - t)
1498         {
1499                 if(snd_decr != "")
1500                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1501         }
1502         else if(v0 >= v0 + t)
1503         {
1504                 if(snd_incr != "")
1505                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1506         }
1507 }
1508
1509 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1510 {
1511         if(v0 < v1)
1512                 e.rotfield = max(e.rotfield, time + rottime);
1513         else if(v0 > v1)
1514                 e.regenfield = max(e.regenfield, time + regentime);
1515 }
1516
1517 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1518 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1519 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1520 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1521
1522 float GiveItems(entity e, float beginarg, float endarg)
1523 {
1524         float got, i, j, val, op;
1525         float _switchweapon;
1526         entity wi;
1527         string cmd;
1528
1529         val = 999;
1530         op = OP_SET;
1531
1532         got = 0;
1533
1534         _switchweapon = FALSE;
1535         if (e.autoswitch)
1536                 if (e.switchweapon == w_getbestweapon(e))
1537                         _switchweapon = TRUE;
1538
1539         e.strength_finished = max(0, e.strength_finished - time);
1540         e.invincible_finished = max(0, e.invincible_finished - time);
1541
1542         PREGIVE(e, items);
1543         PREGIVE(e, weapons);
1544         PREGIVE(e, strength_finished);
1545         PREGIVE(e, invincible_finished);
1546         PREGIVE(e, ammo_nails);
1547         PREGIVE(e, ammo_cells);
1548         PREGIVE(e, ammo_shells);
1549         PREGIVE(e, ammo_rockets);
1550         PREGIVE(e, ammo_fuel);
1551         PREGIVE(e, armorvalue);
1552         PREGIVE(e, health);
1553
1554         for(i = beginarg; i < endarg; ++i)
1555         {
1556                 cmd = argv(i);
1557
1558                 if(cmd == "0" || stof(cmd))
1559                 {
1560                         val = stof(cmd);
1561                         continue;
1562                 }
1563                 switch(cmd)
1564                 {
1565                         case "no":
1566                                 op = OP_MAX;
1567                                 val = 0;
1568                                 continue;
1569                         case "max":
1570                                 op = OP_MAX;
1571                                 continue;
1572                         case "min":
1573                                 op = OP_MIN;
1574                                 continue;
1575                         case "plus":
1576                                 op = OP_PLUS;
1577                                 continue;
1578                         case "minus":
1579                                 op = OP_MINUS;
1580                                 continue;
1581                         case "ALL":
1582                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1583                                 got += GiveValue(e, strength_finished, op, time);
1584                                 got += GiveValue(e, invincible_finished, op, time);
1585                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1586                         case "all":
1587                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1588                                 got += GiveValue(e, health, op, val);
1589                                 got += GiveValue(e, armorvalue, op, val);
1590                         case "allweapons":
1591                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1592                                 {
1593                                         wi = get_weaponinfo(j);
1594                                         if(wi.weapons)
1595                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1596                                 }
1597                         case "allammo":
1598                                 got += GiveValue(e, ammo_cells, op, val);
1599                                 got += GiveValue(e, ammo_shells, op, val);
1600                                 got += GiveValue(e, ammo_nails, op, val);
1601                                 got += GiveValue(e, ammo_rockets, op, val);
1602                                 got += GiveValue(e, ammo_fuel, op, val);
1603                                 break;
1604                         case "unlimited_ammo":
1605                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1606                                 break;
1607                         case "unlimited_weapon_ammo":
1608                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1609                                 break;
1610                         case "unlimited_superweapons":
1611                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1612                                 break;
1613                         case "jetpack":
1614                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1615                                 break;
1616                         case "fuel_regen":
1617                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1618                                 break;
1619                         case "strength":
1620                                 got += GiveValue(e, strength_finished, op, val);
1621                                 break;
1622                         case "invincible":
1623                                 got += GiveValue(e, invincible_finished, op, val);
1624                                 break;
1625                         case "cells":
1626                                 got += GiveValue(e, ammo_cells, op, val);
1627                                 break;
1628                         case "shells":
1629                                 got += GiveValue(e, ammo_shells, op, val);
1630                                 break;
1631                         case "nails":
1632                         case "bullets":
1633                                 got += GiveValue(e, ammo_nails, op, val);
1634                                 break;
1635                         case "rockets":
1636                                 got += GiveValue(e, ammo_rockets, op, val);
1637                                 break;
1638                         case "health":
1639                                 got += GiveValue(e, health, op, val);
1640                                 break;
1641                         case "armor":
1642                                 got += GiveValue(e, armorvalue, op, val);
1643                                 break;
1644                         case "fuel":
1645                                 got += GiveValue(e, ammo_fuel, op, val);
1646                                 break;
1647                         default:
1648                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1649                                 {
1650                                         wi = get_weaponinfo(j);
1651                                         if(cmd == wi.netname)
1652                                         {
1653                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1654                                                 break;
1655                                         }
1656                                 }
1657                                 if(j > WEP_LAST)
1658                                         print("give: invalid item ", cmd, "\n");
1659                                 break;
1660                 }
1661                 val = 999;
1662                 op = OP_SET;
1663         }
1664
1665         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1666         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1667         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1668         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1669         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1670         {
1671                 wi = get_weaponinfo(j);
1672                 if(wi.weapons)
1673                 {
1674                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1675                         if not(save_weapons & wi.weapons)
1676                                 if(e.weapons & wi.weapons)
1677                                         weapon_action(wi.weapon, WR_PRECACHE);
1678                 }
1679         }
1680         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1681         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1682         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1683         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1684         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1685         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1686         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1687         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1688         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1689
1690         if (g_minstagib)
1691         {
1692                 e.health = bound(0, e.health, 100);
1693                 e.armorvalue = bound(0, e.armorvalue, 999);
1694         }
1695
1696         if(e.strength_finished <= 0)
1697                 e.strength_finished = 0;
1698         else
1699                 e.strength_finished += time;
1700         if(e.invincible_finished <= 0)
1701                 e.invincible_finished = 0;
1702         else
1703                 e.invincible_finished += time;
1704
1705         if not(e.weapons & W_WeaponBit(e.switchweapon))
1706                 _switchweapon = TRUE;
1707         if(_switchweapon)
1708                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1709
1710         return got;
1711 }