qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 void trigger_push_use()
  12 {
  13         if(teams_matter)
  14                 self.team = activator.team;
  15 }
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         local float grav, sdist, zdist, vs, vz, jumpheight;
  34         local vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = cvar("sv_gravity");
  39
  40         zdist = torg_z - org_z;
  41         sdist = vlen(torg - org - zdist * '0 0 1');
  42         sdir = normalize(torg - org - zdist * '0 0 1');
  43
  44         // how high do we need to push the player?
  45         jumpheight = fabs(ht);
  46         if(zdist > 0)
  47                 jumpheight = jumpheight + zdist;
  48
  49         /*
  50                 STOP.
  51
  52                 You will not understand the following equations anyway...
  53                 But here is what I did to get them.
  54
  55                 I used the functions
  56
  57                   s(t) = t * vs
  58                   z(t) = t * vz - 1/2 grav t^2
  59
  60                 and solved for:
  61
  62                   s(ti) = sdist
  63                   z(ti) = zdist
  64                   max(z, ti) = jumpheight
  65
  66                 From these three equations, you will find the three parameters vs, vz
  67                 and ti.
  68          */
  69
  70         // push him so high...
  71         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  72
  73         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  74         if(ht < 0)
  75                 if(zdist < 0)
  76                         vz = -vz;
  77
  78         vector solution;
  79         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  80         // ALWAYS solvable because jumpheight >= zdist
  81         if(!solution_z)
  82                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  83         if(zdist == 0)
  84                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  85
  86         if(zdist < 0)
  87         {
  88                 // down-jump
  89                 if(ht < 0)
  90                 {
  91                         // almost straight line type
  92                         // jump apex is before the jump
  93                         // we must take the larger one
  94                         trigger_push_calculatevelocity_flighttime = solution_y;
  95                 }
  96                 else
  97                 {
  98                         // regular jump
  99                         // jump apex is during the jump
 100                         // we must take the larger one too
 101                         trigger_push_calculatevelocity_flighttime = solution_y;
 102                 }
 103         }
 104         else
 105         {
 106                 // up-jump
 107                 if(ht < 0)
 108                 {
 109                         // almost straight line type
 110                         // jump apex is after the jump
 111                         // we must take the smaller one
 112                         trigger_push_calculatevelocity_flighttime = solution_x;
 113                 }
 114                 else
 115                 {
 116                         // regular jump
 117                         // jump apex is during the jump
 118                         // we must take the larger one
 119                         trigger_push_calculatevelocity_flighttime = solution_y;
 120                 }
 121         }
 122         vs = sdist / trigger_push_calculatevelocity_flighttime;
 123
 124         // finally calculate the velocity
 125         return sdir * vs + '0 0 1' * vz;
 126 }
 127
 128 void trigger_push_touch()
 129 {
 130         if (self.active == ACTIVE_NOT)
 131                 return;
 132
 133         // FIXME: add a .float for whether an entity should be tossed by jumppads
 134         if (!other.iscreature)
 135         if (other.classname != "corpse")
 136         if (other.classname != "body")
 137         if (other.classname != "gib")
 138         if (other.classname != "casing")
 139         if (other.classname != "droppedweapon")
 140         if (!other.projectiledeathtype || other.classname == "bullet")
 141                 return;
 142
 143         if (other.deadflag && other.iscreature)
 144                 return;
 145
 146         if(self.team)
 147                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 148                         return;
 149
 150         EXACTTRIGGER_TOUCH;
 151
 152         if(self.target)
 153                 self.movedir = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 154
 155         other.flags &~= FL_ONGROUND;
 156
 157         other.velocity = self.movedir;
 158
 159         if (other.classname == "player")
 160         {
 161                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 162                 other.oldvelocity = other.velocity;
 163
 164                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 165                 {
 166                         // flash when activated
 167                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 168                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 169                         self.pushltime = time + 0.2;
 170                 }
 171                 local float ct;
 172                 ct = clienttype(other);
 173                 if( ct == CLIENTTYPE_REAL)
 174                 {
 175                         local float i;
 176                         local float found;
 177                         found = FALSE;
 178                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 179                                 if(other.(jumppadsused[i]) == self)
 180                                         found = TRUE;
 181                         if(!found)
 182                         {
 183                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 184                                 other.jumppadcount = other.jumppadcount + 1;
 185                         }
 186
 187                         if(self.message)
 188                                 centerprint(other, self.message);
 189                 }
 190                 else if(ct == CLIENTTYPE_BOT)
 191                         other.lastteleporttime = time;
 192                 else
 193                         other.jumppadcount = TRUE;
 194
 195                 // reset tracking of who pushed you into a hazard (for kill credit)
 196                 other.pushltime = 0;
 197         }
 198
 199         if(self.enemy.target)
 200         {
 201                 entity oldself;
 202                 oldself = self;
 203                 activator = other;
 204                 self = self.enemy;
 205                 SUB_UseTargets();
 206                 self = oldself;
 207         }
 208
 209         if (other.flags & FL_PROJECTILE)
 210         {
 211                 other.angles = vectoangles (other.velocity);
 212                 switch(other.movetype)
 213                 {
 214                         case MOVETYPE_FLY:
 215                                 other.movetype = MOVETYPE_TOSS;
 216                                 other.gravity = 1;
 217                                 break;
 218                         case MOVETYPE_BOUNCEMISSILE:
 219                                 other.movetype = MOVETYPE_BOUNCE;
 220                                 other.gravity = 1;
 221                                 break;
 222                 }
 223                 UpdateCSQCProjectile(other);
 224         }
 225
 226         if (self.spawnflags & PUSH_ONCE)
 227         {
 228                 self.touch = SUB_Null;
 229                 self.think = SUB_Remove;
 230                 self.nextthink = time;
 231         }
 232 };
 233
 234 .vector dest;
 235 void trigger_push_findtarget()
 236 {
 237         local entity e;
 238         local vector org;
 239         local float flighttime;
 240
 241         // first calculate a typical start point for the jump
 242         org = (self.absmin + self.absmax) * 0.5;
 243         org_z = self.absmax_z - PL_MIN_z;
 244
 245         if (self.target)
 246         {
 247                 // find the target
 248                 self.enemy = find(world, targetname, self.target);
 249                 if (!self.enemy)
 250                 {
 251                         objerror("trigger_push: target not found\n");
 252                         remove(self);
 253                         return;
 254                 }
 255
 256                 self.movedir = trigger_push_calculatevelocity(org, self.enemy, self.height);
 257                 flighttime = trigger_push_calculatevelocity_flighttime;
 258         }
 259         else
 260                 flighttime = 0;
 261
 262         // calculate the destination and spawn a teleporter spawnfunc_waypoint
 263         e = spawn();
 264         setorigin(e, org);
 265         setsize(e, PL_MIN, PL_MAX);
 266         e.velocity = self.movedir;
 267         tracetoss(e, e);
 268         self.dest = trace_endpos;
 269         remove(e);
 270
 271         waypoint_spawnforteleporter(self, self.dest, flighttime);
 272 };
 273
 274 /*
 275  * ENTITY PARAMETERS:
 276  *
 277  *   target:  target of jump
 278  *   height:  the absolute value is the height of the highest point of the jump
 279  *            trajectory above the higher one of the player and the target.
 280  *            the sign indicates whether the highest point is INSIDE (positive)
 281  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 282  *            positive values for targets mounted on the floor, and use negative
 283  *            values to target a point on the ceiling.
 284  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 285  */
 286 void spawnfunc_trigger_push()
 287 {
 288         if (self.angles != '0 0 0')
 289                 SetMovedir ();
 290
 291         EXACTTRIGGER_INIT;
 292
 293         self.active = ACTIVE_ACTIVE;
 294         self.use = trigger_push_use;
 295         self.touch = trigger_push_touch;
 296
 297         // normal push setup
 298         if (!self.speed)
 299                 self.speed = 1000;
 300         self.movedir = self.movedir * self.speed * 10;
 301
 302         if not(self.noise)
 303                 self.noise = "misc/jumppad.wav";
 304         precache_sound (self.noise);
 305
 306         // this must be called to spawn the teleport waypoints for bots
 307         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 308 };
 309
 310 void spawnfunc_target_push() {};
 311 void spawnfunc_info_notnull() {};
 312 void spawnfunc_target_position() {};