qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 void trigger_push_use()
  12 {
  13         if(teamplay)
  14                 self.team = activator.team;
  15 }
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         local float grav, sdist, zdist, vs, vz, jumpheight;
  34         local vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = autocvar_sv_gravity;
  39
  40         zdist = torg_z - org_z;
  41         sdist = vlen(torg - org - zdist * '0 0 1');
  42         sdir = normalize(torg - org - zdist * '0 0 1');
  43
  44         // how high do we need to push the player?
  45         jumpheight = fabs(ht);
  46         if(zdist > 0)
  47                 jumpheight = jumpheight + zdist;
  48
  49         /*
  50                 STOP.
  51
  52                 You will not understand the following equations anyway...
  53                 But here is what I did to get them.
  54
  55                 I used the functions
  56
  57                   s(t) = t * vs
  58                   z(t) = t * vz - 1/2 grav t^2
  59
  60                 and solved for:
  61
  62                   s(ti) = sdist
  63                   z(ti) = zdist
  64                   max(z, ti) = jumpheight
  65
  66                 From these three equations, you will find the three parameters vs, vz
  67                 and ti.
  68          */
  69
  70         // push him so high...
  71         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  72
  73         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  74         if(ht < 0)
  75                 if(zdist < 0)
  76                         vz = -vz;
  77
  78         vector solution;
  79         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  80         // ALWAYS solvable because jumpheight >= zdist
  81         if(!solution_z)
  82                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  83         if(zdist == 0)
  84                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  85
  86         if(zdist < 0)
  87         {
  88                 // down-jump
  89                 if(ht < 0)
  90                 {
  91                         // almost straight line type
  92                         // jump apex is before the jump
  93                         // we must take the larger one
  94                         trigger_push_calculatevelocity_flighttime = solution_y;
  95                 }
  96                 else
  97                 {
  98                         // regular jump
  99                         // jump apex is during the jump
 100                         // we must take the larger one too
 101                         trigger_push_calculatevelocity_flighttime = solution_y;
 102                 }
 103         }
 104         else
 105         {
 106                 // up-jump
 107                 if(ht < 0)
 108                 {
 109                         // almost straight line type
 110                         // jump apex is after the jump
 111                         // we must take the smaller one
 112                         trigger_push_calculatevelocity_flighttime = solution_x;
 113                 }
 114                 else
 115                 {
 116                         // regular jump
 117                         // jump apex is during the jump
 118                         // we must take the larger one
 119                         trigger_push_calculatevelocity_flighttime = solution_y;
 120                 }
 121         }
 122         vs = sdist / trigger_push_calculatevelocity_flighttime;
 123
 124         // finally calculate the velocity
 125         return sdir * vs + '0 0 1' * vz;
 126 }
 127
 128 void trigger_push_touch()
 129 {
 130         if (self.active == ACTIVE_NOT)
 131                 return;
 132
 133         if (!isPushable(other))
 134                 return;
 135
 136         if(self.team)
 137                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 138                         return;
 139
 140         EXACTTRIGGER_TOUCH;
 141
 142         if(self.target)
 143                 self.movedir = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 144
 145         other.flags &~= FL_ONGROUND;
 146
 147         other.velocity = self.movedir;
 148
 149         if (other.classname == "player")
 150         {
 151                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 152                 other.oldvelocity = other.velocity;
 153
 154                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 155                 {
 156                         // flash when activated
 157                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 158                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 159                         self.pushltime = time + 0.2;
 160                 }
 161                 local float ct;
 162                 ct = clienttype(other);
 163                 if( ct == CLIENTTYPE_REAL || ct == CLIENTTYPE_BOT)
 164                 {
 165                         local float i;
 166                         local float found;
 167                         found = FALSE;
 168                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 169                                 if(other.(jumppadsused[i]) == self)
 170                                         found = TRUE;
 171                         if(!found)
 172                         {
 173                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 174                                 other.jumppadcount = other.jumppadcount + 1;
 175                         }
 176
 177                         if(ct == CLIENTTYPE_REAL)
 178                         {
 179                                 if(self.message)
 180                                         centerprint(other, self.message);
 181                         }
 182                         else
 183                                 other.lastteleporttime = time;
 184                 }
 185                 else
 186                         other.jumppadcount = TRUE;
 187
 188                 // reset tracking of who pushed you into a hazard (for kill credit)
 189                 other.pushltime = 0;
 190         }
 191
 192         if(self.enemy.target)
 193         {
 194                 entity oldself;
 195                 oldself = self;
 196                 activator = other;
 197                 self = self.enemy;
 198                 SUB_UseTargets();
 199                 self = oldself;
 200         }
 201
 202         if (other.flags & FL_PROJECTILE)
 203         {
 204                 other.angles = vectoangles (other.velocity);
 205                 switch(other.movetype)
 206                 {
 207                         case MOVETYPE_FLY:
 208                                 other.movetype = MOVETYPE_TOSS;
 209                                 other.gravity = 1;
 210                                 break;
 211                         case MOVETYPE_BOUNCEMISSILE:
 212                                 other.movetype = MOVETYPE_BOUNCE;
 213                                 other.gravity = 1;
 214                                 break;
 215                 }
 216                 UpdateCSQCProjectile(other);
 217         }
 218
 219         if (self.spawnflags & PUSH_ONCE)
 220         {
 221                 self.touch = SUB_Null;
 222                 self.think = SUB_Remove;
 223                 self.nextthink = time;
 224         }
 225 };
 226
 227 .vector dest;
 228 void trigger_push_findtarget()
 229 {
 230         local entity e;
 231         local vector org;
 232         local float flighttime;
 233
 234         // first calculate a typical start point for the jump
 235         org = (self.absmin + self.absmax) * 0.5;
 236         org_z = self.absmax_z - PL_MIN_z;
 237
 238         if (self.target)
 239         {
 240                 // find the target
 241                 self.enemy = find(world, targetname, self.target);
 242                 if (!self.enemy)
 243                 {
 244                         objerror("trigger_push: target not found\n");
 245                         remove(self);
 246                         return;
 247                 }
 248
 249                 self.movedir = trigger_push_calculatevelocity(org, self.enemy, self.height);
 250                 flighttime = trigger_push_calculatevelocity_flighttime;
 251         }
 252         else
 253                 flighttime = 0;
 254
 255         // calculate the destination and spawn a teleporter spawnfunc_waypoint
 256         e = spawn();
 257         setorigin(e, org);
 258         setsize(e, PL_MIN, PL_MAX);
 259         e.velocity = self.movedir;
 260         tracetoss(e, e);
 261         self.dest = trace_endpos;
 262         remove(e);
 263
 264         waypoint_spawnforteleporter(self, self.dest, flighttime);
 265 };
 266
 267 /*
 268  * ENTITY PARAMETERS:
 269  *
 270  *   target:  target of jump
 271  *   height:  the absolute value is the height of the highest point of the jump
 272  *            trajectory above the higher one of the player and the target.
 273  *            the sign indicates whether the highest point is INSIDE (positive)
 274  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 275  *            positive values for targets mounted on the floor, and use negative
 276  *            values to target a point on the ceiling.
 277  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 278  */
 279 void spawnfunc_trigger_push()
 280 {
 281         SetMovedir ();
 282
 283         EXACTTRIGGER_INIT;
 284
 285         self.active = ACTIVE_ACTIVE;
 286         self.use = trigger_push_use;
 287         self.touch = trigger_push_touch;
 288
 289         // normal push setup
 290         if (!self.speed)
 291                 self.speed = 1000;
 292         self.movedir = self.movedir * self.speed * 10;
 293
 294         if not(self.noise)
 295                 self.noise = "misc/jumppad.wav";
 296         precache_sound (self.noise);
 297
 298         // this must be called to spawn the teleport waypoints for bots
 299         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 300 };
 301
 302 void spawnfunc_target_push() {};
 303 void spawnfunc_info_notnull() {};
 304 void spawnfunc_target_position() {};