qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teamplay)
   4                 self.team = activator.team;
   5 }
   6
   7 #define TDEATHLOOP(o) \
   8         entity head; \
   9         vector deathmin; \
  10         vector deathmax; \
  11         float deathradius; \
  12         deathmin = (o) + player.mins; \
  13         deathmax = (o) + player.maxs; \
  14         if(telefragmin != telefragmax) \
  15         { \
  16                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x; \
  17                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y; \
  18                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z; \
  19                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x; \
  20                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y; \
  21                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z; \
  22         } \
  23         deathradius = max(vlen(deathmin), vlen(deathmax)); \
  24         for(head = findradius(o, deathradius); head; head = head.chain) \
  25                 if(head != player) \
  26                         if(head.takedamage) \
  27                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  28
  29
  30 float check_tdeath(entity player, vector org, vector telefragmin, vector telefragmax)
  31 {
  32         if (player.classname == "player" && player.health >= 1)
  33         {
  34                 TDEATHLOOP(org)
  35                 {
  36                         if not(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team)
  37                                 if(head.classname == "player")
  38                                         if(head.health >= 1)
  39                                                 return 1;
  40                 }
  41         }
  42         return 0;
  43 }
  44 float tdeath_hit;
  45 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
  46 {
  47         TDEATHLOOP(player.origin)
  48         {
  49                 if (player.classname == "player" && player.health >= 1)
  50                 {
  51                         if not(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team)
  52                         {
  53                                 if(head.classname == "player")
  54                                         if(head.health >= 1)
  55                                                 ++tdeath_hit;
  56                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                         }
  58                 }
  59                 else // dead bodies and monsters gib themselves instead of telefragging
  60                         Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  61         }
  62 }
  63
  64 void spawn_tdeath(vector v0, entity e, vector v)
  65 {
  66         tdeath(e, e, e, '0 0 0', '0 0 0');
  67 }
  68
  69 .entity pusher;
  70 #define TELEPORT_FLAG_SOUND 1
  71 #define TELEPORT_FLAG_PARTICLES 2
  72 #define TELEPORT_FLAG_TDEATH 4
  73 #define TELEPORT_FLAG_FORCE_TDEATH 8
  74
  75 #define TELEPORT_FLAGS_WARPZONE   0
  76 #define TELEPORT_FLAGS_PORTAL     (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH | TELEPORT_FLAG_FORCE_TDEATH)
  77 #define TELEPORT_FLAGS_TELEPORTER (TELEPORT_FLAG_SOUND | TELEPORT_FLAG_PARTICLES | TELEPORT_FLAG_TDEATH)
  78 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax, float tflags)
  79 {
  80         entity telefragger;
  81         vector from;
  82
  83         if(teleporter.owner)
  84                 telefragger = teleporter.owner;
  85         else
  86                 telefragger = player;
  87
  88         makevectors (to_angles);
  89
  90         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  91         {
  92                 if(tflags & TELEPORT_FLAG_SOUND)
  93                         sound (player, CH_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  94                 if(tflags & TELEPORT_FLAG_PARTICLES)
  95                 {
  96                         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  97                         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  98                 }
  99                 self.pushltime = time + 0.2;
 100         }
 101
 102         // Relocate the player
 103         // assuming to allows PL_MIN to PL_MAX box and some more
 104         from = player.origin;
 105         setorigin (player, to);
 106         player.oldorigin = to; // don't undo the teleport by unsticking
 107         player.angles = to_angles;
 108         player.fixangle = TRUE;
 109         player.velocity = to_velocity;
 110         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
 111
 112         UpdateCSQCProjectileAfterTeleport(player);
 113
 114         if(player.classname == "player")
 115         {
 116                 if(tflags & TELEPORT_FLAG_TDEATH)
 117                         if(player.takedamage && player.deadflag == DEAD_NO && !g_race && !g_cts && (autocvar_g_telefrags || (tflags & TELEPORT_FLAG_FORCE_TDEATH)))
 118                                 tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
 119
 120                 // player no longer is on ground
 121                 player.flags &~= FL_ONGROUND;
 122
 123                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 124                 player.oldvelocity = player.velocity;
 125
 126                 // reset tracking of who pushed you into a hazard (for kill credit)
 127                 if(teleporter.owner)
 128                 {
 129                         player.pusher = teleporter.owner;
 130                         player.pushltime = time + autocvar_g_maxpushtime;
 131                 }
 132                 else
 133                 {
 134                         player.pushltime = 0;
 135                 }
 136
 137                 player.lastteleporttime = time;
 138         }
 139 }
 140
 141 void Teleport_Touch (void)
 142 {
 143         entity oldself, e;
 144         vector o;
 145         float p;
 146         string s;
 147
 148         if (self.active != ACTIVE_ACTIVE)
 149                 return;
 150
 151         if not(other.iscreature)
 152                 return;
 153
 154         // for gameplay: vehicles can't teleport
 155         if (other.vehicle_flags & VHF_ISVEHICLE)
 156                 return;
 157
 158         if (other.deadflag != DEAD_NO)
 159                 return;
 160
 161         if(self.team)
 162                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 163                         return;
 164
 165         EXACTTRIGGER_TOUCH;
 166
 167         makevectors(self.enemy.mangle);
 168
 169         if(other.classname == "player")
 170                 RemoveGrapplingHook(other);
 171
 172         if(self.enemy)
 173         {
 174                 e = self.enemy;
 175         }
 176         else
 177         {
 178                 RandomSelection_Init();
 179                 for(e = world; (e = find(e, targetname, self.target)); )
 180                 {
 181                         p = 1;
 182                         if(autocvar_g_telefrags_avoid)
 183                         {
 184                                 o = e.origin + '0 0 1' * (1 - other.mins_z - 24);
 185                                 if(check_tdeath(other, o, '0 0 0', '0 0 0'))
 186                                         p = 0;
 187                         }
 188                         if(e.cnt)
 189                                 RandomSelection_Add(e, 0, string_null, e.cnt, p);
 190                         else
 191                                 RandomSelection_Add(e, 0, string_null, 1, p);
 192                 }
 193                 e = RandomSelection_chosen_ent;
 194         }
 195
 196         if(!e)
 197         {
 198                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 199         }
 200
 201         if(e.speed)
 202                 if(vlen(other.velocity) > e.speed)
 203                         other.velocity = normalize(other.velocity) * max(0, e.speed);
 204         if(autocvar_g_teleport_maxspeed)
 205                 if(vlen(other.velocity) > autocvar_g_teleport_maxspeed)
 206                         other.velocity = normalize(other.velocity) * max(0, autocvar_g_teleport_maxspeed);
 207
 208         o = e.origin + '0 0 1' * (1 - other.mins_z - 24);
 209         TeleportPlayer(self, other, o, e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 210
 211         activator = other;
 212         s = self.target; self.target = string_null;
 213         SUB_UseTargets();
 214         if not(self.target) self.target = s;
 215
 216         oldself = self;
 217         self = e;
 218         SUB_UseTargets();
 219         self = oldself;
 220 }
 221
 222 void spawnfunc_info_teleport_destination (void)
 223 {
 224         self.classname = "info_teleport_destination";
 225
 226         self.mangle = self.angles;
 227         self.angles = '0 0 0';
 228
 229         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 230         setorigin (self, self.origin);
 231
 232         IFTARGETED
 233         {
 234         }
 235         else
 236                 objerror ("^3Teleport destination without a targetname");
 237 }
 238
 239 void spawnfunc_misc_teleporter_dest (void)
 240 {
 241         spawnfunc_info_teleport_destination();
 242 }
 243
 244 void spawnfunc_target_teleporter (void)
 245 {
 246         spawnfunc_info_teleport_destination();
 247 }
 248
 249 void teleport_findtarget (void)
 250 {
 251         entity e;
 252         float n;
 253
 254         n = 0;
 255         for(e = world; (e = find(e, targetname, self.target)); )
 256         {
 257                 ++n;
 258                 if(e.movetype == MOVETYPE_NONE)
 259                         waypoint_spawnforteleporter(self, e.origin, 0);
 260                 if(e.classname != "info_teleport_destination")
 261                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 262         }
 263
 264         if(n == 0)
 265         {
 266                 // no dest!
 267                 objerror ("Teleporter with nonexistant target");
 268                 return;
 269         }
 270         else if(n == 1)
 271         {
 272                 // exactly one dest - bots love that
 273                 self.enemy = find(e, targetname, self.target);
 274         }
 275         else
 276         {
 277                 // have to use random selection every single time
 278                 self.enemy = world;
 279         }
 280
 281         // now enable touch
 282         self.touch = Teleport_Touch;
 283 }
 284
 285 void spawnfunc_trigger_teleport (void)
 286 {
 287         self.angles = '0 0 0';
 288
 289         EXACTTRIGGER_INIT;
 290
 291         self.active = ACTIVE_ACTIVE;
 292
 293         self.use = trigger_teleport_use;
 294
 295         // this must be called to spawn the teleport waypoints for bots
 296         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 297
 298         if (!self.target)
 299         {
 300                 objerror ("Teleporter with no target");
 301                 return;
 302         }
 303 }
 304
 305 void WarpZone_PostTeleportPlayer_Callback(entity pl)
 306 {
 307         UpdateCSQCProjectileAfterTeleport(pl);
 308         // "disown" projectiles after teleport
 309         if(pl.owner == pl.realowner)
 310                 pl.owner = world;
 311         if(pl.classname == "player")
 312         {
 313                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 314                 pl.oldvelocity = pl.velocity;
 315                 // reset teleport time tracking too (or multijump can cause insane speeds)
 316                 pl.lastteleporttime = time;
 317         }
 318 }