qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(cvar("bot_vs_human") && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!cvar("g_balance_teams_force"))
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void nb_init();
  75 void entcs_init();
  76
  77 void LogTeamchange(float player_id, float team_number, float type)
  78 {
  79         if(!cvar("sv_eventlog"))
  80                 return;
  81
  82         if(player_id < 1)
  83                 return;
  84
  85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  86 }
  87
  88 void WriteGameCvars()
  89 {
  90         cvar_set("g_dm", ftos(g_dm));
  91         cvar_set("g_tdm", ftos(g_tdm));
  92         cvar_set("g_domination", ftos(g_domination));
  93         cvar_set("g_ctf", ftos(g_ctf));
  94         cvar_set("g_runematch", ftos(g_runematch));
  95         cvar_set("g_lms", ftos(g_lms));
  96         cvar_set("g_arena", ftos(g_arena));
  97         cvar_set("g_ca", ftos(g_ca));
  98         cvar_set("g_keyhunt", ftos(g_keyhunt));
  99         cvar_set("g_assault", ftos(g_assault));
 100         cvar_set("g_onslaught", ftos(g_onslaught));
 101         cvar_set("g_race", ftos(g_race));
 102         cvar_set("g_nexball", ftos(g_nexball));
 103         cvar_set("g_cts", ftos(g_cts));
 104         cvar_set("g_ka", ftos(g_ka));
 105 }
 106
 107 void ReadGameCvars()
 108 {
 109         float found;
 110         float prev;
 111         float i;
 112
 113         found = 0;
 114         prev = cvar("gamecfg");
 115         for(i = 0; i < 2; ++i)
 116         {
 117                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 118                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 119                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 120                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 121                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 122                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 123                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 124                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 125                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 126                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 127                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 128                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 129                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 130                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 131                 found += (g_ka = (!found && (prev != GAME_KEEPAWAY) && cvar("g_ka")));
 132
 133                 if(found)
 134                         break;
 135
 136                 prev = -1; // second attempt takes place WITHOUT prev set
 137         }
 138
 139         if(!found)
 140                 g_dm = 1;
 141
 142         if(g_dm && cvar("deathmatch_force_teamplay"))
 143         {
 144                 g_dm = 0;
 145                 g_tdm = 1;
 146         }
 147
 148         teams_matter = 0;
 149 }
 150
 151 void default_delayedinit()
 152 {
 153         if(!scores_initialized)
 154                 ScoreRules_generic();
 155 }
 156
 157 void ActivateTeamplay()
 158 {
 159         float teamplay_default;
 160         teamplay_default = cvar("teamplay_default");
 161
 162         if(teamplay_default)
 163                 teamplay = teamplay_default;
 164         else
 165                 teamplay = 3;
 166         cvar_set("teamplay", ftos(teamplay));
 167
 168         teams_matter = 1;
 169 }
 170
 171 void InitGameplayMode()
 172 {
 173         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 174
 175         qualifying_override = -1;
 176
 177         VoteReset();
 178
 179         teams_matter = 0;
 180         cvar_set("teamplay", "0");
 181
 182         // make sure only ONE type is selected
 183         ReadGameCvars();
 184         WriteGameCvars();
 185
 186         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 187         get_mi_min_max(1);
 188         world.mins = mi_min;
 189         world.maxs = mi_max;
 190
 191         MapInfo_LoadMapSettings(mapname);
 192
 193         if not(cvar_value_issafe(world.fog))
 194         {
 195                 print("The current map contains a potentially harmful fog setting, ignored\n");
 196                 world.fog = string_null;
 197         }
 198         if(MapInfo_Map_fog != "")
 199                 if(MapInfo_Map_fog == "none")
 200                         world.fog = string_null;
 201                 else
 202                         world.fog = strzone(MapInfo_Map_fog);
 203         clientstuff = strzone(MapInfo_Map_clientstuff);
 204
 205         MapInfo_ClearTemps();
 206
 207         // in case mapinfo switched the type
 208         ReadGameCvars();
 209
 210         // set both here, gamemode can override it later
 211         timelimit_override = cvar("timelimit_override");
 212         fraglimit_override = cvar("fraglimit_override");
 213         leadlimit_override = cvar("leadlimit_override");
 214
 215         if(g_dm)
 216         {
 217                 game = GAME_DEATHMATCH;
 218                 gamemode_name = "Deathmatch";
 219         }
 220
 221         if(g_tdm)
 222         {
 223                 game = GAME_TEAM_DEATHMATCH;
 224                 gamemode_name = "Team Deathmatch";
 225                 ActivateTeamplay();
 226                 tdm_init();
 227                 if(cvar("g_tdm_team_spawns"))
 228                         have_team_spawns = -1; // request team spawns
 229         }
 230
 231         if(g_domination)
 232         {
 233                 game = GAME_DOMINATION;
 234                 gamemode_name = "Domination";
 235                 ActivateTeamplay();
 236                 fraglimit_override = cvar("g_domination_point_limit");
 237                 leadlimit_override = cvar("g_domination_point_leadlimit");
 238                 dom_init();
 239                 have_team_spawns = -1; // request team spawns
 240         }
 241
 242         if(g_ctf)
 243         {
 244                 game = GAME_CTF;
 245                 gamemode_name = "Capture the Flag";
 246                 ActivateTeamplay();
 247                 if(cvar("g_campaign"))
 248                         g_ctf_win_mode = 2;
 249                 else
 250                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 251                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 252                 if(g_ctf_win_mode == 2)
 253                 {
 254                         fraglimit_override = cvar("g_ctf_capture_limit");
 255                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 256                 }
 257                 else
 258                 {
 259                         fraglimit_override = cvar("capturelimit_override");
 260                         leadlimit_override = cvar("captureleadlimit_override");
 261                 }
 262                 ctf_init();
 263                 have_team_spawns = -1; // request team spawns
 264         }
 265
 266         if(g_runematch)
 267         {
 268                 game = GAME_RUNEMATCH;
 269                 gamemode_name = "Rune Match";
 270                 if(cvar("deathmatch_force_teamplay"))
 271                         ActivateTeamplay();
 272                 fraglimit_override = cvar("g_runematch_point_limit");
 273                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 274                 runematch_init();
 275         }
 276
 277         if(g_lms)
 278         {
 279                 game = GAME_LMS;
 280                 gamemode_name = "Last Man Standing";
 281                 fraglimit_override = cvar("g_lms_lives_override");
 282                 leadlimit_override = 0; // not supported by LMS
 283                 if(fraglimit_override == 0)
 284                         fraglimit_override = -1;
 285                 lms_lowest_lives = 9999;
 286                 lms_next_place = 0;
 287                 ScoreRules_lms();
 288         }
 289
 290         if(g_arena)
 291         {
 292                 game = GAME_ARENA;
 293                 gamemode_name = "Arena";
 294                 fraglimit_override = cvar("g_arena_point_limit");
 295                 leadlimit_override = cvar("g_arena_point_leadlimit");
 296                 maxspawned = cvar("g_arena_maxspawned");
 297                 if(maxspawned < 2)
 298                         maxspawned = 2;
 299                 arena_roundbased = cvar("g_arena_roundbased");
 300         }
 301
 302         if(g_ca)
 303         {
 304                 game = GAME_CA;
 305                 gamemode_name = "Clan Arena";
 306                 ActivateTeamplay();
 307                 fraglimit_override = cvar("g_ca_point_limit");
 308                 leadlimit_override = cvar("g_ca_point_leadlimit");
 309                 precache_sound("ctf/red_capture.wav");
 310                 precache_sound("ctf/blue_capture.wav");
 311         }
 312         if(g_keyhunt)
 313         {
 314                 game = GAME_KEYHUNT;
 315                 gamemode_name = "Key Hunt";
 316                 ActivateTeamplay();
 317                 fraglimit_override = cvar("g_keyhunt_point_limit");
 318                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 319                 MUTATOR_ADD(gamemode_keyhunt);
 320         }
 321
 322         if(g_assault)
 323         {
 324                 game = GAME_ASSAULT;
 325                 gamemode_name = "Assault";
 326                 ActivateTeamplay();
 327                 ScoreRules_assault();
 328                 have_team_spawns = -1; // request team spawns
 329         }
 330
 331         if(g_onslaught)
 332         {
 333                 game = GAME_ONSLAUGHT;
 334                 gamemode_name = "Onslaught";
 335                 ActivateTeamplay();
 336                 have_team_spawns = -1; // request team spawns
 337         }
 338
 339         if(g_race)
 340         {
 341                 game = GAME_RACE;
 342                 gamemode_name = "Race";
 343
 344                 if(cvar("g_race_teams"))
 345                 {
 346                         ActivateTeamplay();
 347                         race_teams = bound(2, cvar("g_race_teams"), 4);
 348                         have_team_spawns = -1; // request team spawns
 349                 }
 350                 else
 351                         race_teams = 0;
 352
 353                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 354                 fraglimit_override = cvar("g_race_laps_limit");
 355                 leadlimit_override = 0; // currently not supported by race
 356         }
 357
 358         if(g_cts)
 359         {
 360                 game = GAME_CTS;
 361                 gamemode_name = "CTS";
 362                 g_race_qualifying = 1;
 363                 fraglimit_override = 0;
 364                 leadlimit_override = 0;
 365         }
 366
 367         if(g_nexball)
 368         {
 369                 game = GAME_NEXBALL;
 370                 gamemode_name = "Nexball";
 371                 fraglimit_override = cvar("g_nexball_goallimit");
 372                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 373                 ActivateTeamplay();
 374                 nb_init();
 375                 have_team_spawns = -1; // request team spawns
 376         }
 377
 378         if(g_ka)
 379         {
 380                 game = GAME_KEEPAWAY;
 381                 gamemode_name = "Keepaway";
 382                 MUTATOR_ADD(gamemode_ka);
 383         }
 384
 385         if(teams_matter)
 386                 entcs_init();
 387
 388         // save it (for the next startup)
 389         cvar_set("gamecfg", ftos(game));
 390
 391         cache_mutatormsg = strzone("");
 392         cache_lastmutatormsg = strzone("");
 393
 394         // enforce the server's universal frag/time limits
 395         if(!cvar("g_campaign"))
 396         {
 397                 if(fraglimit_override >= 0)
 398                         cvar_set("fraglimit", ftos(fraglimit_override));
 399                 if(timelimit_override >= 0)
 400                         cvar_set("timelimit", ftos(timelimit_override));
 401                 if(leadlimit_override >= 0)
 402                         cvar_set("leadlimit", ftos(leadlimit_override));
 403                 if(qualifying_override >= 0)
 404                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 405         }
 406
 407         if(g_race)
 408         {
 409                 // we need to find out the correct value for g_race_qualifying
 410                 if(cvar("g_campaign"))
 411                 {
 412                         g_race_qualifying = 1;
 413                 }
 414                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 415                 {
 416                         g_race_qualifying = 2;
 417                         race_fraglimit = cvar("fraglimit");
 418                         race_leadlimit = cvar("leadlimit");
 419                         race_timelimit = cvar("timelimit");
 420                         cvar_set("fraglimit", "0");
 421                         cvar_set("leadlimit", "0");
 422                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 423                 }
 424                 else
 425                         g_race_qualifying = 0;
 426         }
 427
 428         if(g_race || g_cts)
 429         {
 430                 if(g_race_qualifying)
 431                         independent_players = 1;
 432
 433                 ScoreRules_race();
 434         }
 435
 436         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 437 }
 438
 439 string GetClientVersionMessage() {
 440         local string versionmsg;
 441         if (self.version_mismatch) {
 442                 if(self.version < cvar("gameversion")) {
 443                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 444                 } else {
 445                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 446                 }
 447         } else {
 448                 versionmsg = "^2client version and server version are compatible.^8";
 449         }
 450         return versionmsg;
 451 }
 452
 453
 454 void PrintWelcomeMessage(entity pl)
 455 {
 456         string s, modifications, motd;
 457
 458         if(self.cvar_scr_centertime == 0) return;
 459
 460         if(cvar("g_campaign"))
 461         {
 462                 if(self.classname == "player" && !self.BUTTON_INFO)
 463                         return;
 464         }
 465         else
 466         {
 467                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 468                         return;
 469         }
 470
 471         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 472                 if(self.welcomemessage_time > time) return;
 473                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 474         }
 475
 476         if(cvar("g_campaign"))
 477         {
 478                 centerprint(pl, campaign_message);
 479                 return;
 480         }
 481
 482 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 483         if(!self.BUTTON_INFO)
 484         {
 485                 // TODO get rid of this too
 486                 local string specString;
 487                 specString = NEWLINES;
 488                 //if(time < game_starttime) //also show the countdown when being a spectator
 489                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 490                 //else
 491                 if (timeoutStatus != 0)
 492                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 493                 else
 494                 {
 495                         if(self.classname == "player")
 496                                 return;
 497                         goto normal;
 498                 }
 499                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 500         }
 501
 502 :normal
 503         ret_string = "";
 504         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 505         modifications = ret_string;
 506
 507         if(g_minstagib)
 508                 modifications = strcat(modifications, ", MinstaGib");
 509         if(g_weaponarena)
 510         {
 511                 if(g_weaponarena_random)
 512                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 513                 else
 514                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 515         }
 516         if(cvar("g_start_weapon_laser") == 0)
 517                 modifications = strcat(modifications, ", No start weapons");
 518         if(cvar("sv_gravity") < 800)
 519                 modifications = strcat(modifications, ", Low gravity");
 520         if(g_cloaked)
 521                 modifications = strcat(modifications, ", Cloaked");
 522         if(g_grappling_hook)
 523                 modifications = strcat(modifications, ", Hook");
 524         if(g_midair)
 525                 modifications = strcat(modifications, ", Midair");
 526         if(g_pinata)
 527                 modifications = strcat(modifications, ", Pinata");
 528         if(g_weapon_stay)
 529                 modifications = strcat(modifications, ", Weapons stay");
 530         if(g_bloodloss > 0)
 531                 modifications = strcat(modifications, ", Bloodloss");
 532         if(g_jetpack)
 533                 modifications = strcat(modifications, ", Jet pack");
 534         modifications = substring(modifications, 2, strlen(modifications) - 2);
 535
 536         local string versionmessage;
 537         versionmessage = GetClientVersionMessage();
 538
 539         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
 540         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 541
 542         if(modifications != "")
 543                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 544
 545         if(timeoutStatus != 0)
 546                 s = strcat(s, "\n\n", getTimeoutText(1));
 547
 548         if (g_grappling_hook)
 549                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 550
 551         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 552         {
 553                 if(cache_lastmutatormsg)
 554                         strunzone(cache_lastmutatormsg);
 555                 if(cache_mutatormsg)
 556                         strunzone(cache_mutatormsg);
 557                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 558                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 559         }
 560
 561         if (cache_mutatormsg != "") {
 562                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 563         }
 564
 565         motd = cvar_string("sv_motd");
 566         if (motd != "") {
 567                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 568         }
 569         s = strcat(s, "\n");
 570
 571         centerprint(pl, s);
 572 }
 573
 574
 575 void SetPlayerColors(entity pl, float _color)
 576 {
 577         /*string s;
 578         s = ftos(cl);
 579         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 580         pl.team = cl + 1;
 581         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 582         pl.clientcolors = 16*cl + cl;*/
 583
 584         float pants, shirt;
 585         pants = _color & 0x0F;
 586         shirt = _color & 0xF0;
 587
 588
 589         if(teams_matter) {
 590                 setcolor(pl, 16*pants + pants);
 591         } else {
 592                 setcolor(pl, shirt + pants);
 593         }
 594 }
 595
 596 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 597 {
 598         float _color;
 599
 600         if(t == 4)
 601                 _color = COLOR_TEAM4 - 1;
 602         else if(t == 3)
 603                 _color = COLOR_TEAM3 - 1;
 604         else if(t == 2)
 605                 _color = COLOR_TEAM2 - 1;
 606         else
 607                 _color = COLOR_TEAM1 - 1;
 608
 609         SetPlayerColors(pl,_color);
 610
 611         if(t != s) {
 612                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 613
 614                 if(!noprint)
 615                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 616         }
 617
 618 }
 619
 620 // set c1...c4 to show what teams are allowed
 621 void CheckAllowedTeams (entity for_whom)
 622 {
 623         float dm;
 624         entity head;
 625         string teament_name;
 626
 627         c1 = c2 = c3 = c4 = -1;
 628         cb1 = cb2 = cb3 = cb4 = 0;
 629
 630         if(cvar("g_campaign") && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
 631         {
 632                 c1 = 0; // only allow RED team for player joining
 633         }
 634         else if(g_onslaught)
 635         {
 636                 // onslaught is special
 637                 head = findchain(classname, "onslaught_generator");
 638                 while (head)
 639                 {
 640                         if (head.team == COLOR_TEAM1) c1 = 0;
 641                         if (head.team == COLOR_TEAM2) c2 = 0;
 642                         if (head.team == COLOR_TEAM3) c3 = 0;
 643                         if (head.team == COLOR_TEAM4) c4 = 0;
 644                         head = head.chain;
 645                 }
 646         }
 647         else if(g_domination)
 648                 teament_name = "dom_team";
 649         else if(g_ctf)
 650                 teament_name = "ctf_team";
 651         else if(g_tdm)
 652                 teament_name = "tdm_team";
 653         else if(g_nexball)
 654                 teament_name = "nexball_team";
 655         else if(g_assault)
 656                 c1 = c2 = 0; // Assault always has 2 teams
 657         else
 658         {
 659                 // cover anything else by treating it like tdm with no teams spawned
 660                 if(g_race)
 661                         dm = race_teams;
 662                 else
 663                         dm = 2;
 664
 665                 ret_float = dm;
 666                 MUTATOR_CALLHOOK(GetTeamCount);
 667                 dm = ret_float;
 668
 669                 if(dm >= 4)
 670                         c1 = c2 = c3 = c4 = 0;
 671                 else if(dm >= 3)
 672                         c1 = c2 = c3 = 0;
 673                 else
 674                         c1 = c2 = 0;
 675         }
 676
 677         // find out what teams are allowed if necessary
 678         if(teament_name)
 679         {
 680                 head = find(world, classname, teament_name);
 681                 while(head)
 682                 {
 683                         if(!(g_domination && head.netname == ""))
 684                         {
 685                                 if(head.team == COLOR_TEAM1)
 686                                         c1 = 0;
 687                                 else if(head.team == COLOR_TEAM2)
 688                                         c2 = 0;
 689                                 else if(head.team == COLOR_TEAM3)
 690                                         c3 = 0;
 691                                 else if(head.team == COLOR_TEAM4)
 692                                         c4 = 0;
 693                         }
 694                         head = find(head, classname, teament_name);
 695                 }
 696         }
 697
 698         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 699         if(c3==-1 && c4==-1)
 700         if(cvar("bot_vs_human") && for_whom)
 701         {
 702                 if(cvar("bot_vs_human") > 0)
 703                 {
 704                         // bots are all blue
 705                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 706                                 c1 = c3 = c4 = -1;
 707                         else
 708                                 c2 = -1;
 709                 }
 710                 else
 711                 {
 712                         // bots are all red
 713                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 714                                 c2 = c3 = c4 = -1;
 715                         else
 716                                 c1 = -1;
 717                 }
 718         }
 719
 720         // if player has a forced team, ONLY allow that one
 721         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 722                 c2 = c3 = c4 = -1;
 723         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 724                 c1 = c3 = c4 = -1;
 725         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 726                 c1 = c2 = c4 = -1;
 727         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 728                 c1 = c2 = c3 = -1;
 729 }
 730
 731 float PlayerValue(entity p)
 732 {
 733         if(IsTeamBalanceForced() == 1)
 734                 return 1;
 735         return 1;
 736         // FIXME: it always returns 1...
 737 }
 738
 739 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 740 // teams that are allowed will now have their player counts stored in c1...c4
 741 void GetTeamCounts(entity ignore)
 742 {
 743         entity head;
 744         float value, bvalue;
 745         // now count how many players are on each team already
 746
 747         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 748         // also remember the lowest-scoring player
 749
 750         FOR_EACH_PLAYER(head)
 751         {
 752                 if(head != ignore)// && head.netname != "")
 753                 {
 754                         value = PlayerValue(head);
 755                         if(clienttype(head) == CLIENTTYPE_BOT)
 756                                 bvalue = value;
 757                         else
 758                                 bvalue = 0;
 759                         if(head.team == COLOR_TEAM1)
 760                         {
 761                                 if(c1 >= 0)
 762                                 {
 763                                         c1 = c1 + value;
 764                                         cb1 = cb1 + bvalue;
 765                                 }
 766                         }
 767                         if(head.team == COLOR_TEAM2)
 768                         {
 769                                 if(c2 >= 0)
 770                                 {
 771                                         c2 = c2 + value;
 772                                         cb2 = cb2 + bvalue;
 773                                 }
 774                         }
 775                         if(head.team == COLOR_TEAM3)
 776                         {
 777                                 if(c3 >= 0)
 778                                 {
 779                                         c3 = c3 + value;
 780                                         cb3 = cb3 + bvalue;
 781                                 }
 782                         }
 783                         if(head.team == COLOR_TEAM4)
 784                         {
 785                                 if(c4 >= 0)
 786                                 {
 787                                         c4 = c4 + value;
 788                                         cb4 = cb4 + bvalue;
 789                                 }
 790                         }
 791                 }
 792         }
 793 }
 794
 795 // returns # of smallest team (1, 2, 3, 4)
 796 // NOTE: Assumes CheckAllowedTeams has already been called!
 797 float FindSmallestTeam(entity pl, float ignore_pl)
 798 {
 799         float totalteams, balance_type, maxc;
 800         totalteams = 0;
 801
 802         // find out what teams are available
 803         //CheckAllowedTeams();
 804
 805         // make sure there are at least 2 teams to join
 806         if(c1 >= 0)
 807                 totalteams = totalteams + 1;
 808         if(c2 >= 0)
 809                 totalteams = totalteams + 1;
 810         if(c3 >= 0)
 811                 totalteams = totalteams + 1;
 812         if(c4 >= 0)
 813                 totalteams = totalteams + 1;
 814
 815         if((cvar("bot_vs_human") || pl.team_forced > 0) && totalteams == 1)
 816                 totalteams += 1;
 817
 818         if(totalteams <= 1)
 819         {
 820                 if(cvar("g_campaign") && pl && clienttype(pl) == CLIENTTYPE_REAL)
 821                         return 1; // special case for campaign and player joining
 822                 else if(g_domination)
 823                         error("Too few teams available for domination\n");
 824                 else if(g_ctf)
 825                         error("Too few teams available for ctf\n");
 826                 else if(g_keyhunt)
 827                         error("Too few teams available for key hunt\n");
 828                 else
 829                         error("Too few teams available for team deathmatch\n");
 830         }
 831
 832         // count how many players are in each team
 833         if(ignore_pl)
 834                 GetTeamCounts(pl);
 835         else
 836                 GetTeamCounts(world);
 837
 838         // c1...c4 now have counts of each team
 839         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 840
 841         // 2 gives priority to what team you're already on, 1 goes in order
 842         // 2 doesn't seem to work though...
 843         balance_type = 1;
 844
 845         if(bots_would_leave)
 846         //if(pl.classname != "player")
 847         if(clienttype(pl) != CLIENTTYPE_BOT)
 848         {
 849                 c1 -= cb1 * 255.0/256.0;
 850                 c2 -= cb2 * 255.0/256.0;
 851                 c3 -= cb3 * 255.0/256.0;
 852                 c4 -= cb4 * 255.0/256.0;
 853         }
 854         maxc = max4(c1, c2, c3, c4);
 855
 856         RandomSelection_Init();
 857         if(balance_type == 1)
 858         {
 859                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 860                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 861                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 862                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 863                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 864         }
 865         else if(balance_type == 2)
 866         {
 867                 // 1: use team count, if equal prefer own team
 868                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 869                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 870                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 871                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 872         }
 873         else if(balance_type == 3)
 874         {
 875                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 876                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 877                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 878                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 879                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 880         }
 881         return RandomSelection_chosen_float;
 882 }
 883
 884 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 885 {
 886         float smallest, selectedteam;
 887
 888         // don't join a team if we're not playing a team game
 889         if(!teams_matter)
 890                 return 0;
 891
 892         // find out what teams are available
 893         CheckAllowedTeams(pl);
 894
 895         // if we want the player in a certain team for campaign, force him there
 896         if(cvar("g_campaign"))
 897         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
 898         {
 899                 switch(cvar("g_campaign_forceteam"))
 900                 {
 901                         case 1:
 902                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
 903                                 LogTeamchange(pl.playerid, pl.team, 2);
 904                                 return COLOR_TEAM1;
 905                         case 2:
 906                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
 907                                 LogTeamchange(pl.playerid, pl.team, 2);
 908                                 return COLOR_TEAM2;
 909                         case 3:
 910                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
 911                                 LogTeamchange(pl.playerid, pl.team, 2);
 912                                 return COLOR_TEAM3;
 913                         case 4:
 914                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
 915                                 LogTeamchange(pl.playerid, pl.team, 2);
 916                                 return COLOR_TEAM4;
 917                         default:
 918                                 break;
 919                 }
 920         }
 921
 922         // if we don't care what team he ends up on, put him on whatever team he entered as.
 923         // if he's not on a valid team, then let other code put him on the smallest team
 924         if(!forcebestteam)
 925         {
 926                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 927                         selectedteam = pl.team;
 928                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 929                         selectedteam = pl.team;
 930                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 931                         selectedteam = pl.team;
 932                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 933                         selectedteam = pl.team;
 934                 else
 935                         selectedteam = -1;
 936
 937                 if(selectedteam > 0)
 938                 {
 939                         if(!only_return_best)
 940                         {
 941                                 SetPlayerColors(pl, selectedteam - 1);
 942
 943                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 944                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 945                                 LogTeamchange(pl.playerid, pl.team, 99);
 946                         }
 947                         return selectedteam;
 948                 }
 949                 // otherwise end up on the smallest team (handled below)
 950         }
 951
 952         smallest = FindSmallestTeam(pl, TRUE);
 953
 954         if(!only_return_best && !pl.bot_forced_team)
 955         {
 956                 TeamchangeFrags(self);
 957                 if(smallest == 1)
 958                 {
 959                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 960                 }
 961                 else if(smallest == 2)
 962                 {
 963                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 964                 }
 965                 else if(smallest == 3)
 966                 {
 967                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 968                 }
 969                 else if(smallest == 4)
 970                 {
 971                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 972                 }
 973                 else
 974                 {
 975                         error("smallest team: invalid team\n");
 976                 }
 977
 978                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 979
 980                 if(pl.deadflag == DEAD_NO)
 981                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 982         }
 983
 984         return smallest;
 985 }
 986
 987 //void() ctf_playerchanged;
 988 void SV_ChangeTeam(float _color)
 989 {
 990         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 991
 992         // in normal deathmatch we can just apply the color and we're done
 993         if(!teams_matter) {
 994                 SetPlayerColors(self, _color);
 995                 return;
 996         }
 997
 998         scolor = self.clientcolors & 0x0F;
 999         dcolor = _color & 0x0F;
1000
1001         if(scolor == COLOR_TEAM1 - 1)
1002                 steam = 1;
1003         else if(scolor == COLOR_TEAM2 - 1)
1004                 steam = 2;
1005         else if(scolor == COLOR_TEAM3 - 1)
1006                 steam = 3;
1007         else // if(scolor == COLOR_TEAM4 - 1)
1008                 steam = 4;
1009         if(dcolor == COLOR_TEAM1 - 1)
1010                 dteam = 1;
1011         else if(dcolor == COLOR_TEAM2 - 1)
1012                 dteam = 2;
1013         else if(dcolor == COLOR_TEAM3 - 1)
1014                 dteam = 3;
1015         else // if(dcolor == COLOR_TEAM4 - 1)
1016                 dteam = 4;
1017
1018         CheckAllowedTeams(self);
1019
1020         if(dteam == 1 && c1 < 0) dteam = 4;
1021         if(dteam == 4 && c4 < 0) dteam = 3;
1022         if(dteam == 3 && c3 < 0) dteam = 2;
1023         if(dteam == 2 && c2 < 0) dteam = 1;
1024
1025         // not changing teams
1026         if(scolor == dcolor)
1027         {
1028                 //bprint("same team change\n");
1029                 SetPlayerTeam(self, dteam, steam, TRUE);
1030                 return;
1031         }
1032
1033         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
1034                 sprint(self, "Team changes not allowed\n");
1035                 return; // changing teams is not allowed
1036         }
1037
1038         if(cvar("g_balance_teams_prevent_imbalance"))
1039         {
1040                 // only allow changing to a smaller or equal size team
1041
1042                 // find out what teams are available
1043                 //CheckAllowedTeams();
1044                 // count how many players on each team
1045                 GetTeamCounts(world);
1046
1047                 // get desired team
1048                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1049                 {
1050                         dcount = c1;
1051                         dbotcount = cb1;
1052                 }
1053                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1054                 {
1055                         dcount = c2;
1056                         dbotcount = cb2;
1057                 }
1058                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1059                 {
1060                         dcount = c3;
1061                         dbotcount = cb3;
1062                 }
1063                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1064                 {
1065                         dcount = c4;
1066                         dbotcount = cb4;
1067                 }
1068                 else
1069                 {
1070                         sprint(self, "Cannot change to an invalid team\n");
1071
1072                         return;
1073                 }
1074
1075                 // get starting team
1076                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1077                         scount = c1;
1078                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1079                         scount = c2;
1080                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1081                         scount = c3;
1082                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1083                         scount = c4;
1084
1085                 if(scount) // started at a valid, nonempty team
1086                 {
1087                         // check if we're trying to change to a larger team that doens't have bots to swap with
1088                         if(dcount >= scount && dbotcount <= 0)
1089                         {
1090                                 sprint(self, "Cannot change to a larger team\n");
1091                                 return; // can't change to a larger team
1092                         }
1093                 }
1094         }
1095
1096 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1097
1098         if(self.classname == "player" && steam != dteam)
1099         {
1100                 // reduce frags during a team change
1101                 TeamchangeFrags(self);
1102         }
1103
1104         SetPlayerTeam(self, dteam, steam, FALSE);
1105
1106         if(self.classname == "player" && steam != dteam)
1107         {
1108                 // kill player when changing teams
1109                 if(self.deadflag == DEAD_NO)
1110                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1111         }
1112         //ctf_playerchanged();
1113 }
1114
1115 void ShufflePlayerOutOfTeam (float source_team)
1116 {
1117         float smallestteam, smallestteam_count, steam;
1118         float lowest_bot_score, lowest_player_score;
1119         entity head, lowest_bot, lowest_player, selected;
1120
1121         smallestteam = 0;
1122         smallestteam_count = 999999999;
1123
1124         if(c1 >= 0 && c1 < smallestteam_count)
1125         {
1126                 smallestteam = 1;
1127                 smallestteam_count = c1;
1128         }
1129         if(c2 >= 0 && c2 < smallestteam_count)
1130         {
1131                 smallestteam = 2;
1132                 smallestteam_count = c2;
1133         }
1134         if(c3 >= 0 && c3 < smallestteam_count)
1135         {
1136                 smallestteam = 3;
1137                 smallestteam_count = c3;
1138         }
1139         if(c4 >= 0 && c4 < smallestteam_count)
1140         {
1141                 smallestteam = 4;
1142                 smallestteam_count = c4;
1143         }
1144
1145         if(!smallestteam)
1146         {
1147                 bprint("warning: no smallest team\n");
1148                 return;
1149         }
1150
1151         if(source_team == 1)
1152                 steam = COLOR_TEAM1;
1153         else if(source_team == 2)
1154                 steam = COLOR_TEAM2;
1155         else if(source_team == 3)
1156                 steam = COLOR_TEAM3;
1157         else if(source_team == 4)
1158                 steam = COLOR_TEAM4;
1159
1160         lowest_bot = world;
1161         lowest_bot_score = 999999999;
1162         lowest_player = world;
1163         lowest_player_score = 999999999;
1164
1165         // find the lowest-scoring player & bot of that team
1166         FOR_EACH_PLAYER(head)
1167         {
1168                 if(head.team == steam)
1169                 {
1170                         if(head.isbot)
1171                         {
1172                                 if(head.totalfrags < lowest_bot_score)
1173                                 {
1174                                         lowest_bot = head;
1175                                         lowest_bot_score = head.totalfrags;
1176                                 }
1177                         }
1178                         else
1179                         {
1180                                 if(head.totalfrags < lowest_player_score)
1181                                 {
1182                                         lowest_player = head;
1183                                         lowest_player_score = head.totalfrags;
1184                                 }
1185                         }
1186                 }
1187         }
1188
1189         // prefers to move a bot...
1190         if(lowest_bot != world)
1191                 selected = lowest_bot;
1192         // but it will move a player if it has to
1193         else
1194                 selected = lowest_player;
1195         // don't do anything if it couldn't find anyone
1196         if(!selected)
1197         {
1198                 bprint("warning: couldn't find a player to move from team\n");
1199                 return;
1200         }
1201
1202         // smallest team gains a member
1203         if(smallestteam == 1)
1204         {
1205                 c1 = c1 + 1;
1206         }
1207         else if(smallestteam == 2)
1208         {
1209                 c2 = c2 + 1;
1210         }
1211         else if(smallestteam == 3)
1212         {
1213                 c3 = c3 + 1;
1214         }
1215         else if(smallestteam == 4)
1216         {
1217                 c4 = c4 + 1;
1218         }
1219         else
1220         {
1221                 bprint("warning: destination team invalid\n");
1222                 return;
1223         }
1224         // source team loses a member
1225         if(source_team == 1)
1226         {
1227                 c1 = c1 + 1;
1228         }
1229         else if(source_team == 2)
1230         {
1231                 c2 = c2 + 2;
1232         }
1233         else if(source_team == 3)
1234         {
1235                 c3 = c3 + 3;
1236         }
1237         else if(source_team == 4)
1238         {
1239                 c4 = c4 + 4;
1240         }
1241         else
1242         {
1243                 bprint("warning: source team invalid\n");
1244                 return;
1245         }
1246
1247         // move the player to the new team
1248         TeamchangeFrags(selected);
1249         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1250
1251         if(selected.deadflag == DEAD_NO)
1252                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1253         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1254 }
1255
1256 void CauseRebalance(float source_team, float howmany_toomany)
1257 {
1258         if(IsTeamBalanceForced() == 1)
1259         {
1260                 bprint("Rebalancing Teams\n");
1261                 ShufflePlayerOutOfTeam(source_team);
1262         }
1263 }
1264
1265 // part of g_balance_teams_force
1266 // occasionally perform an audit of the teams to make
1267 // sure they're more or less balanced in player count.
1268 void AuditTeams()
1269 {
1270         float numplayers, numteams, smallest, toomany;
1271         float balance;
1272         balance = IsTeamBalanceForced();
1273         if(balance == 0)
1274                 return;
1275
1276         if(audit_teams_time > time)
1277                 return;
1278
1279         audit_teams_time = time + 4 + random();
1280
1281 //      bprint("Auditing teams\n");
1282
1283         CheckAllowedTeams(world);
1284         GetTeamCounts(world);
1285
1286
1287         numteams = numplayers = smallest = 0;
1288         if(c1 >= 0)
1289         {
1290                 numteams = numteams + 1;
1291                 numplayers = numplayers + c1;
1292                 smallest = c1;
1293         }
1294         if(c2 >= 0)
1295         {
1296                 numteams = numteams + 1;
1297                 numplayers = numplayers + c2;
1298                 if(c2 < smallest)
1299                         smallest = c2;
1300         }
1301         if(c3 >= 0)
1302         {
1303                 numteams = numteams + 1;
1304                 numplayers = numplayers + c3;
1305                 if(c3 < smallest)
1306                         smallest = c3;
1307         }
1308         if(c4 >= 0)
1309         {
1310                 numteams = numteams + 1;
1311                 numplayers = numplayers + c4;
1312                 if(c4 < smallest)
1313                         smallest = c4;
1314         }
1315
1316         if(numplayers <= 0)
1317                 return; // no players to move around
1318         if(numteams < 2)
1319                 return; // don't bother shuffling if for some reason there aren't any teams
1320
1321         toomany = smallest + 1;
1322
1323         if(c1 && c1 > toomany)
1324                 CauseRebalance(1, c1 - toomany);
1325         if(c2 && c2 > toomany)
1326                 CauseRebalance(2, c2 - toomany);
1327         if(c3 && c3 > toomany)
1328                 CauseRebalance(3, c3 - toomany);
1329         if(c4 && c4 > toomany)
1330                 CauseRebalance(4, c4 - toomany);
1331
1332         // if teams are still unbalanced, balance them further in the next audit,
1333         // which will happen sooner (keep doing rapid audits until things are in order)
1334         audit_teams_time = time + 0.7 + random()*0.3;
1335 }
1336
1337 // code from here on is just to support maps that don't have team entities
1338 void tdm_spawnteam (string teamname, float teamcolor)
1339 {
1340         local entity e;
1341         e = spawn();
1342         e.classname = "tdm_team";
1343         e.netname = teamname;
1344         e.cnt = teamcolor;
1345         e.team = e.cnt + 1;
1346 };
1347
1348 // spawn some default teams if the map is not set up for tdm
1349 void tdm_spawnteams()
1350 {
1351         float numteams;
1352
1353         numteams = cvar("g_tdm_teams_override");
1354         if(numteams < 2)
1355                 numteams = cvar("g_tdm_teams");
1356         numteams = bound(2, numteams, 4);
1357
1358         tdm_spawnteam("Red", COLOR_TEAM1-1);
1359         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1360         if(numteams >= 3)
1361                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1362         if(numteams >= 4)
1363                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1364 };
1365
1366 void tdm_delayedinit()
1367 {
1368         // if no teams are found, spawn defaults
1369         if (find(world, classname, "tdm_team") == world)
1370                 tdm_spawnteams();
1371 };
1372
1373 void tdm_init()
1374 {
1375         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1376 };