qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void runematch_init();
  17 void tdm_init();
  18 void entcs_init();
  19
  20 void LogTeamchange(float player_id, float team_number, float type)
  21 {
  22         if(!autocvar_sv_eventlog)
  23                 return;
  24
  25         if(player_id < 1)
  26                 return;
  27
  28         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  29 }
  30
  31 void default_delayedinit()
  32 {
  33         if(!scores_initialized)
  34                 ScoreRules_generic();
  35 }
  36
  37 void ActivateTeamplay()
  38 {
  39         serverflags |= SERVERFLAG_TEAMPLAY;
  40         teamplay = 1;
  41 }
  42
  43 void InitGameplayMode()
  44 {
  45         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  46
  47         qualifying_override = -1;
  48
  49         VoteReset();
  50
  51         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  52         get_mi_min_max(1);
  53         world.mins = mi_min;
  54         world.maxs = mi_max;
  55
  56         MapInfo_LoadMapSettings(mapname);
  57         teamplay = 0;
  58         serverflags &~= SERVERFLAG_TEAMPLAY;
  59
  60         if not(cvar_value_issafe(world.fog))
  61         {
  62                 print("The current map contains a potentially harmful fog setting, ignored\n");
  63                 world.fog = string_null;
  64         }
  65         if(MapInfo_Map_fog != "")
  66                 if(MapInfo_Map_fog == "none")
  67                         world.fog = string_null;
  68                 else
  69                         world.fog = strzone(MapInfo_Map_fog);
  70         clientstuff = strzone(MapInfo_Map_clientstuff);
  71
  72         MapInfo_ClearTemps();
  73
  74         // set both here, gamemode can override it later
  75         timelimit_override = autocvar_timelimit_override;
  76         fraglimit_override = autocvar_fraglimit_override;
  77         leadlimit_override = autocvar_leadlimit_override;
  78         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  79
  80         if(g_dm)
  81         {
  82         }
  83
  84         if(g_tdm)
  85         {
  86                 ActivateTeamplay();
  87                 tdm_init();
  88                 if(autocvar_g_tdm_team_spawns)
  89                         have_team_spawns = -1; // request team spawns
  90         }
  91
  92         if(g_domination)
  93         {
  94                 ActivateTeamplay();
  95                 fraglimit_override = autocvar_g_domination_point_limit;
  96                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  97                 MUTATOR_ADD(gamemode_domination);
  98                 have_team_spawns = -1; // request team spawns
  99         }
 100
 101         if(g_ctf)
 102         {
 103                 ActivateTeamplay();
 104                 fraglimit_override = autocvar_capturelimit_override;
 105                 leadlimit_override = autocvar_captureleadlimit_override;
 106                 MUTATOR_ADD(gamemode_ctf);
 107                 have_team_spawns = -1; // request team spawns
 108         }
 109
 110         if(g_runematch)
 111         {
 112                 // ActivateTeamplay();
 113                 fraglimit_override = autocvar_g_runematch_point_limit;
 114                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 115                 runematch_init();
 116         }
 117
 118         if(g_lms)
 119         {
 120                 fraglimit_override = autocvar_g_lms_lives_override;
 121                 leadlimit_override = 0; // not supported by LMS
 122                 if(fraglimit_override == 0)
 123                         fraglimit_override = -1;
 124                 lms_lowest_lives = 9999;
 125                 lms_next_place = 0;
 126                 ScoreRules_lms();
 127         }
 128
 129         if(g_arena)
 130         {
 131                 fraglimit_override = autocvar_g_arena_point_limit;
 132                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 133                 maxspawned = autocvar_g_arena_maxspawned;
 134                 if(maxspawned < 2)
 135                         maxspawned = 2;
 136                 arena_roundbased = autocvar_g_arena_roundbased;
 137         }
 138
 139         if(g_ca)
 140         {
 141                 ActivateTeamplay();
 142                 fraglimit_override = autocvar_g_ca_point_limit;
 143                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 144                 precache_sound("ctf/red_capture.wav");
 145                 precache_sound("ctf/blue_capture.wav");
 146         }
 147         if(g_keyhunt)
 148         {
 149                 ActivateTeamplay();
 150                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 151                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 152                 MUTATOR_ADD(gamemode_keyhunt);
 153         }
 154
 155         if(g_freezetag)
 156         {
 157                 ActivateTeamplay();
 158                 fraglimit_override = autocvar_g_freezetag_point_limit;
 159                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 160                 MUTATOR_ADD(gamemode_freezetag);
 161         }
 162
 163         if(g_assault)
 164         {
 165                 ActivateTeamplay();
 166                 ScoreRules_assault();
 167                 have_team_spawns = -1; // request team spawns
 168         }
 169
 170         if(g_onslaught)
 171         {
 172                 ActivateTeamplay();
 173                 have_team_spawns = -1; // request team spawns
 174                 MUTATOR_ADD(gamemode_onslaught);
 175         }
 176
 177         if(g_race)
 178         {
 179
 180                 if(autocvar_g_race_teams)
 181                 {
 182                         ActivateTeamplay();
 183                         race_teams = bound(2, autocvar_g_race_teams, 4);
 184                         have_team_spawns = -1; // request team spawns
 185                 }
 186                 else
 187                         race_teams = 0;
 188
 189                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 190                 fraglimit_override = autocvar_g_race_laps_limit;
 191                 leadlimit_override = 0; // currently not supported by race
 192         }
 193
 194         if(g_cts)
 195         {
 196                 g_race_qualifying = 1;
 197                 fraglimit_override = 0;
 198                 leadlimit_override = 0;
 199         }
 200
 201         if(g_nexball)
 202         {
 203         fraglimit_override = autocvar_g_nexball_goallimit;
 204         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 205         ActivateTeamplay();
 206         have_team_spawns = -1; // request team spawns
 207             MUTATOR_ADD(gamemode_nexball);
 208         }
 209
 210         if(g_keepaway)
 211         {
 212                 MUTATOR_ADD(gamemode_keepaway);
 213         }
 214
 215         if(teamplay)
 216                 entcs_init();
 217
 218         cache_mutatormsg = strzone("");
 219         cache_lastmutatormsg = strzone("");
 220
 221         // enforce the server's universal frag/time limits
 222         if(!autocvar_g_campaign)
 223         {
 224                 if(fraglimit_override >= 0)
 225                         cvar_set("fraglimit", ftos(fraglimit_override));
 226                 if(timelimit_override >= 0)
 227                         cvar_set("timelimit", ftos(timelimit_override));
 228                 if(leadlimit_override >= 0)
 229                         cvar_set("leadlimit", ftos(leadlimit_override));
 230                 if(qualifying_override >= 0)
 231                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 232         }
 233
 234         if(g_race)
 235         {
 236                 // we need to find out the correct value for g_race_qualifying
 237                 if(autocvar_g_campaign)
 238                 {
 239                         g_race_qualifying = 1;
 240                 }
 241                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 242                 {
 243                         g_race_qualifying = 2;
 244                         race_fraglimit = autocvar_fraglimit;
 245                         race_leadlimit = autocvar_leadlimit;
 246                         race_timelimit = autocvar_timelimit;
 247                         cvar_set("fraglimit", "0");
 248                         cvar_set("leadlimit", "0");
 249                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 250                 }
 251                 else
 252                         g_race_qualifying = 0;
 253         }
 254
 255         if(g_race || g_cts)
 256         {
 257                 if(g_race_qualifying)
 258                         independent_players = 1;
 259
 260                 ScoreRules_race();
 261         }
 262
 263         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 264 }
 265
 266 string GetClientVersionMessage() {
 267         string versionmsg;
 268         if (self.version_mismatch) {
 269                 if(self.version < autocvar_gameversion) {
 270                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 271                 } else {
 272                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 273                 }
 274         } else {
 275                 versionmsg = "^2client version and server version are compatible.^8";
 276         }
 277         return versionmsg;
 278 }
 279
 280 string getwelcomemessage(void)
 281 {
 282         string s, modifications, motd;
 283
 284         ret_string = "";
 285         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 286         modifications = ret_string;
 287
 288         if(g_minstagib)
 289                 modifications = strcat(modifications, ", MinstaGib");
 290         if(g_weaponarena)
 291         {
 292                 if(g_weaponarena_random)
 293                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 294                 else
 295                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 296         }
 297         if(autocvar_g_start_weapon_laser == 0)
 298                 modifications = strcat(modifications, ", No start weapons");
 299         if(autocvar_sv_gravity < 800)
 300                 modifications = strcat(modifications, ", Low gravity");
 301         if(g_cloaked && !g_cts)
 302                 modifications = strcat(modifications, ", Cloaked");
 303         if(g_grappling_hook)
 304                 modifications = strcat(modifications, ", Hook");
 305         if(g_midair)
 306                 modifications = strcat(modifications, ", Midair");
 307         if(g_pinata)
 308                 modifications = strcat(modifications, ", Piñata");
 309         if(g_weapon_stay && !g_cts)
 310                 modifications = strcat(modifications, ", Weapons stay");
 311         if(g_bloodloss > 0)
 312                 modifications = strcat(modifications, ", Blood loss");
 313         if(g_jetpack)
 314                 modifications = strcat(modifications, ", Jet pack");
 315         if(autocvar_g_powerups == 0)
 316                 modifications = strcat(modifications, ", No powerups");
 317         if(autocvar_g_powerups > 0)
 318                 modifications = strcat(modifications, ", Powerups");
 319         modifications = substring(modifications, 2, strlen(modifications) - 2);
 320
 321         string versionmessage;
 322         versionmessage = GetClientVersionMessage();
 323
 324         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 325         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 326
 327         if(modifications != "")
 328                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 329
 330         if (g_grappling_hook)
 331                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 332
 333         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 334         {
 335                 if(cache_lastmutatormsg)
 336                         strunzone(cache_lastmutatormsg);
 337                 if(cache_mutatormsg)
 338                         strunzone(cache_mutatormsg);
 339                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 340                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 341         }
 342
 343         if (cache_mutatormsg != "") {
 344                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 345         }
 346
 347         motd = autocvar_sv_motd;
 348         if (motd != "") {
 349                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 350         }
 351         return s;
 352 }
 353
 354 void SetPlayerColors(entity pl, float _color)
 355 {
 356         /*string s;
 357         s = ftos(cl);
 358         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 359         pl.team = cl + 1;
 360         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 361         pl.clientcolors = 16*cl + cl;*/
 362
 363         float pants, shirt;
 364         pants = _color & 0x0F;
 365         shirt = _color & 0xF0;
 366
 367
 368         if(teamplay) {
 369                 setcolor(pl, 16*pants + pants);
 370         } else {
 371                 setcolor(pl, shirt + pants);
 372         }
 373 }
 374
 375 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 376 {
 377         float _color;
 378
 379         if(t == 4)
 380                 _color = FL_TEAM_4 - 1;
 381         else if(t == 3)
 382                 _color = FL_TEAM_3 - 1;
 383         else if(t == 2)
 384                 _color = FL_TEAM_2 - 1;
 385         else
 386                 _color = FL_TEAM_1 - 1;
 387
 388         SetPlayerColors(pl,_color);
 389
 390         if(t != s) {
 391                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 392
 393                 if(!noprint)
 394                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 395         }
 396
 397 }
 398
 399 // set c1...c4 to show what teams are allowed
 400 void CheckAllowedTeams (entity for_whom)
 401 {
 402         float dm;
 403         entity head;
 404         string teament_name;
 405
 406         c1 = c2 = c3 = c4 = -1;
 407         cb1 = cb2 = cb3 = cb4 = 0;
 408
 409         teament_name = string_null;
 410         if(g_onslaught)
 411         {
 412                 // onslaught is special
 413                 head = findchain(classname, "onslaught_generator");
 414                 while (head)
 415                 {
 416                         if (head.team == FL_TEAM_1) c1 = 0;
 417                         if (head.team == FL_TEAM_2) c2 = 0;
 418                         if (head.team == FL_TEAM_3) c3 = 0;
 419                         if (head.team == FL_TEAM_4) c4 = 0;
 420                         head = head.chain;
 421                 }
 422         }
 423         else if(g_domination)
 424                 teament_name = "dom_team";
 425         else if(g_ctf)
 426                 teament_name = "ctf_team";
 427         else if(g_tdm)
 428                 teament_name = "tdm_team";
 429         else if(g_nexball)
 430                 teament_name = "nexball_team";
 431         else if(g_assault)
 432                 c1 = c2 = 0; // Assault always has 2 teams
 433         else
 434         {
 435                 // cover anything else by treating it like tdm with no teams spawned
 436                 if(g_race)
 437                         dm = race_teams;
 438                 else
 439                         dm = 2;
 440
 441                 ret_float = dm;
 442                 MUTATOR_CALLHOOK(GetTeamCount);
 443                 dm = ret_float;
 444
 445                 if(dm >= 4)
 446                         c1 = c2 = c3 = c4 = 0;
 447                 else if(dm >= 3)
 448                         c1 = c2 = c3 = 0;
 449                 else
 450                         c1 = c2 = 0;
 451         }
 452
 453         // find out what teams are allowed if necessary
 454         if(teament_name)
 455         {
 456                 head = find(world, classname, teament_name);
 457                 while(head)
 458                 {
 459                         if(!(g_domination && head.netname == ""))
 460                         {
 461                                 if(head.team == FL_TEAM_1)
 462                                         c1 = 0;
 463                                 else if(head.team == FL_TEAM_2)
 464                                         c2 = 0;
 465                                 else if(head.team == FL_TEAM_3)
 466                                         c3 = 0;
 467                                 else if(head.team == FL_TEAM_4)
 468                                         c4 = 0;
 469                         }
 470                         head = find(head, classname, teament_name);
 471                 }
 472         }
 473
 474         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 475         if(c3==-1 && c4==-1)
 476         if(autocvar_bot_vs_human && for_whom)
 477         {
 478                 if(autocvar_bot_vs_human > 0)
 479                 {
 480                         // bots are all blue
 481                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 482                                 c1 = c3 = c4 = -1;
 483                         else
 484                                 c2 = -1;
 485                 }
 486                 else
 487                 {
 488                         // bots are all red
 489                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 490                                 c2 = c3 = c4 = -1;
 491                         else
 492                                 c1 = -1;
 493                 }
 494         }
 495
 496         // if player has a forced team, ONLY allow that one
 497         if(self.team_forced == FL_TEAM_1 && c1 >= 0)
 498                 c2 = c3 = c4 = -1;
 499         else if(self.team_forced == FL_TEAM_2 && c2 >= 0)
 500                 c1 = c3 = c4 = -1;
 501         else if(self.team_forced == FL_TEAM_3 && c3 >= 0)
 502                 c1 = c2 = c4 = -1;
 503         else if(self.team_forced == FL_TEAM_4 && c4 >= 0)
 504                 c1 = c2 = c3 = -1;
 505 }
 506
 507 float PlayerValue(entity p)
 508 {
 509         return 1;
 510         // FIXME: it always returns 1...
 511 }
 512
 513 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 514 // teams that are allowed will now have their player counts stored in c1...c4
 515 void GetTeamCounts(entity ignore)
 516 {
 517         entity head;
 518         float value, bvalue;
 519         // now count how many players are on each team already
 520
 521         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 522         // also remember the lowest-scoring player
 523
 524         FOR_EACH_CLIENT(head)
 525         {
 526                 float t;
 527                 if(head.classname == "player")
 528                         t = head.team;
 529                 else if(head.team_forced > 0)
 530                         t = head.team_forced; // reserve the spot
 531                 else
 532                         continue;
 533                 if(head != ignore)// && head.netname != "")
 534                 {
 535                         value = PlayerValue(head);
 536                         if(clienttype(head) == CLIENTTYPE_BOT)
 537                                 bvalue = value;
 538                         else
 539                                 bvalue = 0;
 540                         if(t == FL_TEAM_1)
 541                         {
 542                                 if(c1 >= 0)
 543                                 {
 544                                         c1 = c1 + value;
 545                                         cb1 = cb1 + bvalue;
 546                                 }
 547                         }
 548                         if(t == FL_TEAM_2)
 549                         {
 550                                 if(c2 >= 0)
 551                                 {
 552                                         c2 = c2 + value;
 553                                         cb2 = cb2 + bvalue;
 554                                 }
 555                         }
 556                         if(t == FL_TEAM_3)
 557                         {
 558                                 if(c3 >= 0)
 559                                 {
 560                                         c3 = c3 + value;
 561                                         cb3 = cb3 + bvalue;
 562                                 }
 563                         }
 564                         if(t == FL_TEAM_4)
 565                         {
 566                                 if(c4 >= 0)
 567                                 {
 568                                         c4 = c4 + value;
 569                                         cb4 = cb4 + bvalue;
 570                                 }
 571                         }
 572                 }
 573         }
 574
 575         // if the player who has a forced team has not joined yet, reserve the spot
 576         if(autocvar_g_campaign)
 577         {
 578                 switch(autocvar_g_campaign_forceteam)
 579                 {
 580                         case 1: if(c1 == cb1) ++c1; break;
 581                         case 2: if(c2 == cb2) ++c2; break;
 582                         case 3: if(c3 == cb3) ++c3; break;
 583                         case 4: if(c4 == cb4) ++c4; break;
 584                 }
 585         }
 586 }
 587
 588 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 589 {
 590         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 591         float f;
 592         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 593
 594         switch(ta)
 595         {
 596                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 597                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 598                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 599                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 600         }
 601         switch(tb)
 602         {
 603                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 604                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 605                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 606                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 607         }
 608
 609         // invalid
 610         if(ca < 0 || cb < 0)
 611                 return FALSE;
 612
 613         // equal
 614         if(ta == tb)
 615                 return TRUE;
 616
 617         if(clienttype(e) == CLIENTTYPE_REAL)
 618         {
 619                 if(bots_would_leave)
 620                 {
 621                         ca -= cba * 0.999;
 622                         cb -= cbb * 0.999;
 623                 }
 624         }
 625
 626         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 627         if(ca < 1)
 628                 if(cb >= 1)
 629                         return TRUE;
 630         if(ca >= 1)
 631                 if(cb < 1)
 632                         return FALSE;
 633
 634         // first, normalize
 635         f = max(ca, cb, 1);
 636         ca /= f;
 637         cb /= f;
 638         f = max(sa, sb, 1);
 639         sa /= f;
 640         sb /= f;
 641
 642         // the more we're at the end of the match, the more take scores into account
 643         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 644         ca += (sa - ca) * f;
 645         cb += (sb - cb) * f;
 646
 647         return ca <= cb;
 648 }
 649
 650 // returns # of smallest team (1, 2, 3, 4)
 651 // NOTE: Assumes CheckAllowedTeams has already been called!
 652 float FindSmallestTeam(entity pl, float ignore_pl)
 653 {
 654         float totalteams, t;
 655         totalteams = 0;
 656
 657         // find out what teams are available
 658         //CheckAllowedTeams();
 659
 660         // make sure there are at least 2 teams to join
 661         if(c1 >= 0)
 662                 totalteams = totalteams + 1;
 663         if(c2 >= 0)
 664                 totalteams = totalteams + 1;
 665         if(c3 >= 0)
 666                 totalteams = totalteams + 1;
 667         if(c4 >= 0)
 668                 totalteams = totalteams + 1;
 669
 670         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 671                 totalteams += 1;
 672
 673         if(totalteams <= 1)
 674         {
 675                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 676                         return 1; // special case for campaign and player joining
 677                 else if(g_domination)
 678                         error("Too few teams available for domination\n");
 679                 else if(g_ctf)
 680                         error("Too few teams available for ctf\n");
 681                 else if(g_keyhunt)
 682                         error("Too few teams available for key hunt\n");
 683                 else if(g_freezetag)
 684                         error("Too few teams available for freeze tag\n");
 685                 else
 686                         error("Too few teams available for team deathmatch\n");
 687         }
 688
 689         // count how many players are in each team
 690         if(ignore_pl)
 691                 GetTeamCounts(pl);
 692         else
 693                 GetTeamCounts(world);
 694
 695         RandomSelection_Init();
 696
 697         t = 1;
 698         if(TeamSmallerEqThanTeam(2, t, pl))
 699                 t = 2;
 700         if(TeamSmallerEqThanTeam(3, t, pl))
 701                 t = 3;
 702         if(TeamSmallerEqThanTeam(4, t, pl))
 703                 t = 4;
 704
 705         // now t is the minimum, or A minimum!
 706         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 707                 RandomSelection_Add(world, 1, string_null, 1, 1);
 708         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 709                 RandomSelection_Add(world, 2, string_null, 1, 1);
 710         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 711                 RandomSelection_Add(world, 3, string_null, 1, 1);
 712         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 713                 RandomSelection_Add(world, 4, string_null, 1, 1);
 714
 715         return RandomSelection_chosen_float;
 716 }
 717
 718 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 719 {
 720         float smallest, selectedteam;
 721
 722         // don't join a team if we're not playing a team game
 723         if(!teamplay)
 724                 return 0;
 725
 726         // find out what teams are available
 727         CheckAllowedTeams(pl);
 728
 729         // if we don't care what team he ends up on, put him on whatever team he entered as.
 730         // if he's not on a valid team, then let other code put him on the smallest team
 731         if(!forcebestteam)
 732         {
 733                 if(     c1 >= 0 && pl.team == FL_TEAM_1)
 734                         selectedteam = pl.team;
 735                 else if(c2 >= 0 && pl.team == FL_TEAM_2)
 736                         selectedteam = pl.team;
 737                 else if(c3 >= 0 && pl.team == FL_TEAM_3)
 738                         selectedteam = pl.team;
 739                 else if(c4 >= 0 && pl.team == FL_TEAM_4)
 740                         selectedteam = pl.team;
 741                 else
 742                         selectedteam = -1;
 743
 744                 if(selectedteam > 0)
 745                 {
 746                         if(!only_return_best)
 747                         {
 748                                 SetPlayerColors(pl, selectedteam - 1);
 749
 750                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 751                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 752                                 LogTeamchange(pl.playerid, pl.team, 99);
 753                         }
 754                         return selectedteam;
 755                 }
 756                 // otherwise end up on the smallest team (handled below)
 757         }
 758
 759         smallest = FindSmallestTeam(pl, TRUE);
 760
 761         if(!only_return_best && !pl.bot_forced_team)
 762         {
 763                 TeamchangeFrags(self);
 764                 if(smallest == 1)
 765                 {
 766                         SetPlayerColors(pl, FL_TEAM_1 - 1);
 767                 }
 768                 else if(smallest == 2)
 769                 {
 770                         SetPlayerColors(pl, FL_TEAM_2 - 1);
 771                 }
 772                 else if(smallest == 3)
 773                 {
 774                         SetPlayerColors(pl, FL_TEAM_3 - 1);
 775                 }
 776                 else if(smallest == 4)
 777                 {
 778                         SetPlayerColors(pl, FL_TEAM_4 - 1);
 779                 }
 780                 else
 781                 {
 782                         error("smallest team: invalid team\n");
 783                 }
 784
 785                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 786
 787                 if(pl.deadflag == DEAD_NO)
 788                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 789         }
 790
 791         return smallest;
 792 }
 793
 794 //void() ctf_playerchanged;
 795 void SV_ChangeTeam(float _color)
 796 {
 797         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 798
 799         // in normal deathmatch we can just apply the color and we're done
 800         if(!teamplay) {
 801                 SetPlayerColors(self, _color);
 802                 return;
 803         }
 804
 805         scolor = self.clientcolors & 0x0F;
 806         dcolor = _color & 0x0F;
 807
 808         if(scolor == FL_TEAM_1 - 1)
 809                 steam = 1;
 810         else if(scolor == FL_TEAM_2 - 1)
 811                 steam = 2;
 812         else if(scolor == FL_TEAM_3 - 1)
 813                 steam = 3;
 814         else // if(scolor == FL_TEAM_4 - 1)
 815                 steam = 4;
 816         if(dcolor == FL_TEAM_1 - 1)
 817                 dteam = 1;
 818         else if(dcolor == FL_TEAM_2 - 1)
 819                 dteam = 2;
 820         else if(dcolor == FL_TEAM_3 - 1)
 821                 dteam = 3;
 822         else // if(dcolor == FL_TEAM_4 - 1)
 823                 dteam = 4;
 824
 825         CheckAllowedTeams(self);
 826
 827         if(dteam == 1 && c1 < 0) dteam = 4;
 828         if(dteam == 4 && c4 < 0) dteam = 3;
 829         if(dteam == 3 && c3 < 0) dteam = 2;
 830         if(dteam == 2 && c2 < 0) dteam = 1;
 831
 832         // not changing teams
 833         if(scolor == dcolor)
 834         {
 835                 //bprint("same team change\n");
 836                 SetPlayerTeam(self, dteam, steam, TRUE);
 837                 return;
 838         }
 839
 840         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 841                 sprint(self, "Team changes not allowed\n");
 842                 return; // changing teams is not allowed
 843         }
 844
 845         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 846         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 847         {
 848                 GetTeamCounts(self);
 849                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 850                 {
 851                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 852                         return;
 853                 }
 854         }
 855
 856 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 857
 858         if(self.classname == "player" && steam != dteam)
 859         {
 860                 // reduce frags during a team change
 861                 TeamchangeFrags(self);
 862         }
 863
 864         SetPlayerTeam(self, dteam, steam, FALSE);
 865
 866         if(self.classname == "player" && steam != dteam)
 867         {
 868                 // kill player when changing teams
 869                 if(self.deadflag == DEAD_NO)
 870                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 871         }
 872 }
 873
 874 void ShufflePlayerOutOfTeam (float source_team)
 875 {
 876         float smallestteam, smallestteam_count, steam;
 877         float lowest_bot_score, lowest_player_score;
 878         entity head, lowest_bot, lowest_player, selected;
 879
 880         smallestteam = 0;
 881         smallestteam_count = 999999999;
 882
 883         if(c1 >= 0 && c1 < smallestteam_count)
 884         {
 885                 smallestteam = 1;
 886                 smallestteam_count = c1;
 887         }
 888         if(c2 >= 0 && c2 < smallestteam_count)
 889         {
 890                 smallestteam = 2;
 891                 smallestteam_count = c2;
 892         }
 893         if(c3 >= 0 && c3 < smallestteam_count)
 894         {
 895                 smallestteam = 3;
 896                 smallestteam_count = c3;
 897         }
 898         if(c4 >= 0 && c4 < smallestteam_count)
 899         {
 900                 smallestteam = 4;
 901                 smallestteam_count = c4;
 902         }
 903
 904         if(!smallestteam)
 905         {
 906                 bprint("warning: no smallest team\n");
 907                 return;
 908         }
 909
 910         if(source_team == 1)
 911                 steam = FL_TEAM_1;
 912         else if(source_team == 2)
 913                 steam = FL_TEAM_2;
 914         else if(source_team == 3)
 915                 steam = FL_TEAM_3;
 916         else // if(source_team == 4)
 917                 steam = FL_TEAM_4;
 918
 919         lowest_bot = world;
 920         lowest_bot_score = 999999999;
 921         lowest_player = world;
 922         lowest_player_score = 999999999;
 923
 924         // find the lowest-scoring player & bot of that team
 925         FOR_EACH_PLAYER(head)
 926         {
 927                 if(head.team == steam)
 928                 {
 929                         if(head.isbot)
 930                         {
 931                                 if(head.totalfrags < lowest_bot_score)
 932                                 {
 933                                         lowest_bot = head;
 934                                         lowest_bot_score = head.totalfrags;
 935                                 }
 936                         }
 937                         else
 938                         {
 939                                 if(head.totalfrags < lowest_player_score)
 940                                 {
 941                                         lowest_player = head;
 942                                         lowest_player_score = head.totalfrags;
 943                                 }
 944                         }
 945                 }
 946         }
 947
 948         // prefers to move a bot...
 949         if(lowest_bot != world)
 950                 selected = lowest_bot;
 951         // but it will move a player if it has to
 952         else
 953                 selected = lowest_player;
 954         // don't do anything if it couldn't find anyone
 955         if(!selected)
 956         {
 957                 bprint("warning: couldn't find a player to move from team\n");
 958                 return;
 959         }
 960
 961         // smallest team gains a member
 962         if(smallestteam == 1)
 963         {
 964                 c1 = c1 + 1;
 965         }
 966         else if(smallestteam == 2)
 967         {
 968                 c2 = c2 + 1;
 969         }
 970         else if(smallestteam == 3)
 971         {
 972                 c3 = c3 + 1;
 973         }
 974         else if(smallestteam == 4)
 975         {
 976                 c4 = c4 + 1;
 977         }
 978         else
 979         {
 980                 bprint("warning: destination team invalid\n");
 981                 return;
 982         }
 983         // source team loses a member
 984         if(source_team == 1)
 985         {
 986                 c1 = c1 + 1;
 987         }
 988         else if(source_team == 2)
 989         {
 990                 c2 = c2 + 2;
 991         }
 992         else if(source_team == 3)
 993         {
 994                 c3 = c3 + 3;
 995         }
 996         else if(source_team == 4)
 997         {
 998                 c4 = c4 + 4;
 999         }
1000         else
1001         {
1002                 bprint("warning: source team invalid\n");
1003                 return;
1004         }
1005
1006         // move the player to the new team
1007         TeamchangeFrags(selected);
1008         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1009
1010         if(selected.deadflag == DEAD_NO)
1011                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1012         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1013 }
1014
1015 // code from here on is just to support maps that don't have team entities
1016 void tdm_spawnteam (string teamname, float teamcolor)
1017 {
1018         entity e;
1019         e = spawn();
1020         e.classname = "tdm_team";
1021         e.netname = teamname;
1022         e.cnt = teamcolor;
1023         e.team = e.cnt + 1;
1024 }
1025
1026 // spawn some default teams if the map is not set up for tdm
1027 void tdm_spawnteams()
1028 {
1029         float numteams;
1030
1031         numteams = autocvar_g_tdm_teams_override;
1032         if(numteams < 2)
1033                 numteams = autocvar_g_tdm_teams;
1034         numteams = bound(2, numteams, 4);
1035
1036         tdm_spawnteam("Red", FL_TEAM_1-1);
1037         tdm_spawnteam("Blue", FL_TEAM_2-1);
1038         if(numteams >= 3)
1039                 tdm_spawnteam("Yellow", FL_TEAM_3-1);
1040         if(numteams >= 4)
1041                 tdm_spawnteam("Pink", FL_TEAM_4-1);
1042 }
1043
1044 void tdm_delayedinit()
1045 {
1046         // if no teams are found, spawn defaults
1047         if (find(world, classname, "tdm_team") == world)
1048                 tdm_spawnteams();
1049 }
1050
1051 void tdm_init()
1052 {
1053         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1054 }