qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2
   3 #include "client.qh"
   4 #include "race.qh"
   5 #include "scores.qh"
   6 #include "scores_rules.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/vote.qh"
  11
  12 #include "mutators/_mod.qh"
  13
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/gamemodes/_mod.qh"
  16 #include "../common/teams.qh"
  17
  18 /// \brief Describes a state of team balance entity.
  19 enum
  20 {
  21         TEAM_BALANCE_UNINITIALIZED, ///< The team balance has not been initialized.
  22         /// \brief TeamBalance_CheckAllowedTeams has been called.
  23         TEAM_BALANCE_TEAMS_CHECKED,
  24         /// \brief TeamBalance_GetTeamCounts has been called.
  25         TEAM_BALANCE_TEAM_COUNTS_FILLED
  26 };
  27
  28 /// \brief Indicates that the player is not allowed to join a team.
  29 const int TEAM_NOT_ALLOWED = -1;
  30
  31 .int m_team_balance_state; ///< Holds the state of the team balance entity.
  32 .entity m_team_balance_team[NUM_TEAMS]; ///< ???
  33
  34 .float m_team_score; ///< The score of the team.
  35 .int m_num_players; ///< Number of players (both humans and bots) in a team.
  36 .int m_num_bots; ///< Number of bots in a team.
  37 .entity m_lowest_human; ///< Human with the lowest score in a team.
  38 .entity m_lowest_bot; ///< Bot with the lowest score in a team.
  39
  40 entity g_team_entities[NUM_TEAMS]; ///< Holds global team entities.
  41
  42 STATIC_INIT(g_team_entities)
  43 {
  44         for (int i = 0; i < NUM_TEAMS; ++i)
  45         {
  46                 g_team_entities[i] = spawn();
  47         }
  48 }
  49
  50 entity Team_GetTeamFromIndex(int index)
  51 {
  52         if (!Team_IsValidIndex(index))
  53         {
  54                 LOG_FATALF("Team_GetTeamFromIndex: Index is invalid: %f", index);
  55         }
  56         return g_team_entities[index - 1];
  57 }
  58
  59 entity Team_GetTeam(int team_num)
  60 {
  61         if (!Team_IsValidTeam(team_num))
  62         {
  63                 LOG_FATALF("Team_GetTeam: Value is invalid: %f", team_num);
  64         }
  65         return g_team_entities[Team_TeamToIndex(team_num) - 1];
  66 }
  67
  68 float Team_GetTeamScore(entity team_)
  69 {
  70         return team_.m_team_score;
  71 }
  72
  73 void Team_SetTeamScore(entity team_, float score)
  74 {
  75         team_.m_team_score = score;
  76 }
  77
  78 void TeamchangeFrags(entity e)
  79 {
  80         PlayerScore_Clear(e);
  81 }
  82
  83 void LogTeamchange(float player_id, float team_number, float type)
  84 {
  85         if(!autocvar_sv_eventlog)
  86                 return;
  87
  88         if(player_id < 1)
  89                 return;
  90
  91         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  92 }
  93
  94 void default_delayedinit(entity this)
  95 {
  96         if(!scores_initialized)
  97                 ScoreRules_generic();
  98 }
  99
 100 void InitGameplayMode()
 101 {
 102         VoteReset();
 103
 104         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 105         get_mi_min_max(1);
 106         // assign reflectively to avoid "assignment to world" warning
 107         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 108             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 109             if (v) {
 110             putentityfieldstring(i, world, sprintf("%v", v));
 111             if (++done == 2) break;
 112         }
 113         }
 114         // currently, NetRadiant's limit is 131072 qu for each side
 115         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 116         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 117         // in case somebody makes extremely large maps
 118         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 119
 120         MapInfo_LoadMapSettings(mapname);
 121         GameRules_teams(false);
 122
 123         if (!cvar_value_issafe(world.fog))
 124         {
 125                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 126                 world.fog = string_null;
 127         }
 128         if(MapInfo_Map_fog != "")
 129                 if(MapInfo_Map_fog == "none")
 130                         world.fog = string_null;
 131                 else
 132                         world.fog = strzone(MapInfo_Map_fog);
 133         clientstuff = strzone(MapInfo_Map_clientstuff);
 134
 135         MapInfo_ClearTemps();
 136
 137         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 138
 139         cache_mutatormsg = strzone("");
 140         cache_lastmutatormsg = strzone("");
 141
 142         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 143 }
 144
 145 string GetClientVersionMessage(entity this)
 146 {
 147         if (CS(this).version_mismatch) {
 148                 if(CS(this).version < autocvar_gameversion) {
 149                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 150                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 151                 } else {
 152                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 153                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 154                 }
 155         } else {
 156                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 157         }
 158 }
 159
 160 string getwelcomemessage(entity this)
 161 {
 162         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 163         string modifications = M_ARGV(0, string);
 164
 165         if(g_weaponarena)
 166         {
 167                 if(g_weaponarena_random)
 168                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 169                 else
 170                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 171         }
 172         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
 173                 modifications = strcat(modifications, ", No start weapons");
 174         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 175                 modifications = strcat(modifications, ", Low gravity");
 176         if(g_weapon_stay && !g_cts)
 177                 modifications = strcat(modifications, ", Weapons stay");
 178         if(g_jetpack)
 179                 modifications = strcat(modifications, ", Jet pack");
 180         if(autocvar_g_powerups == 0)
 181                 modifications = strcat(modifications, ", No powerups");
 182         if(autocvar_g_powerups > 0)
 183                 modifications = strcat(modifications, ", Powerups");
 184         modifications = substring(modifications, 2, strlen(modifications) - 2);
 185
 186         string versionmessage = GetClientVersionMessage(this);
 187         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
 188
 189         if(modifications != "")
 190                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 191
 192         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 193         {
 194                 if(cache_lastmutatormsg)
 195                         strunzone(cache_lastmutatormsg);
 196                 if(cache_mutatormsg)
 197                         strunzone(cache_mutatormsg);
 198                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 199                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 200         }
 201
 202         if (cache_mutatormsg != "") {
 203                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 204         }
 205
 206         string mutator_msg = "";
 207         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
 208         mutator_msg = M_ARGV(0, string);
 209
 210         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
 211
 212         string motd = autocvar_sv_motd;
 213         if (motd != "") {
 214                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 215         }
 216         return s;
 217 }
 218
 219 void setcolor(entity this, int clr)
 220 {
 221 #if 0
 222         this.clientcolors = clr;
 223         this.team = (clr & 15) + 1;
 224 #else
 225         builtin_setcolor(this, clr);
 226 #endif
 227 }
 228
 229 void SetPlayerColors(entity player, float _color)
 230 {
 231         float pants = _color & 0x0F;
 232         float shirt = _color & 0xF0;
 233         if (teamplay)
 234         {
 235                 setcolor(player, 16 * pants + pants);
 236         }
 237         else
 238         {
 239                 setcolor(player, shirt + pants);
 240         }
 241 }
 242
 243 void KillPlayerForTeamChange(entity player)
 244 {
 245         if (IS_DEAD(player))
 246         {
 247                 return;
 248         }
 249         if (MUTATOR_CALLHOOK(Player_ChangeTeamKill, player) == true)
 250         {
 251                 return;
 252         }
 253         Damage(player, player, player, 100000, DEATH_TEAMCHANGE.m_id, DMG_NOWEP,
 254                 player.origin, '0 0 0');
 255 }
 256
 257 bool SetPlayerTeamSimple(entity player, int team_num)
 258 {
 259         if (player.team == team_num)
 260         {
 261                 // This is important when players join the game and one of their color
 262                 // matches the team color while other doesn't. For example [BOT]Lion.
 263                 SetPlayerColors(player, team_num - 1);
 264                 return true;
 265         }
 266         int old_team_index = Team_TeamToIndex(player.team);
 267         int new_team_index = Team_TeamToIndex(team_num);
 268         if (MUTATOR_CALLHOOK(Player_ChangeTeam, player, old_team_index,
 269                 new_team_index) == true)
 270         {
 271                 // Mutator has blocked team change.
 272                 return false;
 273         }
 274         SetPlayerColors(player, team_num - 1);
 275         MUTATOR_CALLHOOK(Player_ChangedTeam, player, old_team_index,
 276                 new_team_index);
 277         return true;
 278 }
 279
 280 bool SetPlayerTeam(entity player, int destination_team_index,
 281         int source_team_index, bool no_print)
 282 {
 283         int team_num = Team_IndexToTeam(destination_team_index);
 284         if (!SetPlayerTeamSimple(player, team_num))
 285         {
 286                 return false;
 287         }
 288         LogTeamchange(player.playerid, player.team, 3);  // log manual team join
 289         if (no_print)
 290         {
 291                 return true;
 292         }
 293         bprint(playername(player, false), "^7 has changed from ",
 294                 Team_IndexToColoredFullName(source_team_index), "^7 to ",
 295                 Team_IndexToColoredFullName(destination_team_index), "\n");
 296         return true;
 297 }
 298
 299 entity TeamBalance_CheckAllowedTeams(entity for_whom)
 300 {
 301         entity balance = spawn();
 302         for (int i = 0; i < NUM_TEAMS; ++i)
 303         {
 304                 entity team_ = balance.m_team_balance_team[i] = spawn();
 305                 team_.m_team_score = g_team_entities[i].m_team_score;
 306                 team_.m_num_players = TEAM_NOT_ALLOWED;
 307                 team_.m_num_bots = 0;
 308                 team_.m_lowest_human = NULL;
 309                 team_.m_lowest_bot = NULL;
 310         }
 311
 312         int teams_mask = 0;
 313         string teament_name = string_null;
 314         bool mutator_returnvalue = MUTATOR_CALLHOOK(TeamBalance_CheckAllowedTeams,
 315                 teams_mask, teament_name, for_whom);
 316         teams_mask = M_ARGV(0, float);
 317         teament_name = M_ARGV(1, string);
 318         if (mutator_returnvalue)
 319         {
 320                 for (int i = 0; i < NUM_TEAMS; ++i)
 321                 {
 322                         if (teams_mask & BIT(i))
 323                         {
 324                                 balance.m_team_balance_team[i].m_num_players = 0;
 325                         }
 326                 }
 327         }
 328
 329         if (teament_name)
 330         {
 331                 entity head = find(NULL, classname, teament_name);
 332                 while (head)
 333                 {
 334                         if (Team_IsValidTeam(head.team))
 335                         {
 336                                 TeamBalance_GetTeam(balance, head.team).m_num_players = 0;
 337                         }
 338                         head = find(head, classname, teament_name);
 339                 }
 340         }
 341
 342         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 343         if (AvailableTeams() == 2)
 344         if (autocvar_bot_vs_human && for_whom)
 345         {
 346                 if (autocvar_bot_vs_human > 0)
 347                 {
 348                         // find last team available
 349                         if (IS_BOT_CLIENT(for_whom))
 350                         {
 351                                 if (TeamBalance_IsTeamAllowedInternal(balance, 4))
 352                                 {
 353                                         TeamBalance_BanTeamsExcept(balance, 4);
 354                                 }
 355                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 3))
 356                                 {
 357                                         TeamBalance_BanTeamsExcept(balance, 3);
 358                                 }
 359                                 else
 360                                 {
 361                                         TeamBalance_BanTeamsExcept(balance, 2);
 362                                 }
 363                                 // no further cases, we know at least 2 teams exist
 364                         }
 365                         else
 366                         {
 367                                 if (TeamBalance_IsTeamAllowedInternal(balance, 1))
 368                                 {
 369                                         TeamBalance_BanTeamsExcept(balance, 1);
 370                                 }
 371                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 2))
 372                                 {
 373                                         TeamBalance_BanTeamsExcept(balance, 2);
 374                                 }
 375                                 else
 376                                 {
 377                                         TeamBalance_BanTeamsExcept(balance, 3);
 378                                 }
 379                                 // no further cases, bots have one of the teams
 380                         }
 381                 }
 382                 else
 383                 {
 384                         // find first team available
 385                         if (IS_BOT_CLIENT(for_whom))
 386                         {
 387                                 if (TeamBalance_IsTeamAllowedInternal(balance, 1))
 388                                 {
 389                                         TeamBalance_BanTeamsExcept(balance, 1);
 390                                 }
 391                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 2))
 392                                 {
 393                                         TeamBalance_BanTeamsExcept(balance, 2);
 394                                 }
 395                                 else
 396                                 {
 397                                         TeamBalance_BanTeamsExcept(balance, 3);
 398                                 }
 399                                 // no further cases, we know at least 2 teams exist
 400                         }
 401                         else
 402                         {
 403                                 if (TeamBalance_IsTeamAllowedInternal(balance, 4))
 404                                 {
 405                                         TeamBalance_BanTeamsExcept(balance, 4);
 406                                 }
 407                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 3))
 408                                 {
 409                                         TeamBalance_BanTeamsExcept(balance, 3);
 410                                 }
 411                                 else
 412                                 {
 413                                         TeamBalance_BanTeamsExcept(balance, 2);
 414                                 }
 415                                 // no further cases, bots have one of the teams
 416                         }
 417                 }
 418         }
 419
 420         if (!for_whom)
 421         {
 422                 balance.m_team_balance_state = TEAM_BALANCE_TEAMS_CHECKED;
 423                 return balance;
 424         }
 425
 426         // if player has a forced team, ONLY allow that one
 427         for (int i = 1; i <= NUM_TEAMS; ++i)
 428         {
 429                 if (for_whom.team_forced == Team_IndexToTeam(i) &&
 430                         TeamBalance_IsTeamAllowedInternal(balance, i))
 431                 {
 432                         TeamBalance_BanTeamsExcept(balance, i);
 433                 }
 434                 break;
 435         }
 436         balance.m_team_balance_state = TEAM_BALANCE_TEAMS_CHECKED;
 437         return balance;
 438 }
 439
 440 void TeamBalance_Destroy(entity balance)
 441 {
 442         if (balance == NULL)
 443         {
 444                 return;
 445         }
 446         for (int i = 0; i < NUM_TEAMS; ++i)
 447         {
 448                 remove(balance.(m_team_balance_team[i]));
 449         }
 450         remove(balance);
 451 }
 452
 453 int TeamBalance_GetAllowedTeams(entity balance)
 454 {
 455         if (balance == NULL)
 456         {
 457                 LOG_FATAL("TeamBalance_GetAllowedTeams: Team balance entity is NULL.");
 458         }
 459         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 460         {
 461                 LOG_FATAL("TeamBalance_GetAllowedTeams: "
 462                         "Team balance entity is not initialized.");
 463         }
 464         int result = 0;
 465         for (int i = 1; i <= NUM_TEAMS; ++i)
 466         {
 467                 if (TeamBalance_IsTeamAllowedInternal(balance, i))
 468                 {
 469                         result |= Team_IndexToBit(i);
 470                 }
 471         }
 472         return result;
 473 }
 474
 475 bool TeamBalance_IsTeamAllowed(entity balance, int index)
 476 {
 477         if (balance == NULL)
 478         {
 479                 LOG_FATAL("TeamBalance_IsTeamAllowed: Team balance entity is NULL.");
 480         }
 481         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 482         {
 483                 LOG_FATAL("TeamBalance_IsTeamAllowed: "
 484                         "Team balance entity is not initialized.");
 485         }
 486         if (!Team_IsValidIndex(index))
 487         {
 488                 LOG_FATALF("TeamBalance_IsTeamAllowed: Team index is invalid: %f",
 489                         index);
 490         }
 491         return TeamBalance_IsTeamAllowedInternal(balance, index);
 492 }
 493
 494 void TeamBalance_GetTeamCounts(entity balance, entity ignore)
 495 {
 496         if (balance == NULL)
 497         {
 498                 LOG_FATAL("TeamBalance_GetTeamCounts: Team balance entity is NULL.");
 499         }
 500         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 501         {
 502                 LOG_FATAL("TeamBalance_GetTeamCounts: "
 503                         "Team balance entity is not initialized.");
 504         }
 505         if (MUTATOR_CALLHOOK(TeamBalance_GetTeamCounts) == true)
 506         {
 507                 // Mutator has overriden the configuration.
 508                 for (int i = 1; i <= NUM_TEAMS; ++i)
 509                 {
 510                         entity team_ = TeamBalance_GetTeamFromIndex(balance, i);
 511                         if (TeamBalanceTeam_IsAllowed(team_))
 512                         {
 513                                 MUTATOR_CALLHOOK(TeamBalance_GetTeamCount, Team_IndexToTeam(i),
 514                                         ignore, team_.m_num_players, team_.m_num_bots,
 515                                         team_.m_lowest_human, team_.m_lowest_bot);
 516                                 team_.m_num_players = M_ARGV(2, float);
 517                                 team_.m_num_bots = M_ARGV(3, float);
 518                                 team_.m_lowest_human = M_ARGV(4, entity);
 519                                 team_.m_lowest_bot = M_ARGV(5, entity);
 520                         }
 521                 }
 522         }
 523         else
 524         {
 525                 // Manually count all players.
 526                 FOREACH_CLIENT(true,
 527                 {
 528                         if (it == ignore)
 529                         {
 530                                 continue;
 531                         }
 532                         int team_num;
 533                         if (IS_PLAYER(it) || it.caplayer)
 534                         {
 535                                 team_num = it.team;
 536                         }
 537                         else if (it.team_forced > 0)
 538                         {
 539                                 team_num = it.team_forced; // reserve the spot
 540                         }
 541                         else
 542                         {
 543                                 continue;
 544                         }
 545                         if (!Team_IsValidTeam(team_num))
 546                         {
 547                                 continue;
 548                         }
 549                         entity team_ = TeamBalance_GetTeam(balance, team_num);
 550                         if (!TeamBalanceTeam_IsAllowed(team_))
 551                         {
 552                                 continue;
 553                         }
 554                         ++team_.m_num_players;
 555                         if (IS_BOT_CLIENT(it))
 556                         {
 557                                 ++team_.m_num_bots;
 558                         }
 559                         float temp_score = PlayerScore_Get(it, SP_SCORE);
 560                         if (!IS_BOT_CLIENT(it))
 561                         {
 562                                 if (team_.m_lowest_human == NULL)
 563                                 {
 564                                         team_.m_lowest_human = it;
 565                                         continue;
 566                                 }
 567                                 if (temp_score < PlayerScore_Get(team_.m_lowest_human,
 568                                         SP_SCORE))
 569                                 {
 570                                         team_.m_lowest_human = it;
 571                                 }
 572                                 continue;
 573                         }
 574                         if (team_.m_lowest_bot == NULL)
 575                         {
 576                                 team_.m_lowest_bot = it;
 577                                 continue;
 578                         }
 579                         if (temp_score < PlayerScore_Get(team_.m_lowest_bot, SP_SCORE))
 580                         {
 581                                 team_.m_lowest_bot = it;
 582                         }
 583                 });
 584         }
 585
 586         // if the player who has a forced team has not joined yet, reserve the spot
 587         if (autocvar_g_campaign)
 588         {
 589                 if (Team_IsValidIndex(autocvar_g_campaign_forceteam))
 590                 {
 591                         entity team_ = TeamBalance_GetTeamFromIndex(balance,
 592                                 autocvar_g_campaign_forceteam);
 593                         if (team_.m_num_players == team_.m_num_bots)
 594                         {
 595                                 ++team_.m_num_players;
 596                         }
 597                 }
 598         }
 599         balance.m_team_balance_state = TEAM_BALANCE_TEAM_COUNTS_FILLED;
 600 }
 601
 602 int TeamBalance_GetNumberOfPlayers(entity balance, int index)
 603 {
 604         if (balance == NULL)
 605         {
 606                 LOG_FATAL("TeamBalance_GetNumberOfPlayers: "
 607                         "Team balance entity is NULL.");
 608         }
 609         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 610         {
 611                 LOG_FATAL("TeamBalance_GetNumberOfPlayers: "
 612                         "TeamBalance_GetTeamCounts has not been called.");
 613         }
 614         if (!Team_IsValidIndex(index))
 615         {
 616                 LOG_FATALF("TeamBalance_GetNumberOfPlayers: Team index is invalid: %f",
 617                         index);
 618         }
 619         return balance.m_team_balance_team[index - 1].m_num_players;
 620 }
 621
 622 int TeamBalance_FindBestTeam(entity balance, entity player, bool ignore_player)
 623 {
 624         if (balance == NULL)
 625         {
 626                 LOG_FATAL("TeamBalance_FindBestTeam: Team balance entity is NULL.");
 627         }
 628         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 629         {
 630                 LOG_FATAL("TeamBalance_FindBestTeam: "
 631                         "Team balance entity is not initialized.");
 632         }
 633         // count how many players are in each team
 634         if (ignore_player)
 635         {
 636                 TeamBalance_GetTeamCounts(balance, player);
 637         }
 638         else
 639         {
 640                 TeamBalance_GetTeamCounts(balance, NULL);
 641         }
 642         int team_bits = TeamBalance_FindBestTeams(balance, player, true);
 643         if (team_bits == 0)
 644         {
 645                 LOG_FATALF("TeamBalance_FindBestTeam: No teams available for %s\n",
 646                         MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 647         }
 648         RandomSelection_Init();
 649         for (int i = 1; i <= NUM_TEAMS; ++i)
 650         {
 651                 if (team_bits & Team_IndexToBit(i))
 652                 {
 653                         RandomSelection_AddFloat(i, 1, 1);
 654                 }
 655         }
 656         return RandomSelection_chosen_float;
 657 }
 658
 659 int TeamBalance_FindBestTeams(entity balance, entity player, bool use_score)
 660 {
 661         if (balance == NULL)
 662         {
 663                 LOG_FATAL("TeamBalance_FindBestTeams: Team balance entity is NULL.");
 664         }
 665         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 666         {
 667                 LOG_FATAL("TeamBalance_FindBestTeams: "
 668                         "TeamBalance_GetTeamCounts has not been called.");
 669         }
 670         if (MUTATOR_CALLHOOK(TeamBalance_FindBestTeams, player) == true)
 671         {
 672                 return M_ARGV(1, float);
 673         }
 674         int team_bits = 0;
 675         int previous_team = 0;
 676         for (int i = 1; i <= NUM_TEAMS; ++i)
 677         {
 678                 if (!TeamBalance_IsTeamAllowedInternal(balance, i))
 679                 {
 680                         continue;
 681                 }
 682                 if (previous_team == 0)
 683                 {
 684                         team_bits = Team_IndexToBit(i);
 685                         previous_team = i;
 686                         continue;
 687                 }
 688                 int compare = TeamBalance_CompareTeams(balance, i, previous_team,
 689                         player, use_score);
 690                 if (compare == TEAMS_COMPARE_LESS)
 691                 {
 692                         team_bits = Team_IndexToBit(i);
 693                         previous_team = i;
 694                         continue;
 695                 }
 696                 if (compare == TEAMS_COMPARE_EQUAL)
 697                 {
 698                         team_bits |= Team_IndexToBit(i);
 699                         previous_team = i;
 700                 }
 701         }
 702         return team_bits;
 703 }
 704
 705 void TeamBalance_JoinBestTeam(entity this, bool force_best_team)
 706 {
 707         // don't join a team if we're not playing a team game
 708         if (!teamplay)
 709         {
 710                 return;
 711         }
 712
 713         // find out what teams are available
 714         entity balance = TeamBalance_CheckAllowedTeams(this);
 715
 716         // if we don't care what team they end up on, put them on whatever team they entered as.
 717         // if they're not on a valid team, then let other code put them on the smallest team
 718         if (!force_best_team)
 719         {
 720                 int selected_team_num = -1;
 721                 for (int i = 1; i <= NUM_TEAMS; ++i)
 722                 {
 723                         if (TeamBalance_IsTeamAllowedInternal(balance, i) && (this.team ==
 724                                 Team_IndexToTeam(i)))
 725                         {
 726                                 selected_team_num = this.team;
 727                                 break;
 728                         }
 729                 }
 730
 731                 if (Team_IsValidTeam(selected_team_num))
 732                 {
 733                         SetPlayerTeamSimple(this, selected_team_num);
 734                         LogTeamchange(this.playerid, this.team, 99);
 735                         TeamBalance_Destroy(balance);
 736                         return;
 737                 }
 738         }
 739         // otherwise end up on the smallest team (handled below)
 740         if (this.bot_forced_team)
 741         {
 742                 TeamBalance_Destroy(balance);
 743                 return;
 744         }
 745         int best_team_index = TeamBalance_FindBestTeam(balance, this, true);
 746         int best_team_num = Team_IndexToTeam(best_team_index);
 747         int old_team_index = Team_TeamToIndex(this.team);
 748         TeamchangeFrags(this);
 749         SetPlayerTeamSimple(this, best_team_num);
 750         LogTeamchange(this.playerid, this.team, 2); // log auto join
 751         if ((old_team_index != -1) && !IS_BOT_CLIENT(this))
 752         {
 753                 TeamBalance_AutoBalanceBots(balance, old_team_index, best_team_index);
 754         }
 755         KillPlayerForTeamChange(this);
 756         TeamBalance_Destroy(balance);
 757 }
 758
 759 int TeamBalance_CompareTeams(entity balance, int team_index_a, int team_index_b,
 760         entity player, bool use_score)
 761 {
 762         if (balance == NULL)
 763         {
 764                 LOG_FATAL("TeamBalance_CompareTeams: Team balance entity is NULL.");
 765         }
 766         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 767         {
 768                 LOG_FATAL("TeamBalance_CompareTeams: "
 769                         "TeamBalance_GetTeamCounts has not been called.");
 770         }
 771         if (!Team_IsValidIndex(team_index_a))
 772         {
 773                 LOG_FATALF("TeamBalance_CompareTeams: team_index_a is invalid: %f",
 774                         team_index_a);
 775         }
 776         if (!Team_IsValidIndex(team_index_b))
 777         {
 778                 LOG_FATALF("TeamBalance_CompareTeams: team_index_b is invalid: %f",
 779                         team_index_b);
 780         }
 781         if (team_index_a == team_index_b)
 782         {
 783                 return TEAMS_COMPARE_EQUAL;
 784         }
 785         entity team_a = TeamBalance_GetTeamFromIndex(balance, team_index_a);
 786         entity team_b = TeamBalance_GetTeamFromIndex(balance, team_index_b);
 787         return TeamBalance_CompareTeamsInternal(team_a, team_b, player, use_score);
 788 }
 789
 790 void TeamBalance_AutoBalanceBots(entity balance, int source_team_index,
 791         int destination_team_index)
 792 {
 793         if (balance == NULL)
 794         {
 795                 LOG_FATAL("TeamBalance_AutoBalanceBots: Team balance entity is NULL.");
 796         }
 797         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 798         {
 799                 LOG_FATAL("TeamBalance_AutoBalanceBots: "
 800                         "TeamBalance_GetTeamCounts has not been called.");
 801         }
 802         if (!Team_IsValidIndex(source_team_index))
 803         {
 804                 LOG_WARNF("AutoBalanceBots: Source team index is invalid: %f",
 805                         source_team_index);
 806                 return;
 807         }
 808         if (!Team_IsValidIndex(destination_team_index))
 809         {
 810                 LOG_WARNF("AutoBalanceBots: Destination team index is invalid: %f",
 811                         destination_team_index);
 812                 return;
 813         }
 814         if (!autocvar_g_balance_teams ||
 815                 !autocvar_g_balance_teams_prevent_imbalance)
 816         {
 817                 return;
 818         }
 819         entity source_team = TeamBalance_GetTeamFromIndex(balance,
 820                 source_team_index);
 821         if (!TeamBalanceTeam_IsAllowed(source_team))
 822         {
 823                 return;
 824         }
 825         entity destination_team = TeamBalance_GetTeamFromIndex(balance,
 826                 destination_team_index);
 827         if ((destination_team.m_num_players <= source_team.m_num_players) ||
 828                 (destination_team.m_lowest_bot == NULL))
 829         {
 830                 return;
 831         }
 832         SetPlayerTeamSimple(destination_team.m_lowest_bot,
 833                 Team_IndexToTeam(source_team_index));
 834         KillPlayerForTeamChange(destination_team.m_lowest_bot);
 835 }
 836
 837 bool TeamBalance_IsTeamAllowedInternal(entity balance, int index)
 838 {
 839         return balance.m_team_balance_team[index - 1].m_num_players !=
 840                 TEAM_NOT_ALLOWED;
 841 }
 842
 843 void TeamBalance_BanTeamsExcept(entity balance, int index)
 844 {
 845         for (int i = 1; i <= NUM_TEAMS; ++i)
 846         {
 847                 if (i != index)
 848                 {
 849                         balance.m_team_balance_team[i - 1].m_num_players = TEAM_NOT_ALLOWED;
 850                 }
 851         }
 852 }
 853
 854 entity TeamBalance_GetTeamFromIndex(entity balance, int index)
 855 {
 856         if (!Team_IsValidIndex(index))
 857         {
 858                 LOG_FATALF("TeamBalance_GetTeamFromIndex: Index is invalid: %f", index);
 859         }
 860         return balance.m_team_balance_team[index - 1];
 861 }
 862
 863 entity TeamBalance_GetTeam(entity balance, int team_num)
 864 {
 865         return TeamBalance_GetTeamFromIndex(balance, Team_TeamToIndex(team_num));
 866 }
 867
 868 bool TeamBalanceTeam_IsAllowed(entity team_)
 869 {
 870         return team_.m_num_players != TEAM_NOT_ALLOWED;
 871 }
 872
 873 int TeamBalanceTeam_GetNumberOfPlayers(entity team_)
 874 {
 875         return team_.m_num_players;
 876 }
 877
 878 int TeamBalanceTeam_GetNumberOfBots(entity team_)
 879 {
 880         return team_.m_num_bots;
 881 }
 882
 883 entity TeamBalanceTeam_GetLowestHuman(entity team_)
 884 {
 885         return team_.m_lowest_human;
 886 }
 887
 888 entity TeamBalanceTeam_GetLowestBot(entity team_)
 889 {
 890         return team_.m_lowest_bot;
 891 }
 892
 893 int TeamBalance_CompareTeamsInternal(entity team_a, entity team_b,
 894         entity player, bool use_score)
 895 {
 896         if (team_a == team_b)
 897         {
 898                 return TEAMS_COMPARE_EQUAL;
 899         }
 900         if (!TeamBalanceTeam_IsAllowed(team_a) ||
 901                 !TeamBalanceTeam_IsAllowed(team_b))
 902         {
 903                 return TEAMS_COMPARE_INVALID;
 904         }
 905         int num_players_team_a = team_a.m_num_players;
 906         int num_players_team_b = team_b.m_num_players;
 907         if (IS_REAL_CLIENT(player) && bots_would_leave)
 908         {
 909                 num_players_team_a -= team_a.m_num_bots;
 910                 num_players_team_b -= team_b.m_num_bots;
 911         }
 912         if (num_players_team_a < num_players_team_b)
 913         {
 914                 return TEAMS_COMPARE_LESS;
 915         }
 916         if (num_players_team_a > num_players_team_b)
 917         {
 918                 return TEAMS_COMPARE_GREATER;
 919         }
 920         if (!use_score)
 921         {
 922                 return TEAMS_COMPARE_EQUAL;
 923         }
 924         if (team_a.m_team_score < team_b.m_team_score)
 925         {
 926                 return TEAMS_COMPARE_LESS;
 927         }
 928         if (team_a.m_team_score > team_b.m_team_score)
 929         {
 930                 return TEAMS_COMPARE_GREATER;
 931         }
 932         return TEAMS_COMPARE_EQUAL;
 933 }
 934
 935 void SV_ChangeTeam(entity this, float _color)
 936 {
 937         int source_color, destination_color;
 938         int source_team_index, destination_team_index;
 939
 940         // in normal deathmatch we can just apply the color and we're done
 941         if(!teamplay)
 942                 SetPlayerColors(this, _color);
 943
 944         if(!IS_CLIENT(this))
 945         {
 946                 // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 947                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 948                 return;
 949         }
 950
 951         if(!teamplay)
 952                 return;
 953
 954         source_color = this.clientcolors & 0x0F;
 955         destination_color = _color & 0x0F;
 956
 957         source_team_index = Team_TeamToIndex(source_color + 1);
 958         destination_team_index = Team_TeamToIndex(destination_color + 1);
 959
 960         if (destination_team_index == -1)
 961         {
 962                 return;
 963         }
 964
 965         entity balance = TeamBalance_CheckAllowedTeams(this);
 966
 967         if (destination_team_index == 1 && !TeamBalance_IsTeamAllowedInternal(
 968                 balance, 1))
 969         {
 970                 destination_team_index = 4;
 971         }
 972         if (destination_team_index == 4 && !TeamBalance_IsTeamAllowedInternal(
 973                 balance, 4))
 974         {
 975                 destination_team_index = 3;
 976         }
 977         if (destination_team_index == 3 && !TeamBalance_IsTeamAllowedInternal(
 978                 balance, 3))
 979         {
 980                 destination_team_index = 2;
 981         }
 982         if (destination_team_index == 2 && !TeamBalance_IsTeamAllowedInternal(
 983                 balance, 2))
 984         {
 985                 destination_team_index = 1;
 986         }
 987
 988         // not changing teams
 989         if (source_color == destination_color)
 990         {
 991                 SetPlayerTeam(this, destination_team_index, source_team_index, true);
 992                 TeamBalance_Destroy(balance);
 993                 return;
 994         }
 995
 996         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && CS(this).wasplayer)) {
 997                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 998                 return; // changing teams is not allowed
 999         }
1000
1001         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
1002         if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
1003         {
1004                 TeamBalance_GetTeamCounts(balance, this);
1005                 if ((Team_IndexToBit(destination_team_index) &
1006                         TeamBalance_FindBestTeams(balance, this, false)) == 0)
1007                 {
1008                         Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
1009                         TeamBalance_Destroy(balance);
1010                         return;
1011                 }
1012         }
1013         if (IS_PLAYER(this) && source_team_index != destination_team_index)
1014         {
1015                 // reduce frags during a team change
1016                 TeamchangeFrags(this);
1017         }
1018         if (!SetPlayerTeam(this, destination_team_index, source_team_index,
1019                 !IS_CLIENT(this)))
1020         {
1021                 TeamBalance_Destroy(balance);
1022                 return;
1023         }
1024         TeamBalance_AutoBalanceBots(balance, source_team_index,
1025                 destination_team_index);
1026         if (!IS_PLAYER(this) || (source_team_index == destination_team_index))
1027         {
1028                 TeamBalance_Destroy(balance);
1029                 return;
1030         }
1031         KillPlayerForTeamChange(this);
1032         TeamBalance_Destroy(balance);
1033 }