qcsrc/server/tturrets/system/system_main.qc

   1 #define cvar_base "g_turrets_unit_"
   2
   3 /*
   4 float turret_customizeentityforclient()
   5 {
   6 }
   7
   8 float Turret_SendEntity(entity to, float sf)
   9 {
  10
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_TURRET);
  12         WriteCoord(MSG_ENTITY, self.tur_head.angles_x);
  13         WriteCoord(MSG_ENTITY, self.tur_head.angles_y);
  14     WriteByte(MSG_ENTITY, self.tur_head.frame);
  15
  16         //WriteCoord(MSG_ENTITY, self.tur_head.angles_z);
  17
  18         return TRUE;
  19 }
  20 */
  21
  22 void load_unit_settings(entity ent, string unitname, float is_reload)
  23 {
  24     string sbase;
  25
  26     if (ent == world)
  27         return;
  28
  29     if not (ent.turret_scale_damage)    ent.turret_scale_damage  = 1;
  30     if not (ent.turret_scale_range)     ent.turret_scale_range   = 1;
  31     if not (ent.turret_scale_refire)    ent.turret_scale_refire  = 1;
  32     if not (ent.turret_scale_ammo)      ent.turret_scale_ammo    = 1;
  33     if not (ent.turret_scale_aim)       ent.turret_scale_aim     = 1;
  34     if not (ent.turret_scale_health)    ent.turret_scale_health  = 1;
  35     if not (ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
  36
  37     sbase = strcat(cvar_base,unitname);
  38     if (is_reload)
  39     {
  40         ent.enemy = world;
  41         ent.tur_head.avelocity = '0 0 0';
  42
  43         ent.tur_head.angles = '0 0 0';
  44     }
  45
  46     ent.health      = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
  47     ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
  48
  49     ent.shot_dmg          = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
  50     ent.shot_refire       = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
  51     ent.shot_radius       = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
  52     ent.shot_speed        = cvar(strcat(sbase,"_shot_speed"));
  53     ent.shot_spread       = cvar(strcat(sbase,"_shot_spread"));
  54     ent.shot_force        = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
  55     ent.shot_volly        = cvar(strcat(sbase,"_shot_volly"));
  56     ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
  57
  58     ent.target_range         = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
  59     ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
  60     ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
  61     //ent.target_range_fire    = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
  62
  63     ent.target_select_rangebias  = cvar(strcat(sbase,"_target_select_rangebias"));
  64     ent.target_select_samebias   = cvar(strcat(sbase,"_target_select_samebias"));
  65     ent.target_select_anglebias  = cvar(strcat(sbase,"_target_select_anglebias"));
  66     ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
  67     //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
  68
  69     ent.ammo_max      = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
  70     ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
  71
  72     ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
  73     ent.aim_speed    = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
  74     ent.aim_maxrot   = cvar(strcat(sbase,"_aim_maxrot"));
  75     ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
  76
  77     ent.track_type        = cvar(strcat(sbase,"_track_type"));
  78     ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
  79     ent.track_accel_rot   = cvar(strcat(sbase,"_track_accel_rot"));
  80     ent.track_blendrate   = cvar(strcat(sbase,"_track_blendrate"));
  81
  82     if(is_reload)
  83         if(ent.turret_respawnhook)
  84             ent.turret_respawnhook();
  85 }
  86
  87
  88 /**
  89 ** updates enemy distances, predicted impact point/time
  90 ** and updated aim<->predict impact distance.
  91 **/
  92 void turret_do_updates(entity t_turret)
  93 {
  94     vector enemy_pos, oldpos;
  95     entity oldself;
  96
  97     oldself = self;
  98     self = t_turret;
  99
 100     enemy_pos = real_origin(self.enemy);
 101
 102     turret_tag_fire_update();
 103
 104     self.tur_shotdir_updated = v_forward;
 105     self.tur_dist_enemy  = vlen(self.tur_shotorg - enemy_pos);
 106     self.tur_dist_aimpos = vlen(self.tur_shotorg - self.tur_aimpos);
 107
 108     if((self.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (self.enemy))
 109     {
 110         oldpos = self.enemy.origin;
 111         setorigin(self.enemy,self.tur_aimpos);
 112         tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1',self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos),MOVE_NORMAL,self);
 113         setorigin(self.enemy,oldpos);
 114
 115         if(trace_ent == self.enemy)
 116             self.tur_dist_impact_to_aimpos = 0;
 117         else
 118             self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos);
 119
 120
 121     }
 122     else
 123         tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos),MOVE_NORMAL,self);
 124
 125         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos) - (vlen(self.enemy.maxs - self.enemy.mins) * 0.5);
 126         self.tur_impactent             = trace_ent;
 127         self.tur_impacttime            = vlen(self.tur_shotorg - trace_endpos) / self.shot_speed;
 128
 129     self = oldself;
 130 }
 131
 132 /*
 133 vector turret_fovsearch_pingpong()
 134 {
 135     vector wish_angle;
 136     if(self.phase < time)
 137     {
 138         if( self.tur_head.phase )
 139             self.tur_head.phase = 0;
 140         else
 141             self.tur_head.phase = 1;
 142         self.phase = time + 5;
 143     }
 144
 145     if( self.tur_head.phase)
 146         wish_angle = self.idle_aim + '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
 147     else
 148         wish_angle = self.idle_aim - '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
 149
 150     return wish_angle;
 151 }
 152
 153 vector turret_fovsearch_steprot()
 154 {
 155     vector wish_angle;
 156     //float rot_add;
 157
 158     wish_angle   = self.tur_head.angles;
 159     wish_angle_x = self.idle_aim_x;
 160
 161     if (self.phase < time)
 162     {
 163         //rot_add = self.aim_maxrot / self.target_select_fov;
 164         wish_angle_y += (self.target_select_fov * 2);
 165
 166         if(wish_angle_y > 360)
 167             wish_angle_y = wish_angle_y - 360;
 168
 169          self.phase = time + 1.5;
 170     }
 171
 172     return wish_angle;
 173 }
 174
 175 vector turret_fovsearch_random()
 176 {
 177     vector wish_angle;
 178
 179     if (self.phase < time)
 180     {
 181         wish_angle_y = random() * self.aim_maxrot;
 182         if(random() < 0.5)
 183             wish_angle_y *= -1;
 184
 185         wish_angle_x = random() * self.aim_maxpitch;
 186         if(random() < 0.5)
 187             wish_angle_x *= -1;
 188
 189         self.phase = time + 5;
 190
 191         self.tur_aimpos = wish_angle;
 192     }
 193
 194     return self.idle_aim + self.tur_aimpos;
 195 }
 196 */
 197
 198 /**
 199 ** Handles head rotation according to
 200 ** the units .track_type and .track_flags
 201 **/
 202 void turret_stdproc_track()
 203 {
 204     vector target_angle; // This is where we want to aim
 205     vector move_angle;   // This is where we can aim
 206     float f_tmp;
 207
 208     if (self.track_flags == TFL_TRACK_NO)
 209         return;
 210
 211     if not (self.tur_active)
 212         target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
 213     else if (self.enemy == world)
 214     {
 215         if(time > self.lip)
 216             target_angle = self.idle_aim + self.angles;
 217         else
 218             target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 219     }
 220     else
 221     {
 222         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 223     }
 224
 225     self.tur_head.angles_x = anglemods(self.tur_head.angles_x);
 226     self.tur_head.angles_y = anglemods(self.tur_head.angles_y);
 227
 228     // Find the diffrence between where we currently aim and where we want to aim
 229     move_angle = target_angle - (self.angles + self.tur_head.angles);
 230     move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
 231
 232     switch(self.track_type)
 233     {
 234         case TFL_TRACKTYPE_STEPMOTOR:
 235             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 236             if (self.track_flags & TFL_TRACK_PITCH)
 237             {
 238                 self.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 239                 if(self.tur_head.angles_x > self.aim_maxpitch)
 240                     self.tur_head.angles_x = self.aim_maxpitch;
 241
 242                 if(self.tur_head.angles_x  < -self.aim_maxpitch)
 243                     self.tur_head.angles_x = self.aim_maxpitch;
 244             }
 245
 246             if (self.track_flags & TFL_TRACK_ROT)
 247             {
 248                 self.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 249                 if(self.tur_head.angles_y > self.aim_maxrot)
 250                     self.tur_head.angles_y = self.aim_maxrot;
 251
 252                 if(self.tur_head.angles_y  < -self.aim_maxrot)
 253                     self.tur_head.angles_y = self.aim_maxrot;
 254             }
 255
 256             return;
 257
 258         case TFL_TRACKTYPE_FLUIDINERTIA:
 259             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 260             move_angle_x = bound(-self.aim_speed, move_angle_x * self.track_accel_pitch * f_tmp, self.aim_speed);
 261             move_angle_y = bound(-self.aim_speed, move_angle_y * self.track_accel_rot * f_tmp, self.aim_speed);
 262             move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
 263             break;
 264
 265         case TFL_TRACKTYPE_FLUIDPRECISE:
 266
 267             move_angle_y = bound(-self.aim_speed, move_angle_y, self.aim_speed);
 268             move_angle_x = bound(-self.aim_speed, move_angle_x, self.aim_speed);
 269
 270             break;
 271     }
 272
 273     //  pitch
 274     if (self.track_flags & TFL_TRACK_PITCH)
 275     {
 276         self.tur_head.avelocity_x = move_angle_x;
 277         if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) > self.aim_maxpitch)
 278         {
 279             self.tur_head.avelocity_x = 0;
 280             self.tur_head.angles_x = self.aim_maxpitch;
 281         }
 282
 283         if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) < -self.aim_maxpitch)
 284         {
 285             self.tur_head.avelocity_x = 0;
 286             self.tur_head.angles_x = -self.aim_maxpitch;
 287         }
 288     }
 289
 290     //  rot
 291     if (self.track_flags & TFL_TRACK_ROT)
 292     {
 293         self.tur_head.avelocity_y = move_angle_y;
 294
 295         if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) > self.aim_maxrot)
 296         {
 297             self.tur_head.avelocity_y = 0;
 298             self.tur_head.angles_y = self.aim_maxrot;
 299         }
 300
 301         if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) < -self.aim_maxrot)
 302         {
 303             self.tur_head.avelocity_y = 0;
 304             self.tur_head.angles_y = -self.aim_maxrot;
 305         }
 306     }
 307 }
 308
 309
 310 /*
 311  + = implemented
 312  - = not implemented
 313
 314  + TFL_FIRECHECK_NO
 315  + TFL_FIRECHECK_WORLD
 316  + TFL_FIRECHECK_DEAD
 317  + TFL_FIRECHECK_DISTANCES
 318  - TFL_FIRECHECK_LOS
 319  + TFL_FIRECHECK_AIMDIST
 320  + TFL_FIRECHECK_REALDIST
 321  - TFL_FIRECHECK_ANGLEDIST
 322  - TFL_FIRECHECK_TEAMCECK
 323  + TFL_FIRECHECK_AFF
 324  + TFL_FIRECHECK_OWM_AMMO
 325  + TFL_FIRECHECK_OTHER_AMMO
 326  + TFL_FIRECHECK_REFIRE
 327 */
 328
 329 /**
 330 ** Preforms pre-fire checks based on the uints firecheck_flags
 331 **/
 332 float turret_stdproc_firecheck()
 333 {
 334     // This one just dont care =)
 335     if (self.firecheck_flags & TFL_FIRECHECK_NO) return 1;
 336
 337     // Ready?
 338     if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
 339         if (self.attack_finished_single > time) return 0;
 340
 341     // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 342     if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 343         if (self.volly_counter != self.shot_volly)
 344                         if(self.ammo >= self.shot_dmg)
 345                                 return 1;
 346
 347     // Lack of zombies makes shooting dead things unnecessary :P
 348     if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
 349         if (self.enemy.deadflag != DEAD_NO)
 350             return 0;
 351
 352     // Plz stop killing the world!
 353     if (self.firecheck_flags & TFL_FIRECHECK_WORLD)
 354         if (self.enemy == world)
 355             return 0;
 356
 357     // Own ammo?
 358     if (self.firecheck_flags & TFL_FIRECHECK_OWM_AMMO)
 359         if (self.ammo < self.shot_dmg)
 360             return 0;
 361
 362     // Other's ammo? (support-supply units)
 363     if (self.firecheck_flags & TFL_FIRECHECK_OTHER_AMMO)
 364         if (self.enemy.ammo >= self.enemy.ammo_max)
 365             return 0;
 366
 367         // Target of opertunity?
 368         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 369         {
 370                 self.enemy = self.tur_impactent;
 371                 return 1;
 372         }
 373
 374     if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 375     {
 376         // To close?
 377         if (self.tur_dist_aimpos < self.target_range_min)
 378                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 379                                 return 1; // Target of opertunity?
 380                         else
 381                                 return 0;
 382     }
 383
 384     // Try to avoid FF?
 385     if (self.firecheck_flags & TFL_FIRECHECK_AFF)
 386         if (self.tur_impactent.team == self.team)
 387             return 0;
 388
 389     // aim<->predicted impact
 390     if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 391         if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
 392             return 0;
 393
 394     // Volly status
 395     if (self.shot_volly > 1)
 396         if (self.volly_counter == self.shot_volly)
 397             if (self.ammo < (self.shot_dmg * self.shot_volly))
 398                 return 0;
 399
 400     if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 401         if(self.tur_impactent != self.enemy)
 402             return 0;
 403
 404     return 1;
 405 }
 406
 407 /*
 408  + TFL_TARGETSELECT_NO
 409  + TFL_TARGETSELECT_LOS
 410  + TFL_TARGETSELECT_PLAYERS
 411  + TFL_TARGETSELECT_MISSILES
 412  - TFL_TARGETSELECT_TRIGGERTARGET
 413  + TFL_TARGETSELECT_ANGLELIMITS
 414  + TFL_TARGETSELECT_RANGELIMTS
 415  + TFL_TARGETSELECT_TEAMCHECK
 416  - TFL_TARGETSELECT_NOBUILTIN
 417  + TFL_TARGETSELECT_OWNTEAM
 418 */
 419
 420 /**
 421 ** Evaluate a entity for target valitity based on validate_flags
 422 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 423 **/
 424 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 425 {
 426     vector v_tmp;
 427
 428     //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 429     //    return -0.5;
 430
 431     if(e_target.owner == e_turret)
 432         return -0.5;
 433
 434     if not(checkpvs(e_target.origin, e_turret))
 435         return -1;
 436
 437     if not (e_target)
 438         return -2;
 439
 440         if(g_onslaught)
 441                 if (substring(e_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
 442                         return - 3;
 443
 444     if (validate_flags & TFL_TARGETSELECT_NO)
 445         return -4;
 446
 447     // If only this was used more..
 448     if (e_target.flags & FL_NOTARGET)
 449         return -5;
 450
 451     // Cant touch this
 452     if (e_target.health < 0)
 453         return -6;
 454
 455     // player
 456     if (e_target.flags & FL_CLIENT)
 457     {
 458         if not (validate_flags & TFL_TARGETSELECT_PLAYERS)
 459             return -7;
 460
 461         if (e_target.deadflag != DEAD_NO)
 462             return -8;
 463     }
 464
 465         // enemy turrets
 466         if (validate_flags & TFL_TARGETSELECT_NOTURRETS)
 467         if (e_target.turret_firefunc || e_target.owner.tur_head == e_target)
 468             if(e_target.team != e_turret.team) // Dont break support units.
 469                 return -9;
 470
 471     // Missile
 472     if (e_target.flags & FL_PROJECTILE)
 473         if not (validate_flags & TFL_TARGETSELECT_MISSILES)
 474             return -10;
 475
 476     if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 477         if not (e_target.flags & FL_PROJECTILE)
 478             return -10.5;
 479
 480     // Team check
 481     if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 482     {
 483         if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 484         {
 485             if (e_target.team != e_turret.team)
 486                 return -11;
 487
 488             if (e_turret.team != e_target.owner.team)
 489                 return -12;
 490         }
 491         else
 492         {
 493             if (e_target.team == e_turret.team)
 494                 return -13;
 495
 496             if (e_turret.team == e_target.owner.team)
 497                 return -14;
 498         }
 499     }
 500
 501     // Range limits?
 502     tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 503     if (validate_flags & TFL_TARGETSELECT_RANGELIMTS)
 504     {
 505         if (tvt_dist < e_turret.target_range_min)
 506             return -15;
 507
 508         if (tvt_dist > e_turret.target_range)
 509             return -16;
 510     }
 511
 512     // Can we even aim this thing?
 513     tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 514     tvt_tadv  = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 515     tvt_thadf = vlen(tvt_thadv);
 516     tvt_tadf  = vlen(tvt_tadv);
 517
 518     /*
 519     if(validate_flags & TFL_TARGETSELECT_FOV)
 520     {
 521         if(e_turret.target_select_fov < tvt_thadf)
 522             return -21;
 523     }
 524     */
 525
 526     if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 527     {
 528         if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 529             return -17;
 530
 531         if (fabs(tvt_tadv_y) > e_turret.aim_maxrot)
 532             return -18;
 533     }
 534
 535     // Line of sight?
 536     if (validate_flags & TFL_TARGETSELECT_LOS)
 537     {
 538         v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 539
 540         traceline(e_turret.tur_shotorg, v_tmp, 0, e_turret);
 541
 542         if (e_turret.aim_firetolerance_dist < vlen(v_tmp - trace_endpos))
 543             return -19;
 544     }
 545
 546     if (e_target.classname == "grapplinghook")
 547         return -20;
 548
 549     /*
 550     if (e_target.classname == "func_button")
 551         return -21;
 552     */
 553
 554 #ifdef TURRET_DEBUG_TARGETSELECT
 555     dprint("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
 556 #endif
 557
 558     return 1;
 559 }
 560
 561 entity turret_select_target()
 562 {
 563     entity e;        // target looper entity
 564     float  score;    // target looper entity score
 565     entity e_enemy;  // currently best scoreing target
 566     float  m_score;  // currently best scoreing target's score
 567
 568     m_score = 0;
 569     if(self.enemy)
 570         if(self.enemy.takedamage)
 571     if(turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
 572     {
 573         e_enemy = self.enemy;
 574         m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
 575     }
 576     else
 577         self.enemy = world;
 578
 579     e = findradius(self.origin, self.target_range);
 580
 581     // Nothing to aim at?
 582     if (!e)
 583                 return world;
 584
 585     while (e)
 586     {
 587                 if(e.takedamage)
 588                 {
 589                         if (turret_validate_target(self, e, self.target_select_flags) > 0)
 590                         {
 591                                 score = self.turret_score_target(self,e);
 592                                 if ((score > m_score) && (score > 0))
 593                                 {
 594                                         e_enemy = e;
 595                                         m_score = score;
 596                                 }
 597                         }
 598                 }
 599         e = e.chain;
 600     }
 601
 602     return e_enemy;
 603 }
 604
 605 void turret_think()
 606 {
 607     entity e;
 608
 609     self.nextthink = time + self.ticrate;
 610
 611     // ONS uses somewhat backwards linking.
 612     if (teams_matter)
 613     {
 614         if not (g_onslaught)
 615             if (self.target)
 616             {
 617                 e = find(world, targetname,self.target);
 618                 if (e != world)
 619                     self.team = e.team;
 620             }
 621
 622         if (self.team != self.tur_head.team)
 623             turret_stdproc_respawn();
 624     }
 625
 626 #ifdef TURRET_DEBUG
 627     if (self.tur_dbg_tmr1 < time)
 628     {
 629         if (self.enemy) paint_target (self.enemy,128,self.tur_dbg_rvec,0.9);
 630         paint_target(self,256,self.tur_dbg_rvec,0.9);
 631         self.tur_dbg_tmr1 = time + 1;
 632     }
 633 #endif
 634
 635     // Handle ammo
 636     if not (self.spawnflags & TSF_NO_AMMO_REGEN)
 637     if (self.ammo < self.ammo_max)
 638         self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
 639
 640     if (self.health < (self.tur_health * 0.5))
 641                 if(random() < 0.25)
 642                         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 643
 644     // Inactive turrets needs to run the think loop,
 645     // So they can handle animation and wake up if need be.
 646     if not (self.tur_active)
 647     {
 648         turret_stdproc_track();
 649         return;
 650     }
 651
 652     // This is typicaly used for zaping every target in range
 653     // turret_fusionreactor uses this to recharge friendlys.
 654     if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
 655     {
 656         // Do a self.turret_fire for every valid target.
 657         e = findradius(self.origin,self.target_range);
 658         while (e)
 659         {
 660                         if(e.takedamage)
 661                         {
 662                                 if (turret_validate_target(self,e,self.target_validate_flags))
 663                                 {
 664                                         self.enemy = e;
 665
 666                                         turret_do_updates(self);
 667
 668                                         if (self.turret_firecheckfunc())
 669                                                 turret_fire();
 670                                 }
 671                         }
 672
 673             e = e.chain;
 674         }
 675         self.enemy = world;
 676     }
 677     else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
 678     {
 679         // This one is doing something.. oddball. assume its handles what needs to be handled.
 680
 681         // Predict?
 682         if not(self.aim_flags & TFL_AIM_NO)
 683             self.tur_aimpos = turret_stdproc_aim_generic();
 684
 685         // Turn & pitch?
 686         if not(self.track_flags & TFL_TRACK_NO)
 687             turret_stdproc_track();
 688
 689         turret_do_updates(self);
 690
 691         // Fire?
 692         if (self.turret_firecheckfunc())
 693             turret_fire();
 694     }
 695     else
 696     {
 697         // Special case for volly always. if it fired once it must compleate the volly.
 698         if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 699             if(self.volly_counter != self.shot_volly)
 700             {
 701                 // Predict or whatnot
 702                 if not(self.aim_flags & TFL_AIM_NO)
 703                     self.tur_aimpos = turret_stdproc_aim_generic();
 704
 705                 // Turn & pitch
 706                 if not(self.track_flags & TFL_TRACK_NO)
 707                     turret_stdproc_track();
 708
 709                 turret_do_updates(self);
 710
 711                 // Fire!
 712                 if (self.turret_firecheckfunc() != 0)
 713                     turret_fire();
 714
 715                 if(self.turret_postthink)
 716                     self.turret_postthink();
 717
 718                 return;
 719             }
 720
 721         // Check if we have a vailid enemy, and try to find one if we dont.
 722
 723         // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
 724         float do_target_scan;
 725         if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
 726             do_target_scan = 1;
 727
 728         // Old target (if any) invalid?
 729         if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
 730         {
 731                 self.enemy = world;
 732                 do_target_scan = 1;
 733         }
 734
 735         // But never more often then g_turrets_targetscan_mindelay!
 736         if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
 737             do_target_scan = 0;
 738
 739         if(do_target_scan)
 740         {
 741             self.enemy = turret_select_target();
 742             self.target_select_time = time;
 743         }
 744
 745         // No target, just go to idle, do any custom stuff and bail.
 746         if (self.enemy == world)
 747         {
 748             // Turn & pitch
 749             if not(self.track_flags & TFL_TRACK_NO)
 750                 turret_stdproc_track();
 751
 752             // do any per-turret stuff
 753             if(self.turret_postthink)
 754                 self.turret_postthink();
 755
 756             // And bail.
 757             return;
 758         }
 759         else
 760             self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
 761
 762         // Predict?
 763         if not(self.aim_flags & TFL_AIM_NO)
 764             self.tur_aimpos = turret_stdproc_aim_generic();
 765
 766         // Turn & pitch?
 767         if not(self.track_flags & TFL_TRACK_NO)
 768             turret_stdproc_track();
 769
 770         turret_do_updates(self);
 771
 772         // Fire?
 773         if (self.turret_firecheckfunc())
 774             turret_fire();
 775     }
 776
 777     // do any custom per-turret stuff
 778     if(self.turret_postthink)
 779         self.turret_postthink();
 780 }
 781
 782 void turret_fire()
 783 {
 784     if (autocvar_g_turrets_nofire != 0)
 785         return;
 786
 787     self.turret_firefunc();
 788
 789     self.attack_finished_single = time + self.shot_refire;
 790     self.ammo -= self.shot_dmg;
 791     self.volly_counter = self.volly_counter - 1;
 792
 793     if (self.volly_counter <= 0)
 794     {
 795         self.volly_counter = self.shot_volly;
 796
 797         if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
 798             self.enemy = world;
 799
 800         if (self.shot_volly > 1)
 801             self.attack_finished_single = time + self.shot_volly_refire;
 802     }
 803
 804 #ifdef TURRET_DEBUG
 805     if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_dbg_rvec, self.tur_impacttime + 0.25);
 806 #endif
 807 }
 808
 809 void turret_stdproc_fire()
 810 {
 811     dprint("^1Bang, ^3your dead^7 ",self.enemy.netname,"! ^1(turret with no real firefunc)\n");
 812 }
 813
 814 /*
 815     When .used a turret switch team to activator.team.
 816     If activator is world, the turret go inactive.
 817 */
 818 void turret_stdproc_use()
 819 {
 820     dprint("Turret ",self.netname, " used by ", activator.classname, "\n");
 821
 822     self.team = activator.team;
 823
 824     if(self.team == 0)
 825         self.tur_active = 0;
 826     else
 827         self.tur_active = 1;
 828
 829 }
 830
 831 void turret_link()
 832 {
 833     //Net_LinkEntity(self, FALSE, 0, Turret_SendEntity);
 834     self.think      = turret_think;
 835     self.nextthink  = time;
 836 }
 837
 838 void turrets_manager_think()
 839 {
 840     self.nextthink = time + 1;
 841
 842     entity e;
 843     if (autocvar_g_turrets_reloadcvars == 1)
 844     {
 845         e = nextent(world);
 846         while (e)
 847         {
 848             if (e.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 849             {
 850                 load_unit_settings(e,e.cvar_basename,1);
 851                 if(e.turret_postthink)
 852                     e.turret_postthink();
 853             }
 854
 855             e = nextent(e);
 856         }
 857         cvar_set("g_turrets_reloadcvars","0");
 858     }
 859 }
 860
 861 /*
 862 * Standard turret initialization. use this!
 863 * (unless you have a very good reason not to)
 864 * if the return value is 0, the turret should be removed.
 865 */
 866 float turret_stdproc_init (string cvar_base_name, float csqc_shared, string base, string head)
 867 {
 868         entity e, ee;
 869
 870     // Are turrets allowed?
 871     if (autocvar_g_turrets == 0)
 872         return 0;
 873
 874
 875     e = find(world, classname, "turret_manager");
 876     if not (e)
 877     {
 878         e = spawn();
 879
 880         /*
 881         setorigin(e,'0 0 0');
 882         setmodel(e,"models/turrets/plasma.md3");
 883         vector v;
 884         v = gettaginfo(e,gettagindex(e,"tag_fire"));
 885         if(v == '0 0 0')
 886         {
 887             //objerror("^1ERROR: Engine is borken! Turrets will NOT work. force g_turrets to 0 to run maps with turrets anyway.");
 888             //crash();
 889         }
 890         setmodel(e,"");
 891         */
 892
 893         e.classname = "turret_manager";
 894         e.think = turrets_manager_think;
 895         e.nextthink = time + 2;
 896     }
 897
 898     if(csqc_shared)
 899     {
 900         dprint("WARNING: turret requested csqc_shared but this is not implemented. Expect strange things to happen.\n");
 901         csqc_shared = 0;
 902     }
 903
 904     if not (self.spawnflags & TSF_SUSPENDED)
 905         droptofloor_builtin();
 906
 907     // Terrainbase spawnflag. This puts a enlongated model
 908     // under the turret, so it looks ok on uneaven surfaces.
 909     if (self.spawnflags & TSF_TERRAINBASE)
 910     {
 911         entity tb;
 912         tb = spawn();
 913         setmodel(tb,"models/turrets/terrainbase.md3");
 914         setorigin(tb,self.origin);
 915         tb.solid = SOLID_BBOX;
 916     }
 917
 918     self.cvar_basename = cvar_base_name;
 919     load_unit_settings(self,self.cvar_basename, 0);
 920
 921     // Handle turret teams.
 922     if (autocvar_g_assault != 0)
 923     {
 924         if not (self.team)
 925             self.team = 14; // Assume turrets are on the defending side if not explicitly set otehrwize
 926     }
 927     else if not (teams_matter)
 928                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
 929         else if(g_onslaught && self.targetname)
 930         {
 931                 e = find(world,target,self.targetname);
 932                 if(e != world)
 933                 {
 934                         self.team = e.team;
 935                         ee = e;
 936                 }
 937         }
 938         else if(!self.team)
 939                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
 940
 941     /*
 942     * Try to guess some reasonaly defaults
 943     * for missing params and do sanety checks
 944     * thise checks could produce some "interesting" results
 945     * if it hits a glitch in my logic :P so try to set as mutch
 946     * as possible beforehand.
 947     */
 948     if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
 949         self.ticrate = 0.2;     // Support units generaly dont need to have a high speed ai-loop
 950     else
 951         self.ticrate = 0.1;     // 10 fps for normal turrets
 952
 953     self.ticrate = bound(sys_frametime, self.ticrate, 60);  // keep it sane
 954
 955 // General stuff
 956     if (self.netname == "")
 957         self.netname = self.classname;
 958
 959     if not (self.respawntime)
 960         self.respawntime = 60;
 961     self.respawntime = max(-1, self.respawntime);
 962
 963     if not (self.health)
 964         self.health = 1000;
 965     self.tur_health = max(1, self.health);
 966
 967     if not (self.turrcaps_flags)
 968         self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL;
 969
 970     if not (self.damage_flags)
 971         self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE;
 972
 973 // Shot stuff.
 974     if not (self.shot_refire)
 975         self.shot_refire = 1;
 976     self.shot_refire = bound(0.01, self.shot_refire, 9999);
 977
 978     if not (self.shot_dmg)
 979         self.shot_dmg  = self.shot_refire * 50;
 980     self.shot_dmg = max(1, self.shot_dmg);
 981
 982     if not (self.shot_radius)
 983         self.shot_radius = self.shot_dmg * 0.5;
 984     self.shot_radius = max(1, self.shot_radius);
 985
 986     if not (self.shot_speed)
 987         self.shot_speed = 2500;
 988     self.shot_speed = max(1, self.shot_speed);
 989
 990     if not (self.shot_spread)
 991         self.shot_spread = 0.0125;
 992     self.shot_spread = bound(0.0001, self.shot_spread, 500);
 993
 994     if not (self.shot_force)
 995         self.shot_force = self.shot_dmg * 0.5 + self.shot_radius * 0.5;
 996     self.shot_force = bound(0.001, self.shot_force, 5000);
 997
 998     if not (self.shot_volly)
 999         self.shot_volly = 1;
1000     self.shot_volly = bound(1, self.shot_volly, floor(self.ammo_max / self.shot_dmg));
1001
1002     if not (self.shot_volly_refire)
1003         self.shot_volly_refire = self.shot_refire * self.shot_volly;
1004     self.shot_volly_refire = bound(self.shot_refire, self.shot_volly_refire, 60);
1005
1006     if not (self.firecheck_flags)
1007         self.firecheck_flags = TFL_FIRECHECK_WORLD | TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES |
1008                                TFL_FIRECHECK_LOS | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCECK |
1009                                TFL_FIRECHECK_OWM_AMMO | TFL_FIRECHECK_REFIRE | TFL_FIRECHECK_WORLD;
1010
1011 // Range stuff.
1012     if not (self.target_range)
1013         self.target_range = self.shot_speed * 0.5;
1014     self.target_range = bound(0, self.target_range, MAX_SHOT_DISTANCE);
1015
1016     if not (self.target_range_min)
1017         self.target_range_min = self.shot_radius * 2;
1018     self.target_range_min = bound(0, self.target_range_min, MAX_SHOT_DISTANCE);
1019
1020     if not (self.target_range_optimal)
1021         self.target_range_optimal = self.target_range * 0.5;
1022     self.target_range_optimal = bound(0, self.target_range_optimal, MAX_SHOT_DISTANCE);
1023
1024
1025 // Aim stuff.
1026     if not (self.aim_maxrot)
1027         self.aim_maxrot = 90;
1028     self.aim_maxrot = bound(0, self.aim_maxrot, 360);
1029
1030     if not (self.aim_maxpitch)
1031         self.aim_maxpitch = 20;
1032     self.aim_maxpitch = bound(0, self.aim_maxpitch, 90);
1033
1034     if not (self.aim_speed)
1035         self.aim_speed = 36;
1036     self.aim_speed  = bound(0.1, self.aim_speed, 1000);
1037
1038     if not (self.aim_firetolerance_dist)
1039         self.aim_firetolerance_dist  = 5 + (self.shot_radius * 2);
1040     self.aim_firetolerance_dist = bound(0.1, self.aim_firetolerance_dist, MAX_SHOT_DISTANCE);
1041
1042     if not (self.aim_flags)
1043     {
1044         self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;
1045         if(self.turrcaps_flags & TFL_TURRCAPS_RADIUSDMG)
1046             self.aim_flags |= TFL_AIM_GROUND2;
1047     }
1048
1049     if not (self.track_type)
1050         self.track_type = TFL_TRACKTYPE_STEPMOTOR;
1051
1052     if (self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1053     {
1054         // Fluid / Ineria mode. Looks mutch nicer.
1055         // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1056
1057         if not (self.aim_speed)
1058             self.aim_speed = 180;
1059         self.aim_speed = bound(0.1, self.aim_speed, 1000);
1060
1061         if not (self.track_accel_pitch)
1062             self.track_accel_pitch = 0.5;
1063
1064         if not (self.track_accel_rot)
1065             self.track_accel_rot   = 0.5;
1066
1067         if not (self.track_blendrate)
1068             self.track_blendrate   = 0.35;
1069     }
1070
1071     if (!self.track_flags)
1072         self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROT;
1073
1074
1075 // Target selection stuff.
1076     if not (self.target_select_rangebias)
1077         self.target_select_rangebias = 1;
1078     self.target_select_rangebias = bound(-10, self.target_select_rangebias, 10);
1079
1080     if not (self.target_select_samebias)
1081         self.target_select_samebias = 1;
1082     self.target_select_samebias = bound(-10, self.target_select_samebias, 10);
1083
1084     if not (self.target_select_anglebias)
1085         self.target_select_anglebias = 1;
1086     self.target_select_anglebias = bound(-10, self.target_select_anglebias, 10);
1087
1088     if not (self.target_select_missilebias)
1089         self.target_select_missilebias = -10;
1090
1091     self.target_select_missilebias = bound(-10, self.target_select_missilebias, 10);
1092     self.target_select_playerbias = bound(-10, self.target_select_playerbias, 10);
1093
1094     if not (self.target_select_flags)
1095     {
1096             self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK
1097                                      | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_ANGLELIMITS;
1098
1099         if (self.turrcaps_flags & TFL_TURRCAPS_MISSILEKILL)
1100             self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1101
1102         if (self.turrcaps_flags & TFL_TURRCAPS_PLAYERKILL)
1103             self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1104         //else
1105         //    self.target_select_flags = TFL_TARGETSELECT_NO;
1106     }
1107
1108     self.target_validate_flags = self.target_select_flags;
1109
1110
1111 // Ammo stuff
1112     if not (self.ammo_max)
1113         self.ammo_max = self.shot_dmg * 10;
1114     self.ammo_max = max(self.shot_dmg, self.ammo_max);
1115
1116     if not (self.ammo)
1117         self.ammo = self.shot_dmg * 5;
1118     self.ammo = bound(0,self.ammo, self.ammo_max);
1119
1120     if not (self.ammo_recharge)
1121         self.ammo_recharge = self.shot_dmg * 0.5;
1122     self.ammo_recharge = max(0 ,self.ammo_recharge);
1123
1124     // Convert the recharge from X per sec to X per ticrate
1125     self.ammo_recharge = self.ammo_recharge * self.ticrate;
1126
1127     if not (self.ammo_flags)
1128         self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE;
1129
1130 // Damage stuff
1131     if(self.spawnflags & TSL_NO_RESPAWN)
1132         if not (self.damage_flags & TFL_DMG_DEATH_NORESPAWN)
1133             self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1134
1135 // Offsets & origins
1136     if (!self.tur_shotorg)   self.tur_shotorg = '50 0 50';
1137
1138 // Gane hooks
1139         if(MUTATOR_CALLHOOK(TurretSpawn))
1140                 return 0;
1141
1142 // End of default & sanety checks, start building the turret.
1143
1144 // Spawn extra bits
1145     self.tur_head         = spawn();
1146     self.tur_head.netname = self.tur_head.classname = "turret_head";
1147     self.tur_head.team    = self.team;
1148     self.tur_head.owner   = self;
1149
1150     setmodel(self, base);
1151     setmodel(self.tur_head, head);
1152
1153     setsize(self, '-32 -32 0', '32 32 64');
1154     setsize(self.tur_head, '0 0 0', '0 0 0');
1155
1156     setorigin(self.tur_head, '0 0 0');
1157     setattachment(self.tur_head, self, "tag_head");
1158
1159     if (!self.health)
1160         self.health = 150;
1161
1162     self.tur_health          = self.health;
1163     self.solid               = SOLID_BBOX;
1164     self.tur_head.solid      = SOLID_NOT;
1165     self.takedamage          = DAMAGE_AIM;
1166     self.tur_head.takedamage = DAMAGE_NO;
1167     self.movetype            = MOVETYPE_NOCLIP;
1168     self.tur_head.movetype   = MOVETYPE_NOCLIP;
1169
1170     // Defend mode?
1171     if not (self.tur_defend)
1172     if (self.target != "")
1173     {
1174         self.tur_defend = find(world, targetname, self.target);
1175         if (self.tur_defend == world)
1176         {
1177             self.target = "";
1178             dprint("Turret has invalid defendpoint!\n");
1179         }
1180     }
1181
1182     // In target defend mode, aim on the spot to defend when idle.
1183     if (self.tur_defend)
1184         self.idle_aim  = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1185     else
1186         self.idle_aim  = '0 0 0';
1187
1188     // Team color
1189     if (self.team == COLOR_TEAM1) self.colormod = '1.4 0.8 0.8';
1190     if (self.team == COLOR_TEAM2) self.colormod = '0.8 0.8 1.4';
1191
1192     // Attach stdprocs. override when and what needed
1193     if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
1194     {
1195         self.turret_score_target    = turret_stdproc_targetscore_support;
1196         self.turret_firecheckfunc   = turret_stdproc_firecheck;
1197         self.turret_firefunc        = turret_stdproc_fire;
1198         self.event_damage           = turret_stdproc_damage;
1199     }
1200     else
1201     {
1202         self.turret_score_target    = turret_stdproc_targetscore_generic;
1203         self.turret_firecheckfunc   = turret_stdproc_firecheck;
1204         self.turret_firefunc        = turret_stdproc_fire;
1205         self.event_damage           = turret_stdproc_damage;
1206     }
1207
1208     self.use = turret_stdproc_use;
1209     self.bot_attack = TRUE;
1210
1211     // Initiate the main AI loop
1212     if(csqc_shared)
1213         self.think     = turret_link;
1214     else
1215         self.think     = turret_think;
1216
1217     ++turret_count;
1218     self.nextthink = time + 1;
1219     self.nextthink +=  turret_count * sys_frametime;
1220
1221     self.tur_head.team = self.team;
1222     self.view_ofs = '0 0 0';
1223
1224 #ifdef TURRET_DEBUG
1225     self.tur_dbg_start = self.nextthink;
1226     while (vlen(self.tur_dbg_rvec) < 2)
1227         self.tur_dbg_rvec  = randomvec() * 4;
1228
1229     self.tur_dbg_rvec_x = fabs(self.tur_dbg_rvec_x);
1230     self.tur_dbg_rvec_y = fabs(self.tur_dbg_rvec_y);
1231     self.tur_dbg_rvec_z = fabs(self.tur_dbg_rvec_z);
1232 #endif
1233
1234     // Its all good.
1235     self.turrcaps_flags |= TFL_TURRCAPS_ISTURRET;
1236
1237     self.classname = "turret_main";
1238
1239     self.tur_active = 1;
1240
1241     // In ONS mode, and linked to a ONS ent. need to call the use to set team.
1242     if (g_onslaught && ee)
1243     {
1244         activator = ee;
1245         self.use();
1246     }
1247
1248         turret_stdproc_respawn();
1249     return 1;
1250 }
1251
1252