qcsrc/server/tturrets/units/unit_flac.qc

   1 void spawnfunc_turret_flac();
   2 void turret_flac_dinit();
   3 void turret_flac_attack();
   4 void turret_flac_projectile_explode();
   5
   6 void turret_flac_attack()
   7 {
   8     local entity proj;
   9
  10     turret_tag_fire_update();
  11
  12     sound (self, CHAN_WEAPON, "weapons/hagar_fire.wav", VOL_BASE, ATTN_NORM);
  13     proj = spawn ();
  14     setorigin(proj, self.tur_shotorg);
  15     setsize(proj, '0 0 0', '0 0 0');
  16     proj.classname          = "flac_projectile";
  17     proj.owner              = self;
  18     proj.bot_dodge          = TRUE;
  19     proj.bot_dodgerating    = self.shot_dmg;
  20     proj.solid              = SOLID_BBOX;
  21     proj.movetype           = MOVETYPE_FLYMISSILE;
  22     proj.flags              = FL_PROJECTILE;
  23     proj.takedamage         = DAMAGE_NO;
  24     proj.velocity           = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
  25     proj.angles             = vectoangles(proj.velocity);
  26     proj.touch              = turret_flac_projectile_explode;
  27     proj.think              = turret_flac_projectile_explode;
  28     proj.nextthink          = time + max(self.tur_impacttime,(self.shot_radius * 3) / self.shot_speed);
  29     proj.enemy              = self.enemy;
  30     proj.cnt                = time + 5;
  31
  32     CSQCProjectile(proj, TRUE, PROJECTILE_HAGAR, TRUE);
  33
  34     self.tur_head.frame = self.tur_head.frame + 1;
  35     if (self.tur_head.frame >= 4) self.tur_head.frame = 0;
  36
  37 }
  38
  39 void turret_flac_projectile_explode()
  40 {
  41     float ftmp;
  42
  43     // FIXME: tur_impacttime is not accurate enougth, this is a dirty hakk to make flac work.
  44
  45     //w_deathtypestring = "got caught in the flack.";
  46
  47
  48
  49     if( (self.enemy != world) &&
  50         (vlen(self.origin - self.enemy.origin) < self.owner.shot_radius * 3) )
  51     {
  52         // OMG HAXX!
  53         setorigin(self,self.enemy.origin + randomvec() * self.owner.shot_radius);
  54     }
  55
  56
  57
  58     te_explosion (self.origin);
  59
  60     ftmp = crandom();
  61     if (ftmp<-0.7)
  62         sound (self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
  63     else if (ftmp<0.4)
  64         sound (self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
  65     else if (ftmp<1)
  66         sound (self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
  67
  68
  69     self.event_damage = SUB_Null;
  70
  71
  72 #ifdef TURRET_DEBUG
  73     ftmp = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);
  74     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + ftmp; //self.owner.shot_dmg;
  75     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;
  76 #else
  77     RadiusDamage (self, self.owner, self.owner.shot_dmg, self.owner.shot_dmg * 0.5, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);
  78 #endif
  79
  80     remove (self);
  81 }
  82
  83
  84 void turret_flac_dinit()
  85 {
  86     if (self.netname == "")      self.netname  = "FLAC Cannon";
  87
  88     self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_FASTPROJ | TFL_TURRCAPS_MISSILEKILL;
  89     self.ammo_flags     = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;
  90     self.aim_flags      = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;
  91
  92     if (turret_stdproc_init("flac_std",0,"models/turrets/base.md3","models/turrets/flac.md3") == 0)
  93     {
  94         remove(self);
  95         return;
  96     }
  97     setsize(self.tur_head,'-32 -32 0','32 32 64');
  98
  99     self.damage_flags |= TFL_DMG_HEADSHAKE;
 100     self.target_select_flags |= TFL_TARGETSELECT_NOTURRETS | TFL_TARGETSELECT_MISSILESONLY;
 101
 102     if (!turret_tag_fire_update())
 103         dprint("Warning: Turret ",self.classname, " faild to initialize md3 tags\n");
 104
 105     // Our fire routine
 106     self.turret_firefunc  = turret_flac_attack;
 107
 108 }
 109 /*QUAKED turret_flac (0 .5 .8) ?
 110 */
 111
 112 void spawnfunc_turret_flac()
 113 {
 114     precache_model ("models/turrets/base.md3");
 115     precache_model ("models/turrets/flac.md3");
 116
 117     self.think = turret_flac_dinit;
 118     self.nextthink = time + 0.5;
 119 }
 120