qcsrc/server/tturrets/units/unit_mlrs.qc

   1 void spawnfunc_turret_mlrs();
   2 void turret_mlrs_dinit();
   3 void turret_mlrs_attack();
   4 void turret_mlrs_rocket_explode();
   5 void turret_mlrs_rocket_touch();
   6
   7 void turret_mlrs_postthink()
   8 {
   9
  10     // 0 = full, 6 = empty
  11     self.tur_head.frame = rint(6 - (self.ammo / self.shot_dmg));
  12 }
  13
  14 void turret_mlrs_attack()
  15 {
  16     entity missile;
  17
  18     turret_tag_fire_update();
  19
  20     sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", VOL_BASE, ATTN_NORM);
  21
  22     missile                    = spawn ();
  23     setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
  24     setorigin(missile, self.tur_shotorg);
  25     missile.classname          = "mlrs_missile";
  26     missile.owner              = self;
  27     missile.bot_dodge          = TRUE;
  28     missile.bot_dodgerating    = self.shot_dmg;
  29     missile.takedamage         = DAMAGE_NO;
  30     missile.damageforcescale   = 4;
  31     missile.think              = turret_mlrs_rocket_explode;
  32     missile.nextthink          = time + max(self.tur_impacttime,(self.shot_radius * 2) / self.shot_speed);
  33     missile.solid              = SOLID_BBOX;
  34     missile.movetype           = MOVETYPE_FLYMISSILE;
  35     missile.velocity           = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
  36     missile.angles             = vectoangles(missile.velocity);
  37     missile.touch              = turret_mlrs_rocket_touch;
  38     missile.flags              = FL_PROJECTILE;
  39     missile.solid              = SOLID_BBOX;
  40     missile.enemy              = self.enemy;
  41
  42         CSQCProjectile(missile, TRUE, PROJECTILE_ROCKET, FALSE); // no cull, fly sound
  43
  44     te_explosion (missile.origin);
  45 }
  46
  47 void turret_mlrs_rocket_touch()
  48 {
  49     if( (other == self.owner) || (other == self.owner.tur_head) )
  50         return;
  51
  52     PROJECTILE_TOUCH;
  53
  54     turret_mlrs_rocket_explode();
  55 }
  56
  57 void turret_mlrs_rocket_explode()
  58 {
  59     vector org2;
  60
  61     if(self.event_damage != SUB_Null)
  62     {
  63         self.event_damage = SUB_Null;
  64         self.think = turret_mlrs_rocket_explode;
  65         self.nextthink = time;
  66         return;
  67     }
  68
  69
  70     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  71     org2 = findbetterlocation (self.origin, 16);
  72     pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  73     //w_deathtypestring = "dident escape the rocket barrage";
  74 #ifdef TURRET_DEBUG
  75     float d;
  76
  77     d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);
  78     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + d; //self.owner.shot_dmg;
  79     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;
  80 #else
  81     RadiusDamage (self, self.owner, self.owner.shot_dmg, self.owner.shot_dmg * 0.5, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);
  82 #endif
  83
  84     // Target dead, Tell turret.
  85     if ((self.enemy.deadflag != DEAD_NO) && (self.enemy == self.owner.enemy))
  86         self.owner.enemy = world;
  87
  88     remove (self);
  89 }
  90
  91 void turret_mlrs_dinit()
  92 {
  93     if (self.netname == "")      self.netname  = "MLRS turret";
  94
  95     self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL;
  96     self.ammo_flags = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;
  97     self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;// | TFL_AIM_GROUND2;
  98
  99     if (turret_stdproc_init("mlrs_std",0,"models/turrets/base.md3","models/turrets/mlrs.md3") == 0)
 100     {
 101         remove(self);
 102         return;
 103     }
 104
 105     self.damage_flags |= TFL_DMG_HEADSHAKE;
 106     self.shoot_flags  |= TFL_SHOOT_VOLLYALWAYS;
 107     self.volly_counter = self.shot_volly;
 108
 109     if (!turret_tag_setup())
 110         dprint("Warning: Turret ",self.classname, " faild to initialize md3 tags\n");
 111
 112     // Our fire routine
 113     self.turret_firefunc  = turret_mlrs_attack;
 114     self.turret_postthink = turret_mlrs_postthink;
 115
 116 }
 117
 118 /*QUAKED turret_mlrs (0 .5 .8) ?
 119 */
 120
 121 void spawnfunc_turret_mlrs()
 122 {
 123     precache_model ("models/turrets/mlrs.md3");
 124     precache_model ("models/turrets/base.md3");
 125
 126     self.think = turret_mlrs_dinit;
 127     self.nextthink = time + 0.5;
 128 }
 129
 130