qcsrc/server/vehicles/bumblebee.qc

   1 #define BRG_SETUP 2
   2 #define BRG_START 4
   3 #define BRG_END 8
   4
   5 #ifdef SVQC
   6 // Auto cvars
   7 float autocvar_g_vehicle_bumblebee_speed_forward;
   8 float autocvar_g_vehicle_bumblebee_speed_strafe;
   9 float autocvar_g_vehicle_bumblebee_speed_up;
  10 float autocvar_g_vehicle_bumblebee_speed_down;
  11 float autocvar_g_vehicle_bumblebee_turnspeed;
  12 float autocvar_g_vehicle_bumblebee_pitchspeed;
  13 float autocvar_g_vehicle_bumblebee_pitchlimit;
  14 float autocvar_g_vehicle_bumblebee_friction;
  15
  16 float autocvar_g_vehicle_bumblebee_energy;
  17 float autocvar_g_vehicle_bumblebee_energy_regen;
  18 float autocvar_g_vehicle_bumblebee_energy_regen_pause;
  19
  20 float autocvar_g_vehicle_bumblebee_health;
  21 float autocvar_g_vehicle_bumblebee_health_regen;
  22 float autocvar_g_vehicle_bumblebee_health_regen_pause;
  23
  24 float autocvar_g_vehicle_bumblebee_shield;
  25 float autocvar_g_vehicle_bumblebee_shield_regen;
  26 float autocvar_g_vehicle_bumblebee_shield_regen_pause;
  27
  28 float autocvar_g_vehicle_bumblebee_cannon_cost;
  29 float autocvar_g_vehicle_bumblebee_cannon_damage;
  30 float autocvar_g_vehicle_bumblebee_cannon_radius;
  31 float autocvar_g_vehicle_bumblebee_cannon_refire;
  32 float autocvar_g_vehicle_bumblebee_cannon_speed;
  33 float autocvar_g_vehicle_bumblebee_cannon_spread;
  34 float autocvar_g_vehicle_bumblebee_cannon_force;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo;
  37 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen;
  38 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause;
  39
  40 var float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  41
  42 float autocvar_g_vehicle_bumblebee_cannon_turnspeed;
  43 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down;
  44 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up;
  45 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  46 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  47
  48
  49 float autocvar_g_vehicle_bumblebee_raygun_turnspeed;
  50 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down;
  51 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up;
  52 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides;
  53
  54 float autocvar_g_vehicle_bumblebee_raygun_range;
  55 float autocvar_g_vehicle_bumblebee_raygun_dps;
  56 float autocvar_g_vehicle_bumblebee_raygun_aps;
  57 float autocvar_g_vehicle_bumblebee_raygun_fps;
  58
  59 float autocvar_g_vehicle_bumblebee_raygun;
  60 float autocvar_g_vehicle_bumblebee_healgun_hps;
  61 float autocvar_g_vehicle_bumblebee_healgun_hmax;
  62 float autocvar_g_vehicle_bumblebee_healgun_aps;
  63 float autocvar_g_vehicle_bumblebee_healgun_amax;
  64 float autocvar_g_vehicle_bumblebee_healgun_sps;
  65 float autocvar_g_vehicle_bumblebee_healgun_locktime;
  66
  67 float autocvar_g_vehicle_bumblebee_respawntime;
  68
  69 float autocvar_g_vehicle_bumblebee_blowup_radius;
  70 float autocvar_g_vehicle_bumblebee_blowup_coredamage;
  71 float autocvar_g_vehicle_bumblebee_blowup_edgedamage;
  72 float autocvar_g_vehicle_bumblebee_blowup_forceintensity;
  73 var vector autocvar_g_vehicle_bumblebee_bouncepain;
  74
  75 var float autocvar_g_vehicle_bumblebee = 0;
  76
  77
  78 float bumble_raygun_send(entity to, float sf);
  79
  80 #define BUMB_MIN '-130 -130 -130'
  81 #define BUMB_MAX '130 130 130'
  82
  83 void bumb_fire_cannon(entity _gun, string _tagname, entity _owner)
  84 {
  85         vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
  86         vehicles_projectile("bigplasma_muzzleflash", "weapons/flacexp3.wav",
  87                                                 v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  88                                                 autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  89                                                 DEATH_BUMB_GUN, PROJECTILE_BUMBLE_GUN, 0, TRUE, TRUE, _owner);
  90 }
  91
  92 float bumb_gunner_frame()
  93 {
  94         entity vehic    = self.vehicle.owner;
  95         entity gun      = self.vehicle;
  96         entity gunner   = self;
  97         self = vehic;
  98
  99
 100
 101
 102         vehic.solid = SOLID_NOT;
 103         //setorigin(gunner, vehic.origin);
 104         gunner.velocity = vehic.velocity;
 105
 106         float _in, _out;
 107         vehic.angles_x *= -1;
 108         makevectors(vehic.angles);
 109         vehic.angles_x *= -1;
 110         if((gun == vehic.gun1))
 111         {
 112                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 113                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 114                 setorigin(gunner, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 115         }
 116         else
 117         {
 118                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 119                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 120                 setorigin(gunner, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 121         }
 122
 123         crosshair_trace(gunner);
 124         vector _ct = trace_endpos;
 125         vector ad;
 126
 127         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 128         {
 129                 if(gun.lock_time < time)
 130                         gun.enemy = world;
 131
 132                 if(trace_ent)
 133                         if(trace_ent.movetype)
 134                                 if(trace_ent.takedamage)
 135                                         if(!trace_ent.deadflag)
 136                                         {
 137                                                 if(teamplay)
 138                                                 {
 139                                                         if(trace_ent.team != gunner.team)
 140                                                         {
 141                                                                 gun.enemy = trace_ent;
 142                                                                 gun.lock_time = time + 5;
 143                                                         }
 144                                                 }
 145                                                 else
 146                                                 {
 147                                                         gun.enemy = trace_ent;
 148                                                         gun.lock_time = time + 5;
 149                                                 }
 150                                         }
 151         }
 152
 153         if(gun.enemy)
 154         {
 155                 float i, distance, impact_time;
 156
 157                 vector vf = real_origin(gun.enemy);
 158                 vector _vel = gun.enemy.velocity;
 159                 if(gun.enemy.movetype == MOVETYPE_WALK)
 160                         _vel_z *= 0.1;
 161
 162
 163                 ad = vf;
 164                 for(i = 0; i < 4; ++i)
 165                 {
 166                         distance = vlen(ad - gunner.origin);
 167                         impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 168                         ad = vf + _vel * impact_time;
 169                 }
 170                 trace_endpos = ad;
 171
 172
 173                 UpdateAuxiliaryXhair(gunner, ad, '1 0 1', 1);
 174                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 175                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 176                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 177
 178         }
 179         else
 180                 vehicle_aimturret(vehic, _ct, gun, "fire",
 181                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 182                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 183
 184         if(gunner.BUTTON_ATCK)
 185                 if(time > gun.attack_finished_single)
 186                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 187                         {
 188                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 189                                 bumb_fire_cannon(gun, "fire", gunner);
 190                                 gun.delay = time;
 191                                 gun.attack_finished_single = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 192                         }
 193
 194         VEHICLE_UPDATE_PLAYER(gunner, health, bumblebee);
 195
 196         if(vehic.vehicle_flags & VHF_HASSHIELD)
 197                 VEHICLE_UPDATE_PLAYER(gunner, shield, bumblebee);
 198
 199         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 200         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 201
 202         UpdateAuxiliaryXhair(gunner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), 0);
 203
 204         if(vehic.owner)
 205                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), ((gunner == vehic.gunner1) ? 1 : 2));
 206
 207         vehic.solid = SOLID_BBOX;
 208         gunner.BUTTON_ATCK = gunner.BUTTON_ATCK2 = gunner.BUTTON_CROUCH = 0;
 209         gunner.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 210
 211         self = gunner;
 212         return 1;
 213 }
 214
 215 void bumb_gunner_exit(float _exitflag)
 216 {
 217
 218
 219         if(clienttype(self) == CLIENTTYPE_REAL)
 220         {
 221                 msg_entity = self;
 222                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 223                 WriteEntity(MSG_ONE, self);
 224
 225                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 226                 WriteAngle(MSG_ONE, 0);
 227                 WriteAngle(MSG_ONE, self.vehicle.angles_y);
 228                 WriteAngle(MSG_ONE, 0);
 229         }
 230
 231         CSQCVehicleSetup(self, HUD_NORMAL);
 232         setsize(self, PL_MIN, PL_MAX);
 233
 234         self.takedamage     = DAMAGE_AIM;
 235         self.solid          = SOLID_SLIDEBOX;
 236         self.movetype       = MOVETYPE_WALK;
 237         self.effects        &~= EF_NODRAW;
 238         self.alpha          = 1;
 239         self.PlayerPhysplug = SUB_Null;
 240         self.view_ofs       = PL_VIEW_OFS;
 241         self.event_damage   = PlayerDamage;
 242         self.hud            = HUD_NORMAL;
 243         self.switchweapon   = self.vehicle.switchweapon;
 244
 245         if(self.flagcarried)
 246         {
 247                 self.flagcarried.scale = 0.6;
 248                 setattachment(self.flagcarried, self, "");
 249                 setorigin(self.flagcarried, FLAG_CARRY_POS);
 250         }
 251
 252         self.vehicle.vehicle_hudmodel.viewmodelforclient = self.vehicle;
 253
 254         fixedmakevectors(self.vehicle.owner.angles);
 255
 256         if(self == self.vehicle.owner.gunner1)
 257         {
 258                 self.vehicle.owner.gunner1 = world;
 259         }
 260         else if(self == self.vehicle.owner.gunner2)
 261         {
 262                 self.vehicle.owner.gunner2 = world;
 263                 v_right *= -1;
 264         }
 265         else
 266                 dprint("^1self != gunner1 or gunner2, this is a BIG PROBLEM, tell tZork this happend.\n");
 267
 268         vector spot = self.vehicle.owner.origin + + v_up * 128 + v_right * 300;
 269         spot = vehicles_findgoodexit(spot);
 270         //setorigin(self , spot);
 271
 272         self.velocity = 0.75 * self.vehicle.owner.velocity + normalize(spot - self.vehicle.owner.origin) * 200;
 273         self.velocity_z += 10;
 274
 275         self.vehicle.phase = time + 5;
 276         self.vehicle        = world;
 277 }
 278
 279 float bumb_gunner_enter()
 280 {
 281         RemoveGrapplingHook(other);
 282         entity _gun, _gunner;
 283         if(!self.gunner1)
 284         {
 285                 _gun = self.gun1;
 286                 _gunner = self.gunner1;
 287                 self.gunner1 = other;
 288         }
 289         else if(!self.gunner2)
 290         {
 291                 _gun = self.gun2;
 292                 _gunner = self.gunner2;
 293                 self.gunner2 = other;
 294         }
 295         else
 296         {
 297                 dprint("^1ERROR:^7Tried to enter a fully occupied vehicle!\n");
 298                 return FALSE;
 299         }
 300
 301         _gunner            = other;
 302         _gunner.vehicle    = _gun;
 303         _gun.switchweapon  = other.switchweapon;
 304         _gun.vehicle_exit  = bumb_gunner_exit;
 305
 306         other.angles            = self.angles;
 307         other.takedamage        = DAMAGE_NO;
 308         other.solid             = SOLID_NOT;
 309         other.movetype          = MOVETYPE_NOCLIP;
 310         other.alpha             = -1;
 311         other.event_damage      = SUB_Null;
 312         other.view_ofs          = '0 0 0';
 313         other.hud               = _gun.hud;
 314         other.PlayerPhysplug    = _gun.PlayerPhysplug;
 315         other.vehicle_ammo1     = self.vehicle_ammo1;
 316         other.vehicle_ammo2     = self.vehicle_ammo2;
 317         other.vehicle_reload1   = self.vehicle_reload1;
 318         other.vehicle_reload2   = self.vehicle_reload2;
 319         other.vehicle_energy    = self.vehicle_energy;
 320         other.PlayerPhysplug    = bumb_gunner_frame;
 321         other.flags             &~= FL_ONGROUND;
 322
 323         msg_entity = other;
 324         WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 325         WriteEntity(MSG_ONE, _gun.vehicle_viewport);
 326         WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 327         WriteAngle(MSG_ONE, _gun.angles_x + self.angles_x);    // tilt
 328         WriteAngle(MSG_ONE, _gun.angles_y + self.angles_y);    // yaw
 329         WriteAngle(MSG_ONE, 0);                             // roll
 330         _gun.vehicle_hudmodel.viewmodelforclient = other;
 331
 332         CSQCVehicleSetup(other, other.hud);
 333
 334     if(other.flagcarried)
 335     {
 336         if(!autocvar_g_vehicles_allow_flagcarry)
 337             DropFlag(other.flagcarried, world, world);
 338         else
 339         {
 340             other.flagcarried.scale = 1;
 341             setattachment(other.flagcarried, self, "");
 342             setorigin(other.flagcarried, '0 0 1' * self.maxs_z);
 343         }
 344     }
 345
 346         return TRUE;
 347 }
 348
 349 float vehicles_valid_pilot()
 350 {
 351         if(other.classname != "player")
 352                 return FALSE;
 353
 354         if(other.deadflag != DEAD_NO)
 355                 return FALSE;
 356
 357         if(other.vehicle != world)
 358                 return FALSE;
 359
 360         if(clienttype(other) != CLIENTTYPE_REAL)
 361                 if(!autocvar_g_vehicles_allow_bots)
 362                         return FALSE;
 363
 364         if(teamplay && other.team != self.team)
 365                 return FALSE;
 366
 367         return TRUE;
 368 }
 369
 370 void bumb_touch()
 371 {
 372
 373         if(self.gunner1 != world && self.gunner2 != world)
 374         {
 375                 vehicles_touch();
 376                 return;
 377         }
 378
 379         if(vehicles_valid_pilot())
 380         {
 381                 if(self.gun1.phase <= time)
 382                         if(bumb_gunner_enter())
 383                                 return;
 384
 385                 if(self.gun2.phase <= time)
 386                         if(bumb_gunner_enter())
 387                                 return;
 388         }
 389
 390         vehicles_touch();
 391 }
 392
 393 void bumb_regen()
 394 {
 395         if(self.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 396                 self.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 397                                                                            self.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 398
 399         if(self.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 400                 self.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 401                                                                            self.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 402
 403         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 404                 vehicles_regen(self.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, TRUE);
 405
 406         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 407                 vehicles_regen(self.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, FALSE);
 408
 409         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 410                 vehicles_regen(self.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, FALSE);
 411
 412 }
 413
 414 float bumb_pilot_frame()
 415 {
 416         entity pilot, vehic;
 417         vector newvel;
 418
 419         pilot = self;
 420         vehic = self.vehicle;
 421         self   = vehic;
 422
 423
 424         if(vehic.deadflag != DEAD_NO)
 425         {
 426                 self = pilot;
 427                 pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = 0;
 428                 return 1;
 429         }
 430
 431         bumb_regen();
 432
 433         crosshair_trace(pilot);
 434
 435         vector vang;
 436         float ftmp;
 437
 438         vang = vehic.angles;
 439         newvel = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 440         vang_x *= -1;
 441         newvel_x *= -1;
 442         if(newvel_x > 180)  newvel_x -= 360;
 443         if(newvel_x < -180) newvel_x += 360;
 444         if(newvel_y > 180)  newvel_y -= 360;
 445         if(newvel_y < -180) newvel_y += 360;
 446
 447         ftmp = shortangle_f(pilot.v_angle_y - vang_y, vang_y);
 448         if(ftmp > 180)  ftmp -= 360;
 449         if(ftmp < -180) ftmp += 360;
 450         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 451
 452         // Pitch
 453         ftmp = 0;
 454         if(pilot.movement_x > 0 && vang_x < autocvar_g_vehicle_bumblebee_pitchlimit)
 455                 ftmp = 4;
 456         else if(pilot.movement_x < 0 && vang_x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 457                 ftmp = -8;
 458
 459         newvel_x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x , autocvar_g_vehicle_bumblebee_pitchlimit);
 460         ftmp = vang_x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 461         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 462
 463         vehic.angles_x = anglemods(vehic.angles_x);
 464         vehic.angles_y = anglemods(vehic.angles_y);
 465         vehic.angles_z = anglemods(vehic.angles_z);
 466
 467         makevectors('0 1 0' * vehic.angles_y);
 468         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 469
 470         if(pilot.movement_x != 0)
 471         {
 472                 if(pilot.movement_x > 0)
 473                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 474                 else if(pilot.movement_x < 0)
 475                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 476         }
 477
 478         if(pilot.movement_y != 0)
 479         {
 480                 if(pilot.movement_y < 0)
 481                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 482                 else if(pilot.movement_y > 0)
 483                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 484                 ftmp = newvel * v_right;
 485                 ftmp *= frametime * 0.1;
 486                 vehic.angles_z = bound(-15, vehic.angles_z + ftmp, 15);
 487         }
 488         else
 489         {
 490                 vehic.angles_z *= 0.95;
 491                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 492                         vehic.angles_z = 0;
 493         }
 494
 495         if(pilot.BUTTON_CROUCH)
 496                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 497         else if(pilot.BUTTON_JUMP)
 498                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 499
 500         vehic.velocity  += newvel * frametime;
 501         pilot.velocity = pilot.movement  = vehic.velocity;
 502
 503
 504         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 505         {
 506                 if(vehic.tur_head.lock_time < time || vehic.tur_head.enemy.deadflag)
 507                         vehic.tur_head.enemy = world;
 508
 509                 if(trace_ent)
 510                 if(trace_ent.movetype)
 511                 if(trace_ent.takedamage)
 512                 if(!trace_ent.deadflag)
 513                 {
 514                         if(teamplay)
 515                         {
 516                                 if(trace_ent.team == pilot.team)
 517                                 {
 518                                         vehic.tur_head.enemy = trace_ent;
 519                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 520                                 }
 521                         }
 522                         else
 523                         {
 524                                 vehic.tur_head.enemy = trace_ent;
 525                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 526                         }
 527                 }
 528
 529                 if(vehic.tur_head.enemy)
 530                 {
 531                         trace_endpos = real_origin(vehic.tur_head.enemy);
 532                         UpdateAuxiliaryXhair(pilot, trace_endpos, '0 0.75 0', 0);
 533                 }
 534         }
 535
 536         vang = vehicle_aimturret(vehic, trace_endpos, self.gun3, "fire",
 537                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 538                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 539
 540         if((pilot.BUTTON_ATCK || pilot.BUTTON_ATCK2) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 541         {
 542                 vehic.gun3.enemy.realowner = pilot;
 543                 vehic.gun3.enemy.effects &~= EF_NODRAW;
 544
 545                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 546                 vehic.gun3.enemy.SendFlags |= BRG_START;
 547
 548                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 549
 550                 if(trace_ent)
 551                 {
 552                         if(autocvar_g_vehicle_bumblebee_raygun)
 553                         {
 554                                 Damage(trace_ent, vehic, pilot, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 555                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 556                         }
 557                         else
 558                         {
 559                                 if(trace_ent.deadflag == DEAD_NO)
 560                                         if((teamplay && trace_ent.team == pilot.team) || !teamplay)
 561                                         {
 562
 563                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 564                                                 {
 565                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.tur_health)
 566                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.tur_health);
 567
 568                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 569                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 570                                                 }
 571                                                 else if(trace_ent.flags & FL_CLIENT)
 572                                                 {
 573                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 574                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 575
 576                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 577                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 578
 579                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 580                                                 }
 581                                                 else if(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 582                                                 {
 583                                                         if(trace_ent.health  <= trace_ent.tur_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 584                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 585                                                         //else ..hmmm what? ammo?
 586
 587                                                         trace_ent.SendFlags |= TNSF_STATUS;
 588                                                 }
 589                                         }
 590                         }
 591                 }
 592
 593                 vehic.gun3.enemy.hook_end = trace_endpos;
 594                 setorigin(vehic.gun3.enemy, trace_endpos);
 595                 vehic.gun3.enemy.SendFlags |= BRG_END;
 596
 597                 vehic.wait = time + 1;
 598         }
 599         else
 600                 vehic.gun3.enemy.effects |= EF_NODRAW;
 601         /*{
 602                 if(vehic.gun3.enemy)
 603                         remove(vehic.gun3.enemy);
 604
 605                 vehic.gun3.enemy = world;
 606         }
 607         */
 608
 609         VEHICLE_UPDATE_PLAYER(pilot, health, bumblebee);
 610         VEHICLE_UPDATE_PLAYER(pilot, energy, bumblebee);
 611
 612         pilot.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 613         pilot.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 614
 615         if(vehic.vehicle_flags & VHF_HASSHIELD)
 616                 VEHICLE_UPDATE_PLAYER(pilot, shield, bumblebee);
 617
 618         vehic.angles_x *= -1;
 619         makevectors(vehic.angles);
 620         vehic.angles_x *= -1;
 621         setorigin(pilot, vehic.origin + v_up * 48 + v_forward * 160);
 622
 623         pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = pilot.BUTTON_CROUCH = 0;
 624         self = pilot;
 625
 626         return 1;
 627 }
 628
 629 void bumb_think()
 630 {
 631         self.movetype = MOVETYPE_TOSS;
 632
 633                 //self.velocity = self.velocity * 0.5;
 634         self.angles_z *= 0.8;
 635         self.angles_x *= 0.8;
 636
 637         self.nextthink = time + 0.05;
 638
 639         if(!self.owner)
 640         {
 641                 entity oldself = self;
 642                 if(self.gunner1)
 643                 {
 644                         self = self.gunner1;
 645                         oldself.gun1.vehicle_exit(VHEF_EJECT);
 646                         entity oldother = other;
 647                         other = self;
 648                         self = oldself;
 649                         self.phase = 0;
 650                         self.touch();
 651                         other = oldother;
 652                         return;
 653                 }
 654
 655                 if(self.gunner2)
 656                 {
 657                         self = self.gunner2;
 658                         oldself.gun2.vehicle_exit(VHEF_EJECT);
 659                         entity oldother = other;
 660                         other = self;
 661                         self = oldself;
 662                         self.phase = 0;
 663                         self.touch();
 664                         other = oldother;
 665                         return;
 666                 }
 667         }
 668
 669 }
 670
 671 void bumb_enter()
 672 {
 673         self.touch = bumb_touch;
 674         self.nextthink = 0;
 675         self.movetype = MOVETYPE_BOUNCEMISSILE;
 676         //setattachment(self.owner, self.vehicle_viewport, "");
 677 }
 678
 679 void bumb_exit(float eject)
 680 {
 681         self.touch = vehicles_touch;
 682         self.think = bumb_think;
 683         self.nextthink = time;
 684
 685         if(!self.owner)
 686                 return;
 687
 688         fixedmakevectors(self.angles);
 689         vector spot;
 690         if(vlen(self.velocity) > autocvar_g_vehicle_bumblebee_speed_forward * 0.5)
 691                 spot = self.origin + v_up * 128 + v_forward * 200;
 692         else
 693                 spot = self.origin + v_up * 128 - v_forward * 200;
 694
 695         spot = vehicles_findgoodexit(spot);
 696
 697
 698         self.owner.velocity = 0.75 * self.vehicle.velocity + normalize(spot - self.vehicle.origin) * 200;
 699         self.owner.velocity_z += 10;
 700         setorigin(self.owner, spot);
 701
 702         /*if(eject)
 703         {
 704             spot = self.origin + v_forward * 100 + '0 0 64';
 705             spot = vehicles_findgoodexit(spot);
 706             //setorigin(self.owner , spot);
 707             self.owner.velocity = (v_up + v_forward * 0.25) * 250;
 708             self.owner.oldvelocity = self.owner.velocity;
 709         }
 710         else
 711         {
 712                 if(vlen(self.velocity) > autocvar_g_vehicle_bumblebee_speed_forward * 0.5)
 713                 {
 714                         if(vlen(self.velocity) > autocvar_sv_maxairspeed)
 715                                 self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed;
 716                         else
 717                                 self.owner.velocity = self.velocity + v_forward * 100;
 718
 719                         self.owner.velocity_z += 200;
 720                         spot = self.origin + v_forward * 128 + '0 0 32';
 721                         spot = vehicles_findgoodexit(spot);
 722                 }
 723                 else
 724                 {
 725                         self.owner.velocity = self.velocity * 0.5;
 726                         self.owner.velocity_z += 10;
 727                         spot = self.origin - v_forward * 300 + '0 0 32';
 728                         spot = vehicles_findgoodexit(spot);
 729                 }
 730             self.owner.oldvelocity = self.owner.velocity;
 731             //setorigin(self.owner , spot);
 732         }
 733         */
 734
 735         antilag_clear(self.owner);
 736     self.owner = world;
 737 }
 738
 739 void bumb_blowup()
 740 {
 741         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 742                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 743                                  autocvar_g_vehicle_bumblebee_blowup_radius, self,
 744                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 745                                  DEATH_WAKIBLOWUP, world);
 746
 747         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 748         pointparticles(particleeffectnum("explosion_large"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 749
 750         if(self.owner.deadflag == DEAD_DYING)
 751                 self.owner.deadflag = DEAD_DEAD;
 752
 753         remove(self);
 754 }
 755
 756 void bumb_diethink()
 757 {
 758         if(time >= self.wait)
 759                 self.think = bumb_blowup;
 760
 761         if(random() < 0.1)
 762         {
 763                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 764                 pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 765         }
 766
 767         self.nextthink = time + 0.1;
 768 }
 769
 770 void bumb_die()
 771 {
 772         entity oldself = self;
 773
 774         // Hide beam
 775         if(self.gun3.enemy || !wasfreed(self.gun3.enemy))
 776                 self.gun3.enemy.effects |= EF_NODRAW;
 777
 778         if(self.gunner1)
 779         {
 780                 self = self.gunner1;
 781                 oldself.gun1.vehicle_exit(VHEF_EJECT);
 782                 self = oldself;
 783         }
 784
 785         if(self.gunner2)
 786         {
 787                 self = self.gunner2;
 788                 oldself.gun2.vehicle_exit(VHEF_EJECT);
 789                 self = oldself;
 790         }
 791
 792         self.vehicle_exit(VHEF_EJECT);
 793
 794         fixedmakevectors(self.angles);
 795         vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 796         vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 797         vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 798
 799         entity _body = vehicle_tossgib(self, self.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 800
 801         if(random() > 0.5)
 802                 _body.touch = bumb_blowup;
 803         else
 804                 _body.touch = SUB_Null;
 805
 806         _body.think = bumb_diethink;
 807         _body.nextthink = time;
 808         _body.wait = time + 2 + (random() * 8);
 809         _body.owner = self;
 810         _body.enemy = self.enemy;
 811
 812         pointparticles(particleeffectnum("explosion_medium"), findbetterlocation(self.origin, 16), '0 0 0', 1);
 813
 814         self.health                     = 0;
 815         self.event_damage       = SUB_Null;
 816         self.solid                      = SOLID_CORPSE;
 817         self.takedamage         = DAMAGE_NO;
 818         self.deadflag           = DEAD_DYING;
 819         self.movetype           = MOVETYPE_NONE;
 820         self.effects            = EF_NODRAW;
 821         self.colormod           = '0 0 0';
 822         self.avelocity          = '0 0 0';
 823         self.velocity           = '0 0 0';
 824         self.touch                      = SUB_Null;
 825         self.nextthink          = 0;
 826
 827         setorigin(self, self.pos1);
 828
 829 }
 830
 831 void bumb_impact()
 832 {
 833     if(autocvar_g_vehicle_bumblebee_bouncepain_x)
 834         vehilces_impact(autocvar_g_vehicle_bumblebee_bouncepain_x,
 835                                                 autocvar_g_vehicle_bumblebee_bouncepain_y,
 836                                                 autocvar_g_vehicle_bumblebee_bouncepain_z);
 837 }
 838
 839 void bumb_spawn(float _f)
 840 {
 841         /*
 842         float i;
 843         for(i=1; gettaginfo(self.gun1, i), gettaginfo_name; ++i)
 844         {
 845
 846             dprint(" ------- ^1gettaginfo_name^2(",ftos(i),") ^3=", gettaginfo_name, "\n");
 847         }
 848         */
 849         if(!self.gun1)
 850         {
 851                 // for some reason, autosizing of the shiled entity refuses to work for this one so set it up in advance.
 852                 self.vehicle_shieldent = spawn();
 853                 self.vehicle_shieldent.effects = EF_LOWPRECISION;
 854                 setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 855                 setattachment(self.vehicle_shieldent, self, "");
 856                 setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 857                 self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 858                 self.vehicle_shieldent.think       = shieldhit_think;
 859                 self.vehicle_shieldent.alpha = -1;
 860                 self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 861
 862                 self.gun1 = spawn();
 863                 self.gun2 = spawn();
 864                 self.gun3 = spawn();
 865
 866                 self.vehicle_flags |= VHF_MULTISLOT;
 867
 868                 self.gun1.owner = self;
 869                 self.gun2.owner = self;
 870                 self.gun3.owner = self;
 871
 872                 setmodel(self.gun1, "models/vehicles/bumblebee_plasma_right.dpm");
 873                 setmodel(self.gun2, "models/vehicles/bumblebee_plasma_left.dpm");
 874                 setmodel(self.gun3, "models/vehicles/bumblebee_ray.dpm");
 875
 876                 setattachment(self.gun1, self, "cannon_right");
 877                 setattachment(self.gun2, self, "cannon_left");
 878
 879                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 880                 self.gun3.pos1 = self.angles;
 881                 self.angles = '0 0 0';
 882                 vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 883                 ofs -= self.origin;
 884                 setattachment(self.gun3, self, "");
 885                 setorigin(self.gun3, ofs);
 886                 self.angles = self.gun3.pos1;
 887
 888                 vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 889                 vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 890
 891                 setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 892                 setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 893
 894                 //fixme-model-bones
 895                 setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 896                 setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 897                 //fixme-model-bones
 898                 setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 899                 setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 900
 901                 self.scale = 1.5;
 902
 903                 // Raygun beam
 904                 if(self.gun3.enemy == world)
 905                 {
 906                         self.gun3.enemy = spawn();
 907                         Net_LinkEntity(self.gun3.enemy, TRUE, 0, bumble_raygun_send);
 908                         self.gun3.enemy.SendFlags = BRG_SETUP;
 909                         self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 910                         self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 911                 }
 912         }
 913
 914         self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 915         self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 916         self.solid          = SOLID_BBOX;
 917         //self.movetype         = MOVETYPE_BOUNCEMISSILE;
 918         self.movetype           = MOVETYPE_TOSS;
 919         self.vehicle_impact = bumb_impact;
 920         self.damageforcescale = 0.025;
 921
 922         setorigin(self, self.origin + '0 0 25');
 923 }
 924
 925 void spawnfunc_vehicle_bumblebee()
 926 {
 927         if(!autocvar_g_vehicle_bumblebee)
 928         {
 929                 remove(self);
 930                 return;
 931         }
 932
 933         precache_model("models/vehicles/bumblebee_body.dpm");
 934         precache_model("models/vehicles/bumblebee_plasma_left.dpm");
 935         precache_model("models/vehicles/bumblebee_plasma_right.dpm");
 936         precache_model("models/vehicles/bumblebee_ray.dpm");
 937         precache_model("models/vehicles/wakizashi_cockpit.dpm");
 938         precache_model("models/vehicles/spiderbot_cockpit.dpm");
 939         precache_model("models/vehicles/raptor_cockpit.dpm");
 940
 941         if(autocvar_g_vehicle_bumblebee_energy)
 942                 if(autocvar_g_vehicle_bumblebee_energy_regen)
 943                         self.vehicle_flags |= VHF_ENERGYREGEN;
 944
 945         if(autocvar_g_vehicle_bumblebee_shield)
 946                 self.vehicle_flags |= VHF_HASSHIELD;
 947
 948         if(autocvar_g_vehicle_bumblebee_shield_regen)
 949                 self.vehicle_flags |= VHF_SHIELDREGEN;
 950
 951         if(autocvar_g_vehicle_bumblebee_health_regen)
 952                 self.vehicle_flags |= VHF_HEALTHREGEN;
 953
 954         if not(vehicle_initialize(
 955                            "Bumblebee", "models/vehicles/bumblebee_body.dpm",
 956                            "", "models/vehicles/spiderbot_cockpit.dpm", "", "", "tag_viewport",
 957                            HUD_BUMBLEBEE, BUMB_MIN, BUMB_MAX, FALSE,
 958                            bumb_spawn, autocvar_g_vehicle_bumblebee_respawntime,
 959                            bumb_pilot_frame, bumb_enter, bumb_exit,
 960                            bumb_die, bumb_think, FALSE, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_shield))
 961         {
 962                 remove(self);
 963                 return;
 964         }
 965 }
 966
 967 float bumble_raygun_send(entity to, float sf)
 968 {
 969         WriteByte(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
 970
 971         WriteByte(MSG_ENTITY, sf);
 972         if(sf & BRG_SETUP)
 973         {
 974                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 975                 WriteByte(MSG_ENTITY, self.realowner.team);
 976                 WriteByte(MSG_ENTITY, self.cnt);
 977         }
 978
 979         if(sf & BRG_START)
 980         {
 981                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 982                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 983                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 984         }
 985
 986         if(sf & BRG_END)
 987         {
 988                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 989                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 990                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 991         }
 992
 993         return TRUE;
 994 }
 995 #endif // SVQC
 996
 997 #ifdef CSQC
 998 /*
 999 .vector raygun_l1
1000 .vector raygun_l2;
1001 .vector raygun_l3;
1002 */
1003
1004 void bumble_raygun_draw()
1005 {
1006         float _len;
1007         vector _dir;
1008         vector _vtmp1, _vtmp2;
1009
1010         _len = vlen(self.origin - self.move_origin);
1011         _dir = normalize(self.move_origin - self.origin);
1012
1013         if(self.total_damages < time)
1014         {
1015                 boxparticles(self.traileffect, self, self.origin, self.origin + _dir * -64, _dir * -_len , _dir * -_len, 1, PARTICLES_USEALPHA);
1016                 boxparticles(self.lip, self, self.move_origin, self.move_origin + _dir * -64, _dir * -200 , _dir * -200, 1, PARTICLES_USEALPHA);
1017                 self.total_damages = time + 0.1;
1018         }
1019
1020         float i, df, sz, al;
1021         for(i = -0.1; i < 0.2; i += 0.1)
1022         {
1023                 df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
1024                 sz = 5 + random() * 5;
1025                 al = 0.25 + random() * 0.5;
1026                 _vtmp1 = self.origin + _dir * _len * (0.25 + i);
1027                 _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //self.raygun_l1;
1028                 Draw_CylindricLine(self.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1029
1030                 _vtmp2 = self.origin + _dir * _len * (0.5 + i);
1031                 _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //self.raygun_l2;
1032                 Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1033
1034                 _vtmp1 = self.origin + _dir * _len * (0.75 + i);
1035                 _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //self.raygun_l3;
1036                 Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1037
1038                 Draw_CylindricLine(_vtmp1, self.move_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1039         }
1040 }
1041
1042 void bumble_raygun_read(float bIsNew)
1043 {
1044         float sf = ReadByte();
1045
1046         if(sf & BRG_SETUP)
1047         {
1048                 self.cnt  = ReadByte();
1049                 self.team = ReadByte();
1050                 self.cnt  = ReadByte();
1051
1052                 if(self.cnt)
1053                         self.colormod = '1 0 0';
1054                 else
1055                         self.colormod = '0 1 0';
1056
1057                 self.traileffect = particleeffectnum("healray_muzzleflash");
1058                 self.lip = particleeffectnum("healray_impact");
1059
1060                 self.draw = bumble_raygun_draw;
1061         }
1062
1063
1064         if(sf & BRG_START)
1065         {
1066                 self.origin_x = ReadCoord();
1067                 self.origin_y = ReadCoord();
1068                 self.origin_z = ReadCoord();
1069                 setorigin(self, self.origin);
1070         }
1071
1072         if(sf & BRG_END)
1073         {
1074                 self.move_origin_x = ReadCoord();
1075                 self.move_origin_y = ReadCoord();
1076                 self.move_origin_z = ReadCoord();
1077         }
1078 }
1079
1080 void bumblebee_draw()
1081 {
1082
1083 }
1084
1085 void bumblebee_draw2d()
1086 {
1087
1088 }
1089
1090 void bumblebee_read_extra()
1091 {
1092
1093 }
1094
1095 void vehicle_bumblebee_assemble()
1096 {
1097
1098 }
1099 #endif //CSQC