qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3
   4 #ifdef SVQC
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19 float autocvar_g_vehicle_racer_friction;
  20
  21 float autocvar_g_vehicle_racer_hovertype;
  22 float autocvar_g_vehicle_racer_hoverpower;
  23
  24 float autocvar_g_vehicle_racer_turnroll;
  25 float autocvar_g_vehicle_racer_turnspeed;
  26 float autocvar_g_vehicle_racer_pitchspeed;
  27
  28 float autocvar_g_vehicle_racer_energy;
  29 float autocvar_g_vehicle_racer_energy_regen;
  30 float autocvar_g_vehicle_racer_energy_regen_pause;
  31
  32 float autocvar_g_vehicle_racer_health;
  33 float autocvar_g_vehicle_racer_health_regen;
  34 float autocvar_g_vehicle_racer_health_regen_pause;
  35
  36 float autocvar_g_vehicle_racer_shield;
  37 float autocvar_g_vehicle_racer_shield_regen;
  38 float autocvar_g_vehicle_racer_shield_regen_pause;
  39
  40 float autocvar_g_vehicle_racer_cannon_cost;
  41 float autocvar_g_vehicle_racer_cannon_damage;
  42 float autocvar_g_vehicle_racer_cannon_radius;
  43 float autocvar_g_vehicle_racer_cannon_refire;
  44 float autocvar_g_vehicle_racer_cannon_speed;
  45 float autocvar_g_vehicle_racer_cannon_spread;
  46 float autocvar_g_vehicle_racer_cannon_force;
  47
  48 float autocvar_g_vehicle_racer_rocket_accel;
  49 float autocvar_g_vehicle_racer_rocket_damage;
  50 float autocvar_g_vehicle_racer_rocket_radius;
  51 float autocvar_g_vehicle_racer_rocket_force;
  52 float autocvar_g_vehicle_racer_rocket_refire;
  53 float autocvar_g_vehicle_racer_rocket_speed;
  54 float autocvar_g_vehicle_racer_rocket_turnrate;
  55
  56 float autocvar_g_vehicle_racer_rocket_locktarget;
  57 float autocvar_g_vehicle_racer_rocket_locking_time;
  58 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  59 float autocvar_g_vehicle_racer_rocket_locked_time;
  60 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  61
  62 float autocvar_g_vehicle_racer_respawntime;
  63
  64 float autocvar_g_vehicle_racer_blowup_radius;
  65 float autocvar_g_vehicle_racer_blowup_coredamage;
  66 float autocvar_g_vehicle_racer_blowup_edgedamage;
  67 float autocvar_g_vehicle_racer_blowup_forceintensity;
  68
  69 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  70
  71 void racer_align4point()
  72 {
  73     vector push_vector, v_add;
  74     float fl_push, fr_push, bl_push, br_push;
  75
  76
  77     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  78     fr_push      = force_fromtag_normpower;
  79     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  80
  81     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  82     fl_push      = force_fromtag_normpower;
  83     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  84
  85     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  86     br_push      = force_fromtag_normpower;
  87     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  88
  89     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90     bl_push      = force_fromtag_normpower;
  91     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93     self.velocity += (push_vector * frametime);
  94
  95     // Anti ocilation
  96     if(self.velocity_z  > 0)
  97         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  98
  99     self.velocity   += v_add;
 100     //self.velocity_z -= autocvar_sv_gravity * frametime;
 101
 102     push_vector_x =  (fl_push - bl_push);
 103     push_vector_x += (fr_push - br_push);
 104     push_vector_x *= 360;
 105
 106     push_vector_z = (fr_push - fl_push);
 107     push_vector_z += (br_push - bl_push);
 108     push_vector_z *= 360;
 109
 110     // Apply angle diffrance
 111     self.angles_z += push_vector_z * frametime;
 112     self.angles_x += push_vector_x * frametime;
 113
 114     // Apply stabilizer
 115     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 116     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117 }
 118
 119 void racer_fire_cannon(string tagname)
 120 {
 121     vector v;
 122     entity bolt;
 123
 124     v = gettaginfo(self, gettagindex(self, tagname));
 125     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 126                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 127                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 128                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 129
 130         // Fix z-aim (for chase mode)
 131     v = normalize(trace_endpos - bolt.origin);
 132     v_forward_z = v_z * 0.5;
 133     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 134 }
 135
 136 void racer_rocket_groundhugger()
 137 {
 138     vector olddir, newdir;
 139     float oldvel, newvel;
 140
 141     self.nextthink  = time;
 142
 143     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 144     {
 145         self.use();
 146         return;
 147     }
 148
 149     if not (self.realowner.vehicle)
 150     {
 151         UpdateCSQCProjectile(self);
 152         return;
 153     }
 154
 155     olddir = normalize(self.velocity);
 156     oldvel = vlen(self.velocity);
 157     newvel = oldvel + self.lip;
 158
 159     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 160     if(trace_fraction <= 0.5)
 161     {
 162         // Hitting somethign soon, just speed ahead
 163         self.velocity = olddir * newvel;
 164         UpdateCSQCProjectile(self);
 165         return;
 166     }
 167
 168     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 169     if(trace_fraction != 1.0)
 170     {
 171         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 172         self.velocity = normalize(olddir + newdir) * newvel;
 173     }
 174     else
 175     {
 176         self.velocity = olddir * newvel;
 177         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 178     }
 179
 180     UpdateCSQCProjectile(self);
 181     return;
 182 }
 183
 184 void racer_rocket_tracker()
 185 {
 186     vector olddir, newdir;
 187     float oldvel, newvel;
 188
 189     self.nextthink  = time;
 190
 191     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 192     {
 193         self.use();
 194         return;
 195     }
 196
 197     if not (self.realowner.vehicle)
 198     {
 199         UpdateCSQCProjectile(self);
 200         return;
 201     }
 202
 203     olddir = normalize(self.velocity);
 204     oldvel = vlen(self.velocity);
 205     newvel = oldvel + self.lip;
 206     makevectors(vectoangles(olddir));
 207
 208     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 209     newdir = normalize(self.enemy.origin - self.origin);
 210
 211     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 212     {
 213         //bprint("Target lost!\n");
 214         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 215         self.think = racer_rocket_groundhugger;
 216         return;
 217     }
 218
 219     if(trace_fraction != 1.0)
 220         newdir_z += 16 * sys_frametime;
 221
 222     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 223     self.velocity_z -= 800 * sys_frametime;
 224
 225     UpdateCSQCProjectile(self);
 226     return;
 227 }
 228
 229 void racer_fire_rocket(string tagname, entity trg)
 230 {
 231     vector v;
 232     entity rocket;
 233
 234     v = gettaginfo(self, gettagindex(self, tagname));
 235     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 236                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 237                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 238                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 239
 240     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 241     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 242     rocket.nextthink        = time;
 243     rocket.enemy            = trg;
 244     rocket.cnt              = time + 15;
 245
 246     if(trg)
 247         rocket.think            = racer_rocket_tracker;
 248     else
 249         rocket.think            = racer_rocket_groundhugger;
 250 }
 251
 252 float racer_frame()
 253 {
 254     entity player, racer;
 255     vector df;
 256     float ftmp;
 257
 258         if(intermission_running)
 259                 return 1;
 260
 261     player  = self;
 262     racer   = self.vehicle;
 263     self    = racer;
 264
 265     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 266
 267     vehicles_painframe();
 268
 269     if(racer.deadflag != DEAD_NO)
 270     {
 271         self = player;
 272         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 273         return 1;
 274     }
 275
 276
 277     racer_align4point();
 278     vh_crosshair_trace(player);
 279     racer.angles_x *= -1;
 280
 281     // Yaw
 282     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 283     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 284     racer.angles_y = anglemods(racer.angles_y + ftmp);
 285
 286     // Roll
 287     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 288
 289     // Pitch
 290     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 291     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 292     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 293
 294     makevectors(racer.angles);
 295     racer.angles_x *= -1;
 296
 297
 298     ftmp = racer.velocity_z;
 299     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 300     racer.velocity_z = ftmp;
 301
 302     if(player.movement_x != 0)
 303     {
 304         if(player.movement_x > 0)
 305             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 306         else if(player.movement_x < 0)
 307             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 308     }
 309
 310     if(player.movement_y != 0)
 311     {
 312         if(player.movement_y < 0)
 313             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 314         else if(player.movement_y > 0)
 315             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 316     }
 317
 318     if(vlen(player.movement) != 0)
 319     {
 320         if(self.sound_nexttime < time || self.sounds != 1)
 321         {
 322             self.sounds = 1;
 323             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 324             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 325         }
 326     }
 327     else
 328     {
 329         if(self.sound_nexttime < time || self.sounds != 0)
 330         {
 331             self.sounds = 0;
 332             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 333             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 334         }
 335     }
 336
 337     // Afterburn
 338     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 339     {
 340         if(time - racer.wait > 0.2)
 341             pointparticles(particleeffectnum("wakizashi_booster_smoke"), self.origin, '0 0 0', 1);
 342
 343         racer.wait = time;
 344         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 345         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 346
 347         if(self.invincible_finished < time)
 348         {
 349             traceline(self.origin, self.origin - '0 0 256', MOVE_NORMAL, self);
 350             if(trace_fraction != 1.0)
 351                 pointparticles(particleeffectnum("smoke_small"), trace_endpos, '0 0 0', 1);
 352
 353             self.invincible_finished = time + 0.1 + (random() * 0.1);
 354         }
 355
 356         if(self.strength_finished < time)
 357         {
 358             //self.sounds = 2;
 359             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 360             sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 361         }
 362     }
 363     else
 364     {
 365         self.strength_finished = 0;
 366         sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 367     }
 368
 369
 370     racer.velocity  += df * frametime;
 371
 372     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 373     racer.velocity  = racer.velocity - df;
 374     player.movement = racer.velocity;
 375
 376     if(player.BUTTON_ATCK)
 377     if(time > racer.attack_finished_single)
 378     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 379     {
 380         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 381         racer.wait = time;
 382
 383         crosshair_trace(player);
 384         if(racer.cnt)
 385         {
 386             racer_fire_cannon("tag_fire1");
 387             racer.cnt = 0;
 388         }
 389         else
 390         {
 391             racer_fire_cannon("tag_fire2");
 392             racer.cnt = 1;
 393         }
 394         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 395         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 396     }
 397
 398     if(autocvar_g_vehicle_racer_rocket_locktarget)
 399     {
 400         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 401                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 402                          autocvar_g_vehicle_racer_rocket_locked_time);
 403
 404         if(self.lock_target)
 405         {
 406             if(racer.lock_strength == 1)
 407                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 408             else if(self.lock_strength > 0.5)
 409                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 410             else if(self.lock_strength < 0.5)
 411                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 412         }
 413     }
 414
 415     if(time > racer.delay)
 416     if(player.BUTTON_ATCK2)
 417     {
 418         self.misc_bulletcounter += 1;
 419         racer.delay = time + 0.3;
 420         if(self.misc_bulletcounter == 1)
 421             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 422         else if(self.misc_bulletcounter == 2)
 423         {
 424             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 425             self.lock_strength  = 0;
 426             self.lock_target    = world;
 427             self.misc_bulletcounter = 0;
 428
 429             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 430             racer.lip = time;
 431         }
 432     }
 433     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 434
 435     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 436         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 437
 438     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 439         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 440
 441     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 442         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 443
 444
 445     VEHICLE_UPDATE_PLAYER(health, racer);
 446     VEHICLE_UPDATE_PLAYER(energy, racer);
 447
 448     if(self.vehicle_flags & VHF_HASSHIELD)
 449         VEHICLE_UPDATE_PLAYER(shield, racer);
 450
 451
 452     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 453     setorigin(player,racer.origin + '0 0 32');
 454     player.velocity = racer.velocity;
 455
 456     self = player;
 457     return 1;
 458 }
 459
 460 void racer_think()
 461 {
 462     /*
 463     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 464     b = autocvar_g_vehicle_racer_springlength;
 465     c = autocvar_g_vehicle_racer_hoverpower;
 466
 467     autocvar_g_vehicle_racer_anglestabilizer = 36;
 468     autocvar_g_vehicle_racer_springlength = 96;
 469     autocvar_g_vehicle_racer_hoverpower = 300;
 470     */
 471
 472     racer_align4point(); //time - self.nextthink);
 473
 474     /*
 475     //if(self.velocity_z > 0)
 476     //    self.velocity_z *= 0.95;
 477
 478     autocvar_g_vehicle_racer_anglestabilizer = a;
 479     autocvar_g_vehicle_racer_springlength = b;
 480     autocvar_g_vehicle_racer_hoverpower = c;
 481     */
 482
 483     self.velocity_x *= 0.9;
 484     self.velocity_y *= 0.9;
 485     self.velocity_z *= 0.8;
 486     self.velocity_z += sin(time * 2) * 16;
 487     self.nextthink = time; // + 0.05;
 488 }
 489
 490 void racer_enter()
 491 {
 492     self.movetype = MOVETYPE_BOUNCE;
 493     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 494     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 495
 496     if(self.owner.flagcarried)
 497        setorigin(self.owner.flagcarried, '-190 0 96');
 498 }
 499
 500 void racer_exit(float eject)
 501 {
 502     vector spot;
 503
 504     self.think      = racer_think;
 505     self.nextthink  = time;
 506     self.movetype   = MOVETYPE_TOSS;
 507     sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 508
 509     if not (self.owner)
 510         return;
 511
 512         makevectors(self.angles);
 513         if(eject)
 514         {
 515             spot = self.origin + v_forward * 100 + '0 0 64';
 516             spot = vehicles_findgoodexit(spot);
 517             setorigin(self.owner , spot);
 518             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 519         }
 520         else
 521         {
 522             spot = self.origin - v_forward * 200 + '0 0 64';
 523             spot = vehicles_findgoodexit(spot);
 524             setorigin(self.owner , spot);
 525         }
 526
 527     self.owner = world;
 528 }
 529
 530 void racer_spawn()
 531 {
 532     self.think          = racer_think;
 533     self.nextthink      = time;
 534     self.vehicle_health = autocvar_g_vehicle_racer_health;
 535     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 536
 537     self.movetype       = MOVETYPE_TOSS;
 538     self.solid          = SOLID_SLIDEBOX;
 539     self.delay          = time;
 540     self.scale          = 0.5;
 541
 542     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 543 }
 544
 545
 546 void racer_blowup()
 547 {
 548     self.deadflag    = DEAD_DEAD;
 549     self.vehicle_exit(VHEF_NORMAL);
 550
 551     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 552                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 553                                         autocvar_g_vehicle_racer_blowup_radius, world,
 554                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 555                                         DEATH_WAKIBLOWUP, world);
 556
 557     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 558     self.think      = racer_spawn;
 559     self.movetype   = MOVETYPE_NONE;
 560     self.effects    = EF_NODRAW;
 561
 562     self.colormod  = '0 0 0';
 563     self.avelocity = '0 0 0';
 564     self.velocity  = '0 0 0';
 565
 566     setorigin(self, self.pos1);
 567         self.think     = racer_spawn;
 568         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 569 }
 570
 571 void racer_deadtouch()
 572 {
 573     self.avelocity_x *= 0.7;
 574     self.cnt -= 1;
 575     if(self.cnt <= 0)
 576         racer_blowup();
 577 }
 578
 579 void racer_die()
 580 {
 581     self.health       = 0;
 582     self.event_damage = SUB_Null;
 583     self.solid        = SOLID_CORPSE;
 584     self.takedamage   = DAMAGE_NO;
 585     self.deadflag     = DEAD_DYING;
 586     self.movetype     = MOVETYPE_BOUNCE;
 587     self.wait         = time;
 588     self.cnt          = 1 + random() * 2;
 589     self.touch        = racer_deadtouch;
 590
 591     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 592
 593     if(random() < 0.5)
 594         self.avelocity_z  = 32;
 595     else
 596         self.avelocity_z  = -32;
 597
 598     self.avelocity_x = -vlen(self.velocity) * 0.2;
 599     self.velocity   += '0 0 700';
 600     self.colormod    = '-0.5 -0.5 -0.5';
 601
 602         self.think     = racer_blowup;
 603         self.nextthink = 2 + time + random() * 3;
 604 }
 605
 606 void racer_dinit()
 607 {
 608     if not (vehicle_initialize(
 609              "Wakizashi",
 610              "models/vehicles/wakizashi.dpm",
 611              "null", // we need this so tur_head is networked and usable for sounds
 612              "models/vehicles/wakizashi_cockpit.dpm",
 613              "", "", "tag_viewport",
 614              HUD_WAKIZASHI,
 615              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 616              FALSE,
 617              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 618              racer_frame,
 619              racer_enter, racer_exit,
 620              racer_die,   racer_think,
 621              TRUE))
 622     {
 623         remove(self);
 624         return;
 625     }
 626
 627     if(autocvar_g_vehicle_racer_hovertype != 0)
 628         racer_force_from_tag = vehicles_force_fromtag_maglev;
 629     else
 630         racer_force_from_tag = vehicles_force_fromtag_hover;
 631
 632     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 633     self.scale = 0.5;
 634     setattachment(self.vehicle_hudmodel, self, "");
 635     setattachment(self.vehicle_viewport, self, "tag_viewport");
 636
 637     self.mass               = 900;
 638 }
 639
 640 void spawnfunc_vehicle_racer()
 641 {
 642     self.vehicle_flags |= VHF_DMGSHAKE;
 643     self.vehicle_flags |= VHF_DMGROLL;
 644
 645     precache_sound ("weapons/lasergun_fire.wav");
 646     precache_sound ("weapons/rocket_fire.wav");
 647
 648     precache_sound ("vehicles/racer_idle.wav");
 649     precache_sound ("vehicles/racer_move.wav");
 650     precache_sound ("vehicles/racer_boost.wav");
 651
 652     precache_model ("models/vhshield.md3");
 653     precache_model ("models/vehicles/wakizashi.dpm");
 654     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 655
 656     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 657     if(autocvar_g_vehicle_racer_energy)
 658         if(autocvar_g_vehicle_racer_energy_regen)
 659             self.vehicle_flags |= VHF_ENERGYREGEN;
 660
 661     if(autocvar_g_vehicle_racer_shield)
 662         self.vehicle_flags |= VHF_HASSHIELD;
 663
 664     if(autocvar_g_vehicle_racer_shield_regen)
 665         self.vehicle_flags |= VHF_SHIELDREGEN;
 666
 667     if(autocvar_g_vehicle_racer_health_regen)
 668         self.vehicle_flags |= VHF_HEALTHREGEN;
 669
 670     self.think = racer_dinit;
 671
 672     if(g_assault)
 673         self.nextthink = time + 0.5;
 674     else
 675         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 676 }
 677 #endif // SVQC