qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  77                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  78                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  79                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  80     remove(self);
  81 }
  82
  83 void raptor_bomblet_touch()
  84 {
  85     if(other == self.owner)
  86         return;
  87
  88     PROJECTILE_TOUCH;
  89     self.think = raptor_bomblet_boom;
  90     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  91 }
  92
  93 void raptor_bomb_burst()
  94 {
  95     if(self.cnt > time)
  96     if(autocvar_g_vehicle_raptor_bomblet_alt)
  97     {
  98         self.nextthink = time;
  99         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 100         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 101         {
 102             UpdateCSQCProjectile(self);
 103             return;
 104         }
 105     }
 106
 107     entity bomblet;
 108     float i;
 109
 110     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114         bomblet = spawn();
 115         setorigin(bomblet, self.origin);
 116
 117         bomblet.movetype    = MOVETYPE_TOSS;
 118         bomblet.touch       = raptor_bomblet_touch;
 119         bomblet.think       = raptor_bomblet_boom;
 120         bomblet.nextthink   = time + 5;
 121         bomblet.owner       = self.owner;
 122         bomblet.realowner   = self.realowner;
 123         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 124
 125         PROJECTILE_MAKETRIGGER(bomblet);
 126         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 127     }
 128
 129     remove(self);
 130 }
 131
 132 void raptor_bombdrop()
 133 {
 134     entity bomb_1, bomb_2;
 135
 136     bomb_1 = spawn();
 137     bomb_2 = spawn();
 138
 139     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 140     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 141
 142     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 143     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 144     bomb_1.touch        = bomb_2.touch      = raptor_bomb_burst;
 145     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 146     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 147
 148     if(autocvar_g_vehicle_raptor_bomblet_alt)
 149         bomb_1.nextthink = bomb_2.nextthink  = time;
 150     else
 151         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 152
 153     bomb_1.owner     = bomb_2.owner      = self;
 154     bomb_1.realowner = bomb_2.realowner  = self.owner;
 155     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 156     bomb_1.gravity   = bomb_2.gravity    = 1;
 157
 158     PROJECTILE_MAKETRIGGER(bomb_1);
 159     PROJECTILE_MAKETRIGGER(bomb_2);
 160
 161     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 162     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 163 }
 164
 165
 166 void raptor_fire_cannon(entity gun, string tagname)
 167 {
 168     vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 169                            gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 170                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 171                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 172 }
 173
 174 void raptor_think()
 175 {
 176 }
 177
 178 void raptor_enter()
 179 {
 180     self.owner.PlayerPhysplug = raptor_takeoff;
 181     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 182     self.solid          = SOLID_SLIDEBOX;
 183     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 184     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 185     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 186     self.tur_head.exteriormodeltoclient = self.owner;
 187
 188     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 189     self.lip   = time;
 190
 191     if(self.owner.flagcarried)
 192        setorigin(self.owner.flagcarried, '-20 0 96');
 193
 194 }
 195
 196 void raptor_land()
 197 {
 198
 199     float hgt;
 200
 201     hgt = raptor_altitude(512);
 202     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 203     self.angles_x *= 0.95;
 204     self.angles_z *= 0.95;
 205
 206     if(hgt < 128)
 207         if(self.frame != 0)
 208             self.frame = max(self.frame - 0.25, 0);
 209
 210     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 211     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 212
 213     if(hgt < 16)
 214     {
 215         self.movetype   = MOVETYPE_TOSS;
 216         self.think      = raptor_think;
 217     }
 218
 219     self.nextthink  = time;
 220 }
 221
 222 void raptor_exit(float eject)
 223 {
 224     vector spot;
 225     self.tur_head.exteriormodeltoclient = world;
 226
 227     if(self.deadflag == DEAD_NO)
 228     {
 229         self.think      = raptor_land;
 230         self.nextthink  = time;
 231     }
 232
 233     if not (self.owner)
 234         return;
 235
 236         makevectors(self.angles);
 237         if(eject)
 238         {
 239             spot = self.origin + v_forward * 100 + '0 0 64';
 240             spot = vehicles_findgoodexit(spot);
 241             setorigin(self.owner , spot);
 242             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 243         }
 244         else
 245         {
 246             spot = self.origin - v_forward * 200 + '0 0 64';
 247             spot = vehicles_findgoodexit(spot);
 248             setorigin(self.owner , spot);
 249         }
 250
 251     self.owner = world;
 252 }
 253
 254 float raptor_takeoff()
 255 {
 256     entity player, raptor;
 257
 258     player = self;
 259     raptor = self.vehicle;
 260     self   = raptor;
 261     if(self.sound_nexttime < time)
 262     {
 263         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 264         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 265     }
 266
 267     // Takeoff sequense
 268     if(raptor.frame < 25)
 269     {
 270         raptor.frame += 0.25;
 271         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 272         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 273         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 274         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 275
 276         setorigin(player, raptor.origin + '0 0 32');
 277     }
 278     else
 279         player.PlayerPhysplug = raptor_frame;
 280
 281     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 282         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 283
 284     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 285         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 286
 287     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 288         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 289
 290
 291     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 292     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 293
 294     VEHICLE_UPDATE_PLAYER(health, raptor);
 295     VEHICLE_UPDATE_PLAYER(energy, raptor);
 296     if(self.vehicle_flags & VHF_HASSHIELD)
 297         VEHICLE_UPDATE_PLAYER(shield, raptor);
 298
 299     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 300     self = player;
 301     return 1;
 302 }
 303
 304 float raptor_frame()
 305 {
 306     entity player, raptor;
 307     float ftmp, ftmp2;
 308     vector df;
 309
 310         if(intermission_running)
 311                 return 1;
 312
 313     player = self;
 314     raptor = self.vehicle;
 315     self   = raptor;
 316     vehicles_painframe();
 317     /*
 318     ftmp = vlen(self.velocity);
 319     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 320         ftmp = 1;
 321     else
 322         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 323     */
 324
 325     if(self.sound_nexttime < time)
 326     {
 327         self.sound_nexttime = time + 7.955812;
 328         //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 329         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 330         self.wait = ftmp;
 331     }
 332     /*
 333     else if(fabs(ftmp - self.wait) > 0.2)
 334     {
 335         sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTN_NORM );
 336         sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTN_NORM);
 337         self.wait = ftmp;
 338     }
 339     */
 340
 341     if(raptor.deadflag != DEAD_NO)
 342     {
 343         self = player;
 344         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 345         return 1;
 346     }
 347     crosshair_trace(player);
 348
 349     vector vang;
 350     vang = raptor.angles;
 351     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 352     vang_x *= -1;
 353     df_x *= -1;
 354     if(df_x > 180)  df_x -= 360;
 355     if(df_x < -180) df_x += 360;
 356     if(df_y > 180)  df_y -= 360;
 357     if(df_y < -180) df_y += 360;
 358
 359     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 360     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 361     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 362
 363     // Pitch
 364     ftmp = 0;
 365     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 366     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 367
 368     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 369     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 370     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 371
 372     raptor.angles_x = anglemods(raptor.angles_x);
 373     raptor.angles_y = anglemods(raptor.angles_y);
 374     raptor.angles_z = anglemods(raptor.angles_z);
 375
 376     if(autocvar_g_vehicle_raptor_movestyle == 1)
 377         makevectors('0 1 0' * raptor.angles_y);
 378     else
 379         makevectors(player.v_angle);
 380
 381     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 382
 383     if(player.movement_x != 0)
 384     {
 385         if(player.movement_x > 0)
 386             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 387         else if(player.movement_x < 0)
 388             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 389     }
 390
 391     if(player.movement_y != 0)
 392     {
 393         if(player.movement_y < 0)
 394             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 395         else if(player.movement_y > 0)
 396             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 397
 398         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 399     }
 400     else
 401     {
 402         raptor.angles_z *= 0.95;
 403         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 404             raptor.angles_z = 0;
 405     }
 406
 407     if(player.BUTTON_CROUCH)
 408         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 409     else if (player.BUTTON_JUMP)
 410         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 411
 412     raptor.velocity  += df * frametime;
 413     player.velocity = player.movement  = raptor.velocity;
 414     setorigin(player, raptor.origin + '0 0 32');
 415
 416     vector vf, ad;
 417     // Target lock & predict
 418     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 419     {
 420
 421         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 422                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 423                              autocvar_g_vehicle_raptor_cannon_locked_time);
 424
 425         if(self.lock_target != world)
 426         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 427         if(self.lock_strength == 1)
 428         {
 429             float i, distance, impact_time;
 430
 431             vf = real_origin(raptor.lock_target);
 432             ad = vf;
 433             for(i = 0; i < 4; ++i)
 434             {
 435                 distance = vlen(ad - raptor.origin);
 436                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 437                 ad = vf + raptor.lock_target.velocity * impact_time;
 438             }
 439             trace_endpos = ad;
 440         }
 441
 442         if(self.lock_target)
 443         {
 444             if(raptor.lock_strength == 1)
 445                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 446             else if(self.lock_strength > 0.5)
 447                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 448             else if(self.lock_strength < 0.5)
 449                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 450         }
 451     }
 452
 453     // Aim the gunz
 454     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 455     ftmp = -ftmp2;
 456
 457     // Gun1
 458     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 459     //ad = df;
 460     //vf = v_forward;
 461     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 462     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun1.angles;
 463     df = shortangle_vxy(df, raptor.gun1.angles);
 464
 465     // Bind to aimspeed
 466     df_x = bound(ftmp, df_x, ftmp2);
 467     df_y = bound(ftmp, df_y, ftmp2);
 468     // Bind to limts
 469     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 470     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 471
 472     // Gun2
 473     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 474     //ad += df;
 475     //vf += v_forward;
 476     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 477     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun2.angles;
 478     df = shortangle_vxy(df, raptor.gun2.angles);
 479
 480     // Bind to aimspeed
 481     df_x = bound(ftmp, df_x, ftmp2);
 482     df_y = bound(ftmp, df_y, ftmp2);
 483     // Bind to limts
 484     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 485     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 486
 487     /*
 488     ad = ad * 0.5;
 489     v_forward = vf * 0.5;
 490     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 491     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 492     */
 493
 494     if(player.BUTTON_ATCK)
 495     if(raptor.attack_finished_single <= time)
 496     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 497     {
 498         raptor.misc_bulletcounter += 1;
 499         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 500         if(raptor.misc_bulletcounter <= 2)
 501             raptor_fire_cannon(self.gun1, "fire1");
 502         else if(raptor.misc_bulletcounter == 3)
 503             raptor_fire_cannon(self.gun2, "fire1");
 504         else
 505         {
 506             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 507             raptor_fire_cannon(self.gun2, "fire1");
 508             raptor.misc_bulletcounter = 0;
 509         }
 510         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 511         self.cnt = time;
 512     }
 513
 514     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 515         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 516
 517     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 518         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 519
 520     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 521         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 522
 523
 524     if(time > raptor.delay)
 525     if(player.BUTTON_ATCK2)
 526     {
 527         raptor_bombdrop();
 528         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 529         raptor.lip   = time;
 530     }
 531
 532     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 533     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 534
 535     VEHICLE_UPDATE_PLAYER(health, raptor);
 536     VEHICLE_UPDATE_PLAYER(energy, raptor);
 537     if(self.vehicle_flags & VHF_HASSHIELD)
 538         VEHICLE_UPDATE_PLAYER(shield, raptor);
 539
 540     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 541     return 1;
 542 }
 543
 544 void raptor_blowup()
 545 {
 546     self.deadflag    = DEAD_DEAD;
 547     self.vehicle_exit(VHEF_NORMAL);
 548     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 549
 550     self.alpha          = -1;
 551     self.movetype       = MOVETYPE_NONE;
 552     self.effects        = EF_NODRAW;
 553     self.colormod       = '0 0 0';
 554     self.avelocity      = '0 0 0';
 555     self.velocity       = '0 0 0';
 556
 557     setorigin(self, self.pos1);
 558     self.touch = SUB_Null;
 559     self.nextthink = 0;
 560 }
 561
 562 void raptor_diethink()
 563 {
 564     if(random() < 0.1)
 565     {
 566         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 567         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 568     }
 569     self.nextthink = time + 0.1;
 570 }
 571
 572 void raptor_die()
 573 {
 574     self.health       = 0;
 575     self.event_damage = SUB_Null;
 576     self.solid        = SOLID_CORPSE;
 577     self.takedamage   = DAMAGE_NO;
 578     self.deadflag     = DEAD_DYING;
 579     self.movetype     = MOVETYPE_BOUNCE;
 580     self.think        = raptor_diethink;
 581     self.nextthink    = time;
 582
 583     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 584
 585     self.velocity_z += 600;
 586
 587     self.avelocity = '0 0.5 1' * (random() * 400);
 588     self.avelocity -= '0 0.5 1' * (random() * 400);
 589
 590     self.colormod = '-0.5 -0.5 -0.5';
 591         self.touch     = raptor_blowup;
 592 }
 593
 594 void raptor_spawn()
 595 {
 596     self.frame          = 0;
 597     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 598     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 599     self.movetype       = MOVETYPE_TOSS;
 600     self.solid          = SOLID_SLIDEBOX;
 601     self.vehicle_energy = 1;
 602
 603     self.bomb1.gun1.avelocity_y = 90;
 604     self.bomb1.gun2.avelocity_y = -90;
 605
 606     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 607     self.delay = time;
 608 }
 609
 610 // If we dont do this ever now and then, the raptors rotors
 611 // stop working, presumably due to angle overflow. cute.
 612 void raptor_rotor_anglefix()
 613 {
 614     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 615     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 616     self.nextthink = time + 15;
 617 }
 618
 619 void raptor_dinit()
 620 {
 621     entity spinner;
 622     vector ofs;
 623
 624     if not (vehicle_initialize(
 625              "Raptor",
 626              "models/vehicles/raptor.dpm",
 627              "",
 628              "models/vehicles/raptor_cockpit.dpm",
 629              "", "tag_hud", "tag_camera",
 630              HUD_RAPTOR,
 631              RAPTOR_MIN, RAPTOR_MAX,
 632              FALSE,
 633              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 634              raptor_frame,
 635              raptor_enter, raptor_exit,
 636              raptor_die,   raptor_think,
 637              FALSE))
 638     {
 639         remove(self);
 640         return;
 641     }
 642
 643     //FIXME: Camera is in a bad place in HUD model.
 644     //setorigin(self.vehicle_viewport, '25 0 5');
 645
 646     self.frame = 0;
 647
 648     self.bomb1 = spawn();
 649     self.bomb2 = spawn();
 650     self.gun1  = spawn();
 651     self.gun2  = spawn();
 652
 653     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 654     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 655     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 656     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 657     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 658
 659     setattachment(self.bomb1, self,"bombmount_left");
 660     setattachment(self.bomb2, self,"bombmount_right");
 661     setattachment(self.tur_head, self,"root");
 662
 663
 664     // FIXME Guns mounts to angled bones
 665     self.bomb1.angles = self.angles;
 666     self.angles = '0 0 0';
 667     // This messes up gun-aim, so work arround it.
 668     //setattachment(self.gun1, self, "gunmount_left");
 669     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 670     ofs -= self.origin;
 671     setattachment(self.gun1, self, "");
 672     setorigin(self.gun1, ofs);
 673
 674     //setattachment(self.gun2, self, "gunmount_right");
 675     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 676     ofs -= self.origin;
 677     setattachment(self.gun2, self, "");
 678     setorigin(self.gun2, ofs);
 679
 680     self.angles = self.bomb1.angles;
 681     self.bomb1.angles = '0 0 0';
 682
 683     spinner = spawn();
 684     spinner.owner = self;
 685     setmodel(spinner,"models/vehicles/spinner.dpm");
 686     setattachment(spinner, self, "engine_left");
 687     spinner.movetype = MOVETYPE_NOCLIP;
 688     spinner.avelocity = '0 90 0';
 689     self.bomb1.gun1 = spinner;
 690
 691     spinner = spawn();
 692     spinner.owner = self;
 693     setmodel(spinner,"models/vehicles/spinner.dpm");
 694     setattachment(spinner, self, "engine_right");
 695     spinner.movetype = MOVETYPE_NOCLIP;
 696     spinner.avelocity = '0 -90 0';
 697     self.bomb1.gun2 = spinner;
 698
 699     // Sigh.
 700     self.bomb1.think = raptor_rotor_anglefix;
 701     self.bomb1.nextthink = time;
 702
 703     self.mass               = 1 ;
 704 }
 705
 706 void spawnfunc_vehicle_raptor()
 707 {
 708     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 709
 710     self.vehicle_flags |= VHF_DMGSHAKE;
 711     self.vehicle_flags |= VHF_DMGROLL;
 712
 713     if(autocvar_g_vehicle_raptor_shield)
 714         self.vehicle_flags |= VHF_HASSHIELD;
 715
 716     if(autocvar_g_vehicle_raptor_shield_regen)
 717         self.vehicle_flags |= VHF_SHIELDREGEN;
 718
 719     if(autocvar_g_vehicle_raptor_health_regen)
 720         self.vehicle_flags |= VHF_HEALTHREGEN;
 721
 722     if(autocvar_g_vehicle_raptor_energy_regen)
 723         self.vehicle_flags |= VHF_ENERGYREGEN;
 724
 725     precache_model ("models/vehicles/raptor.dpm");
 726     precache_model ("models/vehicles/raptor_gun.dpm");
 727     precache_model ("models/vehicles/spinner.dpm");
 728     precache_model ("models/vehicles/raptor_cockpit.dpm");
 729     //precache_model ("models/vehicles/clusterbomb.md3");
 730     precache_model ("models/vehicles/clusterbomb_folded.md3");
 731     precache_model ("models/vehicles/raptor_body.dpm");
 732
 733     precache_sound ("vehicles/raptor_fly.wav");
 734     precache_sound ("vehicles/raptor_speed.wav");
 735
 736     self.think = raptor_dinit;
 737
 738     if(g_assault)
 739         self.nextthink = time + 0.5;
 740     else
 741         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 742 }
 743 #endif // SVQC