qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 float autocvar_g_vehicle_raptor_bouncefactor;
  61 float autocvar_g_vehicle_raptor_bouncestop;
  62 vector autocvar_g_vehicle_raptor_bouncepain;
  63
  64 void raptor_spawn();
  65 float raptor_frame();
  66 float raptor_takeoff();
  67
  68 .entity bomb1;
  69 .entity bomb2;
  70
  71 float raptor_altitude(float amax)
  72 {
  73         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  74     return vlen(self.origin - trace_endpos);
  75 }
  76
  77
  78 void raptor_bomblet_boom()
  79 {
  80     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  81                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  82                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  83                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  84     remove(self);
  85 }
  86
  87 void raptor_bomblet_touch()
  88 {
  89     if(other == self.owner)
  90         return;
  91
  92     PROJECTILE_TOUCH;
  93     self.think = raptor_bomblet_boom;
  94     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  95 }
  96
  97 void raptor_bomb_burst()
  98 {
  99     if(self.cnt > time)
 100     if(autocvar_g_vehicle_raptor_bomblet_alt)
 101     {
 102         self.nextthink = time;
 103         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 104         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 105         {
 106             UpdateCSQCProjectile(self);
 107             return;
 108         }
 109     }
 110
 111     entity bomblet;
 112     float i;
 113
 114     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         bomblet.movetype    = MOVETYPE_TOSS;
 122         bomblet.touch       = raptor_bomblet_touch;
 123         bomblet.think       = raptor_bomblet_boom;
 124         bomblet.nextthink   = time + 5;
 125         bomblet.owner       = self.owner;
 126         bomblet.realowner   = self.realowner;
 127         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 128
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bombdrop()
 137 {
 138     entity bomb_1, bomb_2;
 139
 140     bomb_1 = spawn();
 141     bomb_2 = spawn();
 142
 143     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 144     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 145
 146     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 147     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 148     bomb_1.touch        = bomb_2.touch      = raptor_bomb_burst;
 149     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 150     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 151
 152     if(autocvar_g_vehicle_raptor_bomblet_alt)
 153         bomb_1.nextthink = bomb_2.nextthink  = time;
 154     else
 155         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 156
 157     bomb_1.owner     = bomb_2.owner      = self;
 158     bomb_1.realowner = bomb_2.realowner  = self.owner;
 159     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 160     bomb_1.gravity   = bomb_2.gravity    = 1;
 161
 162     PROJECTILE_MAKETRIGGER(bomb_1);
 163     PROJECTILE_MAKETRIGGER(bomb_2);
 164
 165     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 166     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167 }
 168
 169
 170 void raptor_fire_cannon(entity gun, string tagname)
 171 {
 172     vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 173                            gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 174                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 175                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 176 }
 177
 178 void raptor_think()
 179 {
 180 }
 181
 182 void raptor_enter()
 183 {
 184     self.owner.PlayerPhysplug = raptor_takeoff;
 185     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 186     self.solid          = SOLID_SLIDEBOX;
 187     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 188     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 189     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 190     self.tur_head.exteriormodeltoclient = self.owner;
 191
 192     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 193     self.lip   = time;
 194
 195     if(self.owner.flagcarried)
 196        setorigin(self.owner.flagcarried, '-20 0 96');
 197
 198 }
 199
 200 void raptor_land()
 201 {
 202     float hgt;
 203
 204     hgt = raptor_altitude(512);
 205     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 206     self.angles_x *= 0.95;
 207     self.angles_z *= 0.95;
 208
 209     if(hgt < 128)
 210     if(hgt > 0)
 211         self.frame = (hgt / 128) * 25;
 212
 213     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 214     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 215
 216     if(hgt < 16)
 217     {
 218         self.movetype = MOVETYPE_TOSS;
 219         self.think    = raptor_think;
 220         self.frame    = 0;
 221     }
 222
 223     self.nextthink  = time;
 224 }
 225
 226 void raptor_exit(float eject)
 227 {
 228     vector spot;
 229     self.tur_head.exteriormodeltoclient = world;
 230
 231     if(self.deadflag == DEAD_NO)
 232     {
 233         self.think      = raptor_land;
 234         self.nextthink  = time;
 235     }
 236
 237     if not (self.owner)
 238         return;
 239
 240         makevectors(self.angles);
 241         if(eject)
 242         {
 243             spot = self.origin + v_forward * 100 + '0 0 64';
 244             spot = vehicles_findgoodexit(spot);
 245             setorigin(self.owner , spot);
 246             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 247         }
 248         else
 249         {
 250             spot = self.origin - v_forward * 200 + '0 0 64';
 251             spot = vehicles_findgoodexit(spot);
 252             setorigin(self.owner , spot);
 253         }
 254
 255     self.owner = world;
 256 }
 257
 258 float raptor_takeoff()
 259 {
 260     entity player, raptor;
 261
 262     player = self;
 263     raptor = self.vehicle;
 264     self   = raptor;
 265     if(self.sound_nexttime < time)
 266     {
 267         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 268         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 269     }
 270
 271     // Takeoff sequense
 272     if(raptor.frame < 25)
 273     {
 274         raptor.frame += 0.25;
 275         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 276         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 277         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 278         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 279
 280         setorigin(player, raptor.origin + '0 0 32');
 281     }
 282     else
 283         player.PlayerPhysplug = raptor_frame;
 284
 285     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 286         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 287
 288     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 289         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 290
 291     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 292         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 293
 294
 295     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 296     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 297
 298     VEHICLE_UPDATE_PLAYER(health, raptor);
 299     VEHICLE_UPDATE_PLAYER(energy, raptor);
 300     if(self.vehicle_flags & VHF_HASSHIELD)
 301         VEHICLE_UPDATE_PLAYER(shield, raptor);
 302
 303     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 304     self = player;
 305     return 1;
 306 }
 307
 308 float raptor_frame()
 309 {
 310     entity player, raptor;
 311     float ftmp, ftmp2;
 312     vector df;
 313
 314         if(intermission_running)
 315                 return 1;
 316
 317     player = self;
 318     raptor = self.vehicle;
 319     self   = raptor;
 320     vehicles_painframe();
 321     /*
 322     ftmp = vlen(self.velocity);
 323     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 324         ftmp = 1;
 325     else
 326         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 327     */
 328
 329     if(self.sound_nexttime < time)
 330     {
 331         self.sound_nexttime = time + 7.955812;
 332         //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 333         sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 334         self.wait = ftmp;
 335     }
 336     /*
 337     else if(fabs(ftmp - self.wait) > 0.2)
 338     {
 339         sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTN_NORM );
 340         sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTN_NORM);
 341         self.wait = ftmp;
 342     }
 343     */
 344
 345     if(raptor.deadflag != DEAD_NO)
 346     {
 347         self = player;
 348         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 349         return 1;
 350     }
 351     crosshair_trace(player);
 352
 353     vector vang;
 354     vang = raptor.angles;
 355     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 356     vang_x *= -1;
 357     df_x *= -1;
 358     if(df_x > 180)  df_x -= 360;
 359     if(df_x < -180) df_x += 360;
 360     if(df_y > 180)  df_y -= 360;
 361     if(df_y < -180) df_y += 360;
 362
 363     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 364     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 365     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 366
 367     // Pitch
 368     ftmp = 0;
 369     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 370     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 371
 372     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 373     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 374     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 375
 376     raptor.angles_x = anglemods(raptor.angles_x);
 377     raptor.angles_y = anglemods(raptor.angles_y);
 378     raptor.angles_z = anglemods(raptor.angles_z);
 379
 380     if(autocvar_g_vehicle_raptor_movestyle == 1)
 381         makevectors('0 1 0' * raptor.angles_y);
 382     else
 383         makevectors(player.v_angle);
 384
 385     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 386
 387     if(player.movement_x != 0)
 388     {
 389         if(player.movement_x > 0)
 390             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 391         else if(player.movement_x < 0)
 392             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 393     }
 394
 395     if(player.movement_y != 0)
 396     {
 397         if(player.movement_y < 0)
 398             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 399         else if(player.movement_y > 0)
 400             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 401
 402         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 403     }
 404     else
 405     {
 406         raptor.angles_z *= 0.95;
 407         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 408             raptor.angles_z = 0;
 409     }
 410
 411     if(player.BUTTON_CROUCH)
 412         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 413     else if (player.BUTTON_JUMP)
 414         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 415
 416     raptor.velocity  += df * frametime;
 417     player.velocity = player.movement  = raptor.velocity;
 418     setorigin(player, raptor.origin + '0 0 32');
 419
 420     vector vf, ad;
 421     // Target lock & predict
 422     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 423     {
 424
 425         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 426                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 427                              autocvar_g_vehicle_raptor_cannon_locked_time);
 428
 429         if(self.lock_target != world)
 430         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 431         if(self.lock_strength == 1)
 432         {
 433             float i, distance, impact_time;
 434
 435             vf = real_origin(raptor.lock_target);
 436             ad = vf;
 437             for(i = 0; i < 4; ++i)
 438             {
 439                 distance = vlen(ad - raptor.origin);
 440                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 441                 ad = vf + raptor.lock_target.velocity * impact_time;
 442             }
 443             trace_endpos = ad;
 444         }
 445
 446         if(self.lock_target)
 447         {
 448             if(raptor.lock_strength == 1)
 449                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 450             else if(self.lock_strength > 0.5)
 451                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 452             else if(self.lock_strength < 0.5)
 453                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 454         }
 455     }
 456
 457     // Aim the gunz
 458     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 459     ftmp = -ftmp2;
 460
 461     // Gun1
 462     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 463     //ad = df;
 464     //vf = v_forward;
 465     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 466     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun1.angles;
 467     df = shortangle_vxy(df, raptor.gun1.angles);
 468
 469     // Bind to aimspeed
 470     df_x = bound(ftmp, df_x, ftmp2);
 471     df_y = bound(ftmp, df_y, ftmp2);
 472     // Bind to limts
 473     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 474     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 475
 476     // Gun2
 477     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 478     //ad += df;
 479     //vf += v_forward;
 480     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 481     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun2.angles;
 482     df = shortangle_vxy(df, raptor.gun2.angles);
 483
 484     // Bind to aimspeed
 485     df_x = bound(ftmp, df_x, ftmp2);
 486     df_y = bound(ftmp, df_y, ftmp2);
 487     // Bind to limts
 488     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 489     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 490
 491     /*
 492     ad = ad * 0.5;
 493     v_forward = vf * 0.5;
 494     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 495     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 496     */
 497
 498     if(player.BUTTON_ATCK)
 499     if(raptor.attack_finished_single <= time)
 500     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 501     {
 502         raptor.misc_bulletcounter += 1;
 503         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 504         if(raptor.misc_bulletcounter <= 2)
 505             raptor_fire_cannon(self.gun1, "fire1");
 506         else if(raptor.misc_bulletcounter == 3)
 507             raptor_fire_cannon(self.gun2, "fire1");
 508         else
 509         {
 510             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 511             raptor_fire_cannon(self.gun2, "fire1");
 512             raptor.misc_bulletcounter = 0;
 513         }
 514         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 515         self.cnt = time;
 516     }
 517
 518     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 519         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 520
 521     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 522         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 523
 524     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 525         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 526
 527
 528     if(time > raptor.delay)
 529     if(player.BUTTON_ATCK2)
 530     {
 531         raptor_bombdrop();
 532         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 533         raptor.lip   = time;
 534     }
 535
 536     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 537     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 538
 539     VEHICLE_UPDATE_PLAYER(health, raptor);
 540     VEHICLE_UPDATE_PLAYER(energy, raptor);
 541     if(self.vehicle_flags & VHF_HASSHIELD)
 542         VEHICLE_UPDATE_PLAYER(shield, raptor);
 543
 544     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 545     return 1;
 546 }
 547
 548 void raptor_blowup()
 549 {
 550     self.deadflag    = DEAD_DEAD;
 551     self.vehicle_exit(VHEF_NORMAL);
 552     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 553
 554     self.alpha          = -1;
 555     self.movetype       = MOVETYPE_NONE;
 556     self.effects        = EF_NODRAW;
 557     self.colormod       = '0 0 0';
 558     self.avelocity      = '0 0 0';
 559     self.velocity       = '0 0 0';
 560
 561     setorigin(self, self.pos1);
 562     self.touch = SUB_Null;
 563     self.nextthink = 0;
 564 }
 565
 566 void raptor_diethink()
 567 {
 568     if(random() < 0.1)
 569     {
 570         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 571         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 572     }
 573     self.nextthink = time + 0.1;
 574 }
 575
 576 void raptor_die()
 577 {
 578     self.health       = 0;
 579     self.event_damage = SUB_Null;
 580     self.solid        = SOLID_CORPSE;
 581     self.takedamage   = DAMAGE_NO;
 582     self.deadflag     = DEAD_DYING;
 583     self.movetype     = MOVETYPE_BOUNCE;
 584     self.think        = raptor_diethink;
 585     self.nextthink    = time;
 586
 587     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 588
 589     self.velocity_z += 600;
 590
 591     self.avelocity = '0 0.5 1' * (random() * 400);
 592     self.avelocity -= '0 0.5 1' * (random() * 400);
 593
 594     self.colormod = '-0.5 -0.5 -0.5';
 595         self.touch     = raptor_blowup;
 596 }
 597
 598 void raptor_worldimpact()
 599 {
 600     if(self.play_time < time)
 601     if(autocvar_g_vehicle_raptor_bouncepain_x)
 602         vehilces_worldimpact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 603 }
 604
 605 void raptor_spawn()
 606 {
 607     self.frame          = 0;
 608     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 609     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 610     self.movetype       = MOVETYPE_TOSS;
 611     self.solid          = SOLID_SLIDEBOX;
 612     self.vehicle_energy = 1;
 613
 614     self.bomb1.gun1.avelocity_y = 90;
 615     self.bomb1.gun2.avelocity_y = -90;
 616
 617     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 618     self.delay = time;
 619
 620     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 621     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 622     self.vehicle_worldimpact = raptor_worldimpact;
 623 }
 624
 625 // If we dont do this ever now and then, the raptors rotors
 626 // stop working, presumably due to angle overflow. cute.
 627 void raptor_rotor_anglefix()
 628 {
 629     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 630     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 631     self.nextthink = time + 15;
 632 }
 633
 634 void raptor_dinit()
 635 {
 636     entity spinner;
 637     vector ofs;
 638
 639     if not (vehicle_initialize(
 640              "Raptor",
 641              "models/vehicles/raptor.dpm",
 642              "",
 643              "models/vehicles/raptor_cockpit.dpm",
 644              "", "tag_hud", "tag_camera",
 645              HUD_RAPTOR,
 646              RAPTOR_MIN, RAPTOR_MAX,
 647              FALSE,
 648              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 649              raptor_frame,
 650              raptor_enter, raptor_exit,
 651              raptor_die,   raptor_think,
 652              FALSE))
 653     {
 654         remove(self);
 655         return;
 656     }
 657
 658     //FIXME: Camera is in a bad place in HUD model.
 659     //setorigin(self.vehicle_viewport, '25 0 5');
 660
 661     self.frame = 0;
 662
 663     self.bomb1 = spawn();
 664     self.bomb2 = spawn();
 665     self.gun1  = spawn();
 666     self.gun2  = spawn();
 667
 668     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 669     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 670     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 671     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 672     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 673
 674     setattachment(self.bomb1, self,"bombmount_left");
 675     setattachment(self.bomb2, self,"bombmount_right");
 676     setattachment(self.tur_head, self,"root");
 677
 678
 679     // FIXME Guns mounts to angled bones
 680     self.bomb1.angles = self.angles;
 681     self.angles = '0 0 0';
 682     // This messes up gun-aim, so work arround it.
 683     //setattachment(self.gun1, self, "gunmount_left");
 684     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 685     ofs -= self.origin;
 686     setattachment(self.gun1, self, "");
 687     setorigin(self.gun1, ofs);
 688
 689     //setattachment(self.gun2, self, "gunmount_right");
 690     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 691     ofs -= self.origin;
 692     setattachment(self.gun2, self, "");
 693     setorigin(self.gun2, ofs);
 694
 695     self.angles = self.bomb1.angles;
 696     self.bomb1.angles = '0 0 0';
 697
 698     spinner = spawn();
 699     spinner.owner = self;
 700     setmodel(spinner,"models/vehicles/spinner.dpm");
 701     setattachment(spinner, self, "engine_left");
 702     spinner.movetype = MOVETYPE_NOCLIP;
 703     spinner.avelocity = '0 90 0';
 704     self.bomb1.gun1 = spinner;
 705
 706     spinner = spawn();
 707     spinner.owner = self;
 708     setmodel(spinner,"models/vehicles/spinner.dpm");
 709     setattachment(spinner, self, "engine_right");
 710     spinner.movetype = MOVETYPE_NOCLIP;
 711     spinner.avelocity = '0 -90 0';
 712     self.bomb1.gun2 = spinner;
 713
 714     // Sigh.
 715     self.bomb1.think = raptor_rotor_anglefix;
 716     self.bomb1.nextthink = time;
 717
 718     self.mass               = 1 ;
 719 }
 720
 721 void spawnfunc_vehicle_raptor()
 722 {
 723     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 724
 725     self.vehicle_flags |= VHF_DMGSHAKE;
 726     self.vehicle_flags |= VHF_DMGROLL;
 727
 728     if(autocvar_g_vehicle_raptor_shield)
 729         self.vehicle_flags |= VHF_HASSHIELD;
 730
 731     if(autocvar_g_vehicle_raptor_shield_regen)
 732         self.vehicle_flags |= VHF_SHIELDREGEN;
 733
 734     if(autocvar_g_vehicle_raptor_health_regen)
 735         self.vehicle_flags |= VHF_HEALTHREGEN;
 736
 737     if(autocvar_g_vehicle_raptor_energy_regen)
 738         self.vehicle_flags |= VHF_ENERGYREGEN;
 739
 740     precache_model ("models/vehicles/raptor.dpm");
 741     precache_model ("models/vehicles/raptor_gun.dpm");
 742     precache_model ("models/vehicles/spinner.dpm");
 743     precache_model ("models/vehicles/raptor_cockpit.dpm");
 744     //precache_model ("models/vehicles/clusterbomb.md3");
 745     precache_model ("models/vehicles/clusterbomb_folded.md3");
 746     precache_model ("models/vehicles/raptor_body.dpm");
 747
 748     precache_sound ("vehicles/raptor_fly.wav");
 749     precache_sound ("vehicles/raptor_speed.wav");
 750
 751     self.think = raptor_dinit;
 752
 753     if(g_assault)
 754         self.nextthink = time + 0.5;
 755     else
 756         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 757 }
 758 #endif // SVQC