qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 #ifdef SVQC
   5 float autocvar_g_vehicle_spiderbot_respawntime;
   6
   7 float autocvar_g_vehicle_spiderbot_speed_stop;
   8 float autocvar_g_vehicle_spiderbot_speed_strafe;
   9 float autocvar_g_vehicle_spiderbot_speed_walk;
  10 float autocvar_g_vehicle_spiderbot_turnspeed;
  11 float autocvar_g_vehicle_spiderbot_movement_inertia;
  12
  13 float autocvar_g_vehicle_spiderbot_springlength;
  14 float autocvar_g_vehicle_spiderbot_springup;
  15 float autocvar_g_vehicle_spiderbot_springblend;
  16
  17 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  18 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  19 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  20 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  21 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  22
  23 //float autocvar_g_vehicle_spiderbot_energy;
  24 //float autocvar_g_vehicle_spiderbot_energy_regen;
  25 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  26
  27 float autocvar_g_vehicle_spiderbot_health;
  28 float autocvar_g_vehicle_spiderbot_health_regen;
  29 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  30
  31 float autocvar_g_vehicle_spiderbot_shield;
  32 float autocvar_g_vehicle_spiderbot_shield_regen;
  33 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  34
  35 float autocvar_g_vehicle_spiderbot_minigun_damage;
  36 float autocvar_g_vehicle_spiderbot_minigun_refire;
  37 float autocvar_g_vehicle_spiderbot_minigun_spread;
  38 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  39 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  40 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  41 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_force;
  45 float autocvar_g_vehicle_spiderbot_rocket_radius;
  46 float autocvar_g_vehicle_spiderbot_rocket_speed;
  47 float autocvar_g_vehicle_spiderbot_rocket_refire;
  48 float autocvar_g_vehicle_spiderbot_rocket_reload;
  49 float autocvar_g_vehicle_spiderbot_rocket_health;
  50 float autocvar_g_vehicle_spiderbot_rocket_noise;
  51 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  52 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  53
  54 void spiderbot_exit(float eject);
  55 void spiderbot_enter();
  56 void spiderbot_spawn();
  57
  58 void spiderbot_rocket_unguided()
  59 {
  60     vector newdir, olddir;
  61
  62     self.nextthink  = time;
  63
  64     olddir = normalize(self.velocity);
  65     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  66     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  67
  68     UpdateCSQCProjectile(self);
  69
  70     if (self.owner.deadflag != DEAD_NO || self.cnt < time || vlen(self.pos1 - self.origin) < 16)
  71         self.use();
  72 }
  73
  74 void spiderbot_rocket_guided()
  75 {
  76     vector newdir, olddir;
  77
  78     self.nextthink  = time;
  79
  80     if not (self.realowner.vehicle)
  81         self.think = spiderbot_rocket_unguided;
  82
  83     crosshair_trace(self.realowner);
  84     olddir = normalize(self.velocity);
  85     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  86     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  87
  88     UpdateCSQCProjectile(self);
  89
  90     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  91         self.use();
  92 }
  93
  94 void spiderbot_guide_release()
  95 {
  96     entity rkt;
  97     rkt = findchainentity(realowner, self.owner);
  98     if not (rkt)
  99         return;
 100
 101     crosshair_trace(self.owner);
 102     while(rkt)
 103     {
 104         if(rkt.think == spiderbot_rocket_guided)
 105         {
 106             rkt.pos1 = trace_endpos;
 107             rkt.think = spiderbot_rocket_unguided;
 108         }
 109         rkt = rkt.chain;
 110     }
 111 }
 112
 113 void spiderbot_rocket_do()
 114 {
 115
 116     vector v;
 117     entity rocket;
 118
 119     if (self.owner.BUTTON_ATCK2)
 120     {
 121         if (self.wait == 1)
 122         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 123         {
 124             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 125                 self.tur_head.frame = 1;
 126
 127             return;
 128         }
 129         self.wait = 1;
 130     }
 131     else
 132     {
 133         if(self.wait)
 134             spiderbot_guide_release();
 135
 136         self.wait = 0;
 137     }
 138
 139     if(self.gun2.cnt > time)
 140         return;
 141
 142     if (self.tur_head.frame >= 9)
 143         self.tur_head.frame = 1;
 144
 145     if not (self.owner.BUTTON_ATCK2)
 146         return;
 147
 148     crosshair_trace(self.owner);
 149
 150     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 151     rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 152                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 153                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 154                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE);
 155
 156     rocket.cnt        = time + 15;
 157     rocket.classname  = "spiderbot_rocket";
 158     rocket.pos1       = trace_endpos;
 159     rocket.think      = spiderbot_rocket_guided;
 160     rocket.nextthink  = time;
 161     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 162
 163     self.tur_head.frame += 1;
 164     if (self.tur_head.frame == 9)
 165         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 166     else
 167         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 168
 169     self.gun2.cnt = time + self.attack_finished_single;
 170 }
 171
 172 float spiderbot_frame()
 173 {
 174     vector ad;
 175     entity player, spider;
 176     float ftmp;
 177
 178         if(intermission_running)
 179                 return 1;
 180
 181     player = self;
 182     spider = self.vehicle;
 183     self   = spider;
 184
 185     vehicles_painframe();
 186
 187     player.BUTTON_ZOOM      = 0;
 188     player.BUTTON_CROUCH    = 0;
 189     player.switchweapon     = 0;
 190
 191     crosshair_trace(player);
 192     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 193
 194     //player.v_angle_x *= -1;
 195     //gettaginfo(spider.tur_head, 0);
 196     //ad = player.v_angle - vectoangles2(v_forward, v_up);
 197     //ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 198     //player.v_angle_x *= -1;
 199     ad = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(spider.angles), AnglesTransform_FromVAngles(player.v_angle))) - spider.tur_head.angles;
 200
 201     if(ad_x > 180)  ad_x -= 360;
 202     if(ad_x < -180) ad_x += 360;
 203     if(ad_y > 180)  ad_y -= 360;
 204     if(ad_y < -180) ad_y += 360;
 205
 206     // Rotate head
 207     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 208     ad_y = bound(-ftmp, ad_y, ftmp);
 209     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 210
 211     // Pitch head
 212 #if 0 // Enable to pich by cross-trace (more precise in chase, but less predictable)
 213     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 214     if(ad_x > 180) ad_x -= 360;
 215     if(ad_x < -180) ad_x += 360;
 216 #endif
 217     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 218     ad_x = bound(ftmp * -1, ad_x, ftmp);
 219     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 220
 221     // Turn Body
 222     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 223     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 224
 225     makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 226
 227 /*
 228     vector ofs;
 229     ofs = self.origin + v_up * 128;
 230     te_lightning1(world, ofs, ofs + v_up * 32);
 231     te_lightning1(world, ofs, ofs + v_right * 128);
 232     te_lightning1(world, ofs, ofs + v_forward * 256);
 233 */
 234
 235     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 236
 237     if(spider.flags & FL_ONGROUND)
 238     {
 239         if(spider.frame == 4 && self.tur_head.wait != 0)
 240         {
 241             sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_land.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 242             spider.frame = 5;
 243         }
 244
 245         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 246         {
 247             sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_jump.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 248             //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 249             self.delay = 0;
 250
 251             self.tur_head.wait = time + 2;
 252             player.BUTTON_JUMP = 0;
 253             spider.velocity   = v_forward * 700 + v_up * 600;
 254             spider.frame = 4;
 255         }
 256         else
 257         {
 258             if(vlen(player.movement) == 0)
 259             {
 260                 if(self.sound_nexttime < time || self.delay != 3)
 261                 {
 262                     self.delay = 3;
 263                     self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 264                     //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 265                     sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 266                 }
 267                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 268                 spider.frame = 5;
 269             }
 270             else
 271             {
 272                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 273                 spider.tur_head.angles_y -= ftmp;
 274
 275                 if(player.movement_x != 0)
 276                 {
 277                     if(player.movement_x > 0)
 278                     {
 279                         player.movement_x = 1;
 280                         spider.frame = 0;
 281                     }
 282                     else if(player.movement_x < 0)
 283                     {
 284                         player.movement_x = -1;
 285                         spider.frame = 1;
 286                     }
 287                     player.movement_y = 0;
 288                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 289
 290                     if(self.sound_nexttime < time || self.delay != 1)
 291                     {
 292                         self.delay = 1;
 293                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 294                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_walk.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 295                         //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 296                     }
 297                 }
 298                 else if(player.movement_y != 0)
 299                 {
 300                     if(player.movement_y < 0)
 301                     {
 302                         player.movement_y = -1;
 303                         spider.frame = 2;
 304                     }
 305                     else if(player.movement_y > 0)
 306                     {
 307                         player.movement_y = 1;
 308                         spider.frame = 3;
 309                     }
 310                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 311                     if(self.sound_nexttime < time || self.delay != 2)
 312                     {
 313                         self.delay = 2;
 314                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 315                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_strafe.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 316                         //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 317                     }
 318                 }
 319             }
 320         }
 321     }
 322
 323     self.angles_x = bound(-45, self.angles_x, 45);
 324     self.angles_z = bound(-45, self.angles_z, 45);
 325
 326     if(player.BUTTON_ATCK)
 327     {
 328         spider.cnt = time;
 329         if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 330         {
 331             entity gun;
 332             vector v;
 333             spider.misc_bulletcounter += 1;
 334
 335             self = player;
 336
 337             mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 338             v = gettaginfo(gun, gettagindex(gun, "barrels"));
 339             v_forward = normalize(v_forward);
 340             v += v_forward * 50;
 341
 342             fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 343                 autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 344
 345             sound (gun, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 346             trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 347             pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 348
 349             self = spider;
 350
 351             spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 352             spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 353             player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 354             spider.gun1.angles_z += 45;
 355             spider.gun2.angles_z -= 45;
 356             if(spider.gun1.angles_z >= 360)
 357             {
 358                 spider.gun1.angles_z = 0;
 359                 spider.gun2.angles_z = 0;
 360             }
 361         }
 362     }
 363     else
 364         vehicles_regen(cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 365                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 366                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime);
 367
 368
 369     spiderbot_rocket_do();
 370
 371     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 372         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 373
 374     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 375         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 376
 377     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 378     player.vehicle_ammo2 = spider.tur_head.frame;
 379
 380     if(spider.gun2.cnt <= time)
 381         player.vehicle_reload2 = 100;
 382     else
 383         player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 384
 385     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 386     player.velocity = spider.velocity;
 387
 388     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 389
 390     if(self.vehicle_flags & VHF_HASSHIELD)
 391         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 392
 393 #if 1 // 0 to enable per-gun impact aux crosshairs
 394     // Avarage gun impact point's -> aux cross
 395     vector vf;
 396     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 397     vf = v_forward;
 398     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 399     vf += v_forward;
 400     ad = ad * 0.5;
 401     v_forward = vf * 0.5;
 402     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 403     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 404
 405 #else
 406     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 407     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 408     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 409
 410     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 411     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 412     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 413 #endif
 414
 415     self = player;
 416     return 1;
 417 }
 418
 419 void spiderbot_think()
 420 {
 421     if(self.flags & FL_ONGROUND)
 422         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 423
 424     self.nextthink = time;
 425 }
 426
 427 void spiderbot_enter()
 428 {
 429     self.movetype   = MOVETYPE_WALK;
 430
 431     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 432     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 433
 434     if(self.owner.flagcarried)
 435     {
 436         setattachment(self.owner.flagcarried, self.tur_head, "");
 437         setorigin(self.owner.flagcarried, '-20 0 120');
 438     }
 439 }
 440
 441 void spiderbot_exit(float eject)
 442 {
 443     entity e;
 444     vector spot;
 445
 446     e = findchain(classname,"spiderbot_rocket");
 447     while(e)
 448     {
 449         if(e.owner == self.owner)
 450         {
 451             e.realowner = self.owner;
 452             e.owner = world;
 453         }
 454         e = e.chain;
 455     }
 456
 457     self.velocity   = '0 0 0';
 458     self.think      = spiderbot_think;
 459     self.nextthink  = time;
 460     self.frame      = 5;
 461     self.movetype   = MOVETYPE_WALK;
 462
 463     if not (self.owner)
 464         return;
 465
 466         makevectors(self.angles);
 467         if(eject)
 468         {
 469             spot = self.origin + v_forward * 100 + '0 0 64';
 470             spot = vehicles_findgoodexit(spot);
 471             setorigin(self.owner , spot);
 472             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 473         }
 474         else
 475         {
 476             spot = self.origin - v_forward * 200 + '0 0 64';
 477             spot = vehicles_findgoodexit(spot);
 478             setorigin(self.owner , spot);
 479         }
 480
 481     self.owner = world;
 482 }
 483
 484 void spiderbot_spawn()
 485 {
 486     self.frame              = 5;
 487     self.tur_head.frame     = 1;
 488     self.think              = spiderbot_think;
 489     self.nextthink          = time;
 490     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 491     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 492     self.movetype           = MOVETYPE_WALK;
 493     self.solid              = SOLID_SLIDEBOX;
 494     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 495     self.tur_head.angles    = '0 0 0';
 496
 497     setorigin(self, self.pos1 + '0 0 128');
 498     self.angles = self.pos2;
 499 }
 500
 501 void spiderbot_headfade()
 502 {
 503         self.think = spiderbot_headfade;
 504         self.nextthink = self.fade_time;
 505         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 506
 507     if(self.cnt < time || self.alpha < 0.1)
 508     {
 509         if(self.alpha > 0.1)
 510         {
 511             sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 512             pointparticles(particleeffectnum("explosion_big"), self.origin + '0 0 100', '0 0 0', 1);
 513         }
 514         remove(self);
 515     }
 516 }
 517
 518 void spiderbot_blowup()
 519 {
 520     if(self.cnt > time)
 521     {
 522         if(random() < 0.1)
 523         {
 524             sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 525             pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 526         }
 527         self.nextthink = time + 0.1;
 528         return;
 529     }
 530
 531     entity h, g1, g2, b;
 532     b = spawn();
 533     h = spawn();
 534     g1 = spawn();
 535     g2 = spawn();
 536
 537     setmodel(b,  "models/vehicles/spiderbot.dpm");
 538     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 539     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 540     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 541
 542     setorigin(b, self.origin);
 543     b.frame         = 11;
 544     b.angles        = self.angles;
 545     setsize(b, self.mins, self.maxs);
 546
 547     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 548     h.movetype      = MOVETYPE_BOUNCE;
 549     h.solid         = SOLID_BBOX;
 550     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 551     h.modelflags    = MF_ROCKET;
 552     h.effects       = EF_FLAME | EF_LOWPRECISION;
 553     h.avelocity     = randomvec() * 360;
 554
 555     h.alpha         = 1;
 556     h.cnt           = time + (3.5 * random());
 557     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 558     h.fade_time     = time;
 559     h.think         = spiderbot_headfade;
 560     h.nextthink     = time;
 561
 562     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 563     g1.movetype     = MOVETYPE_TOSS;
 564     g1.solid        = SOLID_CORPSE;
 565     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 566     g1.avelocity    = randomvec() * 180;
 567
 568     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 569     g2.movetype     = MOVETYPE_TOSS;
 570     g2.solid        = SOLID_CORPSE;
 571     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 572     g2.avelocity    = randomvec() * 180;
 573
 574     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 575
 576     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 577     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 578     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 579     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 580
 581     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 582
 583     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 584     self.movetype   = MOVETYPE_NONE;
 585     self.deadflag   = DEAD_DEAD;
 586     self.solid      = SOLID_NOT;
 587     self.tur_head.effects  &~=  EF_FLAME;
 588         self.vehicle_hudmodel.viewmodelforclient = self;
 589 }
 590
 591 void spiderbot_die()
 592 {
 593     self.health             = 0;
 594     self.event_damage       = SUB_Null;
 595     self.takedamage         = DAMAGE_NO;
 596     self.touch              = SUB_Null;
 597     self.cnt                = 3.4 + time + random() * 2;
 598     self.think              = spiderbot_blowup;
 599     self.nextthink          = time;
 600     self.deadflag           = DEAD_DYING;
 601         self.frame              = 5;
 602         self.tur_head.effects  |= EF_FLAME;
 603         self.colormod           = self.tur_head.colormod = '-1 -1 -1';
 604         self.frame              = 10;
 605         self.movetype           = MOVETYPE_TOSS;
 606 }
 607
 608 void vewhicle_spiderbot_dinit()
 609 {
 610     if not (vehicle_initialize(
 611              "Spiderbot",
 612              "models/vehicles/spiderbot.dpm",
 613              "models/vehicles/spiderbot_top.dpm",
 614              "models/vehicles/spiderbot_cockpit.dpm",
 615              "tag_head", "tag_hud", "",
 616              HUD_SPIDERBOT,
 617              SPIDERBOT_MIN, SPIDERBOT_MAX,
 618              FALSE,
 619              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 620              spiderbot_frame,
 621              spiderbot_enter, spiderbot_exit,
 622              spiderbot_die,   spiderbot_think,
 623              FALSE))
 624     {
 625         remove(self);
 626         return;
 627     }
 628
 629
 630     self.gun1               = spawn();
 631     self.gun2               = spawn();
 632
 633     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 634     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 635
 636     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 637     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 638
 639     self.gravity            = 2;
 640     self.mass               = 5000;
 641 }
 642
 643 void spawnfunc_vehicle_spiderbot()
 644 {
 645     self.vehicle_flags |= VHF_DMGSHAKE;
 646     //self.vehicle_flags |= VHF_DMGROLL;
 647     //self.vehicle_flags |= VHF_DMGHEADROLL;
 648
 649     precache_model ( "models/vhshield.md3");
 650     precache_model ( "models/vehicles/spiderbot.dpm");
 651     precache_model ( "models/vehicles/spiderbot_top.dpm");
 652     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 653     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 654     precache_model ( "models/uziflash.md3");
 655
 656     precache_sound ( "weapons/uzi_fire.wav" );
 657     precache_sound ( "weapons/rocket_impact.wav");
 658
 659     precache_sound ( "vehicles/spiderbot_die.wav");
 660     precache_sound ( "vehicles/spiderbot_idle.wav");
 661     precache_sound ( "vehicles/spiderbot_jump.wav");
 662     precache_sound ( "vehicles/spiderbot_strafe.wav");
 663     precache_sound ( "vehicles/spiderbot_walk.wav");
 664     precache_sound ( "vehicles/spiderbot_land.wav");
 665
 666     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 667     if(autocvar_g_vehicle_spiderbot_shield)
 668         self.vehicle_flags |= VHF_HASSHIELD;
 669
 670     if(autocvar_g_vehicle_spiderbot_shield_regen)
 671         self.vehicle_flags |= VHF_SHIELDREGEN;
 672
 673     if(autocvar_g_vehicle_spiderbot_health_regen)
 674         self.vehicle_flags |= VHF_HEALTHREGEN;
 675
 676     self.think = vewhicle_spiderbot_dinit;
 677     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_spiderbot_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 678 }
 679 #endif // SVQC