qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 #ifdef SVQC
   5 float autocvar_g_vehicle_spiderbot_respawntime;
   6
   7 float autocvar_g_vehicle_spiderbot_speed_stop;
   8 float autocvar_g_vehicle_spiderbot_speed_strafe;
   9 float autocvar_g_vehicle_spiderbot_speed_walk;
  10 float autocvar_g_vehicle_spiderbot_turnspeed;
  11 float autocvar_g_vehicle_spiderbot_turnspeed_strafe;
  12 float autocvar_g_vehicle_spiderbot_movement_inertia;
  13
  14 float autocvar_g_vehicle_spiderbot_springlength;
  15 float autocvar_g_vehicle_spiderbot_springup;
  16 float autocvar_g_vehicle_spiderbot_springblend;
  17 float autocvar_g_vehicle_spiderbot_tiltlimit;
  18
  19 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  20 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  21 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  22 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  23
  24 //float autocvar_g_vehicle_spiderbot_energy;
  25 //float autocvar_g_vehicle_spiderbot_energy_regen;
  26 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  27
  28 float autocvar_g_vehicle_spiderbot_health;
  29 float autocvar_g_vehicle_spiderbot_health_regen;
  30 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  31
  32 float autocvar_g_vehicle_spiderbot_shield;
  33 float autocvar_g_vehicle_spiderbot_shield_regen;
  34 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  35
  36 float autocvar_g_vehicle_spiderbot_minigun_damage;
  37 float autocvar_g_vehicle_spiderbot_minigun_refire;
  38 float autocvar_g_vehicle_spiderbot_minigun_spread;
  39 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  40 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  41 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  42 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  43 float autocvar_g_vehicle_spiderbot_minigun_force;
  44 float autocvar_g_vehicle_spiderbot_minigun_speed;
  45 float autocvar_g_vehicle_spiderbot_minigun_bulletconstant;
  46
  47 float autocvar_g_vehicle_spiderbot_rocket_damage;
  48 float autocvar_g_vehicle_spiderbot_rocket_force;
  49 float autocvar_g_vehicle_spiderbot_rocket_radius;
  50 float autocvar_g_vehicle_spiderbot_rocket_speed;
  51 float autocvar_g_vehicle_spiderbot_rocket_refire;
  52 float autocvar_g_vehicle_spiderbot_rocket_reload;
  53 float autocvar_g_vehicle_spiderbot_rocket_health;
  54 float autocvar_g_vehicle_spiderbot_rocket_noise;
  55 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  56 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  57
  58 vector autocvar_g_vehicle_spiderbot_bouncepain;
  59
  60
  61 void spiderbot_exit(float eject);
  62 void spiderbot_enter();
  63 void spiderbot_spawn();
  64
  65 void spiderbot_rocket_unguided()
  66 {
  67     vector newdir, olddir;
  68
  69     self.nextthink  = time;
  70
  71     olddir = normalize(self.velocity);
  72     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  73     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  74
  75     UpdateCSQCProjectile(self);
  76
  77     if (self.owner.deadflag != DEAD_NO || self.cnt < time || vlen(self.pos1 - self.origin) < 16)
  78         self.use();
  79 }
  80
  81 void spiderbot_rocket_guided()
  82 {
  83     vector newdir, olddir;
  84
  85     self.nextthink  = time;
  86
  87     if not (self.realowner.vehicle)
  88         self.think = spiderbot_rocket_unguided;
  89
  90     crosshair_trace(self.realowner);
  91     olddir = normalize(self.velocity);
  92     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  93     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  94
  95     UpdateCSQCProjectile(self);
  96
  97     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  98         self.use();
  99 }
 100
 101 void spiderbot_guide_release()
 102 {
 103     entity rkt;
 104     rkt = findchainentity(realowner, self.owner);
 105     if not (rkt)
 106         return;
 107
 108     crosshair_trace(self.owner);
 109     while(rkt)
 110     {
 111         if(rkt.think == spiderbot_rocket_guided)
 112         {
 113             rkt.pos1 = trace_endpos;
 114             rkt.think = spiderbot_rocket_unguided;
 115         }
 116         rkt = rkt.chain;
 117     }
 118 }
 119
 120 void spiderbot_rocket_do()
 121 {
 122
 123     vector v;
 124     entity rocket;
 125
 126     if (self.owner.BUTTON_ATCK2)
 127     {
 128         if (self.wait == 1)
 129         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 130         {
 131             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 132                 self.tur_head.frame = 1;
 133
 134             return;
 135         }
 136         self.wait = 1;
 137     }
 138     else
 139     {
 140         if(self.wait)
 141             spiderbot_guide_release();
 142
 143         self.wait = 0;
 144     }
 145
 146     if(self.gun2.cnt > time)
 147         return;
 148
 149     if (self.tur_head.frame >= 9)
 150         self.tur_head.frame = 1;
 151
 152     if not (self.owner.BUTTON_ATCK2)
 153         return;
 154
 155     crosshair_trace(self.owner);
 156
 157     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 158     rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 159                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 160                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 161                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE);
 162
 163     rocket.cnt        = time + 15;
 164     rocket.classname  = "spiderbot_rocket";
 165     rocket.pos1       = trace_endpos;
 166     rocket.think      = spiderbot_rocket_guided;
 167     rocket.nextthink  = time;
 168     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 169
 170     self.tur_head.frame += 1;
 171     if (self.tur_head.frame == 9)
 172         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 173     else
 174         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 175
 176     self.gun2.cnt = time + self.attack_finished_single;
 177 }
 178
 179 float spiderbot_frame()
 180 {
 181     vector ad, vf;
 182     entity player, spider;
 183     float ftmp;
 184
 185         if(intermission_running)
 186                 return 1;
 187
 188     player = self;
 189     spider = self.vehicle;
 190     self   = spider;
 191
 192     vehicles_painframe();
 193
 194     player.BUTTON_ZOOM      = 0;
 195     player.BUTTON_CROUCH    = 0;
 196     player.switchweapon     = 0;
 197
 198     if(player.impulse == 12)
 199     {
 200         dprint("WOOOOOOOOOOOtotototototOOOOOOOOOOOOttt\n");
 201     }
 202
 203
 204 #if 1 // 0 to enable per-gun impact aux crosshairs
 205     // Avarage gun impact point's -> aux cross
 206     ad = gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint01"));
 207     vf = v_forward;
 208     ad += gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint02"));
 209     vf += v_forward;
 210     ad = ad * 0.5;
 211     v_forward = vf * 0.5;
 212     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 213     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 214 #else
 215     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 216     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 217     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 218     vf = ad;
 219     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 220     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 221     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 222     ad = 0.5 * (ad + vf);
 223 #endif
 224
 225     crosshair_trace(player);
 226     ad = vectoangles(normalize(trace_endpos - ad));
 227     ad = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(spider.angles), AnglesTransform_FromAngles(ad))) - spider.tur_head.angles;
 228     ad = AnglesTransform_Normalize(ad, TRUE);
 229     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 230
 231     // Rotate head
 232     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 233     ad_y = bound(-ftmp, ad_y, ftmp);
 234     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 235
 236     // Pitch head
 237     ad_x = bound(ftmp * -1, ad_x, ftmp);
 238     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 239
 240
 241     //fixedmakevectors(spider.angles);
 242     makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 243
 244     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 245
 246     if(spider.flags & FL_ONGROUND)
 247     {
 248         if(spider.frame == 4 && self.tur_head.wait != 0)
 249         {
 250             sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_land.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 251             spider.frame = 5;
 252         }
 253
 254         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 255         {
 256             sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_jump.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 257             //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 258             self.delay = 0;
 259
 260             self.tur_head.wait = time + 2;
 261             player.BUTTON_JUMP = 0;
 262             spider.velocity   = v_forward * 700 + v_up * 600;
 263             spider.frame = 4;
 264         }
 265         else
 266         {
 267             if(vlen(player.movement) == 0)
 268             {
 269                 if(self.sound_nexttime < time || self.delay != 3)
 270                 {
 271                     self.delay = 3;
 272                     self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 273                     //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 274                     sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 275                 }
 276                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 277                 spider.frame = 5;
 278             }
 279             else
 280             {
 281                 // Turn Body
 282                 if(player.movement_x == 0 && player.movement_y != 0)
 283                     ftmp = autocvar_g_vehicle_spiderbot_turnspeed_strafe * sys_frametime;
 284                 else
 285                     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 286
 287                 ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 288                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 289                 spider.tur_head.angles_y -= ftmp;
 290
 291                 if(player.movement_x != 0)
 292                 {
 293                     if(player.movement_x > 0)
 294                     {
 295                         player.movement_x = 1;
 296                         spider.frame = 0;
 297                     }
 298                     else if(player.movement_x < 0)
 299                     {
 300                         player.movement_x = -1;
 301                         spider.frame = 1;
 302                     }
 303                     player.movement_y = 0;
 304                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 305
 306                     if(self.sound_nexttime < time || self.delay != 1)
 307                     {
 308                         self.delay = 1;
 309                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 310                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_walk.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 311                         //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 312                     }
 313                 }
 314                 else if(player.movement_y != 0)
 315                 {
 316                     if(player.movement_y < 0)
 317                     {
 318                         player.movement_y = -1;
 319                         spider.frame = 2;
 320                     }
 321                     else if(player.movement_y > 0)
 322                     {
 323                         player.movement_y = 1;
 324                         spider.frame = 3;
 325                     }
 326                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 327                     if(self.sound_nexttime < time || self.delay != 2)
 328                     {
 329                         self.delay = 2;
 330                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 331                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_strafe.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 332                         //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 333                     }
 334                 }
 335             }
 336         }
 337     }
 338
 339     self.angles_x = bound(-autocvar_g_vehicle_spiderbot_tiltlimit, self.angles_x, autocvar_g_vehicle_spiderbot_tiltlimit);
 340     self.angles_z = bound(-autocvar_g_vehicle_spiderbot_tiltlimit, self.angles_z, autocvar_g_vehicle_spiderbot_tiltlimit);
 341
 342     if(player.BUTTON_ATCK)
 343     {
 344         spider.cnt = time;
 345         if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 346         {
 347             entity gun;
 348             vector v;
 349             spider.misc_bulletcounter += 1;
 350
 351             self = player;
 352
 353             mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 354             v = gettaginfo(gun, gettagindex(gun, "barrels"));
 355             v_forward = normalize(v_forward);
 356             v += v_forward * 50;
 357
 358 //void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float headshotbonus, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 359
 360             fireBallisticBullet(v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_speed,
 361                                 5, autocvar_g_vehicle_spiderbot_minigun_damage, 0, autocvar_g_vehicle_spiderbot_minigun_force, DEATH_SBMINIGUN, 0, 1, autocvar_g_vehicle_spiderbot_minigun_bulletconstant);
 362             endFireBallisticBullet();
 363
 364 //            fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 365 //                autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 366
 367             sound (gun, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 368             //trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 369             pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 370
 371             self = spider;
 372
 373             spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 374             spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 375             player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 376             spider.gun1.angles_z += 45;
 377             spider.gun2.angles_z -= 45;
 378             if(spider.gun1.angles_z >= 360)
 379             {
 380                 spider.gun1.angles_z = 0;
 381                 spider.gun2.angles_z = 0;
 382             }
 383         }
 384     }
 385     else
 386         vehicles_regen(cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 387                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 388                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime);
 389
 390
 391     spiderbot_rocket_do();
 392
 393     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 394         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 395
 396     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 397         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 398
 399     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 400     player.vehicle_ammo2 = spider.tur_head.frame;
 401
 402     if(spider.gun2.cnt <= time)
 403         player.vehicle_reload2 = 100;
 404     else
 405         player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 406
 407     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 408     player.velocity = spider.velocity;
 409
 410     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 411
 412     if(self.vehicle_flags & VHF_HASSHIELD)
 413         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 414
 415     self = player;
 416     return 1;
 417 }
 418 void spiderbot_think()
 419 {
 420     if(self.flags & FL_ONGROUND)
 421         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 422
 423     self.nextthink = time;
 424 }
 425
 426 void spiderbot_enter()
 427 {
 428     self.movetype   = MOVETYPE_WALK;
 429
 430     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health) * 100;
 431     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield) * 100;
 432
 433     if(self.owner.flagcarried)
 434     {
 435         setattachment(self.owner.flagcarried, self.tur_head, "");
 436         setorigin(self.owner.flagcarried, '-20 0 120');
 437     }
 438 }
 439
 440 void spiderbot_exit(float eject)
 441 {
 442     entity e;
 443     vector spot;
 444
 445     e = findchain(classname,"spiderbot_rocket");
 446     while(e)
 447     {
 448         if(e.owner == self.owner)
 449         {
 450             e.realowner = self.owner;
 451             e.owner = world;
 452         }
 453         e = e.chain;
 454     }
 455
 456     self.velocity   = '0 0 0';
 457     self.think      = spiderbot_think;
 458     self.nextthink  = time;
 459     self.frame      = 5;
 460     self.movetype   = MOVETYPE_WALK;
 461
 462     if not (self.owner)
 463         return;
 464
 465         makevectors(self.angles);
 466         if(eject)
 467         {
 468             spot = self.origin + v_forward * 100 + '0 0 64';
 469             spot = vehicles_findgoodexit(spot);
 470             setorigin(self.owner , spot);
 471             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 472             self.owner.oldvelocity = self.owner.velocity;
 473         }
 474         else
 475         {
 476             self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed;
 477             self.owner.oldvelocity = self.owner.velocity;
 478             spot = self.origin - v_forward * 200 + '0 0 64';
 479             spot = vehicles_findgoodexit(spot);
 480             setorigin(self.owner , spot);
 481         }
 482     antilag_clear(self.owner);
 483     self.owner = world;
 484 }
 485 void spider_impact()
 486 {
 487     if(autocvar_g_vehicle_spiderbot_bouncepain_x)
 488         vehilces_impact(autocvar_g_vehicle_spiderbot_bouncepain_x, autocvar_g_vehicle_spiderbot_bouncepain_y, autocvar_g_vehicle_spiderbot_bouncepain_z);
 489 }
 490 void spiderbot_spawn()
 491 {
 492     self.frame              = 5;
 493     self.tur_head.frame     = 1;
 494     self.think              = spiderbot_think;
 495     self.nextthink          = time;
 496     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 497     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 498     self.movetype           = MOVETYPE_WALK;
 499     self.solid              = SOLID_SLIDEBOX;
 500     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 501     self.tur_head.angles    = '0 0 0';
 502
 503     setorigin(self, self.pos1 + '0 0 128');
 504     self.angles = self.pos2;
 505     self.vehicle_impact = spider_impact;
 506 }
 507
 508 void spiderbot_headfade()
 509 {
 510         self.think = spiderbot_headfade;
 511         self.nextthink = self.fade_time;
 512         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 513
 514     if(self.cnt < time || self.alpha < 0.1)
 515     {
 516         if(self.alpha > 0.1)
 517         {
 518             sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 519             pointparticles(particleeffectnum("explosion_big"), self.origin + '0 0 100', '0 0 0', 1);
 520         }
 521         remove(self);
 522     }
 523 }
 524
 525 void spiderbot_blowup()
 526 {
 527     if(self.cnt > time)
 528     {
 529         if(random() < 0.1)
 530         {
 531             sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 532             pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 533         }
 534         self.nextthink = time + 0.1;
 535         return;
 536     }
 537
 538     entity h, g1, g2, b;
 539     b = spawn();
 540     h = spawn();
 541     g1 = spawn();
 542     g2 = spawn();
 543
 544     setmodel(b,  "models/vehicles/spiderbot.dpm");
 545     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 546     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 547     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 548
 549     setorigin(b, self.origin);
 550     b.frame         = 11;
 551     b.angles        = self.angles;
 552     setsize(b, self.mins, self.maxs);
 553
 554     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 555     h.movetype      = MOVETYPE_BOUNCE;
 556     h.solid         = SOLID_BBOX;
 557     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 558     h.modelflags    = MF_ROCKET;
 559     h.effects       = EF_FLAME | EF_LOWPRECISION;
 560     h.avelocity     = randomvec() * 360;
 561
 562     h.alpha         = 1;
 563     h.cnt           = time + (3.5 * random());
 564     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 565     h.fade_time     = time;
 566     h.think         = spiderbot_headfade;
 567     h.nextthink     = time;
 568
 569     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 570     g1.movetype     = MOVETYPE_TOSS;
 571     g1.solid        = SOLID_CORPSE;
 572     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 573     g1.avelocity    = randomvec() * 180;
 574
 575     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 576     g2.movetype     = MOVETYPE_TOSS;
 577     g2.solid        = SOLID_CORPSE;
 578     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 579     g2.avelocity    = randomvec() * 180;
 580
 581     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 582
 583     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 584     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 585     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 586     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 587
 588     RadiusDamage (self, self.enemy, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 589
 590     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 591     self.movetype   = MOVETYPE_NONE;
 592     self.deadflag   = DEAD_DEAD;
 593     self.solid      = SOLID_NOT;
 594     self.tur_head.effects  &~=  EF_FLAME;
 595         self.vehicle_hudmodel.viewmodelforclient = self;
 596 }
 597
 598 void spiderbot_die()
 599 {
 600     self.health             = 0;
 601     self.event_damage       = SUB_Null;
 602     self.takedamage         = DAMAGE_NO;
 603     self.touch              = SUB_Null;
 604     self.cnt                = 3.4 + time + random() * 2;
 605     self.think              = spiderbot_blowup;
 606     self.nextthink          = time;
 607     self.deadflag           = DEAD_DYING;
 608         self.frame              = 5;
 609         self.tur_head.effects  |= EF_FLAME;
 610         self.colormod           = self.tur_head.colormod = '-1 -1 -1';
 611         self.frame              = 10;
 612         self.movetype           = MOVETYPE_TOSS;
 613 }
 614
 615 void vewhicle_spiderbot_dinit()
 616 {
 617     if not (vehicle_initialize(
 618              "Spiderbot",
 619              "models/vehicles/spiderbot.dpm",
 620              "models/vehicles/spiderbot_top.dpm",
 621              "models/vehicles/spiderbot_cockpit.dpm",
 622              "tag_head", "tag_hud", "",
 623              HUD_SPIDERBOT,
 624              SPIDERBOT_MIN, SPIDERBOT_MAX,
 625              FALSE,
 626              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 627              spiderbot_frame,
 628              spiderbot_enter, spiderbot_exit,
 629              spiderbot_die,   spiderbot_think,
 630              FALSE))
 631     {
 632         remove(self);
 633         return;
 634     }
 635
 636
 637     self.gun1               = spawn();
 638     self.gun2               = spawn();
 639
 640     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 641     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 642
 643     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 644     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 645
 646     self.gravity            = 2;
 647     self.mass               = 5000;
 648 }
 649
 650 void spawnfunc_vehicle_spiderbot()
 651 {
 652     self.vehicle_flags |= VHF_DMGSHAKE;
 653     //self.vehicle_flags |= VHF_DMGROLL;
 654     //self.vehicle_flags |= VHF_DMGHEADROLL;
 655
 656     precache_model ( "models/vhshield.md3");
 657     precache_model ( "models/vehicles/spiderbot.dpm");
 658     precache_model ( "models/vehicles/spiderbot_top.dpm");
 659     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 660     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 661     precache_model ( "models/uziflash.md3");
 662
 663     precache_sound ( "weapons/uzi_fire.wav" );
 664     precache_sound ( "weapons/rocket_impact.wav");
 665
 666     precache_sound ( "vehicles/spiderbot_die.wav");
 667     precache_sound ( "vehicles/spiderbot_idle.wav");
 668     precache_sound ( "vehicles/spiderbot_jump.wav");
 669     precache_sound ( "vehicles/spiderbot_strafe.wav");
 670     precache_sound ( "vehicles/spiderbot_walk.wav");
 671     precache_sound ( "vehicles/spiderbot_land.wav");
 672
 673     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 674     if(autocvar_g_vehicle_spiderbot_shield)
 675         self.vehicle_flags |= VHF_HASSHIELD;
 676
 677     if(autocvar_g_vehicle_spiderbot_shield_regen)
 678         self.vehicle_flags |= VHF_SHIELDREGEN;
 679
 680     if(autocvar_g_vehicle_spiderbot_health_regen)
 681         self.vehicle_flags |= VHF_HEALTHREGEN;
 682
 683     self.think = vewhicle_spiderbot_dinit;
 684
 685     if(g_assault)
 686         self.nextthink = time + 0.5;
 687     else
 688         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_spiderbot_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 689 }
 690 #endif // SVQC