qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5 float autocvar_g_vehicles_allow_flagcarry;
   6
   7 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   8 void vehicles_return();
   9 void vehicles_enter();
  10 void vehicles_touch();
  11 void vehicles_reset_colors();
  12 void vehicles_clearrturn();
  13 void vehicles_setreturn();
  14
  15
  16 /** AuxiliaryXhair*
  17     Send additional points of interest to be drawn, to vehicle owner
  18 **/
  19 float MAX_AXH = 4;
  20 .entity AuxiliaryXhair[MAX_AXH];
  21
  22 float SendAuxiliaryXhair(entity to, float sf)
  23 {
  24
  25         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  26
  27         WriteByte(MSG_ENTITY, self.cnt);
  28
  29         WriteCoord(MSG_ENTITY, self.origin_x);
  30         WriteCoord(MSG_ENTITY, self.origin_y);
  31         WriteCoord(MSG_ENTITY, self.origin_z);
  32
  33     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  35     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  36
  37     return TRUE;
  38 }
  39
  40 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  41 {
  42     entity axh;
  43
  44     axh_id = bound(0, axh_id, MAX_AXH);
  45     axh = own.(AuxiliaryXhair[axh_id]);
  46
  47     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  48     {
  49         axh                     = spawn();
  50         axh.cnt                 = axh_id;
  51         axh.drawonlytoclient    = own;
  52         axh.owner               = own;
  53         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  54     }
  55
  56     setorigin(axh, loc);
  57     axh.colormod            = clr;
  58     axh.SendFlags           = 0x01;
  59     own.(AuxiliaryXhair[axh_id]) = axh;
  60 }
  61
  62 /*
  63 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  64 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  65 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  66 {
  67         msg_entity = own;
  68
  69         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  70         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  71
  72         WriteByte(MSG_ONE, axh_id);
  73
  74         WriteCoord(MSG_ONE, loc_x);
  75         WriteCoord(MSG_ONE, loc_y);
  76         WriteCoord(MSG_ONE, loc_z);
  77
  78     WriteByte(MSG_ONE, rint(clr_x * 255));
  79     WriteByte(MSG_ONE, rint(clr_y * 255));
  80     WriteByte(MSG_ONE, rint(clr_z * 255));
  81
  82 }
  83 */
  84 // End AuxiliaryXhair
  85
  86 /**
  87     Notifies the client that he enterd a vehicle, and sends
  88     realavent data.
  89
  90     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  91 **/
  92 void CSQCVehicleSetup(entity own, float vehicle_id)
  93 {
  94         msg_entity = own;
  95
  96         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  97         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  98         WriteByte(MSG_ONE, vehicle_id);
  99 }
 100
 101 /** vehicles_locktarget
 102
 103     Generic target locking.
 104
 105     Figure out if what target is "locked" (if any), for missile tracking as such.
 106
 107     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 108     you have a locked in target.
 109
 110     Exspects a crosshair_trace() or equivalent to be
 111     dont before calling.
 112
 113 **/
 114 .entity lock_target;
 115 .float  lock_strength;
 116 .float  lock_time;
 117 .float  lock_soundtime;
 118 void vehicles_locktarget(float incr, float decr, float _lock_time)
 119 {
 120     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 121     {
 122         self.lock_target    = world;
 123         self.lock_strength  = 0;
 124         self.lock_time      = 0;
 125     }
 126
 127     if(self.lock_time > time)
 128     {
 129         if(self.lock_target)
 130         if(self.lock_soundtime < time)
 131         {
 132             self.lock_soundtime = time + 0.5;
 133             play2(self.owner, "vehicles/locked.wav");
 134         }
 135
 136         return;
 137     }
 138
 139     if(trace_ent != world)
 140     {
 141         if(teamplay && trace_ent.team == self.team)
 142             trace_ent = world;
 143
 144         if(trace_ent.deadflag != DEAD_NO)
 145             trace_ent = world;
 146
 147         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 148             trace_ent = world;
 149     }
 150
 151     if(self.lock_target == world && trace_ent != world)
 152         self.lock_target = trace_ent;
 153
 154     if(self.lock_target && trace_ent == self.lock_target)
 155     {
 156         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 157         {
 158             play2(self.owner, "vehicles/lock.wav");
 159             self.lock_soundtime = time + 0.8;
 160         }
 161         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 162         {
 163             play2(self.owner, "vehicles/locking.wav");
 164             self.lock_soundtime = time + 0.3;
 165         }
 166
 167     }
 168
 169     // Have a locking target
 170     // Trace hit current target
 171     if(trace_ent == self.lock_target && trace_ent != world)
 172     {
 173         self.lock_strength = min(self.lock_strength + incr, 1);
 174         if(self.lock_strength == 1)
 175             self.lock_time = time + _lock_time;
 176     }
 177     else
 178     {
 179         if(trace_ent)
 180             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 181         else
 182             self.lock_strength = max(self.lock_strength - decr, 0);
 183
 184         if(self.lock_strength == 0)
 185             self.lock_target = world;
 186     }
 187 }
 188
 189 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 190 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 191
 192 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 193 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 194 if(trace_fraction != 1) \
 195     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 196
 197 // Hover movement support
 198 float  force_fromtag_power;
 199 float  force_fromtag_normpower;
 200 vector force_fromtag_origin;
 201 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 202 {
 203     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 204     v_forward  = normalize(v_forward) * -1;
 205     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 206
 207     force_fromtag_power = (1 - trace_fraction) * max_power;
 208     force_fromtag_normpower = force_fromtag_power / max_power;
 209
 210     return v_forward  * force_fromtag_power;
 211 }
 212
 213 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 214 // Can possibly be use to move abt any surface (inclusing walls/celings)
 215 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 216 {
 217
 218     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 219     v_forward  = normalize(v_forward) * -1;
 220     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 221
 222     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 223     if(trace_fraction == 1.0)
 224     {
 225         force_fromtag_normpower = -0.25;
 226         return '0 0 -200';
 227     }
 228
 229     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 230     force_fromtag_normpower = force_fromtag_power / max_power;
 231
 232     return v_forward  * force_fromtag_power;
 233 }
 234
 235 // Generic vehile projectile system
 236 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 237 {
 238     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 239     if(inflictor.owner == self.owner)
 240         return;
 241
 242     self.health -= damage;
 243     self.velocity += force;
 244     if(self.health < 1)
 245     {
 246         self.takedamage = DAMAGE_NO;
 247         self.event_damage = SUB_Null;
 248         self.think = self.use;
 249         self.nextthink = time;
 250     }
 251
 252 }
 253
 254 void vehicles_projectile_explode()
 255 {
 256     if(self.owner && other != world)
 257     {
 258         if(other == self.owner.vehicle)
 259             return;
 260
 261         if(other == self.owner.vehicle.tur_head)
 262             return;
 263     }
 264
 265         PROJECTILE_TOUCH;
 266
 267         self.event_damage = SUB_Null;
 268     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 269
 270     remove (self);
 271 }
 272
 273 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 274                            vector _org, vector _vel,
 275                            float _dmg, float _radi, float _force,  float _size,
 276                            float _deahtype, float _projtype, float _health,
 277                            float _cull, float _clianim)
 278 {
 279     entity proj;
 280
 281     proj = spawn();
 282
 283     PROJECTILE_MAKETRIGGER(proj);
 284     setorigin(proj, _org);
 285
 286     proj.shot_dmg         = _dmg;
 287     proj.shot_radius      = _radi;
 288     proj.shot_force       = _force;
 289     proj.totalfrags       = _deahtype;
 290     proj.solid            = SOLID_BBOX;
 291     proj.movetype         = MOVETYPE_FLYMISSILE;
 292     proj.flags            = FL_PROJECTILE;
 293     proj.bot_dodge        = TRUE;
 294     proj.bot_dodgerating  = _dmg;
 295     proj.velocity         = _vel;
 296     proj.touch            = vehicles_projectile_explode;
 297     proj.use              = vehicles_projectile_explode;
 298     proj.owner            = self;
 299     proj.realowner        = self.owner;
 300     proj.think            = SUB_Remove;
 301     proj.nextthink        = time + 30;
 302
 303     if(_health)
 304     {
 305         proj.takedamage       = DAMAGE_AIM;
 306         proj.event_damage     = vehicles_projectile_damage;
 307         proj.health           = _health;
 308     }
 309     else
 310         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 311
 312     if(_mzlsound)
 313         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 314
 315     if(_mzlfx)
 316         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 317
 318
 319     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 320
 321     CSQCProjectile(proj, _clianim, _projtype, _cull);
 322
 323     return proj;
 324 }
 325 // End generic vehile projectile system
 326
 327 /** vehicles_spawn
 328     Exetuted for all vehicles on (re)spawn.
 329     Sets defaults for newly spawned units.
 330 **/
 331 void vehicles_spawn()
 332 {
 333     dprint("Spawning vehicle: ", self.netname, "\n");
 334
 335     // De-own & reset
 336     self.vehicle_hudmodel.viewmodelforclient = self;
 337
 338     self.owner              = world;
 339     self.touch              = vehicles_touch;
 340     self.event_damage       = vehicles_damage;
 341     self.iscreature         = TRUE;
 342     self.damagedbycontents      = TRUE;
 343     self.movetype           = MOVETYPE_WALK;
 344     self.solid              = SOLID_SLIDEBOX;
 345     self.takedamage         = DAMAGE_AIM;
 346         self.deadflag           = DEAD_NO;
 347     self.bot_attack         = TRUE;
 348     self.flags              = FL_NOTARGET;
 349     self.avelocity          = '0 0 0';
 350     self.velocity           = '0 0 0';
 351
 352     // Reset locking
 353     self.lock_strength      = 0;
 354     self.lock_target        = world;
 355     self.misc_bulletcounter = 0;
 356
 357     // Return to spawn
 358     self.angles             = self.pos2;
 359     setorigin(self, self.pos1 + '0 0 128');
 360     // Show it
 361     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 362
 363     vehicles_reset_colors();
 364     self.vehicle_spawn();
 365 }
 366
 367 // Better way of determening whats crushable needed! (fl_crushable?)
 368 float vehicles_crushable(entity e)
 369 {
 370     if(e.classname == "player")
 371         return TRUE;
 372
 373     if(e.classname == "monster_zombie")
 374         return TRUE;
 375
 376     return FALSE;
 377 }
 378
 379 void vehicles_touch()
 380 {
 381     // Vehicle currently in use
 382     if(self.owner)
 383     {
 384         // Colided with world?
 385         if(other == world)
 386         {
 387         }
 388         else
 389         {
 390             if(other.vehicle_flags & VHF_ISVEHICLE)
 391             {
 392                 //other.velocity += self.velocity * (self.mass / other.mass);
 393             }
 394             else if(vehicles_crushable(other))
 395             {
 396                 if(vlen(self.velocity) != 0)
 397                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 398             }
 399         }
 400         return;
 401     }
 402
 403     if(other.classname != "player")
 404         return;
 405
 406     if(other.deadflag != DEAD_NO)
 407         return;
 408
 409     if(other.vehicle != world)
 410         return;
 411
 412     // Remove this when bots know how to use vehicles.
 413     if (clienttype(other) != CLIENTTYPE_REAL)
 414         return;
 415
 416     vehicles_enter();
 417 }
 418
 419 void vehicles_enter()
 420 {
 421    // Remove this when bots know how to use vehicles
 422     if (clienttype(other) != CLIENTTYPE_REAL)
 423         return;
 424
 425     if(self.phase > time)
 426         return;
 427
 428     if(teamplay)
 429     if(self.team)
 430     if(self.team != other.team)
 431         return;
 432
 433     RemoveGrapplingHook(other);
 434
 435     self.vehicle_ammo1   = 0;
 436     self.vehicle_ammo2   = 0;
 437     self.vehicle_reload1 = 0;
 438     self.vehicle_reload2 = 0;
 439     self.vehicle_energy  = 0;
 440
 441     self.owner          = other;
 442     self.switchweapon   = other.switchweapon;
 443
 444     // .viewmodelforclient works better.
 445     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 446
 447     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 448
 449     self.event_damage         = vehicles_damage;
 450     self.nextthink            = 0;
 451     self.owner.angles         = self.angles;
 452     self.owner.takedamage     = DAMAGE_NO;
 453     self.owner.solid          = SOLID_NOT;
 454     self.owner.movetype       = MOVETYPE_NOCLIP;
 455     self.owner.alpha          = -1;
 456     self.owner.vehicle        = self;
 457     self.owner.event_damage   = SUB_Null;
 458     self.owner.view_ofs       = '0 0 0';
 459     self.colormap             = self.owner.colormap;
 460     if(self.tur_head)
 461         self.tur_head.colormap    = self.owner.colormap;
 462
 463     self.owner.hud            = self.hud;
 464     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 465
 466     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 467     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 468     self.owner.vehicle_reload1  = self.vehicle_reload1;
 469     self.owner.vehicle_reload2  = self.vehicle_reload2;
 470
 471     // Cant do this, hides attached objects too.
 472     //self.exteriormodeltoclient = self.owner;
 473     //self.tur_head.exteriormodeltoclient = self.owner;
 474
 475     other.flags &~= FL_ONGROUND;
 476     self.flags  &~= FL_ONGROUND;
 477
 478     self.team                 = self.owner.team;
 479     self.flags               -= FL_NOTARGET;
 480
 481     msg_entity = other;
 482     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 483     WriteEntity(MSG_ONE, self.vehicle_viewport);
 484
 485     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 486     if(self.tur_head)
 487     {
 488         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 489         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 490         WriteAngle(MSG_ONE, 0);                                      // roll
 491     }
 492     else
 493     {
 494         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 495         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 496         WriteAngle(MSG_ONE,  0);                  // roll
 497     }
 498
 499     vehicles_clearrturn();
 500
 501     CSQCVehicleSetup(self.owner, self.hud);
 502
 503     if(other.flagcarried)
 504     {
 505         if(!autocvar_g_vehicles_allow_flagcarry)
 506             DropFlag(other.flagcarried, world, world);
 507         else
 508         {
 509             other.flagcarried.scale = 1;
 510             setattachment(other.flagcarried, self, "");
 511             setorigin(other, '0 0 96');
 512         }
 513     }
 514
 515     self.vehicle_enter();
 516 }
 517
 518 /** vehicles_findgoodexit
 519     Locates a valid location for the player to exit the vehicle.
 520     Will first try prefer_spot, then up 100 random spots arround the vehicle
 521     wich are in direct line of sight and empty enougth to hold a players bbox
 522 **/
 523 vector vehicles_findgoodexit(vector prefer_spot)
 524 {
 525     //vector exitspot;
 526     float mysize;
 527
 528     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 529     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 530         return prefer_spot;
 531
 532     mysize = vlen(self.maxs - self.mins);
 533     float i;
 534     vector v, v2;
 535     v2 = 0.5 * (self.absmin + self.absmax);
 536     for(i = 0; i < 100; ++i)
 537     {
 538         v = randomvec();
 539         v_z = 0;
 540         v = v2 + normalize(v) * mysize;
 541         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 542         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 543             return v;
 544     }
 545
 546     /*
 547     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 548     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 549     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 550         return exitspot;
 551
 552     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 553     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 554     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 555         return exitspot;
 556
 557     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 558     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 559     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 560         return exitspot;
 561
 562     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 563     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 564     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 565         return exitspot;
 566     */
 567
 568     return self.origin;
 569 }
 570
 571 /** vehicles_exit
 572     Standarrd vehicle release fucntion.
 573     custom code goes in self.vehicle_exit
 574 **/
 575 void vehicles_exit(float eject)
 576 {
 577     entity oldself;
 578     if(self.flags & FL_CLIENT)
 579     {
 580         oldself = self;
 581         self = self.vehicle;
 582     }
 583
 584         self.flags |= FL_NOTARGET;
 585
 586     if (self.owner)
 587     {
 588         msg_entity = self.owner;
 589         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 590         WriteEntity( MSG_ONE, self.owner);
 591
 592         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 593         WriteAngle(MSG_ONE, 0);                 // pich
 594         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 595         WriteAngle(MSG_ONE, 0);                 // roll
 596
 597         setsize(self.owner, PL_MIN,PL_MAX);
 598
 599         self.owner.takedamage     = DAMAGE_AIM;
 600         self.owner.solid          = SOLID_SLIDEBOX;
 601         self.owner.movetype       = MOVETYPE_WALK;
 602         self.owner.effects        &~= EF_NODRAW;
 603         self.owner.alpha          = 1;
 604         self.owner.PlayerPhysplug = SUB_Null;
 605         self.owner.vehicle        = world;
 606         self.owner.view_ofs       = PL_VIEW_OFS;
 607         self.owner.event_damage   = PlayerDamage;
 608         self.owner.hud            = HUD_NORMAL;
 609         self.owner.switchweapon   = self.switchweapon;
 610         //self.owner.BUTTON_USE     = 0;
 611     }
 612
 613     if(self.deadflag == DEAD_NO)
 614         self.avelocity          = '0 0 0';
 615
 616     self.vehicle_hudmodel.viewmodelforclient = self;
 617         self.tur_head.nodrawtoclient             = world;
 618     vehicles_setreturn();
 619
 620     self.phase = time + 1;
 621
 622     if(!teamplay)
 623         self.team = 0;
 624     else
 625         self.team = self.tur_head.team;
 626
 627     if(self.owner.flagcarried)
 628     {
 629         self.owner.flagcarried.scale = 0.6;
 630         setattachment(self.owner.flagcarried, self.owner, "");
 631         setorigin(self.owner.flagcarried, FLAG_CARRY_POS);
 632     }
 633
 634     sound (self, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 635     self.vehicle_exit(eject);
 636     self.owner = world;
 637     vehicles_reset_colors();
 638
 639     if(oldself)
 640         self = oldself;
 641 }
 642
 643
 644 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 645 {
 646     if(self.regen_field < field_max)
 647     if(self.timer + rpause < time)
 648     {
 649         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 650
 651         if(self.owner)
 652             self.owner.regen_field = (self.regen_field / field_max) * 100;
 653     }
 654 }
 655
 656 void shieldhit_think()
 657 {
 658     self.alpha -= 0.1;
 659     if (self.alpha <= 0)
 660     {
 661         //setmodel(self, "");
 662         self.alpha = -1;
 663     }
 664     else
 665     {
 666         self.nextthink = time + 0.1;
 667     }
 668 }
 669
 670 void vehicles_painframe()
 671 {
 672 //.float        pain_finished;                  //Added by Supajoe
 673
 674     if(self.owner.vehicle_health <= 50)
 675     if(self.pain_frame < time)
 676     {
 677         float _ftmp;
 678         _ftmp = self.owner.vehicle_health / 50;
 679         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 680         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 681
 682         if(self.vehicle_flags & VHF_DMGSHAKE)
 683             self.velocity += randomvec() * 30;
 684
 685         if(self.vehicle_flags & VHF_DMGROLL)
 686             if(self.vehicle_flags & VHF_DMGHEADROLL)
 687                 self.tur_head.angles += randomvec();
 688             else
 689                 self.angles += randomvec();
 690
 691     }
 692 }
 693
 694 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 695 {
 696     self.dmg_time = time;
 697
 698     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 699     {
 700         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 701         {
 702             self.vehicle_shieldent = spawn();
 703             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 704
 705             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 706             setattachment(self.vehicle_shieldent, self, "");
 707             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 708             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 709             self.vehicle_shieldent.think       = shieldhit_think;
 710         }
 711
 712         self.vehicle_shieldent.colormod    = '1 1 1';
 713         self.vehicle_shieldent.alpha       = 0.45;
 714         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 715         self.vehicle_shieldent.nextthink   = time;
 716
 717         self.vehicle_shield -= damage;
 718
 719         if(self.vehicle_shield < 0)
 720         {
 721             self.vehicle_health            -= fabs(self.vehicle_shield);
 722             self.vehicle_shieldent.colormod = '2 0 0';
 723             self.vehicle_shield             = 0;
 724             self.vehicle_shieldent.alpha    = 0.75;
 725
 726                 if(sound_allowed(MSG_BROADCAST, attacker))
 727                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 728         }
 729         else
 730                 if(sound_allowed(MSG_BROADCAST, attacker))
 731                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 732
 733     }
 734     else
 735     {
 736         self.vehicle_health -= damage;
 737
 738         if(sound_allowed(MSG_BROADCAST, attacker))
 739             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 740     }
 741
 742     self.velocity += force; // * (vlen(force) / self.mass);
 743
 744     if(self.vehicle_health <= 0)
 745     {
 746         if(self.owner)
 747             if(self.vehicle_flags & VHF_DEATHEJECT)
 748                 vehicles_exit(VHEF_EJECT);
 749             else
 750                 vehicles_exit(VHEF_RELESE);
 751
 752         self.vehicle_die();
 753         vehicles_setreturn();
 754     }
 755 }
 756
 757 void vehicles_clearrturn()
 758 {
 759     entity ret;
 760     // Remove "return helper", if any.
 761     ret = findchain(classname, "vehicle_return");
 762     while(ret)
 763     {
 764         if(ret.enemy == self)
 765         {
 766             ret.classname   = "";
 767             ret.think       = SUB_Remove;
 768             ret.nextthink   = time + 0.1;
 769
 770             if(ret.waypointsprite_attached)
 771                 WaypointSprite_Kill(ret.waypointsprite_attached);
 772
 773             return;
 774         }
 775         ret = ret.chain;
 776     }
 777 }
 778
 779 void vehicles_return()
 780 {
 781     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 782
 783     self.enemy.think     = vehicles_spawn;
 784     self.enemy.nextthink = time;
 785
 786     if(self.waypointsprite_attached)
 787         WaypointSprite_Kill(self.waypointsprite_attached);
 788
 789     remove(self);
 790 }
 791
 792 void vehicles_showwp_goaway()
 793 {
 794     if(self.waypointsprite_attached)
 795         WaypointSprite_Kill(self.waypointsprite_attached);
 796
 797     remove(self);
 798
 799 }
 800
 801 void vehicles_showwp()
 802 {
 803     entity oldself;
 804     vector rgb;
 805
 806     if(self.cnt)
 807     {
 808         self.think      = vehicles_return;
 809         self.nextthink  = self.cnt;
 810     }
 811     else
 812     {
 813         self.think      = vehicles_return;
 814         self.nextthink  = time +1;
 815
 816         oldself = self;
 817         self = spawn();
 818         setmodel(self, "null");
 819         self.team = oldself.enemy.team;
 820         self.enemy = oldself.enemy;
 821         setorigin(self, oldself.enemy.pos1);
 822
 823         self.nextthink = time + 5;
 824         self.think = vehicles_showwp_goaway;
 825     }
 826
 827     if(teamplay && self.team)
 828             rgb = TeamColor(self.team);
 829     else
 830             rgb = '1 1 1';
 831     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 832     if(self.waypointsprite_attached)
 833     {
 834         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.enemy.team, SPRITERULE_DEFAULT);
 835         if(oldself == world)
 836             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 837         WaypointSprite_Ping(self.waypointsprite_attached);
 838     }
 839
 840     if(oldself != world)
 841         self = oldself;
 842 }
 843
 844 void vehicles_setreturn()
 845 {
 846     entity ret;
 847
 848     vehicles_clearrturn();
 849
 850     ret = spawn();
 851     ret.classname   = "vehicle_return";
 852     ret.enemy       = self;
 853     ret.team        = self.team;
 854     ret.think       = vehicles_showwp;
 855
 856     if(self.deadflag != DEAD_NO)
 857     {
 858         ret.cnt         = time + self.vehicle_respawntime;
 859         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
 860     }
 861     else
 862     {
 863         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
 864     }
 865
 866     setmodel(ret, "null");
 867     setorigin(ret, self.pos1 + '0 0 96');
 868
 869 }
 870
 871 void vehicles_configcheck(string  configname, float check_cvar)
 872 {
 873     if(check_cvar == 0)
 874         localcmd(strcat("exec ", configname, "\n"));
 875 }
 876
 877 void vehicles_reset_colors()
 878 {
 879     entity e;
 880     float _effects, _colormap;
 881     vector _glowmod, _colormod;
 882
 883     if(autocvar_g_nodepthtestplayers)
 884         _effects = EF_NODEPTHTEST;
 885
 886     if(autocvar_g_fullbrightplayers)
 887         _effects |= EF_FULLBRIGHT;
 888
 889     if(self.team)
 890         _colormap = 1024 + (self.team - 1) * 17;
 891     else
 892         _colormap = 1024;
 893
 894     _glowmod  = '0 0 0';
 895     _colormod = '0 0 0';
 896
 897     // Find all ents attacked to main model and setup effects, colormod etc.
 898     e = findchainentity(tag_entity, self);
 899     while(e)
 900     {
 901         if(e != self.vehicle_shieldent)
 902         {
 903             e.effects   = _effects; //  | EF_LOWPRECISION;
 904             e.colormod  = _colormod;
 905             e.colormap  = _colormap;
 906             e.alpha     = 1;
 907         }
 908         e = e.chain;
 909     }
 910
 911     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
 912     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 913     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 914     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 915
 916     self.alpha     = 1;
 917     self.avelocity = '0 0 0';
 918     self.velocity  = '0 0 0';
 919     self.effects   = _effects;
 920 }
 921
 922 float vehicle_initialize(string  net_name,
 923                          string  bodymodel,
 924                          string  topmodel,
 925                          string  hudmodel,
 926                          string  toptag,
 927                          string  hudtag,
 928                          string  viewtag,
 929                          float   vhud,
 930                          vector  min_s,
 931                          vector  max_s,
 932                          float   nodrop,
 933                          void()  spawnproc,
 934                          float   _respawntime,
 935                          float() physproc,
 936                          void()  enterproc,
 937                          void(float extflag) exitfunc,
 938                          void() dieproc,
 939                          void() thinkproc,
 940                          float  use_csqc)
 941 {
 942     addstat(STAT_HUD, AS_INT,  hud);
 943         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 944         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 945         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 946
 947         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 948         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 949
 950         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 951         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 952
 953     if(bodymodel == "")
 954         error("vehicles: missing bodymodel!");
 955
 956     if(hudmodel == "")
 957         error("vehicles: missing hudmodel!");
 958
 959     if(net_name == "")
 960         self.netname = self.classname;
 961     else
 962         self.netname = net_name;
 963
 964     if(self.team && !teamplay)
 965         self.team = 0;
 966
 967     self.vehicle_flags |= VHF_ISVEHICLE;
 968
 969     setmodel(self, bodymodel);
 970
 971     self.vehicle_viewport   = spawn();
 972     self.vehicle_hudmodel   = spawn();
 973     self.tur_head           = spawn();
 974     self.tur_head.owner     = self;
 975     self.takedamage         = DAMAGE_AIM;
 976     self.bot_attack         = TRUE;
 977     self.iscreature         = TRUE;
 978     self.damagedbycontents      = TRUE;
 979     self.hud                = vhud;
 980
 981     self.vehicle_die         = dieproc;
 982     self.vehicle_exit        = exitfunc;
 983     self.vehicle_enter       = enterproc;
 984     self.PlayerPhysplug      = physproc;
 985     self.event_damage        = vehicles_damage;
 986     self.touch               = vehicles_touch;
 987     self.think               = vehicles_spawn;
 988     self.nextthink           = time;
 989     self.vehicle_respawntime = _respawntime;
 990     self.vehicle_spawn       = spawnproc;
 991
 992     if(autocvar_g_nodepthtestplayers)
 993         self.effects = self.effects | EF_NODEPTHTEST;
 994
 995     if(autocvar_g_fullbrightplayers)
 996         self.effects = self.effects | EF_FULLBRIGHT;
 997
 998     setmodel(self.vehicle_hudmodel, hudmodel);
 999     setmodel(self.vehicle_viewport, "null");
1000
1001
1002     if(topmodel != "")
1003     {
1004         setmodel(self.tur_head, topmodel);
1005         setattachment(self.tur_head, self, toptag);
1006         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1007         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1008     }
1009     else
1010     {
1011         setattachment(self.tur_head, self, "");
1012         setattachment(self.vehicle_hudmodel, self, hudtag);
1013         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1014     }
1015
1016     setsize(self, min_s, max_s);
1017     if not (nodrop)
1018     {
1019         setorigin(self, self.origin);
1020         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1021         setorigin(self, trace_endpos);
1022     }
1023
1024     self.pos1 = self.origin;
1025     self.pos2 = self.angles;
1026     self.tur_head.team = self.team;
1027
1028     return TRUE;
1029 }
1030
1031 void bugmenot()
1032 {
1033     self.vehicle_exit       = self.vehicle_exit;
1034     self.vehicle_enter      = self.vehicle_exit;
1035     self.vehicle_die        = self.vehicle_exit;
1036     self.vehicle_spawn      = self.vehicle_exit;
1037     self.AuxiliaryXhair     = self.AuxiliaryXhair;
1038 }