qcsrc/server/w_common.qc

   1
   2 void W_GiveWeapon (entity e, float wep, string name)
   3 {
   4         entity oldself;
   5
   6         if (!wep)
   7                 return;
   8
   9         WEPSET_OR_EW(e, wep);
  10
  11         oldself = self;
  12         self = e;
  13
  14         if not(g_minstagib)
  15         if (other.classname == "player")
  16         {
  17                 sprint (other, "You got the ^2");
  18                 sprint (other, name);
  19                 sprint (other, "\n");
  20         }
  21
  22         self = oldself;
  23 }
  24
  25 .float railgundistance;
  26 .vector railgunforce;
  27 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, float deathtype)
  28 {
  29         vector hitloc, force, endpoint, dir;
  30         entity ent, endent;
  31         float endq3surfaceflags;
  32         float totaldmg;
  33         entity o;
  34
  35         float length;
  36         vector beampos;
  37         string snd;
  38         entity pseudoprojectile;
  39         float f, ffs;
  40
  41         pseudoprojectile = world;
  42
  43         railgun_start = start;
  44         railgun_end = end;
  45
  46         dir = normalize(end - start);
  47         length = vlen(end - start);
  48         force = dir * bforce;
  49
  50         // go a little bit into the wall because we need to hit this wall later
  51         end = end + dir;
  52
  53         totaldmg = 0;
  54
  55         // trace multiple times until we hit a wall, each obstacle will be made
  56         // non-solid so we can hit the next, while doing this we spawn effects and
  57         // note down which entities were hit so we can damage them later
  58         o = self;
  59         while (1)
  60         {
  61                 if(self.antilag_debug)
  62                         WarpZone_traceline_antilag (self, start, end, FALSE, o, self.antilag_debug);
  63                 else
  64                         WarpZone_traceline_antilag (self, start, end, FALSE, o, ANTILAG_LATENCY(self));
  65                 if(o && WarpZone_trace_firstzone)
  66                 {
  67                         o = world;
  68                         continue;
  69                 }
  70
  71                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
  72                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
  73
  74                 // if it is world we can't hurt it so stop now
  75                 if (trace_ent == world || trace_fraction == 1)
  76                         break;
  77
  78                 // make the entity non-solid so we can hit the next one
  79                 trace_ent.railgunhit = TRUE;
  80                 trace_ent.railgunhitloc = end;
  81                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
  82                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
  83                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
  84
  85                 // stop if this is a wall
  86                 if (trace_ent.solid == SOLID_BSP)
  87                         break;
  88
  89                 // make the entity non-solid
  90                 trace_ent.solid = SOLID_NOT;
  91         }
  92
  93         endpoint = trace_endpos;
  94         endent = trace_ent;
  95         endq3surfaceflags = trace_dphitq3surfaceflags;
  96
  97         // find all the entities the railgun hit and restore their solid state
  98         ent = findfloat(world, railgunhit, TRUE);
  99         while (ent)
 100         {
 101                 // restore their solid type
 102                 ent.solid = ent.railgunhitsolidbackup;
 103                 ent = findfloat(ent, railgunhit, TRUE);
 104         }
 105
 106         // spawn a temporary explosion entity for RadiusDamage calls
 107         //explosion = spawn();
 108
 109         // Find all non-hit players the beam passed close by
 110         if(deathtype == WEP_MINSTANEX || deathtype == WEP_NEX)
 111         {
 112                 FOR_EACH_REALCLIENT(msg_entity) if(msg_entity != self) if(!msg_entity.railgunhit) if not(msg_entity.classname == "spectator" && msg_entity.enemy == self) // we use realclient, so spectators can hear the whoosh too
 113                 {
 114                         // nearest point on the beam
 115                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 116
 117                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 118                         if(f <= 0)
 119                                 continue;
 120
 121                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 122
 123                         if(!pseudoprojectile)
 124                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 125                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTN_NONE);
 126                 }
 127
 128                 if(pseudoprojectile)
 129                         remove(pseudoprojectile);
 130         }
 131
 132         // find all the entities the railgun hit and hurt them
 133         ent = findfloat(world, railgunhit, TRUE);
 134         while (ent)
 135         {
 136                 // get the details we need to call the damage function
 137                 hitloc = ent.railgunhitloc;
 138
 139                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 140                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 141
 142                 if(accuracy_isgooddamage(self.realowner, ent))
 143                         totaldmg += bdamage * f;
 144
 145                 // apply the damage
 146                 if (ent.takedamage)
 147                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 148
 149                 // create a small explosion to throw gibs around (if applicable)
 150                 //setorigin (explosion, hitloc);
 151                 //RadiusDamage (explosion, self, 10, 0, 50, world, 300, deathtype);
 152
 153                 ent.railgunhitloc = '0 0 0';
 154                 ent.railgunhitsolidbackup = SOLID_NOT;
 155                 ent.railgunhit = FALSE;
 156                 ent.railgundistance = 0;
 157
 158                 // advance to the next entity
 159                 ent = findfloat(ent, railgunhit, TRUE);
 160         }
 161
 162         // calculate hits and fired shots for hitscan
 163         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 164
 165         trace_endpos = endpoint;
 166         trace_ent = endent;
 167         trace_dphitq3surfaceflags = endq3surfaceflags;
 168 }
 169
 170 .float dmg_edge;
 171 .float dmg_force;
 172 .float dmg_radius;
 173 .float dmg_total;
 174 void W_BallisticBullet_Hit (void)
 175 {
 176         float f, q, g;
 177
 178         f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 179         q = 1 + self.dmg_edge / self.dmg;
 180
 181         if(other.solid == SOLID_BSP || other.solid == SOLID_SLIDEBOX)
 182                 Damage_DamageInfo(self.origin, self.dmg * f, 0, 0, max(1, self.dmg_force) * normalize(self.velocity) * f, self.projectiledeathtype, other.species, self);
 183
 184         if(other && other != self.enemy)
 185         {
 186                 endzcurveparticles();
 187
 188                 headshot = 0;
 189                 yoda = 0;
 190                 damage_headshotbonus = self.dmg_edge * f;
 191                 railgun_start = self.origin - 2 * frametime * self.velocity;
 192                 railgun_end = self.origin + 2 * frametime * self.velocity;
 193                 g = accuracy_isgooddamage(self.realowner, other);
 194                 Damage(other, self, self.realowner, self.dmg * f, self.projectiledeathtype, self.origin, self.dmg_force * normalize(self.velocity) * f);
 195                 damage_headshotbonus = 0;
 196
 197                 if(headshot)
 198                         f *= q;
 199                 if(self.dmg_edge > 0)
 200                 {
 201                         if(headshot)
 202                                 AnnounceTo(self.realowner, "headshot");
 203                         if(yoda)
 204                                 AnnounceTo(self.realowner, "awesome");
 205                 }
 206
 207                 // calculate hits for ballistic weapons
 208                 if(g)
 209                 {
 210                         // do not exceed 100%
 211                         q = min(self.dmg * q, self.dmg_total + f * self.dmg) - self.dmg_total;
 212                         self.dmg_total += f * self.dmg;
 213                         accuracy_add(self.realowner, self.realowner.weapon, 0, q);
 214                 }
 215         }
 216
 217         self.enemy = other; // don't hit the same player twice with the same bullet
 218 }
 219
 220 .void(void) W_BallisticBullet_LeaveSolid_think_save;
 221 .float W_BallisticBullet_LeaveSolid_nextthink_save;
 222 .vector W_BallisticBullet_LeaveSolid_origin;
 223 .vector W_BallisticBullet_LeaveSolid_velocity;
 224
 225 void W_BallisticBullet_LeaveSolid_think()
 226 {
 227         setorigin(self, self.W_BallisticBullet_LeaveSolid_origin);
 228         self.velocity = self.W_BallisticBullet_LeaveSolid_velocity;
 229
 230         self.think = self.W_BallisticBullet_LeaveSolid_think_save;
 231         self.nextthink = max(time, self.W_BallisticBullet_LeaveSolid_nextthink_save);
 232         self.W_BallisticBullet_LeaveSolid_think_save = SUB_Null;
 233
 234         self.flags &~= FL_ONGROUND;
 235
 236         if(self.enemy.solid == SOLID_BSP)
 237         {
 238                 float f;
 239                 f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 240                 Damage_DamageInfo(self.origin, 0, 0, 0, max(1, self.dmg_force) * normalize(self.velocity) * -f, self.projectiledeathtype, 0, self);
 241         }
 242
 243         UpdateCSQCProjectile(self);
 244 }
 245
 246 float W_BallisticBullet_LeaveSolid(entity e, vector vel, float constant)
 247 {
 248         // move the entity along its velocity until it's out of solid, then let it resume
 249
 250         float dt, dst, velfactor, v0, vs;
 251         float maxdist;
 252         float E0_m, Es_m;
 253
 254         // outside the world? forget it
 255         if(self.origin_x > world.maxs_x || self.origin_y > world.maxs_y || self.origin_z > world.maxs_z || self.origin_x < world.mins_x || self.origin_y < world.mins_y || self.origin_z < world.mins_z)
 256                 return 0;
 257
 258         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 259         v0 = vlen(vel);
 260
 261         E0_m = 0.5 * v0 * v0;
 262         maxdist = E0_m / constant;
 263         // maxdist = 0.5 * v0 * v0 / constant
 264         // dprint("max dist = ", ftos(maxdist), "\n");
 265
 266         if(maxdist <= autocvar_g_ballistics_mindistance)
 267                 return 0;
 268
 269         traceline_inverted (self.origin, self.origin + normalize(vel) * maxdist, MOVE_NORMAL, self);
 270
 271         if(trace_fraction == 1) // 1: we never got out of solid
 272                 return 0;
 273
 274         self.W_BallisticBullet_LeaveSolid_origin = trace_endpos;
 275
 276         dst = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - self.origin));
 277         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 278         Es_m = E0_m - constant * dst;
 279         if(Es_m <= 0)
 280         {
 281                 // roundoff errors got us
 282                 return 0;
 283         }
 284         vs = sqrt(2 * Es_m);
 285         velfactor = vs / v0;
 286
 287         dt = dst / (0.5 * (v0 + vs));
 288         // this is not correct, but the differential equations have no analytic
 289         // solution - and these times are very small anyway
 290         //print("dt = ", ftos(dt), "\n");
 291
 292         self.W_BallisticBullet_LeaveSolid_think_save = self.think;
 293         self.W_BallisticBullet_LeaveSolid_nextthink_save = self.nextthink;
 294         self.think = W_BallisticBullet_LeaveSolid_think;
 295         self.nextthink = time + dt;
 296
 297         vel = vel * velfactor;
 298
 299         self.velocity = '0 0 0';
 300         self.flags |= FL_ONGROUND; // prevent moving
 301         self.W_BallisticBullet_LeaveSolid_velocity = vel;
 302
 303         return 1;
 304 }
 305
 306 void W_BallisticBullet_Touch (void)
 307 {
 308         float density;
 309
 310         if(self.think == W_BallisticBullet_LeaveSolid_think) // skip this!
 311                 return;
 312
 313         PROJECTILE_TOUCH;
 314         W_BallisticBullet_Hit ();
 315
 316         // if we hit "weapclip", bail out
 317         //
 318         // rationale of this check:
 319         //
 320         // any shader that is solid, nodraw AND trans is meant to clip weapon
 321         // shots and players, but has no other effect!
 322         //
 323         // if it is not trans, it is caulk and should not have this side effect
 324         //
 325         // matching shaders:
 326         //   common/weapclip (intended)
 327         //   common/noimpact (is supposed to eat projectiles, but is erased farther above)
 328         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 329         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID)
 330         if not(trace_dphitcontents & DPCONTENTS_OPAQUE)
 331         {
 332                 remove(self);
 333                 return;
 334         }
 335
 336         density = other.ballistics_density;
 337         if(density == 0)
 338                 density = 1;
 339
 340         // go through solid!
 341         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius * density))
 342         {
 343                 remove(self);
 344                 return;
 345         }
 346
 347         self.projectiledeathtype |= HITTYPE_BOUNCE;
 348 }
 349
 350 void endFireBallisticBullet()
 351 {
 352         endzcurveparticles();
 353 }
 354
 355 entity fireBallisticBullet_trace_callback_ent;
 356 float fireBallisticBullet_trace_callback_eff;
 357 void fireBallisticBullet_trace_callback(vector start, vector hit, vector end)
 358 {
 359         if(vlen(trace_endpos - fireBallisticBullet_trace_callback_ent.origin) > 16)
 360                 zcurveparticles_from_tracetoss(fireBallisticBullet_trace_callback_eff, fireBallisticBullet_trace_callback_ent.origin, trace_endpos, fireBallisticBullet_trace_callback_ent.velocity);
 361         WarpZone_trace_forent = world;
 362         self.owner = world;
 363 }
 364
 365 void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float headshotbonus, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 366 {
 367         float lag, dt, savetime, density;
 368         entity pl, oldself;
 369         float antilagging;
 370
 371         antilagging = (autocvar_g_antilag_bullets && (pSpeed >= autocvar_g_antilag_bullets));
 372
 373         entity proj;
 374         proj = spawn();
 375         proj.classname = "bullet";
 376         proj.owner = proj.realowner = self;
 377         PROJECTILE_MAKETRIGGER(proj);
 378         if(gravityfactor > 0)
 379         {
 380                 proj.movetype = MOVETYPE_TOSS;
 381                 proj.gravity = gravityfactor;
 382         }
 383         else
 384                 proj.movetype = MOVETYPE_FLY;
 385         proj.think = SUB_Remove;
 386         proj.nextthink = time + lifetime; // min(pLifetime, vlen(world.maxs - world.mins) / pSpeed);
 387         W_SetupProjectileVelocityEx(proj, dir, v_up, pSpeed, 0, 0, spread, antilagging);
 388         proj.angles = vectoangles(proj.velocity);
 389         proj.dmg_radius = autocvar_g_ballistics_materialconstant / bulletconstant;
 390         // so: bulletconstant = bullet mass / area of bullet circle
 391         setorigin(proj, start);
 392         proj.flags = FL_PROJECTILE;
 393
 394         proj.touch = W_BallisticBullet_Touch;
 395         proj.dmg = damage;
 396         proj.dmg_edge = headshotbonus;
 397         proj.dmg_force = force;
 398         proj.projectiledeathtype = dtype;
 399
 400         proj.oldvelocity = proj.velocity;
 401
 402         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 403
 404         if(antilagging)
 405         {
 406                 float eff;
 407
 408                 if(tracereffects & EF_RED)
 409                         eff = particleeffectnum("tr_rifle");
 410                 else if(tracereffects & EF_BLUE)
 411                         eff = particleeffectnum("tr_rifle_weak");
 412                 else
 413                         eff = particleeffectnum("tr_bullet");
 414
 415                 // NOTE: this may severely throw off weapon balance
 416                 lag = ANTILAG_LATENCY(self);
 417                 if(lag < 0.001)
 418                         lag = 0;
 419                 if(clienttype(self) != CLIENTTYPE_REAL)
 420                         lag = 0;
 421                 if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 422                         lag = 0; // only do hitscan, but no antilag
 423
 424                 if(lag)
 425                         FOR_EACH_PLAYER(pl)
 426                                 if(pl != self)
 427                                         antilag_takeback(pl, time - lag);
 428
 429                 oldself = self;
 430                 self = proj;
 431
 432                 savetime = frametime;
 433                 frametime = 0.05;
 434
 435                 for(;;)
 436                 {
 437                         // DP tracetoss is stupid and always traces in 0.05s
 438                         // ticks. This makes it trace in 0.05*0.125s ticks
 439                         // instead.
 440                         vector v0;
 441                         float g0;
 442                         v0 = self.velocity;
 443                         g0 = self.gravity;
 444                         self.velocity = self.velocity * 0.125;
 445                         self.gravity *= 0.125 * 0.125;
 446                         trace_fraction = 0;
 447                         fireBallisticBullet_trace_callback_ent = self;
 448                         fireBallisticBullet_trace_callback_eff = eff;
 449                         WarpZone_TraceToss_ThroughZone(self, self.owner, world, fireBallisticBullet_trace_callback);
 450                         self.velocity = v0;
 451                         self.gravity = g0;
 452
 453                         if(trace_fraction == 1)
 454                                 break;
 455                                 // won't hit anything anytime soon (DP's
 456                                 // tracetoss does 200 tics of, here,
 457                                 // 0.05*0.125s, that is, 1.25 seconds
 458
 459                         other = trace_ent;
 460                         dt = WarpZone_tracetoss_time * 0.125; // this is only approximate!
 461                         setorigin(self, trace_endpos);
 462                         self.velocity = WarpZone_tracetoss_velocity * (1 / 0.125);
 463
 464                         if(!SUB_OwnerCheck())
 465                         {
 466                                 if(SUB_NoImpactCheck())
 467                                         break;
 468
 469                                 // hit the player
 470                                 W_BallisticBullet_Hit();
 471                         }
 472
 473                         // if we hit "weapclip", bail out
 474                         //
 475                         // rationale of this check:
 476                         //
 477                         // any shader that is solid, nodraw AND trans is meant to clip weapon
 478                         // shots and players, but has no other effect!
 479                         //
 480                         // if it is not trans, it is caulk and should not have this side effect
 481                         //
 482                         // matching shaders:
 483                         //   common/weapclip (intended)
 484                         //   common/noimpact (is supposed to eat projectiles, but is erased farther above)
 485                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 486                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID)
 487                         if not(trace_dphitcontents & DPCONTENTS_OPAQUE)
 488                                 break;
 489
 490                         density = other.ballistics_density;
 491                         if(density == 0)
 492                                 density = 1;
 493
 494                         // go through solid!
 495                         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius * density))
 496                                 break;
 497
 498                         W_BallisticBullet_LeaveSolid_think();
 499                 }
 500                 frametime = savetime;
 501                 self = oldself;
 502
 503                 if(lag)
 504                         FOR_EACH_PLAYER(pl)
 505                                 if(pl != self)
 506                                         antilag_restore(pl);
 507
 508                 remove(proj);
 509
 510                 return;
 511         }
 512
 513         if(tracereffects & EF_RED)
 514                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET_GLOWING_TRACER, TRUE);
 515         else if(tracereffects & EF_BLUE)
 516                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET_GLOWING, TRUE);
 517         else
 518                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET, TRUE);
 519 }
 520
 521 void fireBullet (vector start, vector dir, float spread, float damage, float force, float dtype, float tracer)
 522 {
 523         vector  end;
 524
 525         dir = normalize(dir + randomvec() * spread);
 526         end = start + dir * MAX_SHOT_DISTANCE;
 527         if(self.antilag_debug)
 528                 traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
 529         else
 530                 traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
 531
 532         end = trace_endpos;
 533
 534         if (pointcontents (trace_endpos) != CONTENT_SKY)
 535         {
 536                 if not (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 537                         Damage_DamageInfo(trace_endpos, damage, 0, 0, dir * max(1, force), dtype, trace_ent.species, self);
 538
 539                 Damage (trace_ent, self, self, damage, dtype, trace_endpos, dir * force);
 540         }
 541         trace_endpos = end;
 542 }
 543
 544 float W_CheckProjectileDamage(entity inflictor, entity projowner, float deathtype, float exception)
 545 {
 546         float is_from_contents = (deathtype == DEATH_SLIME || deathtype == DEATH_LAVA);
 547         float is_from_owner = (inflictor == projowner);
 548         float is_from_exception = (exception != -1);
 549
 550         //dprint(strcat("W_CheckProjectileDamage: from_contents ", ftos(is_from_contents), " : from_owner ", ftos(is_from_owner), " : exception ", strcat(ftos(is_from_exception), " (", ftos(exception), "). \n")));
 551
 552         if(autocvar_g_projectiles_damage <= -2)
 553         {
 554                 return FALSE; // no damage to projectiles at all, not even with the exceptions
 555         }
 556         else if(autocvar_g_projectiles_damage == -1)
 557         {
 558                 if(is_from_exception)
 559                         return (exception); // if exception is detected, allow it to override
 560                 else
 561                         return FALSE; // otherwise, no other damage is allowed
 562         }
 563         else if(autocvar_g_projectiles_damage == 0)
 564         {
 565                 if(is_from_exception)
 566                         return (exception); // if exception is detected, allow it to override
 567                 else if not(is_from_contents)
 568                         return FALSE; // otherwise, only allow damage from contents
 569         }
 570         else if(autocvar_g_projectiles_damage == 1)
 571         {
 572                 if(is_from_exception)
 573                         return (exception); // if exception is detected, allow it to override
 574                 else if not(is_from_contents || is_from_owner)
 575                         return FALSE; // otherwise, only allow self damage and damage from contents
 576         }
 577         else if(autocvar_g_projectiles_damage == 2) // allow any damage, but override for exceptions
 578         {
 579                 if(is_from_exception)
 580                         return (exception); // if exception is detected, allow it to override
 581         }
 582
 583         return TRUE; // if none of these return, then allow damage anyway.
 584 }
 585
 586 void W_PrepareExplosionByDamage(entity attacker, void() explode)
 587 {
 588         self.takedamage = DAMAGE_NO;
 589         self.event_damage = SUB_Null;
 590
 591         if not(g_ca)
 592         {
 593                 self.owner = attacker;
 594                 self.realowner = attacker;
 595         }
 596
 597         // do not explode NOW but in the NEXT FRAME!
 598         // because recursive calls to RadiusDamage are not allowed
 599         self.nextthink = time;
 600         self.think = explode;
 601 }