qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '0 0 -3', '0 0 -3');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 // experimental lightning gun
 188 void W_Electro_Attack3 (void)
 189 {
 190         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 191                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 192         W_SetupShot (self, TRUE, 0, "weapons/crylink_fire2.wav", cvar("g_balance_electro_primary_damage"));
 193
 194         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_electro_primary_radius"), FALSE, self, ANTILAG_LATENCY(self));
 195
 196         float i;
 197         for (i = 0; i < vlen(trace_endpos - w_shotorg)/25; ++i)
 198         {
 199                 pointparticles(particleeffectnum("electro_lightning"), w_shotorg + (i / floor(vlen(w_shotorg - trace_endpos)/25)) * (trace_endpos - w_shotorg), w_shotdir * 1000, 1);
 200         }
 201
 202         if (trace_fraction < 1)
 203                 Damage(trace_ent, self, self, cvar("g_balance_electro_primary_damage"), WEP_ELECTRO | HITTYPE_SECONDARY, trace_endpos, cvar("g_balance_electro_primary_force") * w_shotdir);
 204 }
 205
 206 void spawnfunc_weapon_electro (void)
 207 {
 208         weapon_defaultspawnfunc(WEP_ELECTRO);
 209 }
 210
 211 void w_electro_checkattack()
 212 {
 213         if(self.electro_count > 1)
 214         if(self.BUTTON_ATCK2)
 215         if(weapon_prepareattack(1, -1))
 216         {
 217                 W_Electro_Attack2();
 218                 self.electro_count -= 1;
 219                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 220                 return;
 221         }
 222
 223         w_ready();
 224 }
 225
 226 .float bot_secondary_electromooth;
 227 float w_electro(float req)
 228 {
 229         if (req == WR_AIM)
 230         {
 231                 self.BUTTON_ATCK=FALSE;
 232                 self.BUTTON_ATCK2=FALSE;
 233                 if(vlen(self.origin-self.enemy.origin) > 1000)
 234                         self.bot_secondary_electromooth = 0;
 235                 if(self.bot_secondary_electromooth == 0)
 236                 {
 237                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 238                         {
 239                                 self.BUTTON_ATCK = TRUE;
 240                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 241                         }
 242                 }
 243                 else
 244                 {
 245                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 246                         {
 247                                 self.BUTTON_ATCK2 = TRUE;
 248                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 249                         }
 250                 }
 251         }
 252         else if (req == WR_THINK)
 253         {
 254                 if (self.BUTTON_ATCK)
 255                 if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 256                 {
 257                         if(cvar("g_balance_electro_lightning"))
 258                                 W_Electro_Attack3();
 259                         else
 260                                 W_Electro_Attack();
 261                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 262                 }
 263                 if (self.BUTTON_ATCK2)
 264                 if (time >= self.electro_secondarytime)
 265                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 266                 {
 267                         W_Electro_Attack2();
 268                         self.electro_count = cvar("g_balance_electro_secondary_count");
 269                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 270                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 271                 }
 272         }
 273         else if (req == WR_PRECACHE)
 274         {
 275                 precache_model ("models/weapons/g_electro.md3");
 276                 precache_model ("models/weapons/v_electro.md3");
 277                 precache_model ("models/weapons/h_electro.iqm");
 278                 precache_sound ("weapons/electro_bounce.wav");
 279                 precache_sound ("weapons/electro_fire.wav");
 280                 precache_sound ("weapons/electro_fire2.wav");
 281                 precache_sound ("weapons/electro_impact.wav");
 282                 precache_sound ("weapons/electro_impact_combo.wav");
 283                 if(cvar("g_balance_electro_lightning"))
 284                         precache_sound ("weapons/crylink_fire2.wav");
 285         }
 286         else if (req == WR_SETUP)
 287                 weapon_setup(WEP_ELECTRO);
 288         else if (req == WR_CHECKAMMO1)
 289                 return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 290         else if (req == WR_CHECKAMMO2)
 291                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 292         else if (req == WR_RESETPLAYER)
 293         {
 294                 self.electro_secondarytime = time;
 295         }
 296         return TRUE;
 297 };
 298 #endif
 299 #ifdef CSQC
 300 float w_electro(float req)
 301 {
 302         if(req == WR_IMPACTEFFECT)
 303         {
 304                 vector org2;
 305                 org2 = w_org + w_backoff * 6;
 306                 if(w_deathtype & HITTYPE_SECONDARY)
 307                 {
 308                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 309                         if(!w_issilent)
 310                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 311                 }
 312                 else
 313                 {
 314                         if(w_deathtype & HITTYPE_BOUNCE)
 315                         {
 316                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 317                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 318                                 if(!w_issilent)
 319                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 320                         }
 321                         else
 322                         {
 323                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 324                                 if(!w_issilent)
 325                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 326                         }
 327                 }
 328         }
 329         else if(req == WR_PRECACHE)
 330         {
 331                 precache_sound("weapons/electro_impact.wav");
 332                 precache_sound("weapons/electro_impact_combo.wav");
 333         }
 334         else if (req == WR_SUICIDEMESSAGE)
 335         {
 336                 if(w_deathtype & HITTYPE_SECONDARY)
 337                         w_deathtypestring = "could not remember where they put plasma";
 338                 else
 339                         w_deathtypestring = "played with plasma";
 340         }
 341         else if (req == WR_KILLMESSAGE)
 342         {
 343                 if(w_deathtype & HITTYPE_SECONDARY)
 344                 {
 345                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 346                                 w_deathtypestring = "just noticed #'s blue ball";
 347                         else // unchecked: BOUNCE
 348                                 w_deathtypestring = "got in touch with #'s blue ball";
 349                 }
 350                 else
 351                 {
 352                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 353                                 w_deathtypestring = "felt the electrifying air of #'s combo";
 354                         else if(w_deathtype & HITTYPE_SPLASH)
 355                                 w_deathtypestring = "got too close to #'s blue beam";
 356                         else
 357                                 w_deathtypestring = "was blasted by #'s blue beam";
 358                 }
 359         }
 360         return TRUE;
 361 }
 362 #endif
 363 #endif